BlitzTerrain - GameCreators Forum

Author

Message

kaedroho

17

Years of Service

User Offline

Joined: 21st Aug 2007

Location: Oxford,UK

Posted: 16th Jul 2011 13:59 Edited at: 16th Jul 2011 14:02

Link

JackDawson,

DBPro supports multiple functions with the same name, as long as the parameters are different (this is not available for user functions though).

If you use the 3rd parameter, it will call the seccond one. If you don't, it will call the first one.

Does it say "Already Building" ? If it does then that means you need to add a 1 at the end of build terrain. Or use a build loop. (The 1 tells it to build without the build loop).

Build loops were the way terrains had to be made a long time ago. I left it in for backwards compatibility but it is no longer recommended.

Everyone,

I'm guessing that a lot of people have been wondering where I've been, where the Blitzwerks website went and the future of Blitzwerks Terrain.

Well, its not what it looks like! Blitzwerks is not shutting down, the webserver just had a hard drive failure and I haven't put it back up. The reason for this is that its only job was to host downloads which TGC forums supports anyway.

My exams are over now and I'm in full time work. I have been working on another project which is why I haven't been able to work much on Blitzwerks Terrain recently. I have worked on Blitzwerks Terrain for over 3 years now as my main project and I would like to begin working on something else.

Blitzwerks Terrain is still fully supported. If someone has a major error I will do my best to fix it asap.

As for the future of Blitzwerks Terrain, I haven't binned my todo list. Update 2.03 is still going ahead, it will take a bit longer than expected though.

Your signature has been erased by a mod please reduce it to no larger than 600 x 120.

Back to top

Profile PM Email Website

JackDawson

13

Years of Service

User Offline

Joined: 12th Jul 2011

Location:

Posted: 16th Jul 2011 15:29

Link

Hey there.. and thanks for answering back.

Yes there is already a 1 there. I am using KISTech's source code to his infinate terrain demo that he is able to compile and get to run with your FULL version of your plugin. But he said it should build with your demo as well.

This is his code from the other link.

set display mode desktop width(), desktop height(), 32, 0
sync on : sync rate 0 : sync
autocam off
set camera range 0, 1, 50000

global factor# as float
global flast# as float
global dim factors(30) as float

type player_data
	map as dword
	x as float
	z as float
endtype
global dim Players(0) as player_data

type terrain_data
	id as dword
	objid as dword
	img_h as dword
	img_t as dword
endtype
global dim Terr(256) as terrain_data

global dim Map(18,18) as dword
z = 0
for y = 2 to 17
	for x = 2 to 17
		inc z
		Map(x,y) = z
	next x
next y
for x = 2 to 17
	Map(x,1) = Map(x,17)
	Map(x,18) = Map(x,2)
next x
for y = 1 to 18
	Map(1,y) = Map(17,y)
	Map(18,y) = Map(2,y)
next y
global dim myMap(9) as dword

TerrHM = find free image()
load image "Terrain\Terrain1_HM.bmp", TerrHM, 1
TerrTX = find free image()
load image "Terrain\Terrain1_TX.png", TerrTX, 1

cls
center text screen width()/2, screen height()/2, "Separating Maps.."
sync

set bitmap format 22
create bitmap 1, 4096, 4096
i = 0
for y = 15 to 0 step -1
	for x = 0 to 15
		cls 0
		i = i + 1
		Terr(i).img_h = find free image()
		paste image TerrHM, -(256 * x), -(256 * y)
		get image Terr(i).img_h, 0, 0, 256, 256
	next x
next y
delete bitmap 1
delete image TerrHM : TerrHM = 0
set bitmap format 21
create bitmap 1, 4096, 4096
i = 0
set text size 68
for y = 15 to 0 step -1
	for x = 0 to 15
		cls 0
		i = i + 1
		Terr(i).img_t = find free image()
		paste image TerrTX, -(256 * x), -(256 * y)
		line 0, 0, 256, 0, rgb(255,64,64)
		line 0, 0, 0, 256, rgb(255,64,64)
		line 256, 0, 256, 256, rgb(255,64,64)
		line 0, 256, 256, 256, rgb(255,64,64)
		line 0, 128, 256, 128, rgb(255,255,64)
		line 128, 0, 128, 256, rgb(255,255,64)
		center text 128, 128, str$(i)
		get image Terr(i).img_t, 0, 0, 256, 256
	next x
next y
delete image TerrTX : TerrTX = 0
set text size 14
set current bitmap 0
delete bitmap 1

BT SetATMode 1
global TerrScale as integer = 16
global TerrWidth as integer
TerrWidth = (image width(Terr(1).img_h) * TerrScale) - TerrScale

` Player object
global pObj as dword
pObj = find free object()
make object cube pObj, 1
hide object pObj
position object pObj, 100.0, 0.0, 100.0

Players(0).map = 1
Players(0).x = 100.0
Players(0).z = 100.0

` Set the map matrix around the player
SetMyMap()
` Load the appropriate terrains based on the map matrix
MapCheck()

while not escapekey()
	
	tbm_Update()
	
	text 10, 10, "FPS : "+str$(screen fps())
	text 10, 30, "W,A,S,D - Move around - Hold Shift to move faster"
	text 10, 50, "X : "+str$(Object position x(pObj),2)+"  Z : "+str$(object position z(pObj),2)
	
	` Movement
	speed# = 100.0
	if keystate(42) then speed# = 300.0
	if keystate(17) and intime = 0 then	move object pObj, speed# * factor#
	if keystate(30) and intime = 0 then move object left pObj, speed# * factor#
	if keystate(31) and intime = 0 then move object pObj, -speed# * factor#
	if keystate(32) and intime = 0 then move object right pObj, speed# * factor#
	cx# = BT GetGroundHeight(Terr(Players(0).map).id, object position x(pObj), object position z(pObj))
	position object pObj, object position x(pObj), cx#+35, object position z(pObj)
	if has focus()
		hide mouse
		position mouse screen width()/2, screen height()/2
	else
		show mouse
	endif
	cx#=object angle x(pObj) + mousemovey() / 4.0
	if cx#>90.0 then cx#=90.0
	if cx#<-90.0 then cx#=-90.0
	rotate object pObj, cx#, camera angle y(0) + mousemovex() / 4.0, 0.0
	set camera to object orientation 0, pObj
	position camera 0, object position x(pObj), object position y(pObj), object position z(pObj)
	move camera 0, -3
	Players(0).x = object position x(pObj)
	Players(0).z = object position z(pObj)
	
	` If the player moves to another map, reset their map matrix
	if Players(0).map <> MyMap(5) then SetMyMap()
	` Load / Unload the appropriate maps surrounding the player
	MapCheck()
	
	BT SetCurrentCamera 0
	for t = 1 to 256
		if Terr(t).id > 0
			if BT TerrainExist(Terr(t).id)
				BT UpdateTerrainCull Terr(t).id
				BT UpdateTerrainLOD Terr(t).id
				BT RenderTerrain Terr(t).id
			endif
		endif
	next t
	
	sync
	
endwhile

for t = 1 to 256
	if Terr(t).id > 0
		if BT TerrainExist(Terr(t).id)
			BT DeleteTerrain Terr(t).id
		endif
	endif
next t

end

function LoadTerrain(tt as dword, tx as integer, tz as integer)
	Terr(tt).id = BT MakeTerrain()
	BT SetTerrainHeightMap Terr(tt).id, Terr(tt).img_h
	BT SetTerrainScale Terr(tt).id, TerrScale
	BT SetTerrainYScale Terr(tt).id, 4.0
	BT SetTerrainSplit Terr(tt).id, 8
	BT SetTerrainLOD Terr(tt).id, 3
	BT SetTerrainLODDistance Terr(tt).id, 1, 1500.0
	BT SetTerrainLODDistance Terr(tt).id, 2, 2000.0
	BT SetTerrainSmoothing Terr(tt).id, 1
	BT SetTerrainQuadRotation Terr(tt).id, 1
	Terr(tt).objid = find free object()
	BT BuildTerrain Terr(tt).id, Terr(tt).objid, 1
	texture object Terr(tt).objid, 0, Terr(tt).img_t
	position object Terr(tt).objid, TerrWidth * tx, 0.0, TerrWidth * tz
endfunction

function RemoveTerrain(tt as dword)
	if Terr(tt).id > 0
		if BT TerrainExist(Terr(tt).id)
			BT DeleteTerrain Terr(tt).id
		endif
	endif
	if Terr(tt).objid > 0
		if object exist(Terr(tt).objid)
			delete object Terr(tt).objid
		endif
	endif
	Terr(tt).id = 0
	Terr(tt).objid = 0
endfunction

function SetMyMap()
	z = 0
	MyMap(5) = Players(0).map
	for x = 2 to 17
		for y = 2 to 17
			if Map(x,y) = MyMap(5) and z = 0
				a = x : b = y : z = 1
			endif
		next y
	next x
	MyMap(7) = Map(a-1,b+1) : MyMap(8) = Map(a,b+1) : MyMap(9) = Map(a+1,b+1)
	MyMap(4) = Map(a-1,b)   :                         MyMap(6) = Map(a+1,b)
	MyMap(1) = Map(a-1,b-1) : MyMap(2) = Map(a,b-1) : MyMap(3) = Map(a+1,b-1)
	z = 0
	for y = -1 to 1
		for x = -1 to 1
			inc z
			if Terr(MyMap(z)).id > 0 then position object Terr(MyMap(z)).objid, TerrWidth * x, 0.0, TerrWidth * y
		next x
	next y
endfunction

function MapCheck()
	if Players(0).x < TerrWidth/2 and Players(0).x > 0
		if Terr(MyMap(3)).id > 0 then RemoveTerrain(MyMap(3))
		if Terr(MyMap(6)).id > 0 then RemoveTerrain(MyMap(6))
		if Terr(MyMap(9)).id > 0 then RemoveTerrain(MyMap(9))
		if Terr(MyMap(5)).id = 0 then LoadTerrain(MyMap(5), 0, 0)
		if Players(0).z < TerrWidth/2 and Players(0).z > 0 ` Lower Left Corner
			if Terr(MyMap(7)).id > 0 then RemoveTerrain(MyMap(7))
			if Terr(MyMap(8)).id > 0 then RemoveTerrain(MyMap(8))
			if Terr(MyMap(1)).id = 0 then LoadTerrain(MyMap(1), -1, -1)
			if Terr(MyMap(2)).id = 0 then LoadTerrain(MyMap(2), 0, -1)
			if Terr(MyMap(4)).id = 0 then LoadTerrain(MyMap(4), -1, 0)
		endif
		if Players(0).z > TerrWidth/2 and Players(0).z < TerrWidth ` Upper Left Corner
			if Terr(MyMap(1)).id > 0 then RemoveTerrain(MyMap(1))
			if Terr(MyMap(2)).id > 0 then RemoveTerrain(MyMap(2))
			if Terr(MyMap(4)).id = 0 then LoadTerrain(MyMap(4), -1, 0)
			if Terr(MyMap(7)).id = 0 then LoadTerrain(MyMap(7), -1, 1)
			if Terr(MyMap(8)).id = 0 then LoadTerrain(MyMap(8), 0, 1)
		endif
	endif
	if Players(0).x > TerrWidth/2 and Players(0).x < TerrWidth
		if Terr(MyMap(1)).id > 0 then RemoveTerrain(MyMap(1))
		if Terr(MyMap(4)).id > 0 then RemoveTerrain(MyMap(4))
		if Terr(MyMap(7)).id > 0 then RemoveTerrain(MyMap(7))
		if Terr(MyMap(5)).id = 0 then LoadTerrain(MyMap(5), 0, 0)
		if Players(0).z < TerrWidth/2 and Players(0).z > 0 ` Lower Right Corner
			if Terr(MyMap(8)).id > 0 then RemoveTerrain(MyMap(8))
			if Terr(MyMap(9)).id > 0 then RemoveTerrain(MyMap(9))
			if Terr(MyMap(2)).id = 0 then LoadTerrain(MyMap(2), 0, -1)
			if Terr(MyMap(3)).id = 0 then LoadTerrain(MyMap(3), 1, -1)
			if Terr(MyMap(6)).id = 0 then LoadTerrain(MyMap(6), 1, 0)
		endif
		if Players(0).z > TerrWidth/2 and Players(0).z < TerrWidth ` Upper Right Corner
			if Terr(MyMap(2)).id > 0 then RemoveTerrain(MyMap(2))
			if Terr(MyMap(3)).id > 0 then RemoveTerrain(MyMap(3))
			if Terr(MyMap(6)).id = 0 then LoadTerrain(MyMap(6), 1, 0)
			if Terr(MyMap(8)).id = 0 then LoadTerrain(MyMap(8), 0, 1)
			if Terr(MyMap(9)).id = 0 then LoadTerrain(MyMap(9), 1, 1)
		endif
	endif	
	if Players(0).x < 1
		Players(0).map = MyMap(4)
		Players(0).x = Players(0).x + (TerrWidth - 2)
	endif
	if Players(0).x > TerrWidth-1
		Players(0).map = MyMap(6)
		Players(0).x = Players(0).x - (TerrWidth - 2)
	endif
	if Players(0).z < 1
		Players(0).map = MyMap(2)
		Players(0).z = Players(0).z + (TerrWidth - 2)
	endif
	if Players(0).z > TerrWidth-1
		Players(0).map = MyMap(8)
		Players(0).z = Players(0).z - (TerrWidth - 2)
	endif
	position object pObj, Players(0).x, object position y(pObj), Players(0).z
endfunction

function tbm_update()
	Diff# = hitimer() - flast#
	flast# = hitimer()
	factor# = 0.0
	for tx = 1 to 29
		factors(tx) = factors(tx+1)
		factor# = factor# + factors(tx)
	next tx
	factors(30) = Diff# / 1000.0
	factor# = (factor# + factors(30)) / 30.0
endfunction

+ Code Snippet

set display mode desktop width(), desktop height(), 32, 0
sync on : sync rate 0 : sync
autocam off
set camera range 0, 1, 50000

global factor# as float
global flast# as float
global dim factors(30) as float

type player_data
	map as dword
	x as float
	z as float
endtype
global dim Players(0) as player_data

type terrain_data
	id as dword
	objid as dword
	img_h as dword
	img_t as dword
endtype
global dim Terr(256) as terrain_data

global dim Map(18,18) as dword
z = 0
for y = 2 to 17
	for x = 2 to 17
		inc z
		Map(x,y) = z
	next x
next y
for x = 2 to 17
	Map(x,1) = Map(x,17)
	Map(x,18) = Map(x,2)
next x
for y = 1 to 18
	Map(1,y) = Map(17,y)
	Map(18,y) = Map(2,y)
next y
global dim myMap(9) as dword

TerrHM = find free image()
load image "Terrain\Terrain1_HM.bmp", TerrHM, 1
TerrTX = find free image()
load image "Terrain\Terrain1_TX.png", TerrTX, 1

cls
center text screen width()/2, screen height()/2, "Separating Maps.."
sync

set bitmap format 22
create bitmap 1, 4096, 4096
i = 0
for y = 15 to 0 step -1
	for x = 0 to 15
		cls 0
		i = i + 1
		Terr(i).img_h = find free image()
		paste image TerrHM, -(256 * x), -(256 * y)
		get image Terr(i).img_h, 0, 0, 256, 256
	next x
next y
delete bitmap 1
delete image TerrHM : TerrHM = 0
set bitmap format 21
create bitmap 1, 4096, 4096
i = 0
set text size 68
for y = 15 to 0 step -1
	for x = 0 to 15
		cls 0
		i = i + 1
		Terr(i).img_t = find free image()
		paste image TerrTX, -(256 * x), -(256 * y)
		line 0, 0, 256, 0, rgb(255,64,64)
		line 0, 0, 0, 256, rgb(255,64,64)
		line 256, 0, 256, 256, rgb(255,64,64)
		line 0, 256, 256, 256, rgb(255,64,64)
		line 0, 128, 256, 128, rgb(255,255,64)
		line 128, 0, 128, 256, rgb(255,255,64)
		center text 128, 128, str$(i)
		get image Terr(i).img_t, 0, 0, 256, 256
	next x
next y
delete image TerrTX : TerrTX = 0
set text size 14
set current bitmap 0
delete bitmap 1

BT SetATMode 1
global TerrScale as integer = 16
global TerrWidth as integer
TerrWidth = (image width(Terr(1).img_h) * TerrScale) - TerrScale

` Player object
global pObj as dword
pObj = find free object()
make object cube pObj, 1
hide object pObj
position object pObj, 100.0, 0.0, 100.0

Players(0).map = 1
Players(0).x = 100.0
Players(0).z = 100.0

` Set the map matrix around the player
SetMyMap()
` Load the appropriate terrains based on the map matrix
MapCheck()

while not escapekey()
	
	tbm_Update()
	
	text 10, 10, "FPS : "+str$(screen fps())
	text 10, 30, "W,A,S,D - Move around - Hold Shift to move faster"
	text 10, 50, "X : "+str$(Object position x(pObj),2)+"  Z : "+str$(object position z(pObj),2)
	
	` Movement
	speed# = 100.0
	if keystate(42) then speed# = 300.0
	if keystate(17) and intime = 0 then	move object pObj, speed# * factor#
	if keystate(30) and intime = 0 then move object left pObj, speed# * factor#
	if keystate(31) and intime = 0 then move object pObj, -speed# * factor#
	if keystate(32) and intime = 0 then move object right pObj, speed# * factor#
	cx# = BT GetGroundHeight(Terr(Players(0).map).id, object position x(pObj), object position z(pObj))
	position object pObj, object position x(pObj), cx#+35, object position z(pObj)
	if has focus()
		hide mouse
		position mouse screen width()/2, screen height()/2
	else
		show mouse
	endif
	cx#=object angle x(pObj) + mousemovey() / 4.0
	if cx#>90.0 then cx#=90.0
	if cx#<-90.0 then cx#=-90.0
	rotate object pObj, cx#, camera angle y(0) + mousemovex() / 4.0, 0.0
	set camera to object orientation 0, pObj
	position camera 0, object position x(pObj), object position y(pObj), object position z(pObj)
	move camera 0, -3
	Players(0).x = object position x(pObj)
	Players(0).z = object position z(pObj)
	
	` If the player moves to another map, reset their map matrix
	if Players(0).map <> MyMap(5) then SetMyMap()
	` Load / Unload the appropriate maps surrounding the player
	MapCheck()
	
	BT SetCurrentCamera 0
	for t = 1 to 256
		if Terr(t).id > 0
			if BT TerrainExist(Terr(t).id)
				BT UpdateTerrainCull Terr(t).id
				BT UpdateTerrainLOD Terr(t).id
				BT RenderTerrain Terr(t).id
			endif
		endif
	next t
	
	sync
	
endwhile

for t = 1 to 256
	if Terr(t).id > 0
		if BT TerrainExist(Terr(t).id)
			BT DeleteTerrain Terr(t).id
		endif
	endif
next t

end



function LoadTerrain(tt as dword, tx as integer, tz as integer)
	Terr(tt).id = BT MakeTerrain()
	BT SetTerrainHeightMap Terr(tt).id, Terr(tt).img_h
	BT SetTerrainScale Terr(tt).id, TerrScale
	BT SetTerrainYScale Terr(tt).id, 4.0
	BT SetTerrainSplit Terr(tt).id, 8
	BT SetTerrainLOD Terr(tt).id, 3
	BT SetTerrainLODDistance Terr(tt).id, 1, 1500.0
	BT SetTerrainLODDistance Terr(tt).id, 2, 2000.0
	BT SetTerrainSmoothing Terr(tt).id, 1
	BT SetTerrainQuadRotation Terr(tt).id, 1
	Terr(tt).objid = find free object()
	BT BuildTerrain Terr(tt).id, Terr(tt).objid, 1
	texture object Terr(tt).objid, 0, Terr(tt).img_t
	position object Terr(tt).objid, TerrWidth * tx, 0.0, TerrWidth * tz
endfunction


function RemoveTerrain(tt as dword)
	if Terr(tt).id > 0
		if BT TerrainExist(Terr(tt).id)
			BT DeleteTerrain Terr(tt).id
		endif
	endif
	if Terr(tt).objid > 0
		if object exist(Terr(tt).objid)
			delete object Terr(tt).objid
		endif
	endif
	Terr(tt).id = 0
	Terr(tt).objid = 0
endfunction


function SetMyMap()
	z = 0
	MyMap(5) = Players(0).map
	for x = 2 to 17
		for y = 2 to 17
			if Map(x,y) = MyMap(5) and z = 0
				a = x : b = y : z = 1
			endif
		next y
	next x
	MyMap(7) = Map(a-1,b+1) : MyMap(8) = Map(a,b+1) : MyMap(9) = Map(a+1,b+1)
	MyMap(4) = Map(a-1,b)   :                         MyMap(6) = Map(a+1,b)
	MyMap(1) = Map(a-1,b-1) : MyMap(2) = Map(a,b-1) : MyMap(3) = Map(a+1,b-1)
	z = 0
	for y = -1 to 1
		for x = -1 to 1
			inc z
			if Terr(MyMap(z)).id > 0 then position object Terr(MyMap(z)).objid, TerrWidth * x, 0.0, TerrWidth * y
		next x
	next y
endfunction


function MapCheck()
	if Players(0).x < TerrWidth/2 and Players(0).x > 0
		if Terr(MyMap(3)).id > 0 then RemoveTerrain(MyMap(3))
		if Terr(MyMap(6)).id > 0 then RemoveTerrain(MyMap(6))
		if Terr(MyMap(9)).id > 0 then RemoveTerrain(MyMap(9))
		if Terr(MyMap(5)).id = 0 then LoadTerrain(MyMap(5), 0, 0)
		if Players(0).z < TerrWidth/2 and Players(0).z > 0 ` Lower Left Corner
			if Terr(MyMap(7)).id > 0 then RemoveTerrain(MyMap(7))
			if Terr(MyMap(8)).id > 0 then RemoveTerrain(MyMap(8))
			if Terr(MyMap(1)).id = 0 then LoadTerrain(MyMap(1), -1, -1)
			if Terr(MyMap(2)).id = 0 then LoadTerrain(MyMap(2), 0, -1)
			if Terr(MyMap(4)).id = 0 then LoadTerrain(MyMap(4), -1, 0)
		endif
		if Players(0).z > TerrWidth/2 and Players(0).z < TerrWidth ` Upper Left Corner
			if Terr(MyMap(1)).id > 0 then RemoveTerrain(MyMap(1))
			if Terr(MyMap(2)).id > 0 then RemoveTerrain(MyMap(2))
			if Terr(MyMap(4)).id = 0 then LoadTerrain(MyMap(4), -1, 0)
			if Terr(MyMap(7)).id = 0 then LoadTerrain(MyMap(7), -1, 1)
			if Terr(MyMap(8)).id = 0 then LoadTerrain(MyMap(8), 0, 1)
		endif
	endif
	if Players(0).x > TerrWidth/2 and Players(0).x < TerrWidth
		if Terr(MyMap(1)).id > 0 then RemoveTerrain(MyMap(1))
		if Terr(MyMap(4)).id > 0 then RemoveTerrain(MyMap(4))
		if Terr(MyMap(7)).id > 0 then RemoveTerrain(MyMap(7))
		if Terr(MyMap(5)).id = 0 then LoadTerrain(MyMap(5), 0, 0)
		if Players(0).z < TerrWidth/2 and Players(0).z > 0 ` Lower Right Corner
			if Terr(MyMap(8)).id > 0 then RemoveTerrain(MyMap(8))
			if Terr(MyMap(9)).id > 0 then RemoveTerrain(MyMap(9))
			if Terr(MyMap(2)).id = 0 then LoadTerrain(MyMap(2), 0, -1)
			if Terr(MyMap(3)).id = 0 then LoadTerrain(MyMap(3), 1, -1)
			if Terr(MyMap(6)).id = 0 then LoadTerrain(MyMap(6), 1, 0)
		endif
		if Players(0).z > TerrWidth/2 and Players(0).z < TerrWidth ` Upper Right Corner
			if Terr(MyMap(2)).id > 0 then RemoveTerrain(MyMap(2))
			if Terr(MyMap(3)).id > 0 then RemoveTerrain(MyMap(3))
			if Terr(MyMap(6)).id = 0 then LoadTerrain(MyMap(6), 1, 0)
			if Terr(MyMap(8)).id = 0 then LoadTerrain(MyMap(8), 0, 1)
			if Terr(MyMap(9)).id = 0 then LoadTerrain(MyMap(9), 1, 1)
		endif
	endif	
	if Players(0).x < 1
		Players(0).map = MyMap(4)
		Players(0).x = Players(0).x + (TerrWidth - 2)
	endif
	if Players(0).x > TerrWidth-1
		Players(0).map = MyMap(6)
		Players(0).x = Players(0).x - (TerrWidth - 2)
	endif
	if Players(0).z < 1
		Players(0).map = MyMap(2)
		Players(0).z = Players(0).z + (TerrWidth - 2)
	endif
	if Players(0).z > TerrWidth-1
		Players(0).map = MyMap(8)
		Players(0).z = Players(0).z - (TerrWidth - 2)
	endif
	position object pObj, Players(0).x, object position y(pObj), Players(0).z
endfunction


function tbm_update()
	Diff# = hitimer() - flast#
	flast# = hitimer()
	factor# = 0.0
	for tx = 1 to 29
		factors(tx) = factors(tx+1)
		factor# = factor# + factors(tx)
	next tx
	factors(30) = Diff# / 1000.0
	factor# = (factor# + factors(30)) / 30.0
endfunction

His EXE demo works, but when I go to compile it, I get that error that I explained to you earlier about. Others have made reference to your demo not working, so i'm trying to get something working with your demo with KISTech's source code. He says it should work with your demo.

Any ideas ?

"If you can sing that high, you must have been kicked in the crotch a little too hard."

Back to top

Profile PM

JackDawson

13

Years of Service

User Offline

Joined: 12th Jul 2011

Location:

Posted: 16th Jul 2011 16:04

Link

I forgot to supply his ORIGINAL ZIP file so that you have his media with it as well. Its two image files under the \terrain\ folder that is listed in the source code above.

"If you can sing that high, you must have been kicked in the crotch a little too hard."

Back to top

Profile PM

Mugen Wizardry

User Banned

Posted: 8th Aug 2011 00:18

Link

GOOD job, Kaedroho! And I'm BACK, folks!

Kaedroho, How much did you say this was selling for, and WHERE can I get it?

CHECK OUT SOME MUSIC FROM MY NEW TECHNO CD! TECHNOKINESIS
http://www.youtube.com/watch?v=4a8KedfgVv0
ALSO, CHECK OUT MY NEW TECHNO CD AT Amazon.com!

Back to top

Profile

Clonkex

Forum Vice President

14

Years of Service

User Offline

Joined: 20th May 2010

Location: Northern Tablelands, NSW, Australia

Posted: 8th Aug 2011 02:11

Link

@Mugen Wizardry

www.thegamecreators.com/?m=view_product&id=2286

$40.99 Dollar
€29.99 Euros
£25 Sterling

Clonkex

Never lie -- The government doesn't like the competition.

Intel Core 2 Duo 2.8Ghz, Nvidia GeForce 9400 GT 512mb, 1gb ram.

Back to top

Profile PM Email

Mugen Wizardry

User Banned

Posted: 8th Aug 2011 16:54

Link

Thanks

Is there ANY way to load a blitz terrain, perfect it, then afterwords, save EVERYTHING into a DBO file which can LATER be saved as a PERFECT 3DS, or X file?

I REALLY need this feature.

Including textures, light, tiles, and the like.

CHECK OUT SOME MUSIC FROM MY NEW TECHNO CD! TECHNOKINESIS
http://www.youtube.com/watch?v=4a8KedfgVv0
ALSO, CHECK OUT MY NEW TECHNO CD AT Amazon.com!

Back to top

Profile

kaedroho

17

Years of Service

User Offline

Joined: 21st Aug 2007

Location: Oxford,UK

Posted: 13th Aug 2011 01:10

Link

Welcome back Mugen!

Yep, that feature is available. Once finished editing, just call BT MakeTerrainObject. This will create an object for the entire terrain. You can then use save object on this object to save the terrain.

If you used the painting features, just do save image on the texture you loaded in to start with.

Your signature has been erased by a mod please reduce it to no larger than 600 x 120.

Back to top

Profile PM Email Website

JackDawson

13

Years of Service

User Offline

Joined: 12th Jul 2011

Location:

Posted: 13th Aug 2011 14:31 Edited at: 13th Aug 2011 14:33

Link

Hey there. Well I finally bought the BT Full version, and I keep plugging away at KISTech's demo. But it still does not work the way he has written it. So I am confused more then ever. In fact, anything to do with that command in BT fails in my compiles now. I have tried installing DX 7 , 8 and 9 and I have tried different ways to run this. Even his Demo no longer works from scratch. Am I missing something ?

Win7 64Bit

I also have the C++ 2005, 2008 and 2010 ( Both 32 & 64 Bit ) Redistributables.

"If you can sing that high, you must have been kicked in the crotch a little too hard."

Back to top

Profile PM

KISTech

16

Years of Service

User Offline

Joined: 8th Feb 2008

Location: Aloha, Oregon

Posted: 13th Aug 2011 19:12

Link

What's the main error you're having again?

Back to top

Profile PM Email Website

Mugen Wizardry

User Banned

Posted: 13th Aug 2011 19:37

Link

Trying to save the HIGHLY detailed terrain as an X or 3DS file (Preferably X file)

CHECK OUT SOME MUSIC FROM MY NEW TECHNO CD! TECHNOKINESIS
http://www.youtube.com/watch?v=4a8KedfgVv0
ALSO, CHECK OUT MY NEW TECHNO CD AT Amazon.com!

Back to top

Profile

Mugen Wizardry

User Banned

Posted: 13th Aug 2011 19:40 Edited at: 13th Aug 2011 19:43

Link

You wouldn't happen to have a small example of how to save a terrain with SUPER HIGH quality to an X file, and KEEP the tiling, the texture map, the lighting, and the SUPER HIGH quality intact?

If so, that would be so wonderful!

I am looking forward to buying your plugin next week, @Kaedroho!

CHECK OUT SOME MUSIC FROM MY NEW TECHNO CD! TECHNOKINESIS
http://www.youtube.com/watch?v=4a8KedfgVv0
ALSO, CHECK OUT MY NEW TECHNO CD AT Amazon.com!

Back to top

Profile

Mugen Wizardry

User Banned

Posted: 14th Aug 2011 14:50

Link

Also, @kaedroho, I'm getting a heightmap size is invalid, using a 1024x1024 heightmap. What's wrong with using a 1024x1024 heightmap?

Code:

+ Code Snippet

	Global terrain as integer

	  `BT SetATMode 1
   terrain = BT MakeTerrain()
   BT SetTerrainHeightMap terrain, imgTer

   BT SetTerrainEnvironment terrain, imgEnv
   BT SetTerrainScale terrain, 5
   BT SetTerrainYScale terrain, 1.5
   BT SetTerrainSplit terrain, 128

   BT SetTerrainLOD terrain, 3
   BT SetTerrainLODDistance terrain, 1, 150.0
   BT SetTerrainLODDistance terrain, 2, 100.0

   BT SetTerrainSmoothing terrain, 1
   BT SetTerrainQuadRotation terrain, 1

CHECK OUT MY WEBSITE AT http://imageposeidon.com/ !

Back to top

Profile

JackDawson

13

Years of Service

User Offline

Joined: 12th Jul 2011

Location:

Posted: 14th Aug 2011 17:30

Link

KISTech, here is a picture of the Error message.

"If you can sing that high, you must have been kicked in the crotch a little too hard."

Attachments

Login to view attachments

Back to top

Profile PM

KISTech

16

Years of Service

User Offline

Joined: 8th Feb 2008

Location: Aloha, Oregon

Posted: 14th Aug 2011 19:24 Edited at: 14th Aug 2011 19:29

Link

@Jack, post the code for the build terrain section. I'm pretty sure I know what the problem is.

[edit]
Here is what the LoadTerrain function should look like in the Endless Terrain demo.

+ Code Snippet

function LoadTerrain(tt as dword, tx as integer, tz as integer)
	Terr(tt).id = BT MakeTerrain()
	BT SetTerrainHeightMap Terr(tt).id, Terr(tt).img_h
	BT SetTerrainScale Terr(tt).id, TerrScale
	BT SetTerrainYScale Terr(tt).id, 4.0
	BT SetTerrainSplit Terr(tt).id, 8
	BT SetTerrainLOD Terr(tt).id, 3
	BT SetTerrainLODDistance Terr(tt).id, 1, 1500.0
	BT SetTerrainLODDistance Terr(tt).id, 2, 2000.0
	BT SetTerrainSmoothing Terr(tt).id, 1
	BT SetTerrainQuadRotation Terr(tt).id, 1
	Terr(tt).objid = find free object()
	BT BuildTerrain Terr(tt).id, Terr(tt).objid, 1
	texture object Terr(tt).objid, 0, Terr(tt).img_t
	position object Terr(tt).objid, TerrWidth * tx, 0.0, TerrWidth * tz
endfunction

Back to top

Profile PM Email Website

Mugen Wizardry

User Banned

Posted: 14th Aug 2011 19:43 Edited at: 14th Aug 2011 19:51

Link

I'm getting a black terrain. Why is that? I environment mapped it correctly, scaled it correctly, and the heightmap & envmap images are size 512x512.

I need to fix this in order to complete the LandScape Generator.

function InitWorld

imgTer = Find Free Image()
   Load Image "terrain\HM0000.bmp", imgTer
   imgEnv = Find Free Image()
   Load Image "terrain\EnvMap0000.png", imgEnv
   imgDet = Find Free Image()
   Load Image "terrain\detail.jpg", imgDet
   imgTex = Find Free Image()
   Load Image "terrain\Texture0000.png", imgTex

Global terrain as integer

terrain = BT MakeTerrain()
   BT SetTerrainHeightMap terrain, imgTer

BT SetTerrainEnvironment terrain, imgEnv
   
   BT SetTerrainScale terrain, 5
   BT SetTerrainYScale terrain, 1.5
   BT SetTerrainSplit terrain, 128

BT SetTerrainLOD terrain, 3
   BT SetTerrainLODDistance terrain, 1, 1500.0
   BT SetTerrainLODDistance terrain, 2, 1000.0

BT SetTerrainSmoothing terrain, 1
   BT SetTerrainQuadRotation terrain, 1

For i = 1 to Array Count(environments())
		e = BT AddTerrainEnvironment(terrain, RGB(environments(i).ColorR, environments(i).ColorG, environments(i).ColorB))
	Next 
	
	i = LookUpEnv( "road")
	environments(i).veg = 0
	i = LookUpEnv( "border")
	environments(i).veg = 0

BT BuildTerrain terrain, 1

BT SetBuildStep 0

repeat
      progress = BT ContinueBuild()
   until progress=-1

set Object effect terrain, terFX

Global objScale
	objScale = BT GetTerrainSize(terrain) / Image Width(imgTer)
	Global WorldSize 
	WorldSize = BT GetTerrainSize(terrain)

Global map
	map = FindFreeObject()
	Make Object Plain map, 100, 100
	mapImg = Find Free Image()
	Load Image "terrain/map.png", mapImg
	Texture Object map, mapImg
	Position Object map, 0, 0, 100
	Lock Object On map
	
	Global mapMarker
	mapMarker = FindFreeObject()
	Make Object Sphere mapMarker, 1
	mapImg = Find Free Image()
	Position Object mapMarker, -50, -50, 99
	Lock Object On mapMarker
	
	Hide Object map 
	Hide Object mapMarker

endFunction

+ Code Snippet

function InitWorld

   imgTer = Find Free Image()
   Load Image "terrain\HM0000.bmp", imgTer
   imgEnv = Find Free Image()
   Load Image "terrain\EnvMap0000.png", imgEnv
   imgDet = Find Free Image()
   Load Image "terrain\detail.jpg", imgDet
   imgTex = Find Free Image()
   Load Image "terrain\Texture0000.png", imgTex

	Global terrain as integer

   terrain = BT MakeTerrain()
   BT SetTerrainHeightMap terrain, imgTer

   BT SetTerrainEnvironment terrain, imgEnv
   
   BT SetTerrainScale terrain, 5
   BT SetTerrainYScale terrain, 1.5
   BT SetTerrainSplit terrain, 128

   BT SetTerrainLOD terrain, 3
   BT SetTerrainLODDistance terrain, 1, 1500.0
   BT SetTerrainLODDistance terrain, 2, 1000.0

   BT SetTerrainSmoothing terrain, 1
   BT SetTerrainQuadRotation terrain, 1

	For i = 1 to Array Count(environments())
		e = BT AddTerrainEnvironment(terrain, RGB(environments(i).ColorR, environments(i).ColorG, environments(i).ColorB))
	Next 
	
	i = LookUpEnv( "road")
	environments(i).veg = 0
	i = LookUpEnv( "border")
	environments(i).veg = 0

   BT BuildTerrain terrain, 1

   BT SetBuildStep 0

   repeat
      progress = BT ContinueBuild()
   until progress=-1

   set Object effect terrain, terFX

	Global objScale
	objScale = BT GetTerrainSize(terrain) / Image Width(imgTer)
	Global WorldSize 
	WorldSize = BT GetTerrainSize(terrain)

	Global map
	map = FindFreeObject()
	Make Object Plain map, 100, 100
	mapImg = Find Free Image()
	Load Image "terrain/map.png", mapImg
	Texture Object map, mapImg
	Position Object map, 0, 0, 100
	Lock Object On map
	
	Global mapMarker
	mapMarker = FindFreeObject()
	Make Object Sphere mapMarker, 1
	mapImg = Find Free Image()
	Position Object mapMarker, -50, -50, 99
	Lock Object On mapMarker
	
	Hide Object map 
	Hide Object mapMarker

endFunction

the part to look at:

+ Code Snippet

   imgTer = Find Free Image()
   Load Image "terrain\HM0000.bmp", imgTer
   imgEnv = Find Free Image()
   Load Image "terrain\EnvMap0000.png", imgEnv
   imgDet = Find Free Image()
   Load Image "terrain\detail.jpg", imgDet
   imgTex = Find Free Image()
   Load Image "terrain\Texture0000.png", imgTex

	Global terrain as integer

   terrain = BT MakeTerrain()
   BT SetTerrainHeightMap terrain, imgTer

   BT SetTerrainEnvironment terrain, imgEnv
   
   BT SetTerrainScale terrain, 5
   BT SetTerrainYScale terrain, 1.5
   BT SetTerrainSplit terrain, 128

   BT SetTerrainLOD terrain, 3
   BT SetTerrainLODDistance terrain, 1, 1500.0
   BT SetTerrainLODDistance terrain, 2, 1000.0

   BT SetTerrainSmoothing terrain, 1
   BT SetTerrainQuadRotation terrain, 1

Yes, all the images exist in their proper folders

Thank you guys!

CHECK OUT MY WEBSITE AT http://imageposeidon.com/ !

Back to top

Profile

JackDawson

13

Years of Service

User Offline

Joined: 12th Jul 2011

Location:

Posted: 14th Aug 2011 20:44 Edited at: 14th Aug 2011 20:46

Link

KRISTech, yes I am already using that code. No change.

Here is the whole code I get from your ZIP file. Oh and your EXE demo file you have already compiled no longer works either. And I do not know why. It used too. I am using same OS.

As for libraries I am not sure whats up. But I get the same error on your demo EXE file now as well.