---

This is the second installment of my bitmap fonts. Like the first they are FREE to use however you wish .... enjoy

Note This pack was originally posted in the DarkBASIC Professional forum but it slipped off the page before many people got to see it. So, I have reposted it here, which is where it should have been in the first place!


Pack 1 used 32 x 32 fonts.
Pack 2 uses 64 x 64 fonts.

Load Bitmap and cut images - keeping transparency:
+ Code Snippet

`*********************************
`       LOAD BITMAP FONT
`*********************************
Function LoadBMfont(FileName as string,FontImageNumber)
	
	load image FileName,FontImageNumber,1
	Font = 32
	For y = 0 to 9
		for x = 0 to 9
			GetImage( FontImageNumber, Font + FontImageNumber, x*64, y*64, 64, 64 )
			inc Font
		next x
	next y
`	Delete Image FontImageNumber
	
endfunction


`*********************************
`   GET IMAGE WITH TRANSPARENCY
`*********************************
function GetImage(Image1,NewImage,Xstart,Ystart,Xsize as dword,Ysize as dword)
	
	`Find unused memblocks
	Memblock1 = 1
	repeat
		inc Memblock1
	until memblock exist(Memblock1) = 0
	NewMemblock = 2
	repeat
		inc NewMemblock
	until memblock exist(NewMemblock) = 0
	
	`Set up variables
	Local Width as Dword
	Local Height as Dword
	Local Depth as Dword
	Local Red as Byte
	Local Green as Byte
	Local Blue as Byte
	Local Alpha as Byte
	
	`Do it!
	make memblock from image Memblock1,Image1
	Width = memblock dword(Memblock1,0)
	Height = memblock dword(Memblock1,4)
	Depth = memblock dword(Memblock1,8)
	make memblock NewMemblock,(Width*Height)+12
	
	Write memblock Dword NewMemblock,0,Xsize
	Write memblock Dword NewMemblock,4,Ysize
	Write memblock Dword NewMemblock,8,Depth
	
	Position = (Width  * (Ystart)*4) + (Xstart*4) + 12
	NewPosition = 12
	
	for y = 1 to Ysize
		for x = 1 to Xsize 
	   
	      Blue = memblock byte(Memblock1,Position)
	      Green = memblock byte(Memblock1,Position+1)
	      Red = memblock byte(Memblock1,Position+2)
	      Alpha = memblock byte(Memblock1, Position+3)
	      
	      write memblock byte NewMemblock,NewPosition,Blue
	      write memblock byte NewMemblock,NewPosition+1,Green
	      write memblock byte NewMemblock,NewPosition+2,Red
	      write memblock byte NewMemblock,NewPosition+3,Alpha
	      
	      inc Position,4
	      Inc NewPosition,4
	      
		next x
		inc Position , (width*4) - (Xsize*4)
	next y
	
	make image from memblock NewImage,NewMemblock
	delete memblock Memblock1
	delete memblock NewMemblock
	
endfunction

Trim the transparent edges away from the fonts:
+ Code Snippet

`Put the 2 DIM commands at the top of you code
Dim BMleft(127)
Dim BMwidth(127)
'*********************************
`       TRIM BITMAP FONT
`*********************************

Function TrimBMFont(FontNo)

	Local BlankColumn as boolean
	Local Alpha as byte
	Local Chr as integer
        Local FontWidth as integer = 64
        Local FontHeight as integer = 64
		
	For Chr = 33 to 126
		Make Memblock From Image 1 , FontNo + Chr
		for x = 1 to FontWidth
			BlankColumn = Yes
			for y = 1 to FontHeight - 1
				
				if BMleft(Chr) = 0
					Position = (y * FontWidth * 4) + (x * 4) + 15
					Alpha = memblock byte(1 , Position)

					if Alpha > 0
						BlankColumn = No
						y = FontHeight - 1
					endif
				endif
				
			next y
			
			if BlankColumn = No
				BMleft(Chr) = x
				x = FontWidth
			endif
			
		next x
		
		for x = FontWidth - 1 to 1 step - 1
			BlankColumn = Yes
			for y = 1 to FontHeight - 1
				
				if BMwidth(Chr) = 0
					Position = (y * FontWidth * 4) + (x * 4) + 15
					Alpha = memblock byte(1 , Position)

					if Alpha > 0
						BlankColumn = No
						y = FontHeight
					endif
				endif
				
			next y
			
			if BlankColumn = No
				BMwidth(Chr) = x - BMleft(Chr)
				x = 1
			endif
			
		next x
		delete memblock 1
		
	next Chr

	BMleft(32) = 0
	BMwidth(32) = FontWidth / 2
	
endfunction

Display the font:
+ Code Snippet

`*********************************
`      DISPLAY BITMAP FONT
`*********************************

Function BMFont(X,Y,S as string,ImageNo,SpriteNo,Kern)
	
	
	for k = 1 to len(S)
		Chr = asc(mid$(S,k))
		
		if k > 1
			sprite SpriteNo + k ,NewX - BMleft(Chr) ,Y ,ImageNo + Chr
			NewX = (NewX) + BMwidth(Chr) + Kern
		else
			sprite SpriteNo + k ,X - BMleft(Chr) ,Y ,ImageNo + Chr
			NewX = X + BMwidth(Chr) + Kern
		endif

	next k

endfunction

Click the download button to download the PNG files with transparent backgrounds.


WireFrame


Sketched


Big Cheese


Dark Castle


Under Water


Rustic Logs


PacMania


Old Rope


Football Crazy


Fire 2


Evil


BloodBath 2


Bamboo

---

Scraggle, it's people like you that make the Internet worthwile! Many thanks!

---

Lol, these rule! Thanks, I like the sketched one!

---

Hmm the "Big Cheese" could be interesting for a Star-Wars style introduction if it was flipped a little ...

---

Nice, that blue Sketched one is way cool, i might want to use that for somthing. I also like the Dark Castle, and Evil ones. Nice Work

---

These are cool! And universally usefull, too.

---

Awesome! A very nice spread of EVIL in this pack. Thanks!!

---

Scraggle - I love you. Can I have you babies? These are fantastic! Are there any licensing implications?

---

too fun for my project :\ oho wells.

I never make anything vibrant . they are nice fonts though! really great work

---

@NT Absolutely not! Thank you and no.

or, the long version ... I have three cats, that's all the babies I need thanks. I'm glad you like them There are no licensing implications at all. Do with them whatever the hell you like. If you want to mention me that would be cool, if you don't want to then that's fine too.

Did you see my other free stuff?
Scraggle's Bitmap Fonts Pack 1
Scraggle's Bitmap Fonts Pack 2
Scraggle's Bitmap Fonts Pack 3
Scraggle's Planets
Scraggle's Nebulae
Scraggle's Stars/Suns

---

Looks awesome man!

Does anyone have the functions above in C++ for DGSDK? I do not have time to convert, but Id love to use them.

---

Awesomeness

Whats the kern for?


EDIT: How do I make the font smaller?

---

The Kern value is the gap between characters. It is often neccessary to have this as a negative value if you want the letters very close together.

---

[Update]

I've updated the 'Football Crazy' font by making the football white instead of transparent, I think it looks better but the original is still in the main download if you prefer it like that.

Click Download to get the file as a .PNG file with a transparent background.

---

P.S. (again) how do I make your fonts smaller? Just scale the image down?

---

That would do it.
You would have to change the variables in the cut image function to match though.