Mastermind Algorthym wont work - GameCreators Forum

Author

Message

fubarpk

Retired Moderator

19

Years of Service

User Offline

Joined: 11th Jan 2005

Playing: AGK is my friend

Posted: 22nd Jan 2015 08:10 Edited at: 12th Apr 2018 20:56

Link

Below is a snippet of my algorythm for working out the black and white pieces on a mastermind board. Spritenum holds the difficulty selected. wCount white markers bCount black markers.

now if i use the test data
1,2,3,4 for the 4 correct solutions
1,5,5,1 shows 1 black 1 white
1,2,5,5 shows 2 black as it should
3,3,6,6 shows 1 white
1,1,1,1 shows 1 black 1 white

I dont beleive the exit is working any help would be greatly appreciated

+ Code Snippet

function checkGuess (spriteNum as integer,cols as integer,rows as integer)
wCount=0:bCount=0
dim flag[maxcol]
for t=1 to spriteNum:flag[t]=0:next t
	
for slot = 1 to spriteNum 
         
        if (guess[slot] = comp[slot])  
            inc bCount
        else   
            
            for s = 1 to spriteNum  
                if  (s <> slot) and (guess[slot] = comp[s]) and (flag[s] <> 1)
						inc wCount  
						flag[s]=1
						exit
                endif       
			next s
				
        endif
next slot
         	

if (bCount+wCount)>0 then putMarker(bCount,wCount,(cols*32),rows * 32)
endfunction

</div>

fubar

Back to top

Profile PM Email Website

paulrobson

9

Years of Service

User Offline

Joined: 22nd Nov 2014

Location: Norfolk, England

Posted: 22nd Jan 2015 09:28

Link

Your basic idea is fine (I used to write Mastermind games on a TI-57 programmable calculator in my youth ......).

I think the problem is you do not set flag[slot] to used when you get a black counter. So, in your 1,5,5,1 example, when it does the fourth digit (the second 1) the for loop in the else clause picks up the first 1 (flag[1]) as a white match because it has never been marked 'used'.

I would be inclined to simplify it by having 2 loops - one that tests for blacks then one that tests for whites

Back to top

Profile PM Email

fubarpk

Retired Moderator

19

Years of Service

User Offline

Joined: 11th Jan 2005

Playing: AGK is my friend

Posted: 22nd Jan 2015 13:05

Link

Thanks thats it all fixed now Paulrobson thanks for your help

fubar

Back to top

Profile PM Email Website

fubarpk

Retired Moderator

19

Years of Service

User Offline

Joined: 11th Jan 2005

Playing: AGK is my friend

Posted: 22nd Jan 2015 13:21 Edited at: 12th Apr 2018 20:56

Link

Well i thought i fixed it till i supplied the following test data
answer 1,2,3,4
test data
1,1,1,1 black 1 no white
2,2,2,2 black 1 white 1
3,3,3,3 black 1 white 1

+ Code Snippet

function checkGuess (spriteNum as integer,cols as integer,rows as integer)
wCount=0:bCount=0
dim flag[maxcol]
for t=1 to spriteNum:flag[t]=0:next t
	
for slot = 1 to spriteNum 
         
        if (guess[slot] = comp[slot])  
            inc bCount
            flag[slot]=1
        else   
            
        for s = 1 to spriteNum  
           if  s <> slot and guess[slot] = comp[s] and flag[s] <> 1
		inc wCount  
		flag[s]=1
		exit
           endif       
	next s
				
        endif
next slot
         	
if bCount =spriteNum 
	gosub youWon
else
	if (bCount+wCount)>0 then putMarker(bCount,wCount,(cols*32),rows * 32)
endif
endfunction

but all original test data worked

</div>

fubar

Back to top

Profile PM Email Website

Scraggle

Moderator

20

Years of Service

User Offline

Joined: 10th Jul 2003

Location: Yorkshire

Posted: 23rd Jan 2015 15:40 Edited at: 23rd Jan 2015 15:41

Link

You need to flag both the target pegs and the guesses so that you can discount both from the checks.

Below is a complete mastermind game. There is no user input, just random guesses that continue whilst you click the mouse but the checkGuess() function should be all you need.

// Project: test 
// Created: 2015-01-23

// set window properties
SetWindowTitle( "test" )
SetWindowSize( 400, 200, 0 )

// set display properties
SetVirtualResolution( 400, 200 )
SetOrientationAllowed( 1, 1, 1, 1 )
SetPrintSize(16)

dim target[3]
dim guess[3]
dim flagG[3]
dim flagT[3]
global black as integer
global white as integer

do
	createTarget()
	repeat
		getGuess()
		checkGuess()
		repeat 
			printTarget()
			win = printResults()
			sync()
		until GetPointerPressed()
	until win
loop

function createTarget()
	for k = 0 to 3
		//target[k] = random(1, 6)
		target[k] = k+1
	next k
endfunction

function getGuess()
	for k = 0 to 3
		guess[k] = random(1, 6)
	next k
endfunction

function checkGuess()
	
	black = 0
	white = 0
	for slot = 0 to 3
		flagG[slot] = 0
		flagT[slot] = 0
		if guess[slot] = target[slot]
			flagG[slot] = 1
			flagT[slot] = 1
			inc black
		endif
	next slot
	
	for g = 0 to 3
		if flagG[g] = 0
			for t = 0 to 3
				if flagT[t] = 0
					if guess[g] = target[t]
						flagT[t] = 1
						inc white
					endif
				endif
			next t		
		endif
	next g
	
endfunction

function printTarget()
	for k = 0 to 3
		printC( str(target[k]) + ", " )
	next k
	Print( "Target" )
	Print( " " )
endfunction

function printResults()
	count = 0 
	
	for k = 0 to 3
		printC( str(guess[k]) + ", " )
	next k
	Print( "Guess" )
	Print( "" )
	print( "Black: "+str(black)+", White: " + str(white) )
	
	if black = 4 
		print( "WIN!" )
		exitfunction 1
	else 
		print( "No Win" )
	endif
endfunction 0

+ Code Snippet

// Project: test 
// Created: 2015-01-23

// set window properties
SetWindowTitle( "test" )
SetWindowSize( 400, 200, 0 )

// set display properties
SetVirtualResolution( 400, 200 )
SetOrientationAllowed( 1, 1, 1, 1 )
SetPrintSize(16)

dim target[3]
dim guess[3]
dim flagG[3]
dim flagT[3]
global black as integer
global white as integer

do
	createTarget()
	repeat
		getGuess()
		checkGuess()
		repeat 
			printTarget()
			win = printResults()
			sync()
		until GetPointerPressed()
	until win
loop



function createTarget()
	for k = 0 to 3
		//target[k] = random(1, 6)
		target[k] = k+1
	next k
endfunction

function getGuess()
	for k = 0 to 3
		guess[k] = random(1, 6)
	next k
endfunction

function checkGuess()
	
	black = 0
	white = 0
	for slot = 0 to 3
		flagG[slot] = 0
		flagT[slot] = 0
		if guess[slot] = target[slot]
			flagG[slot] = 1
			flagT[slot] = 1
			inc black
		endif
	next slot
	
	for g = 0 to 3
		if flagG[g] = 0
			for t = 0 to 3
				if flagT[t] = 0
					if guess[g] = target[t]
						flagT[t] = 1
						inc white
					endif
				endif
			next t		
		endif
	next g
	
endfunction

function printTarget()
	for k = 0 to 3
		printC( str(target[k]) + ", " )
	next k
	Print( "Target" )
	Print( " " )
endfunction

function printResults()
	count = 0 
	
	for k = 0 to 3
		printC( str(guess[k]) + ", " )
	next k
	Print( "Guess" )
	Print( "" )
	print( "Black: "+str(black)+", White: " + str(white) )
	
	if black = 4 
		print( "WIN!" )
		exitfunction 1
	else 
		print( "No Win" )
	endif
endfunction 0

AGK V2 user - Tier 1 & 2

Back to top

Profile PM Email

Sorry your browser is not supported!

AppGameKit Classic Chat / Mastermind Algorthym wont work