---

We're now up to 33 plug-ins in this pack - latest release info can be found HERE (Release 20120527).
Download links can be found at the bottom of this post.

In addition, I've uploaded the help files to my website, so you can browse through all of the commands, so you can see what you'll be getting without having to install the whole thing first. Just click here to see them.

01 - Memory Banks - memblocks, with a few new options added
02 - Basic Timing - Metronome type ticking, and hiresolution timing.
03 - Mutexes - system level synchronisation between processes (primarily for use with shared-memory banks)
04 - Raw Memory & String Allocation - low level stuff only of use to masochists
05 - Find Free ... - locate free images, objects ... everything really
06 - Error message control - Take a little control over DBPro error messages, or even trigger your own (with a line number!)
07 - General functions - min/max, plus a few numeric functions that are missing from DBPro
08 - Random numbers - Many different random number generators.
09 - Functions and commands that should have been in DBPro from the start.
10 - Logging - Output logging info from your app, in nicely formatted html or rtf if you want to.
11 - Console window, with colours
12 - Limb information and updates
13 - Desktop & window info + manipulation
14 - Adhoc 'doesn't fit anywhere else' commands
15 - Extra WAIT commands - including system-friendly versions that use no system time
16 - Strings - A comprehensive set of string functions.
17 - 64 bit bitset manipulation - DBPro binary functions don't work with double integers, these functions do
18 - Create custom objects from nothing and get information about the state of objects.
19 - List and group objects
20 - Function pointers
21 - Zone commands, transferred & updated from the original utility plug-in.
22 - File I/O
23 - Colour conversion
24 - System Folders
25 - Windows shortcut files
26 - Syncs and callbacks
27 - Hashing (and encryption in the future)
28 - Networking for IP and UDP (tutorial zip file)
29 - Arrays - Information from arrays, plus sorting, clearing etc.
30 - Basic 2D Commands
31 - String lookup tables (with load/save of ini files).
32 - Vector & Matrix maths - Some commands and functions to make using the 3d maths commands a little easier.
33 - Redirect drawing operations to images


The release is a zip file for easy installation - just let winzip extract it to your DBPro installation folder and it'll all go into the right place.

DBPro 7.1 download and later : http://forumfiles.thegamecreators.com/download/2355306
DBPro 7.0 download and prior : http://forumfiles.thegamecreators.com/download/1599357 (No longer updated)

If the DLLs fail to load, then you may need the files in the following download:
VC++ redistributables : http://forumfiles.thegamecreators.com/?i=959271

- For 32 bit systems, place the contents in c:\Windows\System32
- For 64 bit systems, place the contents in c:\Windows\SysWOW64
- Alternatively, if you are uncomfortable placing these files in those folders, or if you don't have the correct permissions to do so, place the files in the same directory as your executable.


If you have any of the original Matrix1Utility, Matrix1Array or Matrix1Extend1 plug-ins, then you'll need to delete the DLL's and the INI files for them before starting up DBPro.

Please also note: I have not ported any of this code to GDK, and these plug-ins will not work with GDK whatsoever

Warranty: None, for any purpose whatsoever.
Conditions of use: None.
Royalties required: None.

---

Memory banks - expanded memblocks.

For any kind of manipulation of data, you'll soon start to wonder how you did without them. In addition to the standard ability to write different basic data types to the banks, you can also:

- write double integers, double floats and strings too
- copy blocks of data between banks or even memblocks
- share memory between different programs
- map a file into memory (effectively load a file into a bank, but any changes you make are reflected in the file).

A long while ago, I wrote a function that would allow you to write a DBPro bitmap to a bmp file using standard file functions. I've written a small program that uses that function, but also does the same thing using a mapped file - run it yourself to see the speed increase:

+ Code Snippet

   #constant TEST_WIDTH    300
   #constant TEST_HEIGHT   400
   #constant SAVEFILE      ".\test.bmp"

   sync on
   sync rate 0

` ************************************
` **** Create a randomly filled bitmap
` ************************************
   create bitmap 1, TEST_WIDTH, TEST_HEIGHT

` Fill with coloured squares
   for b=1 to 40
      x = rnd(TEST_WIDTH - 1)
      y = rnd(TEST_HEIGHT - 1)
      wx = rnd(TEST_WIDTH - 1 - x)
      wy = rnd(TEST_HEIGHT - 1 - y)
      c = rgb(rnd(4)*64, rnd(4)*64, rnd(4*64))
      box x, y, x + wx, y + wy, c, c, c, c
   next b

` Get a copy for comparison later
   get image 1, 0, 0, TEST_WIDTH, TEST_HEIGHT, 1

   set current bitmap 0

` *******************************************
` **** Run the 'file' version of the function
` *******************************************
   Start = timer()
   SaveBitmapFile(SAVEFILE, 1)
   Finish = timer()

` load the saved image
   load image SAVEFILE, 2, 1

` Place the original and the saved version side by side
   paste image 1, 0, 0
   paste image 2, TEST_WIDTH + 8, 0

` Show the timings
   set cursor 0, TEST_HEIGHT + 8
   print "File commands - Elapsed time : "; Finish - Start

   sync off
   wait key
   sync on
   cls

` *******************************************
` **** Run the 'bank' version of the function
` *******************************************
   Start = timer()
   SaveBitmapBank(SAVEFILE, 1)
   Finish = timer()

` load the saved image
   load image SAVEFILE, 2, 1

` Place the original and the saved version side by side
   paste image 1, 0, 0
   paste image 2, TEST_WIDTH + 8, 0

` Show the timings
   set cursor 0, TEST_HEIGHT + 8
   print "Bank commands - Elapsed time : "; Finish - Start

   sync off
   wait key

   end

` **********************************************
` **** The original file version of the function
` **********************************************
   function SaveBitmapFile(File as string, Bmp as integer)
      local x as integer
      local y as integer
      local Colour as dword

      local OldBmp as integer
      local Width as integer
      local Height as integer
      local PadSize as integer

   ` Save the current bitmap and switch to the one that needs saving
      OldBmp=current bitmap()
      set current bitmap Bmp

      Width=bitmap width()
      Height=bitmap height()

   ` Calculate the padding required at the end of each line
      PadSize=4-((Width*3) mod 4)
      if PadSize=4 then PadSize=0

   ` Clear the file if it already exists
      if file exist(File) then delete file File

   ` Open the file
      open to write 1, File

   ` Write the bitmap header
      write byte 1, asc("B")
      write byte 1, asc("M")
      write long 1, 26+( ((Width*3)+PadSize) * Height )
      write word 1, 0
      write word 1, 0
      write long 1, 26

      write long 1, 12
      write word 1, Width
      write word 1, Height
      write word 1, 1
      write word 1, 24

      Width=Width-1
      Height=Height-1

      lock pixels

   ` Copy the bitmap from the bottom up to the file including padding at
   ` the end of the line when required.
      for y=Height to 0 step -1
         for x=0 to Width
            Colour=point(x,y)
            write byte 1, Colour
            write byte 1, Colour >> 8
            write byte 1, Colour >> 16
         next x
         if PadSize > 0
            for x=1 to PadSize
               write byte 1,0
            next x
         endif
      next y

      unlock pixels

   ` Close the file and return to the original bitmap
      close file 1
      set current bitmap OldBmp
   endfunction


` *****************************************
` **** The new bank version of the function
` *****************************************
   function SaveBitmapBank(File as string, Bmp as integer)
      local x as integer
      local y as integer
      local Colour as dword

      local OldBmp as integer
      local Width as integer
      local Height as integer
      local PadSize as integer

   ` Save the current bitmap and switch to the one that needs saving
      OldBmp=current bitmap()
      set current bitmap Bmp

      Width=bitmap width()
      Height=bitmap height()

   ` Calculate the padding required at the end of each line
      PadSize=4-((Width*3) mod 4)
      if PadSize=4 then PadSize=0

   ` Clear the file if it already exists
      if file exist(File) then delete file File

   ` Map the file to the bank, setting the minimum size to the
   ` size of file required (header size + data size)
      map file to bank File, 1, 26+( ((Width*3)+PadSize) * Height )

   ` Write the bitmap header
      write bank string    1, 0, "BM", 2
      write bank integer   1, 2, get bank size(1)
      write bank word      1, 6, 0
      write bank word      1, 8, 0
      write bank integer   1, 10, 26
      write bank integer   1, 14, 12
      write bank word      1, 18, Width
      write bank word      1, 20, Height
      write bank word      1, 22, 1
      write bank word      1, 24, 24

   ` Copy the bitmap from the bottom up to the bank including padding at
   ` the end of the line when required.
      lock pixels

      Pos = 26
      for y=Height-1 to 0 step -1
         for x=0 to Width-1
            Colour=point(x,y)
            write bank byte 1, Pos, Colour
            write bank byte 1, Pos+1, (Colour >> 8)
            write bank byte 1, Pos+2, (Colour >> 16)
            inc Pos, 3
         next x
         if PadSize > 0
            for x=1 to PadSize
               write bank byte 1, Pos, 0
               inc Pos
            next x
         endif
      next y

      unlock pixels

   ` Delete the bank and return to the original bitmap
      delete bank 1
      set current bitmap OldBmp
   endfunction

---

Timing - simple tickers

There's not much in this plugin really. There's the standard hi-resolution timer that was a part of the original utility plugin, and that works in the same way, and now there is also a regular ticking timer that ticks as often as you tell it.

Here's a simple example with two tickers - one is used to drive the flashing cursor, and the other is driving the tenth-of-a-second timer

+ Code Snippet

type Time_t
   Minutes as integer
   Seconds as integer
   Frame as integer
endtype

global Stopwatch as Time_t
global StopwatchDisplay as string
StopwatchDisplay = "00:00:00"

sync on
sync rate 0
hide mouse

make ticker 1, 500   : ` Flashing cursor, every half-second
make ticker 2, 100   : ` Stopwatch, every 10th of a second

DrawBlock = 0

while spacekey() = 0
   cls

   text 0, 0, StopwatchDisplay

   x = mousex()
   y = mousey()

   if DrawBlock then box x, y, x+16, y+16

   while ticker(1) = 1     : ` Time to flip the cursor
      DrawBlock = 1 - DrawBlock
   endwhile

   while ticker(2) = 1     : ` Time to update the clock
      UpdateTimer()
   endwhile

   sync
endwhile

delete ticker 1
delete ticker 2

end

function UpdateTimer()
   inc Stopwatch.Frame
   if Stopwatch.Frame = 10
      Stopwatch.Frame = 0
      inc Stopwatch.Seconds
      if Stopwatch.Seconds = 60
         Stopwatch.Seconds = 0
         inc Stopwatch.Minutes
      endif
   endif

   StopwatchDisplay = right$(str$(Stopwatch.Minutes + 100), 2) + ":" + right$(str$(Stopwatch.Seconds + 100), 2) + "." + str$(Stopwatch.Frame)
endfunction

---

Error messages

There's not much to say here really (despite this being a real ... hard nut to crack) - error messages, with line numbers. You can trigger your own messages, change the title on DBPro error messages, even trigger messages under certain conditions. Here are a few examples.

As basic as it gets:
+ Code Snippet

report error "Something's gone wrong", "Simple example"

How about this:
+ Code Snippet

raise error 502, "This is my error title"

Error 502 is 'image does not exist' - the numbers can be found in C:\Program Files\Dark Basic Software\Dark Basic Professional\Compiler\lang\english\Errors.txt in the RUNTIME section

Setting a 'reasonable' title for a DBPro error:
+ Code Snippet

set default error title "Whoops"
delete image 1

Ok, so we may differ in our opinion of 'reasonable'

Finally, error under certain circumstances - in the C world this is called an assertion, in which the error does not occur if the condition is true.
+ Code Snippet

`#constant assert rem

for i = 1 to 20 step 2
   MyFunction(i)
next i
end

function MyFunction(Value as integer)
   assert error Value < 10, "Value not < 10 (" + str$(Value) + ")", "MyFunction"

   ` Do something with the value
endfunction

I'll post a few more things tomorrow

---

Here's a full program that I wrote to automatically generate the help and keyword files for all of these plugins, and to demonstrate their use. It mostly uses the banks and string plugins and features:

- Correctly splitting up the command line arguments when dropping files onto the exe
- Reading/writing whole files in a single set of operations
- Reading resource strings from a DLL (used to get all of the commands for the keyword files)
- Complex and fast string manipulation

There are also some little 'bonus' routines in there for dealing with filenames and directories.

---

Here's another one for banks ... they really are my favourite!

In last months newsletter, Rich included a section on the Winch's site that includes details of the makeup of a DBPro executable or .PCK file. I decided that would be a good test of banks, so I wrote the following program that will decipher the exe/pck, list all of the files included within it, and will then explode it out into the separate files.

There's no reverse process ATM, but that may come in the future.

---

The logging plugin might look a little inpenetrable at first sight, so here's a small example program that writes out a html format log file.

You can also see the parameter substitution it provides when it's writing log file types 3 and 4.

+ Code Snippet

Logfile$="Testlog.html"

` Open the log file
if file exist(Logfile$) then delete file Logfile$
OPEN LOG Logfile$, 1

` Enable logging against a tag even if the tag is unknown
SET LOG UNKNOWN TAG 1

` Set up the severity tags
SET LOG TAG 0, "", "<br>"
SET LOG TAG 1, "<font color=#0000ff>", "</font><br>"
SET LOG TAG 2, "<font color=#808080>", "</font><br>"
SET LOG TAG 3, "<font color=#ff8000>", "</font><br>"
SET LOG TAG 4, "<font color=#ff0000>", "</font><br>"

` Write out a html header
WRITELN LOG "<html><body>"

` Write out log details with various parameters
WRITELN LOG 0, "Started logging at %s %s", get date$(), get time$()
WRITELN LOG 0, ""
WRITELN LOG 1, "Severity 1"
WRITELN LOG 2, "Severity 2"
WRITELN LOG 3, "Severity %d", 3
WRITELN LOG 4, "%s %d", "Severity", 4

` Write out a html trailer
WRITELN LOG "</body></html>"

` done with the log
CLOSE LOG

---

Only one suggestion - in part 13, the get display width() command (and others, I assume) interfere with the same command from the DBPro Enhancements Pack. Maybe add a prefix or something?

Other than that, though, this looks awesome!

---

Thanks for pointing that out - I'll change the command and repost it later today

---

Nice little package I'll be replacing my own debug function with your logging, much neater.

The GET DISPLAY WIDTH() is a throwback to the last version. I ventured into the world of string tables for the first tme to edit this last time.

---

Am I right in saying your new ABS command completely takes precedence over existing ABS command. Surprised not to see some sort of duplicate command error that I've seen in the past.

Anyway your ABS command is SO much faster than built in ABS command which is renowned for being so slow so I'm happy.

Too busy to try rest of commands, must get back to work.

---

His string commands are wicked fast on slower machines. Been waiting for this for a bit

---

@Spooky,
Lee provided a ABS command for floating point values - that's why it's slow with integers as it has to convert integer to float, then float back to integer for the result. I've just provided an integer-specific version. It's OK to provide overloaded versions of existing commands and functions in plugins as long as their signatures are different.

@Bmad6 & Batvink,
I'll probably just drop the 'GET' at the start of the name to remove the clash.

---

hmmm... when i run the program i always get a
+ Code Snippet

Cannot Find DLL 
MSVCR71.dll

Then it lists several locations one including autodesk which doesnt make sense, because I don't have any autodesk products.

---

Ah, the old 'runtime library' problem huh?

Here they are for use with the plugins - Just drop them into \Windows\System32 - If you already have these files installed in your machine, do not allow them to overwrite existing ones.

@Everyone else,
I've replaced the zip in the first post with the modified '13' DLL - I've simply removed 'GET' from the start of all of the functions. Just follow the install instructions again and allow the new files to overwrite existing files.

---

This is a really cool collection of commands. Thanks!

---

Thank you.

Here's a simple example of using the bitset commands.

The code that a lot of people use to detect a mouseclick is usually a little ... clunky (using bit manipulation) ... or even plain wrong (using straight comparison).

Instead, you can just treat the value of MOUSECLICK as a bitset, and interrogate the values by key number:
+ Code Snippet

sync on

do
   cls
   for i = 1 to 4
      if bit get(mouseclick(), i-1) then print "Button "; i; " pressed"
   next
   sync
loop

There are other uses too. For instance, in a piece of code that I'm performance testing right now, I can enable and disable various bits of code depending on which bits are set, and I can do it even when the code is running.

Here's a little taster of how that works:
+ Code Snippet

sync on
sync rate 0

global Enabled as integer ` Only really need a 16 bit word, but integers are slightly faster
Enabled = 0xffffffff ` Initialise to all bits are set

do
   cls

   if keystate(59) = 1 ` F1, enables the mode change
      Enabled = bit set(Enabled, 0)
   else
      if bit get(Enabled, 0) ` If the mode change is enabled
         S = scancode()      ` get the scancode
         if S >= 2 and S <= 10 ` Scancodes for the keys 1 to 9
            Enabled = bit flip(Enabled, S-1)
            Enabled = bit clear(Enabled, 0)
         endif
      endif
   endif

   print screen fps()

   if bit get(Enabled, 1)
      print "Code section 1 active"
      wait 5
   else
      print "Code section 1 inactive"
   endif

   if bit get(Enabled, 2)
      print "Code section 2 active"
      wait 5
   else
      print "Code section 2 inactive"
   endif

   if bit get(Enabled, 3)
      print "Code section 3 active"
      wait 5
   else
      print "Code section 3 inactive"
   endif

   if bit get(Enabled, 4)
      print "Code section 4 active"
      wait 5
   else
      print "Code section 4 inactive"
   endif

   sync
loop

Yes, it could also be done using indivually named global variables, or using an appropriately sized array too.

This way uses less storage which can be useful when writing to a file, or storing in a memblock or memory bank. A single bitset is also easier to pass around your program, seeing as it is basically just a standard variable.

---

or:

+ Code Snippet

if mouseclick() && 2^n then print "mouse button n is pressed"

---

I know - I posted that code only a week or so ago, and a lot of the less learned coders on the forums wouldn't even know why it works.
Besides, it's quicker this way

+ Code Snippet

if mouseclick() && (1 << (n-1)) then print "mouse button ";n;" is pressed"

[edit]Quick update to the plugin 17 - It wasn't handling the full 64 bit range correctly - now it is.

---

Just wanted to say thanks for these great dlls.
I am making a snippet to write text files using memory banks mainly to see if i can get some speed improvements over using standard file functions; it's not fully working yet, but here's a link anyway:
http://forum.thegamecreators.com/?m=forum_view&t=86495&b=6
(see 2nd post)

---

Thanks. I've made a post in your thread that may help you get the speed increase you are after.

---

Here is a new update, including one semi-experimental new plugin that allows DBO objects to be loaded from a memory bank.

Matrix1Util_01 1.0.0.2
Added 3 SEARCH BANK functions to allow string searches within banks.
Added 2 ZERO BANK commands to clear banks or areas of banks.

Matrix1Util_07 1.0.0.2
Added GCD functions (greatest common denominator)
Added integer and double version of the clamp and wrap functions

Matrix1Util_12 1.0.0.1
Initial public release (GET LIMB BY NAME, GET LIMB COUNT, GET LIMB FVF)
Added SET LIMB NAME command
Added GET LIMB PARENT/CHILD/SIBLING functions

Matrix1Util_13 1.0.0.2
Added HAS FOCUS function and GRAB FOCUS command.

Matrix1Util_16 1.0.0.2
Faster string-length function for a general speedup throughout.
Fix bug for positional checking in the GET SPLIT WORD function.

Matrix1Util_17 1.0.0.2
Faster bit count routine.

Matrix1Util_18 1.0.0.1
New plugin that allows objects to be created from memory banks.
They need to be .dbo format.

---

Ian you rock this place mate!

---

Thanks.
Have a 'fix' release.


Matrix1Util_13 1.0.0.2
Corrected help files - added 'GET' to all infomation functions

Matrix1Util_18 1.0.0.2
Corrected 'offset' version of the MAKE OBJECT FROM BANK command
Removed need for the fourth argument too as DBO knows how far it can go

Plugin 18 is no longer experimental - it works just fine every time.

---

Here's an example of multiple DBO objects being loaded from a bank. It uses the new bank functions to search for DBO objects and loads them.

It's a little involved, but bear with it.

+ Code Snippet

sync on
sync rate 60

` Clear all working files
if file exist("test.dbw") then delete file "test.dbw"
if file exist("obj1.dbo") then delete file "obj1.dbo"
if file exist("obj2.dbo") then delete file "obj2.dbo"

` Make a cube dbo file
make object cube 1, 1.0
save object "obj1.dbo", 1
delete object 1

` Make a sphere dbo file
make object sphere 1, 1.2
save object "obj2.dbo", 1
delete object 1

` Start assembling a combined file
Total = file size("obj1.dbo") + file size("obj2.dbo")
Offset = 0

map file to bank "test.dbw", 1, Total

` Add the cube dbo to the file
map file to bank "obj1.dbo", 2
copy bank 2, 0, get bank size(2), 1, Offset
inc Offset, get bank size(2)
delete bank 2
delete file "obj1.dbo"

` Add the sphere dbo to the file
map file to bank "obj2.dbo", 2
copy bank 2, 0, get bank size(2), 1, Offset
inc Offset, get bank size(2)
delete bank 2
delete file "obj2.dbo"

delete bank 1
` All done. The combined file is ready



` Load the combined file
map file to bank "test.dbw", 1

` Load all objects from that file
Offset = 0
ObjectNo = 0
repeat
   ` Search for the magic string
   Offset = search bank(1, Offset, "MAGICDBO")
   if Offset >= 0
      ` Ensure that the previous 4 bytes match the length of the string we expect
      if bank integer(1, Offset-4) = 8
         ` Ok, we know that we've found a match
         inc ObjectNo
         make object from bank ObjectNo, 1, Offset-4

         ` Advance the start point of the next search
         inc Offset
      endif
   endif
until Offset < 0

delete bank 1

do
   if object exist(1) then turn object left 1, 1.0
   if object exist(2) then turn object right 2, 1.0
   sync
loop

---

IanM, I am in awe. Great work. In my current project I'm working with x-files. I understand they are slower but it's easier for this human to parse a .x text file. Is it possible for you to add a "make object from bank" command for a text .x file to the collection? A kind of "Load mesh"=>"Make object" command from a virtual file (bank). I know I sure could use it but if I'm the only one, then it's no biggy. Thanks for all you've done already.

---

I've been looking into it since you posted, and there doesn't seem to be an easy way ATM. I won't give up on it though - I'm sure that it can be done.

In the meantime, you can use DBPro to load your x models and save them back out as a dbo file if you want to take advantage of the new command.

When I do figure out the loading of x files from a bank, the same code will be able to load the data without you needing to give it any clues beyond the start position.

---

Hey, thanks for looking into it. I'm basically working on a custom model editor - adding / deleting verts, flipping edges etc. on the fly. I can keep track of that stuff fairly easily in a .x text file. I can use a bank to write the file but it would be nice to not have to re-read it for each model update (since it's already in a bank). Keep up the good work, and thanks again.

---

any advanced matrix functions about? (ie colour individual verticies on a mtx, apply a texture to the whole matrix rather than just a tile, detail texture blending, tile border blending)

---

@IanM - I have probably found an error (what else I can do?), when I call find free memblock() some times I get the memblock id is out of range. So I guess your limits are incorrect. It only happens occasionally because I use random free memblock finding. I tried to lower the value to find free memblock(1,100) then everything worked fine. I dont know but maybe the maximum memblock count is 128?

[Edit]
Did I already told you that these are very good and fast plugins! And Im currently building my FPS engine around these.

---

@ThomasFN,

I don't think that kind of functionality is available for matrix's - you might need to use standard objects & limbs for all of that. You can search in the Code Snippets forum, or in the code base for example code.

I may add something like this in the future.

@Olby,

I can't find any error with the FIND FREE MEMBLOCK code. Are you remembering to check for a returned value of 0? If you do get 0, then you've already used up all of your memblocks.

If you have any example code that exhibits this problem, then just post it here or email it, and I'll take a look.

---

Thanks for your help, IanM. I may use an advanced terrain and used vertex data and limb stuff to do what i want.

---

Cool, I needed that parent limb function

---

Some very handy commands here Ian

I have been trying a few but have come across one that doesn't work 'as advertised'.

+ Code Snippet

s$= "Hello World"
tS = remove$(s$,"World")
print t$
wait key

That code brings up this error:
Cannot perform 'integer' cast on type 'TEMP2' at line 10.

Is there any chance you could have a look at this? It would be very handy.

Thanks

[edit] Same problem with REMOVE ALL$

---

Scraggle, I'm surprised you didn't catch this error!

That error message means that it's trying to store String data in an Integer variable. either replace tS w/ t$ or put tS as integer above this code. (I assume you meant to do the former from the start.)

Corrected code:

+ Code Snippet

s$= "Hello World"
t$ = remove$(s$,"World")
print t$
wait key

And I ran it, to check.

---

Now I feel stupid!

Sorry Ian for assuming it was a problem with your plugin-in and thanks to Bmad for pointing out my stupidity

... and yes, I did mean to do the former from the start.

---

No problem - I generally spend quite a bit of time on testing these before I release to avoid being embarrassed later, so I was surprised to see your post. So far, only 2 bugs found in these plug-ins, and one of those I found myself

Thanks to Bmad6 for finding the problem.

---

I found another bug with split string$.

Check this...
+ Code Snippet

command_line$ = "-help -name -user -stuff"
split string command_line$," -"

It splits string not using all delimeter string " -" but uses just first which is just a space.

Even if this is not a bug adding this functionality for more than one char in delimeter string would be awesome.

---

Sorry, but that's not a bug - the second string is used as a list of single character delimiters. If you want to search for string delimiters, then a simple way to do that would be to REPLACE ALL of your delimiters with a single character, then SPLIT STRING using that character.

Also, if you check out the HelpGen code in one of my earlier posts, you'll find that it contains a source file 'CommandLine.dba' which takes the command line and splits it correctly.

---

just wanna say that im using your plugin for the timer functions . its fast , thanks man