Sorry your browser is not supported!

Global MatrixX = 0
Global MatrixZ = 0

Seed =1
Do
   Cls
   Set Cursor 0,0
   Randomize Seed
   Print "Seed: ";Seed
   Print ""Random" Numbers: ";Rnd(100);", ";Rnd(100);", ";Rnd(100)
   Seed=Seed+Upkey()-Downkey()
   Sleep 30
Loop

REM Project: Caverunner
REM Created: 01/10/2005 09:05:41
REM
REM ***** Main Source File *****
REM
autocam off
rem make the matrix
make matrix 1, 1000, 1000, 20, 20
randomize matrix 1, 50
rem scroll the landscape
do
shift matrix down 1
position camera 50, 40, 70
sync rate 10
UPDATE MATRIX 1
loop
do
if leftkey()=1 then z=z+1
if rightkey()=1 then z=z-1
 position camera 0, 0, z
loop

`beginning of code
sync on
sync rate 100

`main loop
do

`main program goes here

sync
loop 

do
if leftkey()=1 then z=z+1
if rightkey()=1 then z=z-1
 position camera 0, 0, z
loop

if upkey()=1 then shift matrix down 1
if downkey()=1 then shift matrix up 1

set display mode 1280, 1024, 32
sync on
sync rate 0
backdrop on
color backdrop 0


#CONSTANT imgX 128
#CONSTANT imgY 128

oX = 0
oY = 0
generateTerrain(0,0)

`set sprite uv
frameTime# = 1.0
startTime = timer()
do
   frameTime# = (frameTime# * 0.8) + ((timer() - startTime) * 0.2)
   startTime = timer()

   if leftkey()  then dec oX : generateTerrain(oX, oY)
   if rightkey() then inc oX : generateTerrain(oX, oY)
   if upkey()    then dec oY : generateTerrain(oX, oY)
   if downkey()  then inc oY : generateTerrain(oX, oY)


   paste image 1, 0, 0
   sync
loop
end


function generateTerrain(offsetX, offsetY)
   if memblock exist(1) = 0
      make memblock 1, 12 + (imgX * imgY * 4)
      write memblock dword 1, 0, imgX
      write memblock dword 1, 4, imgY
      write memblock dword 1, 8, 32
   endif


   for x = 0 to imgX-1
      for y = 0 to imgY-1
         v# = (PerlinNoise_2D(x + offsetX, y + offsetY) + 1.0) * 127.0
         write memblock dword 1, 12 + ((y*imgX) + x)*4, rgb(v#, v#, v#)
         if escapekey() then end
      next y
   next x

   make image from memblock 1, 1
endfunction



`Linear Interpolation... Not the best - but damn quick!
function Interpolate(a#, b#, x#)
   v# = (a# * (1.0 - x#) + b# * x#)
endfunction v#





function Noise(x,y)
   n as DWORD
   n = x + y * 57
   `text 0, 20, "result: " + str$(n)
   `n = (n << 13) ^ n
   `text 0, 30, "result: " + str$(n)
   result# = (1.0 - ((n * (n * n * 15731 + 789221) + 1376312589) && 0x7fffffff) / 1073741824.0)

endfunction result#




function SmoothedNoise(x, y)
   corners# = ( Noise(x-1,y-1)+Noise(x+1,y+1)+Noise(x+1,y-1)+Noise(x-1,y+1) ) / 16.0
   sides#   = ( Noise(x-1,y  )+Noise(x+1,y  )+Noise(x  ,y-1)+Noise(x  ,y+1) ) /  8.0
   center#  = ( Noise(x  ,y  ) ) / 4.0
   v# = corners#+sides#+center#
endfunction v#






`Produce interpolated noise for pixel x, y
function InterpolatedNoise(x#, y#)
remstart
   intX = int(x#)
   fracX# = x# - intX

   intY = int(y#)
   fracY# = y# - intY
   v1# = SmoothedNoise(IntX  , intY  )
   v2# = SmoothedNoise(IntX+1, intY  )
   v3# = SmoothedNoise(IntX  , intY+1)
   v4# = SmoothedNoise(IntX+1, intY+1)

   i1# = Interpolate(v1#, v2#, fracX#)
   i2# = Interpolate(v3#, v4#, fracX#)

   final# = Interpolate(i1#, i2#, fracY#)
remend
   final# = SmoothedNoise(x#, y#)
endfunction final#






`Produce noise for pixel x,y
function PerlinNoise_2D(x, y)
   total# = 0
   `Persistance
   p# = 0.25
   `Number of Octaves
   n = 1

   for i = 0 to n-1
      frequency# = 2.0 ^ i
      amplitude# = p# ^ i

      inc total#, InterpolatedNoise(x * frequency#, y * frequency#) * amplitude#
   next i
endfunction total#

set display mode 1280, 1024, 32
sync on
sync rate 0
backdrop on
color backdrop 0


#CONSTANT imgX 128
#CONSTANT imgY 128
#CONSTANT imgScale 0.1

global oX# : global oY#
oX# = 10.0
oY# = 10.0

generateTerrain()

`set sprite uv
frameTime# = 1.0
startTime = timer()
do
   frameTime# = (frameTime# * 0.8) + ((timer() - startTime) * 0.2)
   startTime = timer()

   if leftkey()  then shiftTerrainLeft()
   if rightkey() then shiftTerrainRight()
   if upkey()    then shiftTerrainUp()
   if downkey()  then shiftTerrainDown()


   paste image 1, 0, 0

   text 200, 200, "FPS: " + str$(screen fps())
   sync
loop
end






function generateTerrain()
   if memblock exist(1) = 0
      make memblock 1, 12 + (imgX * imgY * 4)
      write memblock dword 1, 0, imgX
      write memblock dword 1, 4, imgY
      write memblock dword 1, 8, 32
   endif


   for x = 0 to imgX-1
      for y = 0 to imgY-1
         v# = (PerlinNoise_2D((x * imgScale) + oX#, (y * imgScale) + oY#) + 1.0) * 127.0
         write memblock dword 1, 12 + ((y*imgX) + x)*4, rgb(v#, v#, v#)
         if escapekey() then end
      next y
   next x

   make image from memblock 1, 1
endfunction


function shiftTerrainDown()
   inc oY#, imgScale
   rowWidth = imgX * 4

   for i = rowWidth + 12 to get memblock size(1)-1 step 4
      write memblock dword 1, i - rowWidth, memblock dword(1, i)

      if i >= get memblock size(1) - rowWidth
         n = i-12
         x = (n MOD rowWidth) / 4
         y = n / rowWidth
         v# = (PerlinNoise_2D((x * imgScale) + oX#, (y * imgScale) + oY#) + 1.0) * 127.0
         write memblock dword 1, i, rgb(v#, v#, v#)
      endif
   next i

   make image from memblock 1, 1
endfunction








function shiftTerrainUp()
   dec oY#, imgScale
   rowWidth = imgX * 4

   for i = get memblock size(1)-rowWidth-4 to 12 step -4
      write memblock dword 1, i+rowWidth, memblock dword(1, i)

      if i <= rowWidth+12
         n = i-12
         x = n / 4
         y = n / rowWidth
         v# = (PerlinNoise_2D((x * imgScale) + oX#, (y * imgScale) + oY#) + 1.0) * 127.0
         write memblock dword 1, i, rgb(v#, v#, v#)
      endif
   next i

   make image from memblock 1, 1
endfunction









function shiftTerrainRight()
   dec oX#, imgScale

   rowWidth = imgX * 4

   for i = 12 to get memblock size(1)-1 step 4
      n = i-12
      x = (n MOD rowWidth) / 4

      if x < imgX-1
         write memblock dword 1, i, memblock dword(1, i + 4)
      else
         y = n / rowWidth
         v# = (PerlinNoise_2D((x * imgScale) + oX#, (y * imgScale) + oY#) + 1.0) * 127.0
         write memblock dword 1, i, rgb(v#, v#, v#)
      endif

   next i

   make image from memblock 1, 1
endfunction










function shiftTerrainLeft()
   inc oX#, imgScale

   rowWidth = imgX * 4

   for i = get memblock size(1)-4 to 12 step -4
      n = i-12
      x = (n MOD rowWidth) / 4

      if x > 0
         write memblock dword 1, i, memblock dword(1, i - 4)
      else
         y = n / rowWidth
         v# = (PerlinNoise_2D((x * imgScale) + oX#, (y * imgScale) + oY#) + 1.0) * 127.0
         write memblock dword 1, i, rgb(v#, v#, v#)
      endif

   next i

   make image from memblock 1, 1
endfunction














`Try unremarking one of these. Only one of the Interpolate functions should be unremarked when running


`No Interpolation.. This is VERY fast ;-)
`function Interpolate(a#, b#, x#)
`endfunction a#



`Linear Interpolation... Not the best - but damn quick!
`function Interpolate(a#, b#, x#)
`   v# = (a# * (1.0 - x#)) + (b# * x#)
`endfunction v#




`Cosine Iterpolation... Slightly slower than above, but better
function Interpolate(a#, b#, x#)
   ft# = x# * 180.0
   f# = (1 - cos(ft#)) * 0.5
   v# = (a# * (1.0 - f#)) + (b# * f#)
endfunction v#






function Noise(x,y)
   n = x + y * 57
   `n = (n << 13) ^ n
   result# = (1.0 - ((n * (n * n * 15731 + 789221) + 1376312589) && 0x7fffffff) / 1073741824.0)

endfunction result#




function SmoothedNoise(x, y)
   corners# = ( Noise(x-1,y-1)+Noise(x+1,y+1)+Noise(x+1,y-1)+Noise(x-1,y+1) ) / 16.0
   sides#   = ( Noise(x-1,y  )+Noise(x+1,y  )+Noise(x  ,y-1)+Noise(x  ,y+1) ) /  8.0
   center#  = ( Noise(x  ,y  ) ) / 4.0
   v# = corners#+sides#+center#
endfunction v#






`Produce interpolated noise for pixel x, y
function InterpolatedNoise(x#, y#)
   intX = int(x#) : fracX# = x# - intX
   intY = int(y#) : fracY# = y# - intY

   v1# = SmoothedNoise(IntX  , intY  )
   v2# = SmoothedNoise(IntX+1, intY  )
   v3# = SmoothedNoise(IntX  , intY+1)
   v4# = SmoothedNoise(IntX+1, intY+1)

   i1# = Interpolate(v1#, v2#, fracX#)
   i2# = Interpolate(v3#, v4#, fracX#)

   final# = Interpolate(i1#, i2#, fracY#)
   `final# = SmoothedNoise(x#, y#)
endfunction final#






`Produce noise for pixel x,y
function PerlinNoise_2D(x#, y#)
   total# = 0
   `Persistance
   p# = 0.25
   `Number of Octaves
   n = 1

   for i = 0 to n-1
      frequency# = 2.0 ^ i
      amplitude# = p# ^ i

      inc total#, InterpolatedNoise(x# * frequency#, y# * frequency#) * amplitude#
   next i
endfunction total#

Rem Never Ending Matrix Example By TDK_Man Oct 2005
Gosub Setup

Do
  Gosub InputControls
  Gosub ScrollMatrix
  Sync
  Center Text 512,0,"Flight Sim-Style Mouse Control: [LMB] Increase Speed [RMB] Decrease Speed     Options: [W]ireframe [Textured]"
  S=Scancode()
  If S=17
    Set Matrix Wireframe On 1
    Repeat
    Until Scancode()<>17
  Endif
  If S=20
    Set Matrix Wireframe Off 1
    Repeat
    Until Scancode()<>20
  Endif
Loop

InputControls:
  CX=Camera Angle X(): CY=Camera Angle Y(): CZ=Camera Angle Z()
  CY=Wrapvalue(CY+mousemovex())
  CX=Wrapvalue(CX-mousemovey())
  Rotate Camera CX,CY,CZ
  If MouseClick()=1 Then Inc Speed#,5
  If MouseClick()=2 Then Dec Speed#,5: If Speed# < 0.0 Then Speed#=0.0
  If Camera Angle X()>300 and Camera Angle X()<=359
    Rem Up
    ClimbRate = 359-Camera Angle X()
    Inc CamPosY,ClimbRate*Speed#
  Endif
  If Camera Angle X()>=1 and Camera Angle X()<90
    Rem Down
    ClimbRate = Camera Angle X()
    Dec CamPosY,ClimbRate*Speed#
  Endif
  Floor = Get Ground Height(1,MatCentreX-MatrixXPosition,MatCentreZ-MatrixZPosition)+300
  If CamPosY < Floor Then CamPosY = Floor
  Position Camera MatCentreX,CamPosY,MatCentreZ
Return

ScrollMatrix:
  Inc MatrixXPosition,Int(DirX#(CY)*Speed#)
  Inc MatrixZPosition,0-(Int(DirZ#(CY))*Speed#)
  If MatrixZPosition <= 0-TileHeight
    MatrixZPosition = 0
    Shift Matrix Down 1
    for f=0 to TilesX
      set matrix height 1,f,TilesZ,get matrix height(1,f,0)
    next f
  Endif
  If MatrixZPosition >= TileHeight
    MatrixZPosition = 0
    Shift Matrix Up 1
    for f=0 to TilesX
      set matrix height 1,f,0,get matrix height(1,f,TilesZ)
    next f
  Endif
  If MatrixXPosition <= 0-TileWidth
    MatrixXPosition = 0
    Shift Matrix Left 1
    for f=0 to TilesZ : set matrix height 1,TilesX,f,get matrix height(1,0,f) : next f
  Endif
  If MatrixXPosition >= TileWidth
    MatrixXPosition = 0
    Shift Matrix Right 1
    for f=0 to TilesZ : set matrix height 1,0,f,get matrix height(1,TilesX,f) : next f
  Endif
  Position Matrix 1, MatrixXPosition,0,MatrixZPosition
Return

Setup:
  Randomize Timer()
  Dim DirX#(359)
  Dim DirZ#(359)
  Gosub CalcDirection: Rem Direction Percentage For All Camera Angles
  Sync On: Sync Rate 60
  CLS 0
  Set Display Mode 1024,768,16
  Hide Mouse

  Rem Initial Variables
  MatPixelWidth = 30000000: MatPixelHeight = 30000000
  TilesX = 70: TilesZ = 70
  MatCentreX = MatPixelWidth/2
  MatCentreZ = MatPixelHeight/2
  TileWidth = MatPixelWidth/TilesX
  TileHeight = MatPixelHeight/TilesZ
  MatrixXPosition = 0
  MatrixZPosition = 0
  Hills = 100
  Speed# = 0

  Set Camera view 0,0,1,1: CLS 0
  Text 0,0,"Please Wait - Initialising Terrain...": Sync: Sync

  Make Matrix 1,MatPixelWidth,MatPixelHeight,TilesX,TilesZ
  Position Matrix 1, MatrixXPosition,0,MatrixZPosition

  Color Backdrop 0
  Fog On
  Fog Color 0
  Fog Distance MatCentreX/2

  For N = 1 To Hills
    X = Rnd(TilesX-2)+1: Z = Rnd(TilesZ-2)+1
    Set Matrix Height 1,x,z,(Rnd(3000)+2000)*1000
    Set Matrix Height 1,x-1,z-1,(Rnd(2000)+1500)*1000
    Set Matrix Height 1,x+1,z-1,(Rnd(2000)+1500)*1000
    Set Matrix Height 1,x-1,z+1,(Rnd(2000)+1500)*1000
    Set Matrix Height 1,x+1,z+1,(Rnd(2000)+1500)*1000
  Next N

  Rem Now Smooth The Hills
  For N = 1 To 5
    Gosub Smooth
  Next N

  Gosub TextureMatrix
  Update Matrix 1
  Set Matrix Wireframe On 1

  CamPosY = Get Ground Height(1,MatCentrex,MatCentrez)+300
  Position Camera MatCentreX,CamPosY,MatCentreZ
  Set Camera Range 30.0,MatPixelWidth*2

  Set Camera view 0,0,1024,768
Return

Smooth:
  Rem Averages matrix heights to remove jagged edges
  For Z=0 to TilesZ
    For X=0 to TilesX
      P0#=Get Matrix Height(1,X,Z):     Rem Current point height
      Rem Get 4 adjoining points heights (if they exist)
      If Z-1 > 0
        P1#=Get Matrix Height(1,X,Z-1)
      Else
        P1#=Get Matrix Height(1,X,TilesZ)
      Endif
      If X+1 < TilesX
        P2#=Get Matrix Height(1,X+1,Z)
      Else
        P2#=Get Matrix Height(1,0,Z)
      Endif
      If Z+1 < TilesZ
        P3#=Get Matrix Height(1,X,Z+1)
      Else
        P3#=Get Matrix Height(1,X,0)
      Endif
      If X-1 > 0
        P4#=Get Matrix Height(1,X-1,Z)
      Else
        P4#=Get Matrix Height(1,TilesX,Z)
      Endif
      Average#=(P0#+P1#+P2#+P3#+P4#)/5: Rem Av height of other points
      Set Matrix Height 1,x,z,Average#
    Next x
  Next z
Return

CalcDirection:
  For Angle = 0 To 359
    If Angle = 0
      Rem Up
      DirX#(Angle) = 0.0
      DirZ#(Angle) = 90.0
    Endif
    If ANGLE > 0 and ANGLE < 90
      Rem up left   1 to 89
      DirX#(Angle) = 0-ANGLE
      DirZ#(Angle) = 90.0 - ANGLE
    Endif
    If ANGLE = 90
      Rem left   90
      DirX#(Angle) = 0-90.0
      DirZ#(Angle) = 0.0
    Endif
    If ANGLE > 90 and ANGLE < 180
      Rem Down left - 91 to 179
      DirX#(Angle) = 0 - (180.0 - ANGLE)
      DirZ#(Angle) = 0 - (ANGLE - 90.0)
    Endif
    If ANGLE = 180
      Rem Down
      DirX#(Angle) = 0.0
      DirZ#(Angle) = 0 - (ANGLE-90.0)
    Endif
    If ANGLE > 180 and ANGLE < 270
      Rem Down Right  181 - 269
      DirX#(Angle) = ANGLE - 180.0
      DirZ#(Angle) = 0 - (270.0-ANGLE)
    Endif
    If ANGLE = 270
      Rem Right   270
      DirX#(Angle) = 360.0-ANGLE: Rem Was 181-
      DirZ#(Angle) = 0.0
    Endif
    If ANGLE > 270 and ANGLE < 360
      Rem Up Right 271 to 359
      DirX#(Angle) = 360.0 - ANGLE
      DirZ#(Angle) = 90.0-(360.0 - ANGLE)
    Endif
  Next Angle
Return

TextureMatrix:
  Create Bitmap 1,600,600
  TextureImageSize = 512
  CLS RGB(35,40,0)
  RatioX = MatPixelWidth/TextureImageSize
  RatioZ = MatPixelHeight/TextureImageSize
  Hi = 0: Lo = 500000
  For Nz = 0 To TextureImageSize
    For Nx = 0 To TextureImageSize
      MatHeight = Get Ground Height(1,Nx*RatioX,Nz*RatioZ)
      If MatHeight > Hi Then Hi = MatHeight
      If MatHeight < Lo Then Lo = MatHeight
    Next Nx
  Next Nz
  RatioY = (Hi-Lo)/255
  For Nz = 0 To TextureImageSize
    For Nx = 0 To TextureImageSize
      MatHeight = Get Ground Height(1,Nx*RatioX,(TextureImageSize-Nz)*RatioZ)
      Band = (MatHeight/RatioY)
      Rem Muddy
      If Band < 4
        R = Band+Rnd(64)+32
        G = Band+Rnd(64)+48
        B = 0
      Endif
      Rem Grassy
      If Band >= 4 and Band < 32
        R = Band
        G = Band+Rnd(64)+48
        B = 0
      Endif
      Rem Grass To Rocky
      If Band >= 32 and Band < 64
        R = Band-Rnd(32)
        G = Band+Rnd(32)+32
        B = R
      Endif
      Rem Mountain Base
      If Band >= 64 and Band < 100
        R = Band-Rnd(32)
        G = Band+Rnd(32)
        B = Band-Rnd(32)-32
      Endif
      Rem Rocky
      If Band >= 100 and Band < 128
        R = Band-Rnd(64)
        G = R
        B = R
      Endif
      Rem Rocky Snow
      If Band >= 128 and Band < 164
        R = Band+Rnd(64)
        G = R
        B = R
      Endif
      Rem Snowy
      If Band >= 164
        R = 255
        G = 255
        B = 255
      Endif
      If  Band < 100
        If Rnd(10)<>0 Then Ink RGB(R,G,B),0: Dot Nx,Nz
      Else
       Ink RGB(R,G,B),0: Dot Nx,Nz
      Endif
    Next Nx
  Next Nz
  Blur Bitmap 1,7
  sync
  Get Image 1,0,0,TextureImageSize-1,TextureImageSize-1
  Sleep 2
  Set Current Bitmap 0
  Delete Bitmap 1
  CLS
  Prepare Matrix Texture 1,1,TilesX,TilesZ
  t=1
  For z = TilesZ-1 to 0 Step -1
    For x = 0 to TilesX-1
      Set Matrix Tile 1,x,z,t
      Inc t
    Next x
  Next z
  Ink RGB(255,255,255),0
Return

`Globals; Can be changed
Global CameraSpeed = 1
Global MatrixSide = 200
Global NumSquares = 20
Global HeightConstant = 20
Global MaxAddHeight = 10
Global SmoothnessConstant = 20

`No point changing these
Global MatrixX As Float
Global MatrixZ As Float

`Screen Stuff
Sync on
Sync Rate 60

Fog on
Fog Distance MatrixSide*.8
Fog Color 0,0,200
color backdrop rgb(0,0,200)




PrepareMatrixes()

Position Camera (MatrixSide*3)/2,HeightConstant*5,(MatrixSide*3)/2




Do

`Control Camera Using Arrowkeys 0,1,1
If upkey() = 1 Then Pitch camera up CameraSpeed
If downkey() = 1 Then Pitch camera down CameraSpeed
If leftkey() = 1 Then Turn Camera left CameraSpeed
If rightkey() = 1 Then Turn Camera right CameraSpeed

If shiftkey() = 1 Then Move Camera CameraSpeed
If controlkey() = 1 Then Move Camera -CameraSpeed


CheckMatrixes()

Text 0,0,str$(screen fps())
`Text 0,20,str$(get ground height(5,Camera Position X(), Camera Position Z()))
`Text 0,40,str$(Camera Position X())
`Text 150,40,str$(Camera Position Z())

Sync
Loop




Function PrepareMatrixes()

`Grass Texture
cls
box 0,0,100,100,rgb(100,200,100),rgb(100,200,100),rgb(100,200,100),rgb(100,200,100)
Get Image 1,0,0,100,100

For x = 0 To 2
	For z = 0 To 2
		Make Matrix x*3+z+1, MatrixSide, MatrixSide, NumSquares, Numsquares
		Prepare Matrix Texture x*3+z+1, 1, 1, 1
	Next z
Next x

UpdateMatrixes()			

endfunction







Function CheckMatrixes()
	
CameraX = Camera Position X()
CameraZ = Camera Position Z()

If MatrixX + MatrixSide >= CameraX
	MatrixX = MatrixX - MatrixSide	
	Update = 1
endif

If MatrixX + (MatrixSide*2) <= CameraX
	MatrixX = MatrixX + MatrixSide	
	Update = 1
endif

If MatrixZ + MatrixSide >= CameraZ
	MatrixZ = MatrixZ	- MatrixSide
	update = 1
endif

If MatrixZ + (MatrixSide*2) <= CameraZ
	MatrixZ = MatrixZ + MatrixSide
	update = 1
endif


If update = 1 Then Updatematrixes()

Endfunction







Function Updatematrixes()
	
NumberX as float
NumberZ as float
smoothness as float
height as float

For x = 0 To 2
	For z = 0 To 2

		For TileX = 0 To NumSquares
			FOr TileZ = 0 To NumSquares
            NumberX = wrapvalue(((MatrixX/MatrixSide)+x)*(Numsquares)+ TileX)
            NumberZ = wrapvalue(((MatrixZ/MatrixSide)+z)*(Numsquares)+ TileZ)
				smoothness = SmoothnessConstant
				Height = cos((NumberX)+(NumberZ))*MaxAddHeight         				
				Set Matrix Height x*3+z+1, TileX, TileZ, HeightConstant*((sin(NumberX*smoothness)+sin(NumberZ*smoothness))+Height)
				
			next tileZ
		next tilex
	   Position Matrix x*3+z+1, (x*MatrixSide)+MatrixX, 0, (z*MatrixSide) + MatrixZ
	Next z
Next x

endfunction
 

`Real-time Matrix/Canyon generator (intemediate tutorial)
`======================
`©CPU
`======================
`*note* many times I will refer to a matrix with x,y coordites, the
`help files refer to them as x,z coordintes.  If you were looking at
`a matrix from the top this is what you would see:
`  help files              Me
`  ____z____           ____y____
` |    |    |         |    |    |
` |    |    |         |    |    |
` -----------x        -----------x
` |    |    |         |    |    |
` |____|____|         |____|____|


rem this will go to a subroutene that will set up our display mode
rem fonts, system optitions and other things that belong at the
rem very begining of our code
gosub startup

rem general varibles
#constant camera_matrix_collision = 1
#constant camera_radius = 15
#constant fogYN = 1
#constant fogcolor = RGB(188,165,129)
#constant fogdis = 2000

rem some matrix specific numbers
#constant matrix_tilex = 50
#constant matrix_tiley = 50
#constant matrix_number = 1
#constant matrix_image = 1
#constant matrix_wire_num = 2
#constant matrix_offsetx = 0
#constant matrix_offsety = 0
#constant matrix_offsetz = 0
#constant matrix_width = 1000
#constant matrix_height = 1000

rem initialize some vaibles and constants used in the terrain
#constant turnchance = 3
#constant turn_base = 8
#constant turn_dev = 5
#constant hillchance = 7
#constant hill_base = 10
#constant hill_dev = 5
#constant hill_sharpness = 5
#constant narrow_chance = 10
#constant narrow_base = 3
#constant narrow_dev = 4
#constant spikechance = 100
#constant spikeheight = 25
#constant height_min = 50
#constant height_max = 300
#constant width_min = 5
#constant width_max = 25
#constant roughness = 0

`build an initial canyon so we don't start out with a flat matrix...
gosub initialCanyonBuild

repeat
	
	rem control mouse, if control key is pressed move 7 units at a time
	rem instead of moving 3 units normaly
	if controlkey() = 1
		MouseControl(7)
	else
		MouseControl(3)
	endif
	
	rem if shiftkey is pressed then shift the matrix down and update the canyon
	if shiftkey() = 1
		shift matrix down matrix_number
		gosub canyon
		equate_matrix(matrix_number, matrix_wire_num, matrix_tilex, matrix_tiley)
		update matrix matrix_number
		update matrix matrix_wire_num
	endif
	
	rem position the wireframe overlay if the returnkey is pressed
	if returnkey() = 1
		position matrix matrix_wire_num, matrix_offsetx, matrix_offsety + 0.5, matrix_offsetz
	else
		rem unfortunatly there is no "hide matrix" command
		position matrix matrix_wire_num,-100000,-100000,-100000
	endif

	rem display some text and update screen
	gosub ScreenPrompts
	sync
rem exit on escapekey
until escapekey() = 1
end

startup:
	rem housecleaning
	set display mode 800,600,32
	sync on
	sync rate 0
	hide mouse
	
	rem makes it so that the camera doesn't intstantly zoom to newly created objects
	autocam off
	
	color backdrop rgb(0,0,0)
	set text size 10
	
	rem turn on fog
	if fogYN = 1 and fog available() = 1
		fog on
		fog color fogcolor
		fog distance fogdis
	endif
	
	rem set the random seed so that the canyon is different every time
	randomize timer()
return

`the first time we go through our code we need to initaly setup the canyon

initialCanyonBuild:
rem these are varibles used to turn, vary the height and narrow or
rem widen the matrix canyon
global turn as integer = 0
global narrow as integer = 0
global hill as integer = 0

rem these are some varibles that hold what height, width, and
rem position(offset) the matrix is updating at
global tilex as integer = 0
global tiley as integer = 0
global offset as integer = 20
global canyon_width as integer = 10
global canyon_height_factor as integer = 100

rem create the ground matrix
`load image "ground.jpg", matrix_image,0
GroundTexture(matrix_image)
make matrix matrix_number, matrix_width, matrix_height ,matrix_tilex, matrix_tiley
prepare matrix texture matrix_number,matrix_image, 1, 1
set matrix texture matrix_number, 1, 1
position matrix matrix_number, matrix_offsetx, matrix_offsety, matrix_offset

rem make the overlay wireframe matrix
make matrix matrix_wire_num, matrix_width, matrix_height, matrix_tilex, matrix_tiley
position matrix matrix_wire_num, matrix_offsetx, matrix_offsety + 0.5, matrix_offsetz
set matrix wireframe on matrix_wire_num
set matrix priority matrix_wire_num, 1


rem this generates a canyon so you don't start with a flat matrix
for tiley = 0 to matrix_tiley - 1
   gosub canyon
next tiley

rem update the matrixs so that you can see the changes
update matrix matrix_number
equate_matrix(matrix_number, matrix_wire_num, matrix_tilex, matrix_tiley)
update matrix matrix_wire_num

rem tiley is the varible that tells the computer which matrix square
rem to update in the y direction
tiley = matrix_tiley - 1

rem set the initial position of the camera
position camera 0,150,-500
return

canyon:
	rem handel the canyon turning
	gosub turn_canyon
	
	rem hande the changing the height of the canyon
	gosub hill_canyon
	
	rem hande the matrix narrowing and widening
	gosub narrow_canyon
	
	rem randomize the matrix
	for tilex = 0 to matrix_tilex - 1
		set matrix height matrix_number, tilex, tiley, rnd(roughness)
	next tilex
	
	rem handel the canyion turning
	rem form the canyon
	tmp_angle_inc = 180/(canyon_width)
	for tilex = offset to offset + canyon_width
		rem apply basic curve to the height
		height = -1*(sin((tilex - offset)*tmp_angle_inc) * canyon_height_factor)
		
		rem apply spike chance
		if rnd(spikechance) = 1
			height = height + (spikeheight/2.0) + rnd(spikeheight/2.0)
		endif
		
		rem apply roughness
		height = height + rnd(roughness)
		if tilex <= matrix_tilex and tiley <= matrix_tilex and tilex >= 0 and tiley >= 0
			set matrix height matrix_number, tilex, tiley, height
		endif
	next tilex
	
	rem make the far end a "wall"
	for tilex = 0 to matrix_tilex
	   set matrix height matrix_number,tilex,matrix_tiley,0
	next x
return

turn_canyon:
   rem make bends in the canyon
   if turn <> 0
      if turn > 0
         rem turn right
         if turn mod 2 = 0
            inc offset
         endif
         dec turn
      else
         rem turn left
         if turn mod 2 = 0
            dec offset
         endif
         inc turn
      endif
   else
   	rem if turnchance = 1 then turn canyon   
      if rnd(turnchance) = 1
      	rem if it equals 1 it's a right turn if it equals 0 its a left one
         if rnd(1) = 1
         	
            turn = turn_base + rnd(turn_dev)
            if offset + turn + width_max > matrix_tilex - 1
            	rem if the turn will "exit" the matrix then turn the oposite way
               turn = turn * -1
            endif
         else
            turn = -1 * turn_base - rnd(turn_dev)
            if offset + turn < 1
            	rem if the turn will "exit" the matrix then turn the oposite way
               turn = turn * -1
            endif
         endif
      endif
   endif
return

hill_canyon:
   rem make rises and falls in the height of the canyon
   if hill <> 0
      if hill > 0
         rem go down
         inc canyon_height_factor, hill_sharpness
         dec hill
      else
         rem go up
         dec canyon_height_factor, hill_sharpness
         inc hill
      endif
   else
   	rem if hillchance = 1 then raise or lower the canyon
      if rnd(hillchance) = 1
      	rem if it equals 1 it goes down, 0 it goes up
         if rnd(1) = 1
         	
            hill = hill_base + rnd(hill_dev)
            if (hill * hill_sharpness)+ canyon_height_factor > height_max
            	rem if the hill will go to low or to high then flip
            	rem the direction of the slope
               hill = hill * -1
            endif
         else
            hill = -1 * hill_base - rnd(hill_dev)
            if (hill * hill_sharpness)+ canyon_height_factor < height_min
            	rem if the hill will go to low or to high then flip
            	rem the direction of the slope
               hill = hill * -1
            endif
         endif
      endif
   endif
return

narrow_canyon:
rem narrow or widen the canyion
	if narrow <> 0
		if narrow > 0
			rem widen 
			inc canyon_width
			dec narrow
		else
			rem narrow
			dec canyon_width
			inc narrow
		endif
	else
		if rnd(narrow_chance) = 1
			rem if it equles 1 it gets narrower, 0 it gets wider
			if rnd(1) = 1
				narrow = -1 * narrow_base - rnd(narrow_dev)
				if narrow + canyon_width < width_min
					rem if its going to get to small then make it get bigger
					narrow = narrow * -1
				endif
			else
				narrow = narrow_base + rnd(narrow_dev)
				if narrow + canyon_width > width_max
					rem if it's going to get to wide then make it get smaller
					narrow = narrow * -1
				endif
			endif
		endif
	endif
return

ScreenPrompts:
   text 0,0,"Screen FPS = " + str$(screen fps())
   text 0,15,"Press Enter to overlay wireframe"
   text 0,30,"Press Shift to scroll matrix"
   text 0,45,"Use Left Mouse button to move forward"
   text 0,60,"Use Right Mouse button to move backwards"
   text 0,75,"Look using mouse"
return

function equate_matrix(matrix_a, matrix_b, xsize, ysize)
	rem this function makes matrix b equal to in form to matrix a
	for n = 0 to xsize
		for m = 0 to ysize
			set matrix height matrix_b, n, m, get matrix height(matrix_a, n, m)
		next m
	next n
endfunction

function MouseControl(Speed as float)
	xrotate camera camera angle x()+(mousemovey()/2.0)
	yrotate camera camera angle y()+(mousemovex()/2.0)
	if mouseclick()=1 then move camera Speed
	if mouseclick()=2 then move camera (0-Speed)
	
	rem this handels camera matrix collision
	if camera_matrix_collision = 1
		if camera position y() < get ground height(matrix_number, camera position x(), camera position z())+1
			position camera camera position x(), get ground height(matrix_number, camera position x(), camera position z())+camera_radius, camera position z()
		endif
	endif
endfunction

function GroundTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer
	
	local tmpXa as integer
	local tmpYa as integer
	local tmpXb as integer
	local tmpYb as integer
	
	local extream as integer
	
	xSize = 255
	ySize = 255
	
	cls rgb(120,90,70)
	for n = 1 to (xSize+ySize)*50
		extream = -60 + rnd(100)
		ink rgb(110+rnd(20)+extream,80+rnd(20)+extream,60+rnd(20)+extream),0
		circle rnd(xSize), rnd(ySize),3
	next n
	
	for n = 1 to (xSize+ySize)*3
		extream = -60 + rnd(100)
		ink rgb(110+rnd(20)+extream,80+rnd(20)+extream,60+rnd(20)+extream),0
		tmpXa = rnd(xSize)
		tmpYa = rnd(ySize)
		tmpXb = rnd(xSize)
		tmpYb = rnd(ySize)
			
		line tmpXa, tmpYa, tmpXb, tmpYb
		
		extream = -60 + rnd(100)
		ink rgb(110+rnd(20)+extream,80+rnd(20)+extream,60+rnd(20)+extream),0
		tmpXa = rnd(10)
		for x = 1 to 5
			circle rnd(xSize), rnd(ySize),5+tmpXa+x
		next x
	next n
	
	blur bitmap 0,5
	
	get image imgNum,xSize/4,ySize/4,(xSize*3)/4,(ySize*3)/4,0
endfunction

`Globals; Can be changed
Global CameraSpeed = 1
Global MatrixSide = 200
Global NumSquares = 20
Global HeightConstant = 20
Global MaxAddHeight = 10
Global SmoothnessConstant = 20

`No point changing these
Global MatrixX As Float
Global MatrixZ As Float

`Screen Stuff
Sync on
Sync Rate 60

Fog on
Fog Distance MatrixSide*.8
Fog Color 0,0,200
color backdrop rgb(0,0,200)




PrepareMatrixes()

Position Camera (MatrixSide*3)/2,HeightConstant*5,(MatrixSide*3)/2




Do

`Control Camera Using Arrowkeys 0,1,1
If upkey() = 1 Then Pitch camera up CameraSpeed
If downkey() = 1 Then Pitch camera down CameraSpeed
If leftkey() = 1 Then Turn Camera left CameraSpeed
If rightkey() = 1 Then Turn Camera right CameraSpeed

If shiftkey() = 1 Then Move Camera CameraSpeed
If controlkey() = 1 Then Move Camera -CameraSpeed


CheckMatrixes()

Text 0,0,str$(screen fps())
`Text 0,20,str$(get ground height(5,Camera Position X(), Camera Position Z()))
`Text 0,40,str$(Camera Position X())
`Text 150,40,str$(Camera Position Z())

Sync
Loop




Function PrepareMatrixes()

`Grass Texture
cls
box 0,0,100,100,rgb(100,200,100),rgb(100,200,100),rgb(100,200,100),rgb(100,200,100)
Get Image 1,0,0,100,100

For x = 0 To 2
	For z = 0 To 2
		Make Matrix x*3+z+1, MatrixSide, MatrixSide, NumSquares, Numsquares
		Prepare Matrix Texture x*3+z+1, 1, 1, 1
	Next z
Next x

UpdateMatrixes()			

endfunction







Function CheckMatrixes()
	
CameraX = Camera Position X()
CameraZ = Camera Position Z()

If MatrixX + MatrixSide >= CameraX
	MatrixX = MatrixX - MatrixSide	
	Update = 1
endif

If MatrixX + (MatrixSide*2) <= CameraX
	MatrixX = MatrixX + MatrixSide	
	Update = 1
endif

If MatrixZ + MatrixSide >= CameraZ
	MatrixZ = MatrixZ	- MatrixSide
	update = 1
endif

If MatrixZ + (MatrixSide*2) <= CameraZ
	MatrixZ = MatrixZ + MatrixSide
	update = 1
endif


If update = 1 Then Updatematrixes()

Endfunction







Function Updatematrixes()
	
NumberX as float
NumberZ as float
smoothness as float
height as float

For x = 0 To 2
	For z = 0 To 2

		For TileX = 0 To NumSquares
			FOr TileZ = 0 To NumSquares
            NumberX = wrapvalue(((MatrixX/MatrixSide)+x)*(Numsquares)+ TileX)
            NumberZ = wrapvalue(((MatrixZ/MatrixSide)+z)*(Numsquares)+ TileZ)
				smoothness = SmoothnessConstant
				Height = cos((NumberX)+(NumberZ))*MaxAddHeight         				
				Set Matrix Height x*3+z+1, TileX, TileZ, HeightConstant*((sin(NumberX*smoothness)+sin(NumberZ*smoothness))+Height)
				
			next tileZ
		next tilex
	   Position Matrix x*3+z+1, (x*MatrixSide)+MatrixX, 0, (z*MatrixSide) + MatrixZ
	Next z
Next x

endfunction
 

TDK - great piece of code that not only works well but looks great too!  Well done.

Segan - first couple of attempts

[edit:again]
also haveing trouble getting background colors to display correctly.
any comments/suggestions welcome.
Rem Project: frogger
Rem Created: 10/9/2005 7:10:44 PM
Rem Creator: sizer : gregory.sizer@us.army.mil
Rem FOR PROPER DISPLAY SET PROJECT TO WINDOWED AT 800x600
`-------------------------------------------
sync off
`game variables
lives$="5"
fx#=400
fy#=500
`-------------------------------------------
`main loop
do
   cls
   text 20,550,"Framerate:"+str$(screen fps()) + "  Lives Left:" + lives$
   Draw_BG()
   Con_Frog()
   Con_Haz()
   ` end program when [END] key is pressed
   if keystate(207) then end
   sync
loop
`-------------------------------------------
`control frogger
function Con_Frog()
   if keystate(200) then dec fy#
   if keystate(208) then inc fy#
   if keystate(203) then dec fx#
   if keystate(205) then inc fx#
   ink RGB(0,255,0),RGB(0,0,0)
   text fx#,fy#,"@"
endfunction
`-------------------------------------------
`control hazards
function Con_Haz()

endfunction
`-------------------------------------------
`main screen
function Draw_BG()
   ink RGB(0,128,64),RGB(0,0,0)
   for s2=1 to 3
      print "########     #####     #####     #####     #####     #####     #####     #####     #####     ########"
   next s2
   ink RGB(255,255,255),RGB(0,0,255)
   for w=1 to 10
      print "~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
   next i
   ink RGB(243,193,75),RGB(240,216,40)
   for s1=1 to 3
      print ";;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;"
   next s1
   ink RGB(255,255,0),RGB(0,0,0)
   for r=1 to 15
      select r
         case 4 : print "=====================================================================================================" :endcase
         case 8 : print "=====================================================================================================" :endcase
         case 12 : print "=====================================================================================================" :endcase
         case default : print "" : endcase
      endselect
   next r
   ink RGB(128,128,128),RGB(0,0,0)
   for s0=1 to 3
      print "|     |     |     |     |     |     |     |     |     |     |     |     |     |     |     |     |     |     |"
   next s0
   print "-----------------------------------------------------------------------------------------------------"
endfunction

`start screen
print "Help The Sheep Cross The Rather Busy Road"
wait key

`hide mouse
hide mouse

`clear screen
cls

`set the fon size
set text size 10

do

`clearscreen
cls

`make the sheep
text 300+x#,450+y#,"()"

text a#,40,"[]"
text b#,100,"[]"
text c#,160,"[]"
text d#,220,"[]"
text e#,280,"[]"
text f#,340,"[]"
text 620-b#,70,"[]"
text 620-c#,130,"[]"
text 620-d#,190,"[]"
text 620-a#,250,"[]"
text 620-f#,310,"[]"
text 620-e#,370,"[]"

`set controls for the sheep
if upkey()=1 then y#=y#-2
if downkey()=1 then y#=y#+2
if leftkey()=1 then x#=x#-2
if rightkey()=1 then x#=x#+2


a#=a#+3.7
if a#>620 then a#=0
b#=b#+5.4
if b#>620 then b#=0
c#=c#+6.2
if c#>620 then c#=0
d#=d#+7.6
if d#>620 then d#=0
e#=e#+3.1
if e#>620 then e#=0
f#=f#+4.9
if f#>620 then f#=0
loop

Rem Project: frogger
Rem Created: 10/9/2005 7:10:44 PM
Rem Creator: sizer : gregory.sizer@us.army.mil
Rem FOR PROPER DISPLAY SET PROJECT TO WINDOWED AT 800x600
`-------------------------------------------
sync off
`game variables
dim fx#(1)
dim fy#(1)
dim lives#(1)
dim gator$(1)
dim lilly$(1)
dim car$(1)
dim l_semi$(1)
dim r_semi$(1)
dim l_start#(1)
dim r_start#(1)
dim l_pos#(15)
dim r_pos#(15)
dim l_pos1#(15)
dim r_pos1#(15)
`initialize hazards
setup_game()
`-------------------------------------------
`main loop
do
   cls
   text 20,550,"Lives Left:" + str$(lives#(1))
   Draw_BG()
   Con_Frog()
   Con_Traffic()
   Con_Aqua()
   ` end program when [END] key is pressed
   if keystate(207) then end
   ` CALL DEBUG CODE ON [d]
   if keystate(32) then DEBUG()
   sync
loop
`-------------------------------------------
`setup hazards
function setup_game()
   fx#(1)=400
   fy#(1)=500
   lives#(1)=9
   gator$(1)=">\===----"
   lilly$(1)="%%%"
   car$(1)="[#]"
   l_semi$(1)="[#]=[#####]"
   r_semi$(1)="[#####]=[#]"
   l_start#(1)=len(l_semi$)
   l_start#(1)=800-l_start#
   r_start#(1)=len(r_semi$)
   for i = 1 to 15
      l_pos#(i) = l_start#(1) - (i * 10)
      r_pos#(i) = (i * 10) + r_start#(1)
   next i
   for i = 1 to 15
      l_pos1#(i) = (l_start#(1) - 200) - (i * 15)
      r_pos1#(i) = (i * 15) + (r_start#(1) + 200)
   next i
endfunction
`-------------------------------------------
`main screen
function Draw_BG()
   ink RGB(0,64,0),RGB(0,0,0)
   for s2=1 to 3
      print "########     #####     #####     #####     #####     #####     #####     #####     #####     ########"
   next s2
   ink RGB(0,0,255),RGB(255,255,255)
   for w=1 to 10
      print "~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~"
   next i
   ink RGB(108,80,40),RGB(240,216,40)
   for s1=1 to 3
      print ";;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;;"
   next s1
   ink RGB(255,255,0),RGB(0,0,0)
   for r=1 to 15
      select r
         case 4 : print "=====================================================================================================" :endcase
         case 8 : print "=====================================================================================================" :endcase
         case 12 : print "=====================================================================================================" :endcase
         case default : print "" : endcase
      endselect
   next r
   ink RGB(108,80,40),RGB(108,80,40)
   for s0=1 to 3
      print "*****************************************************************************************************"
   next s0
   print "-----------------------------------------------------------------------------------------------------"
endfunction
`-------------------------------------------4
`control frogger
function Con_Frog()
   if keystate(200) then fy#(1)=fy#(1)-10
   if keystate(208) then fy#(1)=fy#(1)+10
   if keystate(203) then fx#(1)=fx#(1)-10
   if keystate(205) then fx#(1)=fx#(1)+10
   if fy#(1) >= 499 then fy#(1)=498
   if fx#(1) >= 791 then fx#(1)=790
   if fx#(1) <= 9 then fx#(1)=10
   if fy#(1) <= 9 then fy#(1)=10
   ink RGB(0,255,0),RGB(0,0,0)
   text fx#(1),fy#(1),"@"
endfunction
`-------------------------------------------
`control traffic
function Con_Traffic()
   ink RGB(255,255,255),RGB(0,0,0)
   for i = 1 to 15
` sets current vehicle moving left position
      l_pos#(i)=l_pos#(i)-(i*0.75)
      if l_pos#(i)<=1 then l_pos#(i)=l_start#(1)
      l_pos1#(i)=l_pos1#(i)-(i*0.75)
      if l_pos1#(i)<=1 then l_pos1#(i)=l_start#(1)
` sets current vehicle moving right position
      r_pos#(i)=r_pos#(i)+(i*0.75)
      if r_pos#(i)>=790 then r_pos#(i)=r_start#(1)
      r_pos1#(i)=r_pos1#(i)+(i*0.75)
      if r_pos1#(i)>=790 then r_pos1#(i)=r_start#(1)
   next i
` display vehicles in current position
   for i = 1 to 15
      select i
         case 1 : set cursor l_pos#(i),410 : print l_semi$(1) : endcase
         case 2 : set cursor r_pos#(i),399 : print car$(1) : endcase
         case 3 : set cursor l_pos#(i),388 : print car$(1) : endcase
         case 4 : set cursor r_pos#(i),377 : print r_semi$(1) : endcase
         case 5 : set cursor l_pos#(i),366 : print l_semi$(1) : endcase
         case 6 : set cursor r_pos#(i),355 : print car$(1) : endcase
         case 7 : set cursor l_pos#(i),344 : print car$(1) : endcase
         case 8 : set cursor r_pos#(i),333 : print r_semi$(1) : endcase
         case 9 : set cursor l_pos#(i),322 : print l_semi$(1) : endcase
         case 10 : set cursor r_pos#(i),311 : print car$(1) : endcase
         case 11 : set cursor l_pos#(i),300 : print car$(1) : endcase
         case 12 : set cursor r_pos#(i),289 : print r_semi$(1) : endcase
         case 13 : set cursor l_pos#(i),278 : print l_semi$(1) : endcase
         case 14 : set cursor r_pos#(i),267 : print car$(1) : endcase
         case 15 : set cursor l_pos#(i),256 : print car$(1) : endcase
      endselect
   next i
for i = 1 to 15
      select i
         case 1 : set cursor l_pos1#(i),410 : print l_semi$(1) : endcase
         case 2 : set cursor r_pos1#(i),399 : print car$(1) : endcase
         case 3 : set cursor l_pos1#(i),388 : print car$(1) : endcase
         case 4 : set cursor r_pos1#(i),377 : print r_semi$(1) : endcase
         case 5 : set cursor l_pos1#(i),366 : print l_semi$(1) : endcase
         case 6 : set cursor r_pos1#(i),355 : print car$(1) : endcase
         case 7 : set cursor l_pos1#(i),344 : print car$(1) : endcase
         case 8 : set cursor r_pos1#(i),333 : print r_semi$(1) : endcase
         case 9 : set cursor l_pos1#(i),322 : print l_semi$(1) : endcase
         case 10 : set cursor r_pos1#(i),311 : print car$(1) : endcase
         case 11 : set cursor l_pos1#(i),300 : print car$(1) : endcase
         case 12 : set cursor r_pos1#(i),289 : print r_semi$(1) : endcase
         case 13 : set cursor l_pos1#(i),278 : print l_semi$(1) : endcase
         case 14 : set cursor r_pos1#(i),267 : print car$(1) : endcase
         case 15 : set cursor l_pos1#(i),256 : print car$(1) : endcase
      endselect
   next i
endfunction
`-------------------------------------------
`Control water based stuff
function Con_Aqua()
   ink RGB(0,128,64),RGB(0,0,0)
   for i = 1 to 12
      select i
         case 1 : set cursor l_pos#(i),180  : print gator$(1) : endcase
         case 2 : set cursor r_pos#(i),168 : print lilly$(1) : endcase
         case 3 : set cursor l_pos#(i),156 : print gator$(1) : endcase
         case 4 : set cursor r_pos#(i),144 : print lilly$(1) : endcase
         case 5 : set cursor l_pos#(i),132 : print gator$(1) : endcase
         case 6 : set cursor r_pos#(i),120 : print lilly$(1) : endcase
         case 7 : set cursor l_pos#(i),108 : print gator$(1) : endcase
         case 8 : set cursor r_pos#(i),96 : print lilly$(1) : endcase
         case 9 : set cursor l_pos#(i),84 : print gator$(1) : endcase
         case 10 : set cursor r_pos#(i),72 : print lilly$(1) : endcase
         case 11 : set cursor l_pos#(i),60 : print gator$(1) : endcase
         case 12 : set cursor r_pos#(i),48 : print lilly$(1) : endcase
      endselect
   next i
   for i = 1 to 12
      select i
         case 1 : set cursor l_pos1#(i),180  : print gator$(1) : endcase
         case 2 : set cursor r_pos1#(i),168 : print lilly$(1) : endcase
         case 3 : set cursor l_pos1#(i),156 : print gator$(1) : endcase
         case 4 : set cursor r_pos1#(i),144 : print lilly$(1) : endcase
         case 5 : set cursor l_pos1#(i),132 : print gator$(1) : endcase
         case 6 : set cursor r_pos1#(i),120 : print lilly$(1) : endcase
         case 7 : set cursor l_pos1#(i),108 : print gator$(1) : endcase
         case 8 : set cursor r_pos1#(i),96 : print lilly$(1) : endcase
         case 9 : set cursor l_pos1#(i),84 : print gator$(1) : endcase
         case 10 : set cursor r_pos1#(i),72 : print lilly$(1) : endcase
         case 11 : set cursor l_pos1#(i),60 : print gator$(1) : endcase
         case 12 : set cursor r_pos1#(i),48 : print lilly$(1) : endcase
      endselect
   next i
endfunction
`-------------------------------------------
`DEBUG CODE : REMOVE FOR FINAL ENTRY.
function DEBUG()
   cls
   ink RGB(255,255,255),RGB(0,0,0)
   text 309,11,"fx# = " + str$(fx#(1))
   text 309,22,"fy# = " + str$(fy#(1))
   text 309,33,"lives# = " + str$(lives#(1))
   text 309,44,"car$ = " + car$(1)
   text 309,55,"l_semi$ = " + l_semi$(1)
   text 309,66,"r_semi$ = " + r_semi$(1)
   text 309,77,"l_start# = " + str$(l_start#(1))
   text 309,88,"r_start# = " + str$(r_start#(1))
   text 309,99,"gator$ = " + gator$(1)
   text 309,110,"lilly$ = " + lilly$(1)
   for i = 1 to 15
      text 1,(i*11),"l_pos# = " + str$(l_pos#(i))
      text 155,(i*11),"r_pos# = " + str$(r_pos#(i))
   next i
   text 20,550,"Framerate:"+str$(screen fps())
endfunction