Sorry your browser is not supported!

_Create_Digits:
   Ink RGB(0,255,0),0
   DigitImg = 10

   `ZERO
   Box 0, 2, 2, 12 : Box 0, 14, 2, 24 : Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26
   Get Image DigitImg+0, 0, 0, 16, 26, 1
   CLS

   `ONE
   Box 14, 2, 16, 12 : Box 14, 14, 16, 24
   Get Image DigitImg+1, 0, 0, 16, 26, 1
   CLS

   `TWO
   Box 0, 14, 2, 24 : Box 14, 2, 16, 12 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26 : Box 3, 12, 13, 14
   Get Image DigitImg+2, 0, 0, 16, 26, 1
   CLS

   `THREE
   Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26 : Box 3, 12, 13, 14
   Get Image DigitImg+3, 0, 0, 16, 26, 1
   CLS

   `FOUR
   Box 0, 2, 2, 12 : Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 12, 13, 14
   Get Image DigitImg+4, 0, 0, 16, 26, 1
   CLS

   `FIVE
   Box 0, 2, 2, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26 : Box 3, 12, 13, 14
   Get Image DigitImg+5, 0, 0, 16, 26, 1
   CLS

   `SIX
   Box 0, 2, 2, 12 : Box 0, 14, 2, 24 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26 : Box 3, 12, 13, 14
   Get Image DigitImg+6, 0, 0, 16, 26, 1
   CLS

   `SEVEN
   Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 `Top
   Get Image DigitImg+7, 0, 0, 16, 26, 1
   CLS

   `EIGHT
   Box 0, 2, 2, 12 : Box 0, 14, 2, 24 : Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26 : Box 3, 12, 13, 14
   Get Image DigitImg+8, 0, 0, 16, 26, 1
   CLS

   `NINE
   Box 0, 2, 2, 12 : Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 12, 13, 14
   Get Image DigitImg+9, 0, 0, 16, 26, 1
   CLS

   `COLON
   Box 0, 10, 2, 12 : Box 0, 22, 2, 24
   Get Image DigitImg+10, 0, 0, 2, 26, 1
   CLS
Return

set display mode 1280, 1024, 32
set text font "Arial"
set text size 72
#constant imageSize 64

for i = 0 to 9
   cls
   s$ = str$(i)
   text (imageSize-text width(s$))*0.5, (imageSize-text height(s$))*0.5, s$
   get image i+1, 0, 0, imageSize, imageSize
next i

`and the colon
cls
s$ = ":"
text (imageSize-text width(s$))*0.5, (imageSize-text height(s$))*0.5, s$
get image 12, 0, 0, imageSize, imageSize
cls



`Setup the image holders
for i = 1 to 8
   make object plain i, 1, 1
   position object i, (i-4.5), 0, 0
   point object i, (i-4.5), 0, -1
   `texture object i, i
   set object light i, 0
   set object transparency i,1
   offset limb i, 0, 0, 0.5, 0
next i


`Some arrays
Dim itemChanged(8)
Dim itemAngle#(8)
Dim timeArray(8)
Dim displayArray(8)

`set the default time to 0 but set it so that they're all set to update on the first "tick"
parseTime()
for i = 1 to 8
   texture object i, 1
   displayArray(i) = timeArray(i)
   itemChanged(i) = 1
next i


`initialise the display setup
sync on
sync rate 0
randomize timer()
color backdrop 0
backdrop off


`camera swing
a# = 0.0
b# = 0.0
#constant DIST -12
#constant SWAY_RADIUS 3
#constant ARC_SIZE 20
autocam off

position camera SWAY_RADIUS, 0, BOON
point camera 0, 0, 0



frameTime# = 1.0
startTime = timer()
do
   frameTime# = (frameTime# * 0.8) + ((timer() - startTime) * 0.2)
   startTime = timer()
   parseTime()
   for i = 1 to 8
      `if the current time is different to the displayed time then something has changed to we better update it...
      if timeArray(i) <> displayArray(i)
         `set us to phase 1
         itemChanged(i) = 1
         `display the new time item
         displayArray(i) = timeArray(i)
      endif

      if itemChanged(i) > 0
         `The item has just changed - better change it!!
         inc itemAngle#(i), frameTime# * 0.400
         xrotate object i, sin(itemAngle#(i)) * -90.0
         set alpha mapping on i, 100 - (sin(itemAngle#(i))*100)

         `check the angles
         if itemAngle#(i) >= 180
            `If we've done a full sin arc, make sure the digit is reset to 0 degree's.
            xrotate object i, 0
            `reset its status
            itemChanged(i)=0
            `and its stored angle
            itemAngle#(i) = 0.0
            `and its transparency
            set alpha mapping on i, 100
         else
            `We haven't finished yet, lets see if we've gone past flat (90)
            if itemAngle#(i) >= 90
               `Yup, we're past flat.. ok, are we still in "phase 1" (ie, going down)
               if itemChanged(i) = 1
                  `Yup, ok - you may now change the texture
                  texture object i, displayArray(i)+1
                  `And set us to phase 2
                  itemChanged(i) = 2
               endif
            endif
         endif
      endif
   next i


   `Camera stuff
   inc a#, frameTime# * 0.045
   inc b#, frameTime# * 0.032
   `sin(a#) produces a value between -1.0 and +1.0 in the "shape" of a sine curve.
   `  This is then scaled to produce a nice "swaying value.
   `  Cos does the same but the result is offset by quarter a wavelength.
   `  That means when sin it high, cos is 0...
   position camera SWAY_RADIUS * sin(a#), SWAY_RADIUS * cos(a#), DIST
   `point camera 0,0,0
   yrotate camera sin(b#)*ARC_SIZE

   sync
loop
end


function parseTime()
   t$ = get time$()
   timeArray(1) = val(mid$(t$, 1)) :`H
   timeArray(2) = val(mid$(t$, 2)) :`H
   timeArray(3) = 11 :`:
   timeArray(4) = val(mid$(t$, 4)) :`M
   timeArray(5) = val(mid$(t$, 5)) :`M
   timeArray(6) = 11 :`:
   timeArray(7) = val(mid$(t$, 7)) :`S
   timeArray(8) = val(mid$(t$, 8)) :`S
endfunction

sync on
set display mode 800,600,32
make object cube 1,1
delete object 1
color backdrop 0
autocam off
hide mouse

alpha = 10
set camera to image 0,200,512,512
sprite 1000,0,0,200
set sprite 1000,0,1
set sprite alpha 1000,alpha
size sprite 1000,screen width(),screen height()

ink rgb(0,255,0),0
box 49,0,51,50
get image 1,0,0,100,100
cls
box 48,0,51,50
get image 2,0,0,100,100
cls
box 48,20,51,50
get image 3,0,0,100,100
cls
ink rgb(255,255,255),0
for n=1 to 12
box 98+90*cos(theta#),98+90*sin(theta#),102+90*cos(theta#),102+90*sin(theta#)
inc theta#,30
next n
get image 4,0,0,200,200,1

sprite 101,0,0,1
size sprite 101,100,100
sprite 102,0,0,2
size sprite 102,100,100
sprite 103,0,0,3
size sprite 103,100,100
sprite 104,0,0,4
size sprite 104,120,120

offset sprite 101,50,50
offset sprite 102,50,50
offset sprite 103,50,50
offset sprite 104,60,60

gosub create_digits
dx=1.5
dy=1

r=255

do

t$=get time$()

for n=1 to 8
if n=3 or n=6
  sprite n,n*20+x,y,20
else
  image=val(left$(right$(t$,9-n),1))+10
  sprite n,n*20+x,y,image
endif
set sprite diffuse n,r,g,b
next n

inc x,dx
inc y,dy
if x>screen width()-160 or x<0 then dx=dx*-1
if y>screen height()-150 or y<0 then dy=dy*-1

gosub transitions

s#=val(right$(t$,2))*6
m#=(val(left$(right$(t$,5),2))*6)+s#/60.0
h#=(val(left$(t$,2))*30)+m#/12.0

sprite 101,x+100,y+100,1
sprite 102,x+100,y+100,2
sprite 103,x+100,y+100,3
sprite 104,x+100,y+100,4
rotate sprite 101,s#
rotate sprite 102,m#
rotate sprite 103,h#

set sprite diffuse 104,r,g,b

sync
loop


Create_Digits:

ink rgb(255,255,255),0
   DigitImg = 10

   `ZERO
   Box 0, 2, 2, 12 : Box 0, 14, 2, 24 : Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26
   Get Image DigitImg+0, 0, 0, 16, 26, 1
   CLS

   `ONE
   Box 14, 2, 16, 12 : Box 14, 14, 16, 24
   Get Image DigitImg+1, 0, 0, 16, 26, 1
   CLS

   `TWO
   Box 0, 14, 2, 24 : Box 14, 2, 16, 12 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26 : Box 3, 12, 13, 14
   Get Image DigitImg+2, 0, 0, 16, 26, 1
   CLS

   `THREE
   Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26 : Box 3, 12, 13, 14
   Get Image DigitImg+3, 0, 0, 16, 26, 1
   CLS

   `FOUR
   Box 0, 2, 2, 12 : Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 12, 13, 14
   Get Image DigitImg+4, 0, 0, 16, 26, 1
   CLS

   `FIVE
   Box 0, 2, 2, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26 : Box 3, 12, 13, 14
   Get Image DigitImg+5, 0, 0, 16, 26, 1
   CLS

   `SIX
   Box 0, 2, 2, 12 : Box 0, 14, 2, 24 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26 : Box 3, 12, 13, 14
   Get Image DigitImg+6, 0, 0, 16, 26, 1
   CLS

   `SEVEN
   Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 `Top
   Get Image DigitImg+7, 0, 0, 16, 26, 1
   CLS

   `EIGHT
   Box 0, 2, 2, 12 : Box 0, 14, 2, 24 : Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 24, 13, 26 : Box 3, 12, 13, 14
   Get Image DigitImg+8, 0, 0, 16, 26, 1
   CLS

   `NINE
   Box 0, 2, 2, 12 : Box 14, 2, 16, 12 : Box 14, 14, 16, 24 : Box 3, 0, 13, 2 : Box 3, 12, 13, 14
   Get Image DigitImg+9, 0, 0, 16, 26, 1
   CLS

   `COLON
   Box 7, 9, 9, 11 : Box 7, 15, 9, 17
   Get Image DigitImg+10, 0, 0, 16, 26, 1
   CLS
Return

transitions:

if transition=0
inc g
if g=255 then transition=1
endif
if transition=2
inc b
if b=255 then transition=3
endif
if transition=1
dec r
if r=0 then transition=2
endif
if transition=3
dec g
if g=0 then transition=4
endif
if transition=4
inc r
if r=255 then transition=5
endif
if transition=5
dec b
if b=0 then transition=0
endif

return

Sync On:Sync Rate 0:Autocam Off
Position Camera 0,0,10
Set camera range .2,10000

Global old_time as DWord
Null=Make Vector3(1)

Make_Water_Wheel(1)
Position Object 1,20,0,100

Make_Gear(2,20)
Position Object 2,-24,0,114
Make Object Cylinder 3,14
Scale Object 3,100,20,100
Pitch object Up 3,90
Make Mesh from Object 1,3
Delete Object 3
Add Limb 2,9,1
Offset Limb 2,9,0,0,-4

Make_Gear(3,20)
Position Object 3,-35,0,102
Turn Object Right 3,90
Roll Object Right 3,15

Make_Gear(4,40)
Position Object 4,-55,0,102
Turn Object Right 4,90
Roll Object Right 4,15
Make Object Cylinder 5,2
Scale Object 5,100,1000,100
Pitch Object Down 5,90
Fix Object Pivot 5
Make Mesh from Object 1,5
Delete Object 5
Add limb 4,9,1
Offset Limb 4,9,0,0,10

Make_Gear(5,40)
Position Object 5,-33,22,102
Pitch Object Up 5,90

Make_Gear(6,80)
Position Object 6,-33,29.5,102
Pitch Object Up 6,90

Make_Lever(7,8)
Position Object 7,10,40,60
Rotate Object 7,0,-90,0

Make_Gear(8,80)
Position Object 8,-10,0,-5



Make Particles 1,0,100,5
Position Particles 1,40,45,100
Set Particle Floor 1,0
Set Particle Velocity 1,.01
Set Particle Gravity 1,30
Set Particle Life 1,15
Color Particles 1,100,100,255

Make Object Sphere 100,200
Scale Object 100,100,100,.01
Position Object 100,0,0,-55
Make Object Triangle 101,-2,0,0,0,99,0,2,0,0
Make Object Triangle 102,-8,0,0,0,89,0,8,0,0
Make Object triangle 103,-9,0,0,0,65,0,9,0,0
Position Object 101,0,0,-56
Position Object 102,0,0,-57
Position Object 103,0,0,-58
Make_Numbers()
For i = 1 to 12
   Position Object 10+i,sin(i*30-2)*90+4,cos(i*30-2)*90+2,-58
Next i

Make Object Cylinder 200,500
Offset Limb 200,0,0,250,0
Scale Object 200,100,1000,100
Pitch Object Down 200,90
Position Object 200,0,0,0
Set Object Cull 200,0
Color Object 200,0
Set Object Ambience 200,0

Make Object Cylinder 201,500
Offset Limb 201,0,0,250,0
Scale Object 201,120,900,120
Pitch Object Down 201,90
Position Object 201,0,0,0
Set Object Cull 201,0
Color Object 201,0
Set Object Ambience 201,0

Make Object Cylinder 202,500
Offset Limb 202,0,0,250,0
Scale Object 202,150,700,150
Pitch Object Down 202,90
Position Object 202,0,0,0
Set Object Cull 202,0
Color Object 202,0
Set Object Ambience 202,0


Make_Strap(1000)
lever#=0
levdir#=1

Do
   If Camera Position Z()<-250
      speed#=5.0
   Else
      speed#=0.2
   Endif
   Move Camera (Upkey()-DownKey())*speed#
   If Camera Position Z()<0 and Camera Position Z()>-5
      Position camera Camera Position X(),Camera Position Y(),-10
   Endif
   If Camera POsition Z()<-5 and Camera Position Z()>-10
      Position camera Camera Position X(),Camera Position Y(),0
   Endif
   lr#=Timer()-old_time
   lvr#=lr#
   lr#=lr#*((360.0/8.0)/1000.0)
   old_time=Timer()
   Roll Object Right 1,lr#
   Roll Object Right 2,lr#
   Roll Object Right 3,lr#
   Roll Object Right 4,lr#
   Roll Object Right 5,lr#
   Roll Object Right 6,lr#
   sa#=Get_Second_Angle()
   Rotate Object 101,0,0,sa#
   ma#=Get_Minute_Angle()
   Rotate Object 102,0,0,ma#
   ha#=Get_Hour_Angle()
   Rotate Object 103,0,0,ha#
   Run_Strap(1000,300,-24,20,-2,110)
   lever#=lever#+(levdir#/lvr#)*90.0
   if abs(lever#)>10
      levdir#=levdir#*-1
      lever#=lever#+(levdir#/lvr#)*90.0
   Endif
   Rotate Object 7,0,-90,0
   Roll Object Right 7,lever#
   Rotate Object 8,0,0,sa#
   Rotate Object 200,0,0,sa#
   Rotate Object 201,0,0,ma#
   Rotate Object 202,0,0,ha#
   Set Cursor 0,0
   Print get time$()
   Sync
Loop



Function Make_Water_Wheel(ObjectID)
   Make Object Cylinder ObjectID,10
   Make Mesh From Object 1,ObjectID
   For i = 1 to 7
      Add Limb ObjectID,i,1
      Offset Limb ObjectID,i,Cos(i*45)*20,Sin(i*45)*20,0
      Rotate Limb ObjectID,i,0,0,i*45
   Next i
   Offset Limb ObjectID,0,20,0,0
   For i = 0 to 3
      Add Limb ObjectID,8+i,1
      Scale Limb ObjectID,8+i,50,320,50
      Rotate Limb ObjectID,8+i,0,0,i*45
   Next i
   Set Object Cull ObjectID,0
Endfunction

Function Make_Strap(ObjectID)
   Make Object Plain ObjectID,2,2
   Pitch Object Down ObjectID,90
   Fix Object Pivot ObjectID
   Make Mesh from Object 1,ObjectID
   Delete Object ObjectID
   Make Object ObjectID,1,0
   Add Limb ObjectID,1,1
   Rotate Limb ObjectID,1,0,0,-30
   Set Object Cull ObjectID,0
EndFunction

Function Run_Strap(ObjectID,segs,x1#,x2#,y#,z#)
   If Object Exist(ObjectID+1)=0
      Turn Object Left ObjectID,90
      Position Object ObjectID,(x1#+x2#)/2.0,y#-5,z#
      For i = 1 to segs
         Clone Object ObjectID+i,ObjectID
         Position Object ObjectID+i,(x1#+x2#)/2.0,y#+5,z#
         c=rnd(128)+128
         Color Object ObjectID+i,RGB(c,c,c)
      Next i
   Endif

   For i = segs to 1 step -1
      Set Vector3 1,Object Position X(ObjectID+i-1)-Object Position X(ObjectID+i),Object Position Y(ObjectID+i-1)-Object Position Y(ObjectID+i),Object Position Z(ObjectID+i-1)-Object Position Z(ObjectID+i)
      d#=Length vector3(1)
      if d#=>1
         Position Object ObjectID+i,Object Position X(ObjectID+i-1),Object Position Y(ObjectID+i-1),Object Position Z(ObjectID+i-1)
         Rotate Object ObjectID+i,Object Angle X(ObjectID+i-1),Object Angle Y(ObjectID+i-1),Object Angle Z(ObjectID+i-1)
      Endif
   Next i
   If Object Position X(ObjectID)<x1# or Object Position X(ObjectID)>x2#
      Pitch Object Up ObjectID,4
   Endif
   Move Object ObjectID,.5
Endfunction

Function Make_Gear(ObjectID,size#)
   Make Object Box ObjectID,size#*.08,size#*1.2,size#*.08
   Make Mesh from Object 1,ObjectID
   Delete Object ObjectID
   Make Object Sphere ObjectID,size#
   Scale Object ObjectID,100,100,.1
   Make Mesh From Object 2,ObjectID
   Delete Object ObjectID
   Make Object Cylinder ObjectID,size#
   Scale Limb ObjectID,0,100,11,100
   Pitch Object Down ObjectID,90
   Fix Object Pivot ObjectID
   Make Mesh from Object 3,ObjectID
   Delete Object ObjectID
   Make Object ObjectID,3,0
   Add Limb ObjectID,1,2
   Add Limb ObjectID,2,2
   Offset Limb ObjectID,1,0,0,size#*.05
   Offset Limb ObjectID,2,0,0,size#*-.05
   For i = 0 to 5
      Add Limb ObjectID,3+i,1
      Rotate Limb ObjectID,3+i,0,0,i*30
   Next i
   Set Object Cull ObjectID,0
EndFunction

Function Make_Lever(ObjectID,Size#)
   Make Object Box ObjectID,size#,size#,size#*.2
   Rotate Object ObjectID,0,0,45
   Fix Object Pivot ObjectID
   Make Mesh from Object 1,ObjectID
   Delete Object ObjectID
   Make Object Box ObjectID,Size#*10.0,Size#,Size#*.2
   Add Limb ObjectID,1,1
   Offset Limb ObjectID,1,size#*5.0,Size*-.45,0
Endfunction

Function Get_Second_Angle()
   t$=Get time$()
   s#=val(right$(t$,2))
   s#=-s#*6.0
Endfunction s#

Function Get_Minute_Angle()
   t$=Get time$()
   s#=val(right$(t$,2))
   m#=val(left$(right$(t$,5),2))
   s#=m#*60+s#
   s#=-s#*(6.0/60.0)
Endfunction s#

Function Get_Hour_Angle()
   t$=Get time$()
   s#=val(right$(t$,2))
   m#=val(left$(right$(t$,5),2))
   h#=val(left$(t$,2))
   s#=h#*3600.0+m#*60.0+s#
   s#=-s#*(6.0/60.0/12.0)
Endfunction s#


Function Make_Numbers()
   Ink Rgb(0,0,128),0
   For i=1 to 12
      cls
      Set Cursor 2,2
      Print i
      Get Image i,0,0,20,16,1
      Make Object Plain 10+i,20,20
      Texture Object 10+i,i
      Set Object Transparency 10+i,4
   Next i
Endfunction

Kaiyodo.  Great piece of code, great looking result.  Setting it to my screensaver!

RiiDii.  Was torn between your's and Kaiyodo's, and in the end Kaiyodo's won by a narrow margin based on the 'which one I would most prefer as my screensaver' criterea!

REM Project: Clock
REM Created: 30/10/2005 23:24:32
REM
REM ***** Main Source File *****
REM

sync on : sync rate 0

time$ = get time$()
h$ = mid$(time$,1) + mid$(time$,2)
hB$ = retBinary$(h$)
m$ = mid$(time$,4) + mid$(time$,5)
mB$ = retBinary$(m$)
s$ = mid$(time$,7) + mid$(time$,8)
sB$ = retBinary$(s$)

for a=1 to 18
   make object sphere a,1
   color object a,0
next a

position camera 3.5,1,-5

sync
do

   time$ = get time$()

   h$ = mid$(time$,1) + mid$(time$,2)
   hB$ = retBinary$(h$)
   m$ = mid$(time$,4) + mid$(time$,5)
   mB$ = retBinary$(m$)
   s$ = mid$(time$,7) + mid$(time$,8)
   sB$ = retBinary$(s$)

   renderBinary(0,0,2,hB$)
   renderBinary(6,0,1,mB$)
   renderBinary(12,0,0,sB$)

   control camera using arrowkeys 0,0.25,0.25

   sync
loop
end

function renderBinary(numOff as integer,xOff as integer, yOff as integer, pString$ as string)

   for a=1 to 6
      if mid$(pString$,a) = "1"
         color object numOff+a,rgb(250,250,250)
         position object numOff+a,xOff+a,yOff,0
      else
         if object exist(numOff+a)=1 then color object numOff+a,0
         position object numOff+a,xOff+a,yOff,0
      endif
   next a

endfunction

function retBinary$(pString$ as string)

   retBin$ as string
   temp as string

   temp = bin$(val(pString$))
   for a=26 to 32
      retBin$ = retBin$ + mid$(temp,a)
   next a

endfunction retBin$

`%ProjectTitle%
`======================
`©%Author%
`======================
`Main Source File
sync on
sync rate 0
autocam off

#constant helpObj = 1000
#constant helpMesh = 10
`#constant dfactor = 100.0

#constant sqrWidth = 5
#constant sqrHeight = 5
#constant sqrWidFact = -10
#constant sqrHeiFact = -15

#constant numSpace = 5
#constant minFade = 30.0

#constant numNumbers = 8

position camera -100,100,400
point camera 0,0,0

color backdrop 0

type Vertex
	xpos as float
	ypos as float
	xto as float
	yto as float
endtype

type NumberType
	curNumber as integer
	maxSpd as float
	minSpd as float
	thresh as float
	dfactor as float
	fade as float
endtype

global timeStart as integer

calibrateTimer()

global dim NumVertex(numNumbers,sqrWidth*sqrHeight*6) as Vertex
global dim Numbers(numNumbers) as NumberType

for n = 1 to numNumbers
	makeNumber(n, n, 0, (n-(numNumbers/2)) * (sqrWidFact*-1*sqrWidth+numSpace)-sqrWidFact/2, 0, 0)
	if (n-1) mod 3 = 2
		setNumber(n, 99)
	else
		setNumber(n, (n-1) mod 10)
	endif
	ghost object on n
	set object wireframe n, 1
next n

if numNumbers > 8
	restore numberData
else
	restore numberDataSeconds
endif
for n = 1 to numNumbers
	read Numbers(n).curNumber
	read Numbers(n).maxSpd
	read Numbers(n).minSpd
	read Numbers(n).thresh
	read Numbers(n).dfactor
	Numbers(n).fade = 100
next n

`--------------------------------------------------
`############# enter main loop  ###################
`--------------------------------------------------

do
	updateNumberTime()
	
	for n = 1 to numNumbers
		updateNumber(n, n, 0)
		setNumber(n, Numbers(n).curNumber)
	next n
	
	text 10,10,"updating numbers... (FPS: " + str$(screen fps()) + ")"
	text 10,25,"Current Time: " + getTimeStr()
	set cursor 10,40

	sync
	
loop

function updateNumberTime()
	local tmp as string
	tmp = getTimeStr()
	for n = 1 to numNumbers
		if (n-1) mod 3 = 2
			setNumber(n, 99)
		else
			lastNum = Numbers(n).curNumber
			Numbers(n).curNumber = val(mid$(tmp, numNumbers-n+1))
		endif
		
		`do a lil fadin
		if lastNum <> Numbers(n).curNumber
			Numbers(n).fade = 100.0
		else
			`if  Numbers(n).fade > minFade then dec Numbers(n).fade, ((numNumbers-n)-int((n-1)/3))/600.0
			if int((n-1)/3) = 0
				if  Numbers(n).fade > minFade then dec Numbers(n).fade, 0.02
			else
				if int((n-1)/3) = 1
					if  Numbers(n).fade > minFade then dec Numbers(n).fade, 0.002
				else
					if  Numbers(n).fade > minFade then dec Numbers(n).fade, 0.0002
				endif
			endif
		endif
		
		if  Numbers(n).fade < minFade then Numbers(n).fade = minFade
		
		fade object n, Numbers(n).fade

	next n
endfunction

function getTimeStr()
	local rtrn as string
	rtrn = get time$() + ":" + getMilliSecondsStr()
endfunction rtrn

function getMilliSecondsStr()
	local rtrn as string
	rtrn = str$(getMilliTime()/10 mod 100)
	if len(rtrn) < 2 then rtrn = "0" + rtrn
	if len(rtrn) < 2 then rtrn = "0" + rtrn
endfunction rtrn

function getMilliTime()
	local rtrn as integer
	rtrn = (timer() - timeStart)
endfunction rtrn

function calibrateTimer()
	local time as integer
	local lastTime as integer
	repeat
		lastTime = time
		time = val(right$(get time$(), 1))
	until lastTime <> time
	
	timeStart = timer()
endfunction

function updateNumber(objNum, index, zpos)
	local dist as float
	
	local x as float
	local y as float
	
	lock vertexdata for limb objNum,0,1
	
	for n = 0 to sqrWidth*sqrHeight * 6
		if abs(NumVertex(index,n).xpos - NumVertex(index,n).xto) > Numbers(index).thresh or abs(NumVertex(index,n).ypos - NumVertex(index,n).yto) > Numbers(index).thresh
			
			dist = sqrt((NumVertex(index,n).xpos - NumVertex(index,n).xto)^2 + (NumVertex(index,n).ypos - NumVertex(index,n).yto)^2)
	 		
	 		if dist < Numbers(index).minSpd then dist = Numbers(index).minSpd
	 		if dist > Numbers(index).maxSpd then dist = Numbers(index).maxSpd
	 		
	 		x = -1*(NumVertex(index,n).xpos - NumVertex(index,n).xto)/dist/Numbers(index).dfactor
	 		y = -1*(NumVertex(index,n).ypos - NumVertex(index,n).yto)/dist/Numbers(index).dfactor
	
	 		NumVertex(index,n).xpos = NumVertex(index,n).xpos + x
	 		NumVertex(index,n).ypos = NumVertex(index,n).ypos + y
		endif
		
		if abs(NumVertex(index,n).xpos - NumVertex(index,n).xto) <= Numbers(index).thresh then NumVertex(index,n).xpos = NumVertex(index,n).xto
	 	if abs(NumVertex(index,n).ypos - NumVertex(index,n).yto) <= Numbers(index).thresh then NumVertex(index,n).ypos = NumVertex(index,n).yto
			
		
		set vertexdata position n, NumVertex(index,n).xpos, NumVertex(index,n).ypos, zpos
	next n
	
	unlock vertexdata
endfunction

function makeNumber(objNum, index, image, posx, posy, posz)
	make object plain helpObj,abs(sqrWidFact),abs(sqrHeiFact)
	rotate limb helpObj,0,0,0,0
	make mesh from object helpMesh,helpObj
	delete object helpObj
	
	make object helpObj, helpMesh, image
	
	limbNum = 1
	
	for x = 0 to sqrWidth-1
		for y = 0 to sqrHeight-1
			if y = 0 and x = 0 : else
				add limb helpObj,limbNum,helpMesh
				offset limb helpObj,limbNum,x*sqrWidFact,y*sqrHeiFact,0
				inc limbNum
				sync
				`wait 10
			endif
		next y
	next x
	
	delete mesh helpMesh
	make mesh from object helpMesh, helpObj
	make object objNum, helpMesh, image
	delete object helpObj
	
	
	set object wireframe objNum, 1
	set object cull objNum, 0
	position object objNum, posx, posy, posz
	
	`loop through the vertexes
	lock vertexdata for limb objNum,0,1
	
	for n = 0 to sqrWidth*sqrHeight * 6
		x#=get vertexdata position x(n)
 		y#=get vertexdata position y(n)
 		NumVertex(index,n).xpos = x#+sqrWidFact/2
 		NumVertex(index,n).ypos = y#+sqrHeiFact/2
 		NumVertex(index,n).xto = x#
 		NumVertex(index,n).yto = y#
 		
 		set vertexdata diffuse n, rgb(rnd(255),rnd(255),rnd(255))
 		
 		set vertexdata position n, NumVertex(index,n).xpos, NumVertex(index,n).ypos, 0
	next n
	
	`unlock the vertex data now that we are done reading it
	unlock vertexdata
	
	organize(index)
endfunction

function setNumber(index, number)
	local tmp as integer
	local poly as integer
	select number
		case 0
			restore number0
		endcase
		case 1
			restore number1
		endcase
		case 2
			restore number2
		endcase
		case 3
			restore number3
		endcase
		case 4
			restore number4
		endcase
		case 5
			restore number5
		endcase
		case 6
			restore number6
		endcase
		case 7
			restore number7
		endcase
		case 8
			restore number8
		endcase
		case 9
			restore number9
		endcase
		case 99
			restore numberSYM
		endcase
	endselect
	
	poly = 0
	for y = 0 to sqrHeight - 1
		for x = 0 to sqrWidth - 1
			read tmp
			select tmp
				case 7
					shapeVRT(index, poly, x*sqrWidFact, y*sqrHeiFact)
				endcase
				case 6
					shapeVLF(index, poly, x*sqrWidFact, y*sqrHeiFact)
				endcase
				case 5
					shapeTRI4(index, poly, x*sqrWidFact, y*sqrHeiFact)
				endcase
				case 4
					shapeTRI3(index, poly, x*sqrWidFact, y*sqrHeiFact)
				endcase
				case 3
					shapeTRI2(index, poly, x*sqrWidFact, y*sqrHeiFact)
				endcase
				case 2
					shapeTRI1(index, poly, x*sqrWidFact, y*sqrHeiFact)
				endcase
				case 1
					shapeSQR(index, poly, x*sqrWidFact, y*sqrHeiFact)
				endcase
				case 0
					shapeNON(index, poly, x*sqrWidFact, y*sqrHeiFact)
				endcase
			endselect
			inc poly, 6
		next x
	next y
endfunction

`organize the plains....
function organize(index)
	local poly as integer
	poly = 0
	for y = 0 to sqrHeight-1
		for x = 0 to sqrWidth-1
			`triangle 1
			NumVertex(index,poly+0).xpos = 0         +x*sqrWidFact
			NumVertex(index,poly+0).ypos = 0         +y*sqrHeiFact
			
			NumVertex(index,poly+1).xpos = sqrWidFact+x*sqrWidFact
			NumVertex(index,poly+1).ypos = 0         +y*sqrHeiFact
			
			NumVertex(index,poly+2).xpos = 0         +x*sqrWidFact       
			NumVertex(index,poly+2).ypos = sqrHeiFact+y*sqrHeiFact
			
			`triangle 2
			NumVertex(index,poly+3).xpos = sqrWidFact+x*sqrWidFact   
			NumVertex(index,poly+3).ypos = 0         +y*sqrHeiFact
			                                                          
			NumVertex(index,poly+4).xpos = sqrWidFact+x*sqrWidFact
			NumVertex(index,poly+4).ypos = sqrHeiFact+y*sqrHeiFact
			                                                          
			NumVertex(index,poly+5).xpos = 0         +x*sqrWidFact
			NumVertex(index,poly+5).ypos = sqrHeiFact+y*sqrHeiFact
			inc poly, 6
		next x
	next y
endfunction

`a block of substance
function shapeSQR(index, poly, xOff, yOff)

	`triangle 1
	NumVertex(index,poly+0).xto = 0         +xOff
	NumVertex(index,poly+0).yto = 0         +yOff
	                                         
	NumVertex(index,poly+1).xto = sqrWidFact+xOff   
	NumVertex(index,poly+1).yto = 0         +yOff
	                                         
	NumVertex(index,poly+2).xto = 0         +xOff        
	NumVertex(index,poly+2).yto = sqrHeiFact+yOff
	                                         
	`triangle 2                              
	NumVertex(index,poly+3).xto = sqrWidFact+xOff     
	NumVertex(index,poly+3).yto = 0         +yOff
	                                                                
	NumVertex(index,poly+4).xto = sqrWidFact+xOff    
	NumVertex(index,poly+4).yto = sqrHeiFact+yOff
	                                                                
	NumVertex(index,poly+5).xto = 0         +xOff   
	NumVertex(index,poly+5).yto = sqrHeiFact+yOff

endfunction

`no substance here!
function shapeNON(index, poly, xOff, yOff)

	`triangle 1
	NumVertex(index,poly+0).xto = 0         +xOff        
	NumVertex(index,poly+0).yto = 0         +yOff
	                                                                 
	NumVertex(index,poly+1).xto = 0         +xOff      
	NumVertex(index,poly+1).yto = 0         +yOff
	                                                                 
	NumVertex(index,poly+2).xto = 0         +xOff       
	NumVertex(index,poly+2).yto = 0         +yOff
	                                                                 
	`triangle 2                                                      
	NumVertex(index,poly+3).xto = sqrWidFact+xOff      
	NumVertex(index,poly+3).yto = sqrHeiFact+yOff
	                                                                 
	NumVertex(index,poly+4).xto = sqrWidFact+xOff
	NumVertex(index,poly+4).yto = sqrHeiFact+yOff
	                                                                 
	NumVertex(index,poly+5).xto = sqrWidFact+xOff
	NumVertex(index,poly+5).yto = sqrHeiFact+yOff

endfunction

`top left in
function shapeTRI1(index, poly, xOff, yOff)

	`triangle 1
	NumVertex(index,poly+0).xto = sqrWidFact/2.0+xOff
	NumVertex(index,poly+0).yto = sqrHeiFact/2.0+yOff
	                                         
	NumVertex(index,poly+1).xto = sqrWidFact    +xOff   
	NumVertex(index,poly+1).yto = 0             +yOff
	                                         
	NumVertex(index,poly+2).xto = 0             +xOff        
	NumVertex(index,poly+2).yto = sqrHeiFact    +yOff
	                                         
	`triangle 2                              
	NumVertex(index,poly+3).xto = sqrWidFact    +xOff     
	NumVertex(index,poly+3).yto = 0             +yOff
	                                                                
	NumVertex(index,poly+4).xto = sqrWidFact    +xOff    
	NumVertex(index,poly+4).yto = sqrHeiFact    +yOff
	                                                                
	NumVertex(index,poly+5).xto = 0             +xOff   
	NumVertex(index,poly+5).yto = sqrHeiFact    +yOff

endfunction

`top right in
function shapeTRI2(index, poly, xOff, yOff)

	`triangle 1
	NumVertex(index,poly+0).xto = 0             +xOff
	NumVertex(index,poly+0).yto = 0             +yOff
	                                         
	NumVertex(index,poly+1).xto = sqrWidFact/2.0+xOff   
	NumVertex(index,poly+1).yto = sqrHeiFact/2.0+yOff
	                                         
	NumVertex(index,poly+2).xto = 0             +xOff        
	NumVertex(index,poly+2).yto = sqrHeiFact    +yOff
	                                         
	`triangle 2                              
	NumVertex(index,poly+3).xto = sqrWidFact/2.0+xOff     
	NumVertex(index,poly+3).yto = sqrHeiFact/2.0+yOff
	                                                                
	NumVertex(index,poly+4).xto = sqrWidFact    +xOff    
	NumVertex(index,poly+4).yto = sqrHeiFact    +yOff
	                                                                
	NumVertex(index,poly+5).xto = 0             +xOff   
	NumVertex(index,poly+5).yto = sqrHeiFact    +yOff

endfunction

`bottom right in
function shapeTRI3(index, poly, xOff, yOff)

	`triangle 1
	NumVertex(index,poly+0).xto = 0             +xOff
	NumVertex(index,poly+0).yto = 0             +yOff
	                                         
	NumVertex(index,poly+1).xto = sqrWidFact    +xOff   
	NumVertex(index,poly+1).yto = 0             +yOff
	                                         
	NumVertex(index,poly+2).xto = 0             +xOff        
	NumVertex(index,poly+2).yto = sqrHeiFact    +yOff
	                                         
	`triangle 2                              
	NumVertex(index,poly+3).xto = sqrWidFact    +xOff     
	NumVertex(index,poly+3).yto = 0             +yOff
	                                                                
	NumVertex(index,poly+4).xto = sqrWidFact/2.0+xOff    
	NumVertex(index,poly+4).yto = sqrHeiFact/2.0+yOff
	                                                                
	NumVertex(index,poly+5).xto = 0             +xOff   
	NumVertex(index,poly+5).yto = sqrHeiFact    +yOff

endfunction

`bottom left in
function shapeTRI4(index, poly, xOff, yOff)

	`triangle 1
	NumVertex(index,poly+0).xto = 0             +xOff
	NumVertex(index,poly+0).yto = 0             +yOff
	                                         
	NumVertex(index,poly+1).xto = sqrWidFact    +xOff   
	NumVertex(index,poly+1).yto = 0             +yOff
	                                         
	NumVertex(index,poly+2).xto = sqrWidFact/2.0+xOff        
	NumVertex(index,poly+2).yto = sqrHeiFact/2.0+yOff
	                                         
	`triangle 2                              
	NumVertex(index,poly+3).xto = sqrWidFact    +xOff     
	NumVertex(index,poly+3).yto = 0             +yOff
	                                                                
	NumVertex(index,poly+4).xto = sqrWidFact    +xOff    
	NumVertex(index,poly+4).yto = sqrHeiFact    +yOff
	                                                                
	NumVertex(index,poly+5).xto = sqrWidFact/2.0+xOff   
	NumVertex(index,poly+5).yto = sqrHeiFact/2.0+yOff

endfunction

function shapeVLF(index, poly, xOff, yOff)

	`triangle 1
	NumVertex(index,poly+0).xto = 0             +xOff
	NumVertex(index,poly+0).yto = 0             +yOff
	                                         
	NumVertex(index,poly+1).xto = sqrWidFact    +xOff   
	NumVertex(index,poly+1).yto = 0             +yOff
	                                         
	NumVertex(index,poly+2).xto = sqrWidFact    +xOff        
	NumVertex(index,poly+2).yto = sqrHeiFact/2.0+yOff
	                                         
	`triangle 2                              
	NumVertex(index,poly+3).xto = sqrWidFact    +xOff     
	NumVertex(index,poly+3).yto = sqrHeiFact/2.0+yOff
	                                                                
	NumVertex(index,poly+4).xto = sqrWidFact    +xOff    
	NumVertex(index,poly+4).yto = sqrHeiFact    +yOff
	                                                                
	NumVertex(index,poly+5).xto = 0             +xOff   
	NumVertex(index,poly+5).yto = sqrHeiFact    +yOff

endfunction

function shapeVRT(index, poly, xOff, yOff)

	`triangle 1                                  
	NumVertex(index,poly+0).xto = 0             +xOff
	NumVertex(index,poly+0).yto = 0             +yOff
	                                                
	NumVertex(index,poly+1).xto = sqrWidFact    +xOff   
	NumVertex(index,poly+1).yto = 0             +yOff
	                                                
	NumVertex(index,poly+2).xto = 0             +xOff        
	NumVertex(index,poly+2).yto = sqrHeiFact/2.0+yOff
	                                                
	`triangle 2                                     
	NumVertex(index,poly+3).xto = sqrWidFact    +xOff     
	NumVertex(index,poly+3).yto = sqrHeiFact    +yOff
	                                                               
	NumVertex(index,poly+4).xto = 0             +xOff    
	NumVertex(index,poly+4).yto = sqrHeiFact    +yOff
	                                                               
	NumVertex(index,poly+5).xto = 0             +xOff   
	NumVertex(index,poly+5).yto = sqrHeiFact/2.0+yOff

endfunction


number1:
data 0,2,1,0,0
data 0,1,1,0,0,
data 0,0,1,0,0
data 0,0,1,0,0
data 0,1,1,1,0

number2:
data 2,1,1,1,3
data 1,0,0,6,1
data 0,2,1,1,4
data 2,1,7,0,0
data 1,1,1,1,1

number3:
data 1,1,1,1,3
data 0,0,0,6,1
data 0,1,1,1,7
data 0,0,0,6,1
data 1,1,1,1,4

number4:
data 1,0,0,0,1
data 1,0,0,0,1
data 5,1,1,1,1
data 0,0,0,0,1
data 0,0,0,0,1

number5:
data 2,1,1,1,1
data 1,7,0,0,0
data 5,1,1,1,3
data 0,0,0,6,1
data 1,1,1,1,4

number6:
data 2,1,1,1,0
data 1,7,0,0,0
data 1,1,1,1,3
data 1,7,0,6,1
data 5,1,1,1,4

number7:
data 1,1,1,1,1
data 0,0,0,2,4
data 0,0,2,1,0
data 0,2,1,4,0
data 0,1,4,0,0

number8:
data 2,1,1,1,3
data 1,7,0,6,1
data 6,1,1,1,7
data 1,7,0,6,1
data 5,1,1,1,4

number9:
data 2,1,1,1,3
data 1,7,0,6,1
data 5,1,1,1,1
data 0,0,0,6,1
data 0,1,1,1,4

number0:
data 2,1,1,1,3
data 1,0,2,4,1
data 1,0,1,0,1
data 1,2,4,0,1
data 5,1,1,1,4

numberSYM:
data 0,0,0,0,0
data 0,0,1,0,0
data 0,0,0,0,0
data 0,0,1,0,0
data 0,0,0,0,0

`for digit 1 to 11
numberData:
`num, max, min, thresh, dfactor
data 0,10.0, 5.0, 10.0, 1.0 `data for first digit (hundreths of a second)
data 0,10.0, 5.0, 10.0 , 10.0 `data for second digit (tenths of a second)
data 99,10.0, 1.0, 1.0 , 10.0 `data for first colon
numberDataSeconds:
data 0,10.0, 1.0, 1.0 , 10.0 `data for seconds
data 0,10.0, 1.0, 1.0 , 10.0 `data for ten Seconds
data 99,10.0, 1.0, 1.0 , 10.0`data for second colon
data 0,10.0, 1.0, 1.0 , 10.0`data for minutes
data 0,10.0, 1.0, 1.0 , 10.0`data for ten minutes
data 99,10.0, 1.0, 1.0 , 10.0`data for third colon
data 0,10.0, 1.0, 1.0 , 10.0`data for one hour
data 0,10.0, 1.0, 1.0 , 10.0`data for ten hours

sync on
sync rate 0
set ambient light 100

randomize timer()
#constant CUBE_COUNT 50
#constant IMG_SIZE 256
backdrop on
color backdrop 0


c as dword
make memblock 1, 12 + (IMG_SIZE * IMG_SIZE * 4)
write memblock dword 1, 0, IMG_SIZE
write memblock dword 1, 4, IMG_SIZE
write memblock dword 1, 8, 32
for x = 0 to IMG_SIZE-1
   for y = 0 to IMG_SIZE-1
      c = rgb(0,0,((sin(( y )*5.6470588235294117647058823529412)+1)*127))
      write memblock dword 1, 12 + (4 * (x + (y*IMG_SIZE))), c && 0x99FFFFFF
   next y
next x
make image from memblock 1, 1

remstart
for x = 0 to IMG_SIZE-1
   for y = 0 to IMG_SIZE-1
      c = rgb(0,((sin(( (x+1)*(y+1) )*5.6470588235294117647058823529412)+1)*127), 0)
      write memblock dword 1, 12 + (4 * (x + (y*IMG_SIZE))), c && 0x33FFFFFF
   next y
next x
make image from memblock 2, 1
remend
delete memblock 1


Type FlyingThing
   Speed as float
   Pos as float
EndType


for i = 1 to 1
   make object cube        i, -20 + (i*2)
   scale object            i, 100, 100, 1000
   texture object          i, i
   set object transparency i, 3
   scale object texture    i, 100, 100
next i



dim Thingies(CUBE_COUNT) as FlyingThing
for i = 1 to CUBE_COUNT
   make object cube 10+i, 8
   Thingies(i).Speed = rnd(30) + 20
   Thingies(i).Pos = rnd(100)

   select rnd(3)
      case 0
         `This is the top
         position object 10+i, rnd(20)-10, 10, Thingies(i).Pos
      endcase

      case 1
         `This is the right
         position object 10+i, 10, rnd(20)-10, Thingies(i).Pos
      endcase

      case 2
         `This is the bottom
         position object 10+i, rnd(20)-10, -10, Thingies(i).Pos
      endcase

      case 3
         `This is the left
         position object 10+i, -10, rnd(20)-10, Thingies(i).Pos
      endcase
   endselect
next i

autocam off
set camera range 0.1, 200
set camera fov 175
position camera 0, 0, -49
point camera 0,0,0
frameTime# = 1.0
startTime = timer()
do
   frameTime# = (frameTime# * 0.8) + ((timer() - startTime) * 0.2)
   startTime = timer()
   text 0,0, "FPS: " + str$(screen fps())

`   paste image 2, 0, 0,1


   for i = 1 to CUBE_COUNT
      dec Thingies(i).Pos, frameTime# * Thingies(i).Speed * 0.001
      if Thingies(i).Pos < -50 then Thingies(i).Pos = 100
      obj = 10+i
      position object obj, object position x(obj), object position y(obj), Thingies(i).Pos
   next i

   scroll object texture 1, 0, frameTime# * 0.001
   sync
loop

rem all the cool codz go here

sync on
sync rate 0

do
   center text screen width()/2, screen height()/2, "Da coolest DBPro program ever!!!!"
   sync
loop