Sorry your browser is not supported!

set display mode 1024,768,32
hide mouse
hide light 0
set ambient light 20
make light 1
autocam off
color backdrop 0
randomize timer()
fog on
fog distance 1000
fog color 0

gosub make_textures

sync on
sync rate 25

gosub make_ship
gosub make_speedbar
gosub make_walls
gosub make_barriers
gosub make_lights
gosub make_checkpoints

set text font "arial"
set text size 30
ink rgb(80,80,250),0

startagain:

gosub initial_settings
gosub zoom_in

starttime=timer()

do

if numberofloops<30
  text screen width()/2-10,screen height()/2+10,"GO!"
  inc numberofloops
endif

position light 1,object position x(1),object position y(1)+20,object position z(1)
scroll object texture 9,0,-0.03

gosub countdown
gosub score
gosub move_enemies
gosub move_lights
gosub move_checkpoints
gosub control_ship
gosub wall_collision
gosub move_walls
gosub collision_with_objects
if countdown=<0 then gosub game_over
gosub adjust_speed_bar
gosub move_camera
text 0,0,str$(screen fps())

sync
loop

make_textures:

for colour=100 to 255
ink rgb(colour-30,colour-60,colour),0
line 0,colour,155,colour
next colour
get image 1,0,100,155,255
box 0,0,100,100,rgb(55,50,50),rgb(55,50,50),rgb(50,50,50),rgb(50,50,50)
get image 2,0,0,100,100
box 0,0,100,100,rgb(100,100,150),rgb(0,0,0),rgb(100,100,150),rgb(0,0,0)
get image 3,0,0,100,100
cls
ink rgb(255,0,0),0
box 0,0,10,10
ink 0,0
box 0,0,9,9
get image 4,0,0,10,10
cls
ink rgb(255,0,0),0
set text font "arial"
set text to bold
set text size 20
text 0,20,"CHECKPOINT"
get image 5,0,0,120,60
cls
ink rgb(0,0,255),0
box 0,0,10,10
ink 0,0
box 0,0,9,9
get image 7,0,0,10,10
get image 1000000,0,0,1,1
ink rgb(255,255,0),0
box 0,0,1,1
get image 2000000,0,0,1,1
cls
make object sphere 1000000,1,30,30
ghost object on 1000000
set object specular power 1000000,50
set object specular 1000000,rgb(200,200,200)
position light 1,0,-1,2
position object 1000000,0,0,3
texture object 1000000,2000000
a=int(screen width()/3.0)
b=int(screen height()/3.0)
c=int(screen width()*2/3.0)
d=int(screen height()*2/3.0)
make object sphere 2000000,0.3
position object 2000000,0,-0.2,3
ghost object on 2000000
sync
get image 20,a,b,c,d
delete object 1000000
delete object 2000000
cls
ink rgb(100,100,100),0
box 0,0,400,400
ink 0,0
for n=1 to 200
x=rnd(400)
y=rnd(400)
sizex=rnd(20)
sizey=rnd(20)
box x,y,x+sizex,y+sizey
next n
for n=1 to 200
ink rgb(200+rnd(50),200+rnd(50),200+rnd(50)),0
x=rnd(400)
y=rnd(400)
sizex=rnd(20)
sizey=rnd(20)
box x,y,x+sizex,y+sizey
next n
get image 30,0,0,400,400
cls
ink rgb(255,255,255),0
for n=1 to 100
x=rnd(600)
y=rnd(600)
sizex=rnd(3)+1
sizey=rnd(3)+1
box x,y,x+sizex,y+sizey
next n
get image 31,0,0,600,600

cls
ink rgb(100,100,100),0
box 0,0,200,200
ink rgb(120,120,120),0
for n=1 to 100
x=rnd(200)
y=rnd(200)
sizex=rnd(10)
sizey=rnd(10)
box x,y,x+sizex,y+sizey
next n
for n=1 to 100
ink rgb(100-rnd(50),100-rnd(50),100-rnd(50)),0
x=rnd(200)
y=rnd(200)
sizex=rnd(10)
sizey=rnd(10)
box x,y,x+sizex,y+sizey
next n
get image 40,0,0,200,200

return

make_ship:

make object sphere 1,0.8,20,20
make object sphere 2,1,20,20
scale object 2,110,60,300
glue object to limb 2,1,0
make object cone 3,1
scale object 3,105,250,50
xrotate object 3,90
glue object to limb 3,1,0
position object 3,0,0,1.3
make object cone 4,1.5
scale object 4,20,140,100
zrotate object 4,-75
xrotate object 4,-35
position object 4,0.85,0.2,-1
glue object to limb 4,1,0
make object cone 5,1.5
scale object 5,20,140,100
zrotate object 5,75
xrotate object 5,-35
position object 5,-0.85,0.2,-1
glue object to limb 5,1,0
make object cone 6,0.2
set object cull 6,0
scale object 6,100,100,100
xrotate object 6,90
position object 6,0,0,-1.5
glue object to limb 6,1,0
make object cone 7,0.5
scale object 7,20,140,100
zrotate object 7,-110
xrotate object 7,-40
position object 7,0.3,-0.05,-1.3
glue object to limb 7,1,0
make object cone 8,0.5
scale object 8,20,140,100
zrotate object 8,110
xrotate object 8,-40
position object 8,-0.3,-0.05,-1.3
glue object to limb 8,1,0
for object=3 to 8
texture object object,2
set object smoothing object,100
set object specular power object,1
set object specular object,rgb(100,100,155)
next object
texture object 1,1
set object specular power 1,1
set object specular 1,rgb(100,100,155)
texture object 2,2
ghost object on 1,4
make object cone 9,0.5
set object cull 9,0
xrotate object 9,90
ghost object on 9,5
texture object 9,4
scale object texture 9,1,2
set object texture 9,2,1
set object light 9,0
position object 9,0,-0.05,-15
scale object 9,400,6000,100
glue object to limb 9,1,0
set object collision on 1
for object=1 to 4
set object collision to boxes object
next object


return

make_speedbar:

make object plain 10,3.03,0.52
position object 10,0,-3.5,6.5
set object light 10,0
disable object zdepth 10
make object plain 11,3.0,0.5
position object 11,0,-3.5,6.495
set object light 11,0
disable object zdepth 11
texture object 11,1000000
make object plain 12,3.0,0.5
position object 12,0,-3.5,6.494
set object light 12,0
disable object zdepth 12
texture object 12,2000000
lock object on 10
lock object on 11
lock object on 12
return

make_walls:

`floor
make object plain 200,1000,1000
texture object 200,30
set object light 200,0
xrotate object 200,90
scale object texture 200,5,5
make object plain 300,20,1000
texture object 300,30
set object specular power 300,1
set object specular 300,rgb(200,200,200)
set object emissive 300,rgb(50,50,20)
scale object texture 300,5,5
xrotate object 300,90
position object 300,0,0.1,0

`left
for ob=5000 to 5050
`wallx#=30*sin(theta#)
`inc theta#,2
wallx#=rnd(5)
make object box ob,10,30+rnd(30),15+rnd(15)
position object ob,-30-wallx#,0,(ob-5000)*20
`set object light ob,0
texture object ob,40
next ob
wallx#=0
theta#=0
`right
for ob=6000 to 6050
`wallx#=30*sin(theta#)
`inc theta#,2
wallx#=rnd(5)
make object box ob,10,30+rnd(30),15+rnd(15)
position object ob,30+wallx#,0,(ob-6000)*20
`set object light ob,0
texture object ob,40
next ob

`stars
make object plain 402,5000,5000
position object 402,25,0,0
xrotate object 402,-90
set object light 402,0
texture object 402,31
scale object texture 402,10,10
position object 402,0,300,0
set object fog 402,0
`hide object 402
return

make_barriers:

numberofobjects=20
dim opponentspeed#(numberofobjects+20)
for object=20 to 20+numberofobjects
random=rnd(1)
if random=0 then x#=20+rnd(30):y#=1+rnd(3)
if random=1 then x#=1+rnd(8):y#=10
make object box object,x#,y#,rnd(20)
`make object box object,rnd(10)+1,rnd(10)+1,rnd(10)+1
`color object object,rgb(0,0,250)
texture object object,40

scale object texture object,0.5*x#/y#,0.1
`ghost object on object,2
`set object specular object,rgb(rnd(55),rnd(55),rnd(55))
`set object emissive object,rgb(rnd(255),rnd(255),rnd(255))
`set object fog object,0
set object collision on object
yrotate object object,180
position object object,rnd(40)-20,rnd(10),1000-rnd(1000)
opponentspeed#(object)=rnd(10)/10.0+0.4
next object

return

make_lights:

numberofsigns=99
sign=1
polarity=1
for object=100 to 100+numberofsigns
make object plain object,1,1
ghost object on object
texture object object,20
`set object light object,0
set object transparency object,5
`set object emissive object,rgb(255,255,255)
polarity=polarity*-1
position object object,10*polarity,10,sign*1000/numberofsigns
inc sign
next object

return

make_checkpoints:

make object box 2000,30,30,1
set object collision on 2000
texture object 2000,5
ghost object on 2000
set object transparency 2000,5
set object light 2000,0
make object box 2001,30,30,1
set object collision on 2001
hide object 2001

return

initial_settings:

position camera 0,15,-100
hide object 10
hide object 11
hide object 12
for object=20 to 20+numberofobjects
position object object,rnd(8)-4,rnd(8),1000-rnd(1000)
opponentspeed#(object)=rnd(10)/10.0+0.4
next object
position object 2000,0,4,2000
position object 2001,0,4,2800
position light 1,object position x(1),object position y(1)+20,object position z(1)
addedtocountdown=0
exclusionflag=0
addtime=0
crash=0
skid=0
restart=0
score=0
speed#=0
maxspeed#=0.25
numberofloops=0
hide object 9
position object 1,0,2,0
rotate object 1,0,0,0

return

zoom_in:

do
text screen width()/2-30,screen height()/2-20,"Get ready....."
position camera 0,curvevalue(4,camera position y(0),10),curvevalue(-6,camera position z(0),10)
if camera position z()>-6.1 then exit
sync
loop
show object 9
show object 10
show object 11
show object 12
position camera 0,4,-6

return

countdown:

time=(timer()-starttime)/1000
countdown=40-time+addedtocountdown
ink rgb(250,0,0),0
text screen width()/2-20,0,str$(countdown)

return

score:

ink rgb(80,80,250),0
text screen width()/2-20,30,"Score: "+str$(score)

return

move_enemies:

for object=20 to 20+numberofobjects
position object object,object position x(object),object position y(object),object position z(object)-speed#*30`+opponentspeed#(object)
if object position z(object)<0
  position object object,rnd(50)-25,rnd(10),1000
  if crash=0 and skid=0
    inc score
  endif
endif
if object position z(object)>1000 then position object object,4,6,0
next object

return

move_lights:

for object=100 to 100+numberofsigns
position object object,object position x(object),object position y(object),object position z(object)-speed#*30
if object position z(object)<0 then position object object,object position x(object),object position y(object),1000
if object position z(object)>1000 then position object object,object position x(object),object position y(object),0
next object

return

move_checkpoints:

for object=2000 to 2001
position object object,object position x(1),object position y(1),object position z(object)-speed#*30
if object position z(object)<-50 then position object object,object position x(object),object position y(object),2500
next object

return

control_ship:

if shiftkey()=1 and speed#<maxspeed# then inc speed#,0.0005
if controlkey()=1 and speed#>0 then dec speed#,0.0005
xmousemove#=0
ymousemove#=0
if rightkey()=1 then xmousemove#=.5
if leftkey()=1 then xmousemove#=-.5
if upkey()=1 then ymousemove#=-.5
if downkey()=1 then ymousemove#=.5


if speed#>0
  speedy#=curvevalue(ymousemove#,speedy#,10)
  speedx#=curvevalue(xmousemove#,speedx#,10)
  xrotate object 1,curveangle(-ymousemove#*80,object angle x(1),10)
  zrotate object 1,curveangle(-xmousemove#*80,object angle z(1),10)
endif
if xmousemove#=0
  zrotate object 1,curveangle(0,object angle z(1),20)
  speedx#=curvevalue(0,speedx#,20)
endif
if ymousemove#=0
  xrotate object 1,curveangle(0,object angle x(1),20)
  speedy#=curvevalue(0,speedy#,20)
endif

if crash=0
position object 1,object position x(1)+speedx#,object position y(1)+speedy#,0
endif

return

wall_collision:

if object position x(1)<-22 then position object 1,-22,object position y(1),object position z(1)
if object position x(1)>22 then position object 1,22,object position y(1),object position z(1)
if object position y(1)<0 then position object 1,object position x(1),0,object position z(1)
if object position y(1)>10 then position object 1,object position x(1),10,object position z(1)

return

move_walls:

scroll object texture 200,0,speed#/5
scroll object texture 300,0,speed#/5
`scroll object texture 400,speed#/5,0
`scroll object texture 401,speed#/5,0
`scroll object texture 402,0,0.01
for object=5000 to 5050
position object object,object position x(object),object position y(object),object position z(object)-speed#*30`+opponentspeed#(object)
if object position z(object)<0
  position object object,-30-rnd(5),object position y(object),object position z(object)+1000
endif
next object

for object=6000 to 6050
position object object,object position x(object),object position y(object),object position z(object)-speed#*30`+opponentspeed#(object)
if object position z(object)<0
  position object object,30+rnd(5),object position y(object),object position z(object)+1000
endif
next object

return

collision_with_objects:

for test=1 to 4
collisionnumber=object collision(test,0)
if collisionnumber>=20 and collisionnumber<=20+numberofobjects and crash=0
   skid=1
   crash=1
   hide object 9
   yspeed#=speed#/1.5
   gravity#=0.002
   spin#=speed#*50.0
   goto getout
endif
next test
getout:
`collision with checkpoint
if object position z(1)>object position z(2000) and object position z(1)<object position z(2001) then addtime=1
if addtime=1 and exclusionflag=0
  inc addedtocountdown,20
  exclusionflag=1
endif
`collision with checkpoint reset point
if object position z(1)>object position z(2001) and exclusionflag=1 then exclusionflag=0:addtime=0
if skid=1
   rotate object 1,curveangle(-40,object angle x(1),15),object angle y(1)-spin#,curveangle(90,object angle z(1),10)
   position object 1,object position x(1),object position y(1),0
   if speed#<=0
     restart=1
     skid=0
     speed#=0
     crash=0
     position object 1,object position x(1),1,0
   endif
endif
if crash=1
   position object 1,object position x(1),object position y(1)+yspeed#,object position z(1)
   dec yspeed#,gravity#
   if object position y(1)<=1
     position object 1,object position x(1),1,0
     yspeed#=yspeed#*-0.4
     dec speed#,0.1
   endif
endif
if restart=1
   show object 9
   rotate object 1,0,0,0
   restart=0
endif

return

game_over:

  text screen width()/2-30,screen height()/2-20,"Game Over"
  sync
  wait 2000
  text screen width()/2-100,screen height()/2+20,"Press any key to restart"
  sync
  wait key
  goto startagain

return

adjust_speed_bar:

scale object 12,100*speed#/maxspeed#,100,100
position object 12,-1.5*(1.0-(speed#/maxspeed#)),object position y(12),object position z(12)

return

move_camera:

position camera curvevalue(object position x(1),camera position x(),5),curvevalue(object position y(1)+1,camera position y(),10),-6

return

`Trench Runner
`======================
`© CPU
`======================
`Main Source File

#constant trenchLength = 20
#constant crossBridgeObjQty = 3
#constant crossBridgeChance = 5
#constant maxBlastObjects = 200
#constant bumpMappingOn = 0
#constant turretMax = 25
#constant turretProb = 10
#constant maxShips = 10
#constant maxActionKeys = 30
#constant maxBooms = 27
#constant trenchCeil = 20
#constant maxMessages = 20
#constant hasMessagePanel = 1
#constant winDistance = 5000

#constant pitchSpeed = 1.0
#constant turnSpeed = 1.0
#constant rollSpeed = 0.7

#constant moveSpeed = 0.75
#constant accSpeed = 0.1
#constant fireRate = 90
#constant pathChangeChance = 30
#constant lookAheadDist = 70
#constant randBurstChance = 10
#constant underFireEvadeChance = 50
#constant EvadeAmnt = 1.0
#constant blastDamage = 20
#constant StartSepDist = 20

#constant AutoBReloadTime = 1000

#constant empireShipSize = 0.50
#constant rebelShipSize = 1.0
#constant pathFuzzy = 0.1

#constant cSize = 0.50

#constant turretLead = 25

#constant rayLen = 10000

`helpfull constants
#constant EmpireShip = 2
#constant RebelShip = 1

#constant AIcontrol = 1
#constant playerControl = 2

#constant keyHoldUp = 1
#constant keyJustPressed = 2
#constant keyHoldDown = 3
#constant keyJustReleased = 4

#constant keyPitchUp = 1
#constant keyPitchDown = 2
#constant keyRollLeft = 3
#constant keyRollRight = 4
#constant keyFire = 5
#constant keySlideLeft = 6
#constant keySlideRight = 7
#constant keySlideUp = 8
#constant keySlideDown = 9
#constant keyForward = 10
#constant keyAutoToggle = 11

#constant keyCamRotUp = 12
#constant keyCamRotDown = 13
#constant keyCamRotRight = 14
#constant keyCamRotLeft = 15
#constant keyCamRotRollR = 16
#constant keyCamRotRollL = 17

#constant keyCamMovUp = 18
#constant keyCamMovDown = 19
#constant keyCamMovRight = 20
#constant keyCamMovLeft = 21
#constant keyCamMovFwd = 22
#constant keyCamMovBak = 23

#constant keyToggleFreeRot = 24 
#constant keyToggleMsgPan = 25

#constant keyPhotonTorpedo = 26 
#constant keySwitchShips = 27
#constant keyPauseKey = 28

sync on
sync rate 0
autocam off
set camera range 0.001,1000
disable escapekey
fog on
fog distance trenchLength*10

color backdrop rgb(0,0,0)

make light 1
point light 1,25,100,0

randomize timer()

position camera 1,5,-10
`position camera 25,25,25
point camera 1,5,0

global trenchObj as integer
global trenchTexture as integer
global trenchBumpmap as integer
global curblock as integer
global endTarget as integer

global greenLaserImg as integer
global redLaserImg as integer
global gridImg as integer
global XwingImg as integer
global bladeImg as integer
global explodeImg as integer
global sWaveImg as integer
global msgPanImg as integer
global msgUpImg as integer
global msgDownImg as integer

global SkyBoxNum as integer
global StarsTexture as integer
global DSTexture as integer

global turretFireRate as integer = 300
global messagesLastUpdate as integer
global msgPanalVisible as integer = 1

global playerShip as integer

global camRotX as float
global camRotY as float
global camRotZ as float
global freeRotToggle as integer

global camOffVert as float = 0.6
global camOffHorz as float
global camOffZ as float = -1.2

global rebelVictory as integer
global empireVictory as integer
global EmpireRecreate as integer
global timeLeft as integer
global prgEnd as integer = 0
global gamePaused as integer
global timeStoped as integer
global stopTime as integer

`FPS independent stuff
`variables for FPS independent
 global FPS as integer
 global GameSpeed as integer
 global LoopConstant as double float
 global LoopTime as integer
 global LastLoopTime as integer
 global LoopSpeed as double float
 global FPSISmoothing as integer
 global MaxLoopTime as integer
 

 
 MaxLoopTime = 100
 GameSpeed = 60
 LoopSpeed = 1.0
 FPSISmoothing = 25
 LastLoopTime = timer()

type xyzfloat
	x as float
	y as float
	z as float
endtype

type tsqrType
	objnum as integer
endtype

type colBox
	objNum as integer
	xsize as integer
	ysize as integer
	zsize as integer
endtype

type blastType
	color as integer
	vel as float
	traveledDist as float
	maxDist as float
	objnum as integer
	exist as integer
	startTime as integer
	life as integer
	dynColCheck as float
	live as integer
	BType as integer
endtype

type turretType
	exist as integer
	objNum as integer
	objNumBox as integer
	objNumStand as integer
	reload as integer
	orient as integer
	target as integer
endtype

type autoShip
	controlType as integer
	exist as integer
	side as integer
	objnum as integer
	reload as integer
	intersectUpdate as integer
	roll as float
	vel as float
	newPathOverride as integer
	autoPathX as float
	autoPathY as float
	autoBurst as integer
	autoBreload as integer
	target as integer
	engageTime as integer
	underFire as integer
	health as integer
	incoming as integer
	numTorpedos as integer
endtype

type BoomType
	exist as integer
	boomObj as integer
	shockObj as integer
	scale as float
	scale2 as float
	vanishSize as float
endtype

type keyType
	keycode as integer
	lastState as integer
	currentState as integer
endtype

global dim trenchSqr(trenchLength) as tsqrType
global dim crossBridges(trenchLength,crossBridgeObjQty) as colBox

global dim blast(maxBlastObjects) as blastType
global dim turrets(turretMax) as turretType
global dim autoShips(maxShips) as autoShip
global dim booms(maxBooms) as BoomType

global dim actionKeys(maxActionKeys) as keyType

global dim messages(maxMessages) as string



bladeImg = freeImage()
Blades2Texture(bladeImg)
XwingImg = freeImage()
WhiteStainedTexture(XwingImg)
gridImg = freeImage()
SolarGridTexture(gridImg)
gridImg = freeImage()
SolarGridTexture(gridImg)
greenLaserImg = freeImage()
greenLaserTexture(greenLaserImg)
redLaserImg = freeImage()
redLaserTexture(redLaserImg)
StarsTexture = freeImage()
StarsTexture(StarsTexture)
explodeImg = freeImage()
ExplodeTexture(explodeImg)
sWaveImg = freeImage()
ShockWaveTexture(sWaveImg)
msgPanImg = freeImage()
MessagePanalImg(msgPanImg)

DSTexture = freeImage()
BlockEndTexture(DSTexture)

gosub makeTrenchObj

`cool backround pannel for messages
if hasMessagePanel = 1
	sprite msgPanImg, 0,0,msgPanImg
	set sprite alpha msgPanImg, 125
	hide sprite msgPanImg
endif


`skybox creation
SkyBoxNum = freeObject()
createSkyBox(SkyBoxNum, 1000)

for n = 1 to 6
	texture limb SkyBoxNum, n, StarsTexture
	scale limb texture SkyBoxNum, n, 5,5
next n



for n = 1 to maxBlastObjects
	constructBlast(n)
next n

for n = 1 to turretMax
	buildTurret(n)
next n

`auto ships!!
createAutoShips()

`Kerblooom!!!
makeBooms()

`action keys, change to change controls...
actionKeys(keyPitchUp).keycode = 200
actionKeys(keyPitchDown).keycode = 208
actionKeys(keyRollLeft).keycode = 203
actionKeys(keyRollRight).keycode = 205
actionKeys(keyFire).keycode = 157 `control key
actionKeys(keySlideUp).keycode = 72
actionKeys(keySlideDown).keycode = 80
actionKeys(keySlideLeft).keycode = 75
actionKeys(keySlideRight).keycode = 77
actionKeys(keyForward).keycode = 184 `alt key

actionKeys(keyAutoToggle).keycode = 30 `'a' key

`Extended camera control keys...
actionKeys(keyCamRotUp).keycode = 23
actionKeys(keyCamRotDown).keycode = 37
actionKeys(keyCamRotRight).keycode = 38
actionKeys(keyCamRotLeft).keycode = 36
actionKeys(keyCamRotRollR).keycode = 26
actionKeys(keyCamRotRollL).keycode = 27

actionKeys(keyCamMovUp).keycode = 210
actionKeys(keyCamMovDown).keycode = 211
actionKeys(keyCamMovRight).keycode = 199
actionKeys(keyCamMovLeft).keycode = 207
actionKeys(keyCamMovFwd).keycode = 201
actionKeys(keyCamMovBak).keycode = 209

actionKeys(keyToggleFreeRot).keycode = 46
actionKeys(keyToggleMsgPan).keycode = 50

actionKeys(keyPhotonTorpedo).keycode = 28
actionKeys(keySwitchShips).keycode = 31

actionKeys(keyPauseKey).keycode = 25

remstart
createsound("sparkle1",10,8000,3000,500,30,0.01,10,5,0,0,0.05)
createsound("sparkle2",11,6200,5000,300,30,0.01,10,5,0,0,0.05)
createsound("sparkle3",12,4000,5000,800,30,0.01,10,5,0,0,0.05)
createsound("rocket1",4,1600,1000,4000,0.005,0.2,0,0,0,0,10)
createsound("rocket2",5,1800,1500,8000,0.008,0.2,0,0,0,0,10)
createsound("rocket3",7,2200,2500,500,0.003,0.2,0,0,0,0,10)
createsound("deep explosion",9,30,100,16000,0.00,1.5,.0,0,0,0,100)

soundPlay(10)
soundPlay(11)
soundPlay(12)
soundPlay(4)
soundPlay(5)
soundPlay(7)
soundPlay(9)
remend


`createXwingfighter(1000, 0.5)
`createTIEfighter(1000,0.5)
remstart
make object box 1000,0.25,0.25,0.25
set object collision off 1000
hide object 1000
remend

intro()

do
	
	resetBullets()
	resetTurrets()
	resetBooms()
	resetShips()
	clearMsgs()
	
	menu()
	
	rebelVictory = 0
	empireVictory = 0
	`threee minuts before rebel base ceases to exist...
	timeLeft = getTime() + 180000
	`AddRebelShip(15.0, AIcontrol)
	
	`createTurret(0, 1.25, 0, 1)
	
	`make object box 201,2,2,2
	`point object 201,0,0,10
	`tmpFireTime = timer()
	
	`explode(1000)
	
	`-------------------------------------------------
	`#################  Enter Main loop  #############
	`-------------------------------------------------
	
	repeat
		updateKeys()
		updateMessages()
		
		if wrapvalue(camera angle y()) > 270 or wrapvalue(camera angle y()) < 90
			updateTrench(camera position z(), 10.0, 1)
		else
			updateTrench(camera position z(), 10.0, 0)
		endif
		
		`Skybox Update
		position object SkyBoxNum, camera position x(), camera position y(), camera position z() 
		
		if gamePaused = 0
			updateExplode()
			
		
			`recreate empire ships, the rebels are limited, but harder to hit =)
			if getTime() - EmpireRecreate > 10000
				AddEmpireShip(0, AIcontrol)
				EmpireRecreate = getTime()
			endif
			
			`ok i relent, a few extra rebel ships come in every now and again as well =)
			if rnd(4000) = 1
				tmp = AddRebelShip(0, AIcontrol)
				newMsg(tmp, "Little recon reo commin in...")
			endif
			
			
			
			updateAutoShips()
			updateTurrets(camera position z(), 10.0)
			updateBlasts()
			
			if timeLeft - getTime() <= 0 and rebelVictory = 0 then empireVictory = 1
			if countAutoShips(RebelShip) <= 0 then empireVictory = 1
		
		else
			`so da game is paused...
			ink RGB(0,128,192),0
			center text screen width()/2, screen height()/2,"Game Paused"
		endif
	
		updateExtendedKeyControls()
		
		FPS_UpdateIndependent()
		
		ink rgb(200,140,0),0
		text 5,screen height() - 35, "Rebel Ships: " + str$(countAutoShips(RebelShip))
		text 5,screen height() - 20, "Empire Ships: " + str$(countAutoShips(EmpireShip))
		center text screen width()/2,screen height() - 35, str$(int((timeLeft - getTime())/600)) + "Seconds Remaining"
		center text screen width()/2,screen height() - 20, str$(int(winDistance - camera position z())) + "m Remaining"
		sync
		
		`loop until exscapekey = 1
	until escapekey() = 1 or rebelVictory = 1 or empireVictory = 1

	if escapekey() = 1
		repeat
			sync
			`anti word blocking
		until escapekey() = 0
	endif
	
	if rebelVictory = 1
		rebelWinVid()
	endif
	
	if empireVictory = 1
		EmpireWinVid()
	endif
	
	`so somebody one eh? play me a video =)
	if rebelVictory = 1 or empireVictory = 1
	endif
loop

function getTime()
	local rtrn as integer
	if timeStoped
		rtrn = stopTime
	else
		rtrn = timer() - stopTime
	endif

endfunction rtrn

function startTime()
	timeStoped = 0
	stopTime = timer() - stopTime
endfunction

function stopTime()
	timeStoped = 1
	stopTime = timer() - stopTime
endfunction

function updateExtendedKeyControls()
	`engage/disengage autopilot
	if codeState(keyAutoToggle) = keyJustPressed
		if autoShips(playerShip).controlType = AIcontrol
			autoShips(playerShip).controlType = playerControl
			newMsg(playerShip, "Auto Pilot Disengaged")
		else
			autoShips(playerShip).controlType = AIcontrol
			newMsg(playerShip, "Auto Pilot Engaged - Enjoy the flight.")
		endif
	endif
	
	`Extended camera control keys...
	if codeState(keyCamRotUp) = keyHoldDown then camRotX = camRotX - timeValue(1.5)
	if codeState(keyCamRotDown) = keyHoldDown then camRotX = camRotX + timeValue(1.5)
	if codeState(keyCamRotRight) = keyHoldDown then camRotY = camRotY + timeValue(1.5)
	if codeState(keyCamRotLeft) = keyHoldDown then camRotY = camRotY - timeValue(1.5)
	if codeState(keyCamRotRollR) = keyHoldDown then camRotZ = camRotZ + timeValue(1.5)
	if codeState(keyCamRotRollL) = keyHoldDown then camRotZ = camRotZ - timeValue(1.5)
	
	if codeState(keyCamMovUp) = keyHoldDown then camOffVert = camOffVert + timeValue(0.0125)
	if codeState(keyCamMovDown) = keyHoldDown then camOffVert = camOffVert - timeValue(0.0125)
	if codeState(keyCamMovRight) = keyHoldDown then camOffHorz = camOffHorz + timeValue(0.0125)
	if codeState(keyCamMovLeft) = keyHoldDown then camOffHorz = camOffHorz - timeValue(0.0125)
	if codeState(keyCamMovFwd) = keyHoldDown then camOffZ = camOffZ + timeValue(0.025)
	if codeState(keyCamMovBak) = keyHoldDown then camOffZ = camOffZ - timeValue(0.025)
	
	if codeState(keyToggleFreeRot) = keyJustPressed
		if freeRotToggle = 0
			freeRotToggle = 1
			newMsg(99, "Free Camera Rotate Engaged")
		else
			freeRotToggle = 0
			newMsg(99, "Constrained Camera Rotate Engaged")
		endif
	endif
	
	if codeState(keyToggleMsgPan) = keyJustPressed
		if msgPanalVisible = 0
			msgPanalVisible = 1
			newMsg(99, "Message Pannel Displayed")
		else
			msgPanalVisible = 0
			newMsg(99, "Message Pannel Hidden")
		endif
	endif
	
	if codeState(keyPauseKey) = keyJustPressed
		if gamePaused = 0
			gamePaused = 1
			newMsg(99, "Game Paused")
			stopTime()
		else
			gamePaused = 0
			newMsg(99, "Game Continued")
			startTime()
		endif
	endif
	
	if codeState(keyPhotonTorpedo) = keyJustPressed
		if autoShips(playerShip).side = RebelShip and autoShips(playerShip).numTorpedos > 0
			fireBlast(autoShips(playerShip).objnum, RebelShip, 0,-0.1, 1.5,2)
			fireBlast(autoShips(playerShip).objnum, RebelShip, 0, 0.1, 1.5,2)
			autoShips(playerShip).numTorpedos = autoShips(playerShip).numTorpedos - 2
			newMsg(ship, "Torpedos away!")
		endif
	endif
	
	if codeState(keySwitchShips) = keyJustReleased
		tmp = playerChange(autoShips(playerShip).side)
		if tmp <> -1
			playerShip = tmp
		endif
	endif
	
	`player re-enter if passing exaust port...
	if object position z(autoShips(playerShip).objnum) >= winDistance
		position object autoShips(playerShip).objnum, 0, 20, winDistance - 1000
		autoShips(playerShip).incoming = 1
		newMsg(playerShip, "Goin again...")
	endif
	
	`now update camera
	autoCamera(playerShip)
endfunction

function FPS_UpdateIndependent()
	`update FPS independent code
     LoopTime = timer() - LastLoopTime
     LastLoopTime = timer()

     if LoopTime > MaxLoopTime then LoopTime = MaxLoopTime

     LoopConstant = GameSpeed/1000.0
     LoopSpeed = (LoopSpeed*(FPSISmoothing-1.0) + (LoopTime * LoopConstant * 1.0)) / FPSISmoothing*1.0
     FPS = screen fps()
      `done with FPS independent part
endfunction

function timeValue(value as float)
	local rtrn as float
	rtrn = value * LoopSpeed
endfunction rtrn

function MouseControl(Speed as float)
	
	xrotate camera wrapvalue(camera angle x()+mousemovey()/3.0)
	yrotate camera wrapvalue(camera angle y()+mousemovex()/3.0)
	if mouseclick()=1 then move camera timeValue(Speed)
	if mouseclick()=2 then move camera timeValue((0-Speed))
	
	if camera position y() > 10 then position camera camera position x(), 10, camera position z()
	if camera position y() < 1 then position camera camera position x(), 1, camera position z()
	
	if camera position x() > 4.9 then position camera 4.9, camera position y(), camera position z()
	if camera position x() < -4.9 then position camera -4.9, camera position y(), camera position z()

endfunction

function updateKeys()
	for n = 1 to maxActionKeys
		if actionKeys(n).keycode > 0
			actionKeys(n).lastState = actionKeys(n).currentState
			actionKeys(n).currentState = keystate(actionKeys(n).keycode)
		endif
	next n
endfunction

function codeState(actionKey as integer)
	local rtrn as integer = -1
	if actionKeys(actionKey).keycode > 0
		if actionKeys(actionKey).currentState = 0 and actionKeys(actionKey).lastState = 0
			rtrn = keyHoldUp
		endif
		
		if actionKeys(actionKey).currentState = 1 and  actionKeys(actionKey).lastState = 0
			rtrn = keyJustPressed
		endif
		
		if actionKeys(actionKey).currentState = 1 and  actionKeys(actionKey).lastState = 1
			rtrn = keyHoldDown
		endif
		
		if actionKeys(actionKey).currentState = 0 and  actionKeys(actionKey).lastState = 1
			rtrn = keyJustReleased
		endif
	
	endif
endfunction rtrn



makeTrenchObj:

	local tmpMesh as integer
	local tmpObj as integer
	
	trenchObj = FreeObject()
	tmpMesh = FreeMesh()
	
	trenchTexture = FreeImage()
	BlockTexture(trenchTexture)
	if bumpMappingOn = 1
		trenchBumpmap = FreeImage()
		BWBlockTexture(trenchBumpmap)
	endif

	make object plain trenchObj, 10,10
	
	tmpObj = FreeObject()
	
	make object plain tmpObj, 10,10
	make mesh from object tmpMesh,tmpObj
	delete object tmpObj
	
	add limb trenchObj,1,tmpMesh
	
	offset limb trenchObj,1,5,0,-5
	rotate limb trenchObj,1,0,-90,0
	
	delete mesh tmpMesh
	
	make object plain tmpObj, 10,10
	make mesh from object tmpMesh,tmpObj
	delete object tmpObj
	
	add limb trenchObj,2,tmpMesh
	
	offset limb trenchObj,2,-5,0,-5
	rotate limb trenchObj,2,0,90,0
	
	add limb trenchObj,3,tmpMesh
	offset limb trenchObj,3,105,0,-10
	scale limb trenchObj,3,2000,100,100
	scale limb texture trenchObj,3, 20, 1
	
	add limb trenchObj,4,tmpMesh
	offset limb trenchObj,4,-105,0,-10
	scale limb trenchObj,4,2000,100,100
	scale limb texture trenchObj,4, 20, 1
	
	delete mesh tmpMesh
	
	texture object trenchObj,trenchTexture
	if bumpMappingOn = 1
		set bump mapping on trenchObj,trenchBumpmap
	else
		set object emissive trenchObj, rgb(150,150,150)
	endif
	set object cull trenchObj, 0
	
	position object trenchObj,0,0,0
	rotate object trenchObj,90,0,0
	
	hide object trenchObj
	
	buildTrench(trenchObj, 10)
return

function buildTrench(obj as integer, spacing as float)
	for n = 1 to trenchLength
		trenchSqr(n).objnum = FreeObject()
		instance object trenchSqr(n).objnum, obj
		`texture object trenchSqr(n).objnum,trenchTexture
		`set bump mapping on trenchSqr(n).objnum,trenchBumpmap
		position object trenchSqr(n).objnum,0,0,(n-2)*spacing
		rotate object  trenchSqr(n).objnum,90,0,0
		`show object trenchSqr(n).objnum
	next n
	
	`end target
	endTarget = freeObject()
	make object plain endTarget,10,10
	tmp = freeObject()
	make object box tmp, 10,10,100
	position object tmp,0, 5, winDistance+51
	texture object tmp,trenchTexture
	
	texture object endTarget, DSTexture
	position object endTarget,0,5,winDistance
	set object cull endTarget, 0
	point object endTarget,0,5,0
endfunction

function updateTrench(cameraZ as float, spacing as float, direction as integer)
	local updateBridges as integer
	if curBlock <> int(cameraZ/spacing) then updateBridges = 1 : curBlock = int(cameraZ/spacing)
	if direction = 1
		for n = 1 to trenchLength
			position object trenchSqr(n).objnum,0,0,(n-2)*spacing+int(cameraZ/spacing)*spacing
		next n
	else
		for n = 1 to trenchLength
			position object trenchSqr(n).objnum,0,0,(n+2-trenchLength)*spacing+int(cameraZ/spacing)*spacing
		next n
	endif
	
	`position object 
	
	`I still want to update bridges and turrets, even if looking backwards, but I just need to update the 
	`side walls
		if rnd(crossBridgeChance) = 1 and updateBridges = 1 then buildBridge((curBlock mod trenchLength), (n-2)*spacing+int(cameraZ/spacing)*spacing, spacing)
		`turret time!
		if rnd(turretProb) = 1 and updateBridges = 1
			tmp = rnd(10)
			select tmp
				case 0
					`bottom
					createTurret(-4+rnd(8), 1.25, (n-2)*spacing+int(cameraZ/spacing)*spacing, 1)
				endcase
				case 1
					`left
					createTurret(3.25, rnd(6)+2, (n-2)*spacing+int(cameraZ/spacing)*spacing, 0)
				endcase
				case 2
					`right
					createTurret(-3.25, rnd(6)+2, (n-2)*spacing+int(cameraZ/spacing)*spacing, 0)
				endcase
				case default
					`this way there is more pedistal turrets than trench turrets
					if rnd(1) = 1
						`pedistal turret on the right
						createTurret(15, 25, (n-2)*spacing+int(cameraZ/spacing)*spacing, 2)
					else
						`pedistal turret on the left
						createTurret(-15, 25, (n-2)*spacing+int(cameraZ/spacing)*spacing, 2)
					endif
				endcase
			endselect
		endif
	
endfunction

function buildBridge(tsqr, zPos as float, sqrSize)
	local posy as float
	local posz as float

	posy = rnd(sqrSize)
	posz = zPos - sqrSize/2 + rnd(sqrSize)
	
	for n = 1 to crossBridgeObjQty
		if crossBridges(tsqr,n).objNum > 0
			if object exist(crossBridges(tsqr,n).objNum) = 1 then delete object crossBridges(tsqr,n).objNum
		endif
		crossBridges(tsqr,n).objNum = FreeObject()
		make object box crossBridges(tsqr,n).objNum, 100,100,100
		texture object crossBridges(tsqr,n).objNum,trenchTexture
		`set bump mapping on crossBridges(tsqr,n).objNum,trenchBumpmap
		position object crossBridges(tsqr,n).objNum,(sqrSize/3.0)*(n-2), posy, posz
		
		crossBridges(tsqr,n).xsize = (sqrSize/3.0) + 1.0
		crossBridges(tsqr,n).ysize = rnd(sqrSize/5.0) + 1.0
		crossBridges(tsqr,n).zsize = rnd(sqrSize/5.0) + 1.0
		scale object crossBridges(tsqr,n).objNum, crossBridges(tsqr,n).xsize, crossBridges(tsqr,n).ysize, crossBridges(tsqr,n).zsize
	
		set object collision to boxes crossBridges(tsqr,n).objNum
		`set object collision on crossBridges(tsqr,n).objNum
	next n
endfunction

function createsound(name$,soundnumber,frequency#,length#,loudness#,bend#,decay#,vibratospeed#,vibratodepth#,tremelospeed#,tremelodepth#,attack#)

outWord as word
dword1 as dword: dword2 as dword: dword3 as dword: dword4 as dword
dword5 as dword: dword6 as dword: dword7 as dword

samples=int((length#/1000)*44100)

if memblock exist(1) then delete memblock 1
make memblock 1,samples*2+28

` write 28 memblock header bytes
dword1=1      ` gg query: is this the number of channels?
dword2=2      ` gg query: is this the number of bytes per sample?
dword3=22050  ` gg query: seems to be half the number of samples per second - why?
dword4=88200  ` gg query: is this the number of bytes per second?
dword5=4      ` gg query: what does this represent?
dword6=16     ` gg query:     (ditto)            ?
dword7=0      ` gg query:     (ditto)            ?

position=0
write memblock dword 1, position, dword1 : inc position,4
write memblock dword 1, position, dword2 : inc position,4
write memblock dword 1, position, dword3 : inc position,4
write memblock dword 1, position, dword4 : inc position,4
write memblock dword 1, position, dword5 : inc position,4
write memblock dword 1, position, dword6 : inc position,4
write memblock dword 1, position, dword7 : inc position,4

rem generate and write wave
riseinloudness#=loudness#
for x=1 to samples
  outInteger=int(sin((x/122.5)*(frequency#+vibratodepth#*sin(theta#)))*(loudness#-fallinloudness#-riseinloudness#+tremelodepth#*sin(phi#)))*3.0
  if outInteger <-32767 then outInteger=-32767  ` gg query: is this the valid range?
  if outInteger>32767 then outInteger=32767     ` gg query:       (ditto)          ?
  outWord=outInteger
  inc theta#,vibratospeed#
  inc phi#,tremelospeed#
  dec frequency#,bend#

  if fallinloudness#<loudness#
    inc fallinloudness#,decay#
  endif

  if riseinloudness#>0
    dec riseinloudness#,attack#
  endif

  write memblock word 1, position, outWord : inc position,2
next x

if sound exist(soundnumber)=1 then delete sound soundnumber

make sound from memblock 999, 1 ` assumes you won't need sound number 999!
clone sound soundnumber, 999
delete sound 999

` memblock no longer required
delete memblock 1

endfunction

function FreeMesh()
	repeat
		inc i
		if mesh exist(i)=0 then found=1
	until found
endfunction i

function FreeObject()
	repeat
		inc i 
		if object exist(i)=0 then found=1
	until found
endfunction i

function FreeImage()
	repeat
		inc i
		if image exist(i)=0 then found=1
	until found
endfunction i


function FreeMemblock()
	repeat
		inc i
		if memblock exist(i)=0 then found=1
	until found
endfunction i

function constructBlast(index)
	local tmp as integer
	local tmp2 as integer

	blast(index).objNum = freeObject()
	
	make object plain blast(index).objNum, 0, 0
	
	tmp = freeObject()
	tmp2 = freeMesh()
	
	make object plain tmp, 0.125, 3
	make mesh from object tmp2, tmp
	delete object tmp
	
	add limb blast(index).objNum, 1, tmp2
	rotate limb blast(index).objNum, 1,90,0,90
	add limb blast(index).objNum, 2, tmp2
	rotate limb blast(index).objNum, 2,90,0,0
	
	show limb blast(index).objNum, 1
	show limb blast(index).objNum, 2
	
	set object cull blast(index).objNum,0
	
	rotate object blast(index).objNum, 0,0,0
	position object blast(index).objNum, 0,0,0
	
	ghost object on blast(index).objNum,0
	`set object light blast(index).objNum, 0

	set object emissive blast(index).objNum, rgb(255,255,0)
	
	set object collision off blast(index).objNum

	hide object blast(index).objNum
endfunction

function updateBlasts()
	for n = 1 to maxBlastObjects
		if blast(n).exist = 1
			move object blast(n).objNum, timeValue(blast(n).vel)
			inc blast(n).traveledDist, timeValue(blast(n).vel)
			inc blast(n).dynColCheck, timeValue(blast(n).vel)
			`timer kill
			if getTime() - blast(n).startTime > blast(n).life
				blast(n).exist = 0
				hide object blast(n).objNum
			endif
			
			if blast(n).dynColCheck > 2.0 and blast(n).live = 1
				
				
				tmpx# = object position x(blast(n).objNum)
				tmpy# = object position y(blast(n).objNum)
				tmpz# = object position z(blast(n).objNum)
				move object blast(n).objNum, blast(n).dynColCheck + 2.0
				
				turret = intesectTurret(tmpx#, tmpy#, tmpz#, object position x(blast(n).objNum), object position y(blast(n).objNum), object position z(blast(n).objNum))
				shipHit = intesectShip(tmpx#, tmpy#, tmpz#, object position x(blast(n).objNum), object position y(blast(n).objNum), object position z(blast(n).objNum),(empireShipSize+rebelShipSize)/2)

				move object blast(n).objNum, 0 - blast(n).dynColCheck - 2.0
				
				`collision with turret, life?
				if turret > 0
					hideTurret(turret)
					explode(turrets(turret).objNum)
					newMsg(100, "Turret Scrap heap")
					blast(n).exist = 0
					hide object blast(n).objNum
				endif
				
				`collision with ship, life?
				if shipHit > 0
					blast(n).exist = 0
					hide object blast(n).objNum
					
					autoShips(shipHit).health = autoShips(shipHit).health - blastDamage
					if autoShips(shipHit).health <= 0
						explode(autoShips(shipHit).objNum)
						newMsg(shipHit, "AHHHHHHHHH!!!!!!!!!")
						newMsg(shipHit, "Elimiated")
						killShip(shipHit)
						if playerShip = shipHit
							tmp = playerChange(autoShips(shipHit).side)
							if tmp <> -1
								playerShip = tmp
							endif
						endif
					else
						if autoShips(shipHit).health > 30
							newMsg(shipHit, "Ahh!! I'm hit")
						else
							newMsg(shipHit, "I'm dead meat...")
						endif
					endif
				endif
				
				if blast(n).BType = 2 `photon torpedo...
					if intersectZtarget(object position x(blast(n).objNum),object position y(blast(n).objNum),0, 7.5, 1.25) > 0
						tmpx# = object position x(blast(n).objNum)
						tmpy# = object position y(blast(n).objNum)
						tmpz# = object position z(blast(n).objNum)
						move object blast(n).objNum, blast(n).dynColCheck + 2.0
						
						tmpdist# = intersect object(endTarget, tmpx#, tmpy#, tmpz#, object position x(blast(n).objNum), object position y(blast(n).objNum), object position z(blast(n).objNum))
						
						move object blast(n).objNum, 0 - blast(n).dynColCheck - 2.0
						
						if tmpdist# > 0.01
							`yes!!!! rebels win!
							rebelVictory = 1
						endif
					endif
				endif
				
				
				
				blast(n).dynColCheck = 0
			else
				if blast(n).dynColCheck > 5.0
					blast(n).live = 1
					blast(n).dynColCheck = 2.0
				endif
			endif
			
			if blast(n).maxDist > 1 and blast(n).traveledDist > blast(n).maxDist
				blast(n).exist = 0
				hide object blast(n).objNum
			endif
		endif
	next n
endfunction

function resetBullets()
	for n = 1 to maxBlastObjects
		blast(n).exist = 0
		hide object blast(n).objNum
	next n
endfunction

function fireBlast(sourceObj, color, offX as float, offY as float, offZ as float, bType as integer)
	local tmpIdx as integer
	tmpIdx = freeBlast()
	if tmpIdx > 0
		blast(tmpIdx).exist = 1
		blast(tmpIdx).vel = 1.5
		blast(tmpIdx).startTime = getTime()
		blast(tmpIdx).life = 5000
		blast(tmpIdx).traveledDist = 0
		blast(tmpIdx).maxDist = trenchLength * 10.0 * 2
		blast(tmpIdx).live = 0
		blast(tmpIdx).BType = bType
		
		blast(tmpIdx).dynColCheck = 0
		
		if color = 1
			colorBlast(blast(tmpIdx).objNum, redLaserImg)
		else
			colorBlast(blast(tmpIdx).objNum, greenLaserImg)
		endif
		
		position object blast(tmpIdx).objNum, object position x(sourceObj),object position y(sourceObj),object position z(sourceObj)
		rotate object blast(tmpIdx).objNum, object angle x(sourceObj),object angle y(sourceObj),object angle z(sourceObj)
		
		show object blast(tmpIdx).objNum
		
		move object up blast(tmpIdx).objNum, offX
		move object right blast(tmpIdx).objNum, offY
		move object blast(tmpIdx).objNum, offZ
		
		tmpx = object position x(blast(tmpIdx).objNum)
		tmpy = object position y(blast(tmpIdx).objNum)
		tmpz = object position z(blast(tmpIdx).objNum)
		
		move object blast(tmpIdx).objNum, rayLen
		
		blast(tmpIdx).maxDist = intersectStatic(tmpx, tmpy, tmpz, object position x(blast(tmpIdx).objNum), object position y(blast(tmpIdx).objNum), object position z(blast(tmpIdx).objNum))
	
		move object blast(tmpIdx).objNum, 0-rayLen
	endif
endfunction

function colorBlast(obj, img)
	texture limb obj, 1,img
	texture limb obj, 2,img
endfunction

function freeBlast()
	repeat
		inc i
		if blast(i).exist=0 then found=1
	until found = 1 or i >= maxBlastObjects
	if found = 0 then i = -1
endfunction i

function intesectTurret(x#, y#, z#, xto#, yto#, zto#)
	local dist as float = 1000.0
	local tmp as float
	local turret as integer
	for i = 1 to turretMax
		if turrets(i).objNumBox > 0
			if object exist(turrets(i).objNumBox) = 1 and turrets(i).exist = 1
				tmp = intersect object(turrets(i).objNumBox, x#, y#, z#, xto#, yto#, zto#)
				if dist > tmp and tmp > 0.01
					dist = tmp
					turret = i

				endif
			endif
		endif
	next i
endfunction turret

function intersectBridge(x#, y#, z#, xto#, yto#, zto#)
	local dist as float = 1000.0
	local tmp as float
	for i = 1 to trenchLength
		for j = 1 to crossBridgeObjQty
			if crossBridges(i,j).objNum > 0
				if object exist(crossBridges(i,j).objNum) = 1
					tmp = intersect object(crossBridges(i,j).objNum, x#, y#, z#, xto#, yto#, zto#)
					if dist > tmp and tmp > 0.01 then dist = tmp
				endif
			endif
		next j  
	next i
endfunction dist

function intersectTrench(x#, y#, z#, xto#, yto#, zto#)
	local dist as float = 1000.0
	local tmp as float
	for i = 1 to trenchLength
		if trenchSqr(i).objNum > 0
			if object exist(trenchSqr(i).objNum) = 1
				tmp = intersect object(trenchSqr(i).objNum, x#, y#, z#, xto#, yto#, zto#)
				if dist > tmp and tmp > 0.01 then dist = tmp
			endif
		endif
	next i
endfunction dist

function intersectStatic(x#, y#, z#, xto#, yto#, zto#)
	local dist as float = 0.0
	local tmp as float
	
	dist = intersectBridge(x#, y#, z#, xto#, yto#, zto#)
	tmp = intersectTrench(x#, y#, z#, xto#, yto#, zto#)
	if dist < tmp then dist = tmp
endfunction dist

function intesectShip(x#, y#, z#, xto#, yto#, zto#, hitDist#)
	local dist as float = 1000.0
	local tmp as float
	local tmp2 as float
	local ship as integer
	for n = 1 to maxShips
		if autoShips(n).exist = 1
			if object exist(autoShips(n).objNum) = 1 and autoShips(n).exist = 1
				`tmp = intersect object(autoShips(n).objNum, x#, y#, z#, xto#, yto#, zto#)
				tmp = dCheck(x#, y#, z#, autoShips(n).objNum)
				tmp2 = dCheck(xto#, yto#, zto#, autoShips(n).objNum)
				
				if tmp2 < tmp then tmp = tmp2
				
				`if the ship is close enough, do an intersect test, else it gets to be to much 
				`of a tax on the system and a major slowdown.
				if tmp < hitDist#^2 * 2.0
					tmp = intersect object(autoShips(n).objNum, x#, y#, z#, xto#, yto#, zto#)
					if tmp < dist and tmp > 0.001
						ship = n
						dist = tmp
					endif
					
					`newMsg(99, "Intersect ship performed")
				endif
				
				`newMsg(99, "Hit Distance: " + str$(hitDist#^2 * 2.0) + " tmp: " + str$(tmp))
			endif
		endif
	next i
endfunction ship

function nearShip(ship,radius as float)
	local tmp as integer
	local tmpobj as integer
	tmp = -1
	for n = 1 to maxShips
		if autoShips(n).exist = 1 and n <> ship and autoships(n).side <> autoships(ship).side
			tmpobj = autoShips(ship).objNum
			if intersectZtarget(object position x(tmpobj),object position y(tmpobj),object position x(autoships(n).objNum), object position y(autoships(n).objNum), radius) = 1
				if object position z(tmpobj) < object position z(autoships(n).objNum)
					tmp = n
				endif
			endif
		endif
	next n
endfunction tmp

function intersectZtarget(x#,y#,cirx#, ciry#, cirr#)
	local rtrn as integer = 0
	local tmp as float
	tmp = (x# - cirx#)*(x# - cirx#) + (y# - ciry#)*(y# - ciry#)
	
	if tmp < cirr# * cirr#
		rtrn = 1
	endif
endfunction rtrn

function dCheck(x#, y#, z#, object)
	local tmpRtrn as float
	tmpRtrn = ((x# - object position x(object))*(x# - object position x(object)) + (y# - object position y(object))*(y# - object position y(object)) + (z# - object position z(object))*(z# - object position z(object)))
endfunction tmpRtrn



function GreenLaserTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer

	
	local tmpXa as integer
	local tmpYa as integer
	local tmpXb as integer
	local tmpYb as integer
	
	cls rgb(0,0,0)
	
	xSize = 30
	ySize = 90

	create bitmap 1, xSize, ySize
	set current bitmap 1
	
	cls rgb(0,0,0)
	
	for n = 0 to xSize
		tmpColor = int(sin((((n*1.0)/(xSize*1.0))*180.0))*255)
		ink rgb(tmpColor, 255, tmpColor),0
		
		line n, 0, n, ysize
	next n
	
	get image imgNum,0,0,xSize,ySize,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function RedLaserTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer

	
	local tmpXa as integer
	local tmpYa as integer
	local tmpXb as integer
	local tmpYb as integer
	
	cls rgb(0,0,0)
	
	xSize = 30
	ySize = 90

	create bitmap 1, xSize, ySize
	set current bitmap 1
	
	cls rgb(0,0,0)
	
	for n = 0 to xSize
		tmpColor = int(sin((((n*1.0)/(xSize*1.0))*180.0))*255)
		ink rgb(255, tmpColor, tmpColor),0
		
		line n, 0, n, ysize
	next n
	
	get image imgNum,0,0,xSize,ySize,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function BlockTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer
	
	local colorOff as integer
	local BWScale as integer
	local sqrMaxSize as integer
	
	local tmpXa as integer
	local tmpYa as integer
	local tmpXb as integer
	local tmpYb as integer
	
	cls rgb(0,0,0)
	
	xSize = 255
	ySize = 255
	sqrMaxSize = 100
	
	BWScale = 100
	colorOff = 5
	
	create bitmap 1, xSize+40, ySize+40
	set current bitmap 1
	
	cls rgb(175,175,175)
	
	for n = 1 to 100
		tmpColor = rnd(BWScale) - BWScale/2 + 200
		ink rgb(tmpColor + rnd(colorOff), tmpColor + rnd(colorOff), tmpColor + rnd(colorOff)),0
		
		tmpXa = rnd(xSize+40)
		tmpYa = rnd(ySize+40)
		tmpXb = rnd(sqrMaxSize)
		tmpYb = rnd(sqrMaxSize)
		
		box tmpXa, tmpYa, tmpXa+tmpXb, tmpYa+tmpYb
	next n
	
	get image imgNum,20,20,xSize+20,ySize+20,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function BWBlockTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer
	
	local BWScale as integer
	local sqrMaxSize as integer
	
	local tmpXa as integer
	local tmpYa as integer
	local tmpXb as integer
	local tmpYb as integer
	
	cls rgb(0,0,0)
	
	xSize = 255
	ySize = 255
	sqrMaxSize = 100
	
	BWScale = 255
	
	create bitmap 1, xSize+40, ySize+40
	set current bitmap 1
	
	cls rgb(0,0,0)
	
	for n = 1 to 200
		tmpColor = rnd(BWScale)
		ink rgb(tmpColor, tmpColor, tmpColor),0
		
		tmpXa = rnd(xSize+40)
		tmpYa = rnd(ySize+40)
		tmpXb = rnd(sqrMaxSize)
		tmpYb = rnd(sqrMaxSize)
		
		box tmpXa, tmpYa, tmpXa+tmpXb, tmpYa+tmpYb
	next n
	
	get image imgNum,20,20,xSize+20,ySize+20,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function ColorTexture(imgNum as integer, r as integer, g as integer, b as integer)
	create bitmap 1, 5, 5
	set current bitmap 1
	cls rgb(r, g, b)
	get image imgNum,0,0,5,5,0
	delete bitmap 1
	set current bitmap 0
endfunction

function SolarGridTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer
	
	local xSqrSize as integer
	local ySqrSize as integer
	
	local lineWidth as integer
	
	cls rgb(0,0,0)
	
	xSqrSize = 20
	ySqrSize = 20
	
	xSize = 200
	ySize = 200
	
	lineWidth = 2
	
	create bitmap 1, xSize+40, ySize+40
	set current bitmap 1
	
	cls rgb(64,64,128)
	
	for n = 1 to xSize step xSqrSize
		for m = 1 to ySize step ySqrSize
			tmpColor = rnd(BWScale)
			ink rgb(20, 20, 20),0
			
			box n+lineWidth, m+lineWidth, n+xSqrSize, m+ySqrSize
		next m
	next n
	
	get image imgNum,0,0,xSize,ySize,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function WhiteStainedTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer
	
	local sqrMaxSize as integer
	
	local tmpXa as integer
	local tmpYa as integer
	local tmpXb as integer
	local tmpYb as integer
	
	cls rgb(0,0,0)
	
	xSize = 255
	ySize = 255
	sqrMaxSize = 10
	
	create bitmap 1, xSize+40, ySize+40
	set current bitmap 1
	
	cls rgb(200,200,200)
	
	`dots
	for n = 1 to 5000
		tmp = 160+rnd(80)
		dot rnd(xSize+40),rnd(ySize+40), rgb(tmp,tmp,tmp)
	next n
	
	blur bitmap 1,1
	
	`stains...(or detail...)
	for n = 1 to 100
		tmpColor = 150 + rnd(100)
		ink rgb(tmpColor, 64, 64),0
		
		tmpXa = rnd(xSize+40)
		tmpYa = rnd(ySize+40)
		tmpXb = rnd(sqrMaxSize)
		tmpYb = rnd(sqrMaxSize*2)
		
		box tmpXa, tmpYa, tmpXa+tmpXb, tmpYa+tmpYb
	next n
	
	get image imgNum,20,20,xSize+20,ySize+20,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function StarsTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer

	
	cls rgb(0,0,0)
	
	xSize = 255
	ySize = 255
	
	create bitmap 1, xSize+40, ySize+40
	set current bitmap 1
	
	cls rgb(10,10,10)
	
	seed = timer()
	
	randomize seed
	`dots
	for n = 1 to 1000
		tmp = 100+rnd(80)
		dot rnd(xSize+40),rnd(ySize+40), rgb(tmp+rnd(10),tmp+rnd(10),tmp+rnd(10))
	next n
	
	`'backround mist =)
	blur bitmap 1,5
	
	randomize seed
	
	`detail stars...
	for n = 1 to 1000
		tmp = 215+rnd(40)
		dot rnd(xSize+40),rnd(ySize+40), rgb(tmp,tmp,tmp)
	next n
	
	get image imgNum,20,20,xSize+20,ySize+20,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function Blades2Texture(imgNum as integer)
	local xSize as integer
	local ySize as integer

	
	local tmpXa as integer
	local tmpYa as integer
	local tmpXb as integer
	local tmpYb as integer
	
	cls rgb(0,0,0)
	
	xSize = 30
	ySize = 90

	create bitmap 1, xSize, ySize
	set current bitmap 1
	
	cls rgb(0,0,0)
	
	for n = 0 to xSize
		tmpColor = 255 - int(sin((((n*10.0)/(xSize*1.0))*180.0))*255)
		ink rgb(tmpColor, tmpColor, tmpColor),0
		
		line n, 0, n, ysize
	next n
	
	get image imgNum,0,0,xSize,ySize,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function ExplodeTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer
	
	local sqrMaxSize as integer
	
	local tmpXa as integer
	local tmpYa as integer
	local tmpXb as integer
	local tmpYb as integer
	
	cls rgb(0,0,0)
	
	xSize = 255
	ySize = 255
	sqrMaxSize = 10
	
	create bitmap 1, xSize+40, ySize+40
	set current bitmap 1
	
	cls rgb(0,0,0)
	
	`stains...(or detail...)
	for n = 1 to 200
		ink rgb(200+rnd(40),50+rnd(40),rnd(20)),0
		
		tmpXa = rnd(xSize+40)
		tmpYa = rnd(ySize+40)
		tmpXb = rnd(sqrMaxSize)
		tmpYb = rnd(sqrMaxSize*2)
		
		box tmpXa, tmpYa, tmpXa+tmpXb, tmpYa+tmpYb
	next n
	
	`circles
	for n = 1 to 100
		ink rgb(190+rnd(60),120+rnd(80),rnd(20)), 0
		circle xSize/2+20,ySize/2+20, n*2.5
	next n
	
	blur bitmap 1,1
	
	`dots
	for n = 1 to 5000
		dot rnd(xSize+40),rnd(ySize+40), rgb(190+rnd(60),120+rnd(80),rnd(20))
	next n
	
	blur bitmap 1,6
	
	remstart
	`circles
	for n = 1 to 180
		ink rgb(180-n,180-n,180-n), 0
		circle xSize/2+20,ySize/2+20, cos(sin(n/2.0+90)*180.0)*180.0
	next n
	
	blur bitmap 1,6
	remend

	
	
	get image imgNum,20,20,xSize+20,ySize+20,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function ShockWaveTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer
	local tmpSize as integer
	
	cls rgb(0,0,0)
	
	xSize = 255
	ySize = 255
	
	create bitmap 1, xSize, ySize
	set current bitmap 1
	
	cls rgb(0,0,0)
	
	`tmpSize = int(sqrt(xSize/2.0 + ySize/2.0))
	tmpSize = int(xSize/2.0)-1
	remstart
	`circles
	for n = 1 to tmpSize
		ink rgb(0,0,((n*1.0)/(1.0*tmpSize) * 255)), 0
		circle xSize/2,ySize/2, n
	next n
	remend
	
	`lock pixels
	for x = 1 to xSize
		for y = 1 to ySize
			tmpSize = sqrt((x-xSize/2)^2+(y-ySize/2)^2)
			if tmpSize < int(xSize/2.0)
				dot x, y, rgb(0,0,((tmpSize*1.0)/((1.0*xSize)/2.0) * 255))
			endif
		next y
	next x
	
	`blur bitmap 1,6

	get image imgNum,0,0,xSize,ySize,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function MessagePanalImg(imgNum as integer)
	local xSize as integer
	local ySize as integer
	
	local xSqrSize as integer
	local ySqrSize as integer
	
	local lineWidth as integer
	
	cls rgb(0,0,0)
	
	xSqrSize = 10
	ySqrSize = 10
	
	xSize = 400
	ySize = 320
	
	lineWidth = 1
	
	create bitmap 1, xSize, ySize
	set current bitmap 1
	
	cls rgb(200, 140, 0)
	
	for n = 1 to xSize step xSqrSize
		for m = 1 to ySize step ySqrSize

			ink rgb(0,0,0),0
			
			box n+lineWidth, m+lineWidth, n+xSqrSize, m+ySqrSize
		next m
	next n
	
	ink rgb(128,0,0),0
	line 1,1,xSize-1,1
	line 1,1,1,ySize-1
	line xSize-1,ySize-1,xSize-1, 1
	line xSize-1,ySize-1,1, ySize-1
	
	get image imgNum,0,0,xSize,ySize,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function SymbolButtonImg(imgNum as integer,txt as string)
	local xSize as integer
	local ySize as integer

	xSize = 20
	ySize = 20

	create bitmap 1, xSize, ySize
	set current bitmap 1
	
	cls rgb(200, 140, 0)
	
	for n = 0 to 9
			if n > 4
				ink rgb(128,128,128),0
			else
				ink rgb(n*30+8,n*30+8,n*30+8),0
			endif
		
			box n, n, xSize - n, ySize - n
	next n
	
	ink rgb(128,0,0),0
	center text 10,2,txt
	
	get image imgNum,0,0,xSize,ySize,0
	
	delete bitmap 1
	set current bitmap 0

endfunction

function DeathStarTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer
	
	local xSqrSize as integer
	local ySqrSize as integer
	
	local lineWidth as integer
	
	cls rgb(0,0,0)
	
	xSqrSize = 40
	ySqrSize = 40
	
	xSize = 400
	ySize = 400
	
	lineWidth = 2
	
	create bitmap 1, xSize, ySize
	set current bitmap 1
	
	cls RGB(43,47,51)
	
	`gridded texture
	for n = 1 to xSize step xSqrSize
		for m = 1 to ySize step ySqrSize
			tmpColor = rnd(BWScale)
			ink RGB(68,72,81),0
			
			box n+lineWidth, m+lineWidth, n+xSqrSize, m+ySqrSize
		next m
	next n
	
	`dots
	for n = 1 to 5000
		dot rnd(xSize+40),rnd(ySize+40), rgb(43+rnd(30),47+rnd(30),51+rnd(30))
	next n
	
	`the trench...
	ink RGB(78,82,91),0
	box 0, ySize/2-4, xSize, ySize/2 + 3
	ink RGB(43,47,51),0
	box 0, ySize/2-3, xSize, ySize/2 + 2
	
	`the infamous dish...
	for x = 1 to xSize
		for y = 1 to ySize
			tmpSize = sqrt((x-xSize/2)^2+(y-ySize/4)^2)
			if tmpSize < int(ySize/10.0)
				dot x, y, rgb(((tmpSize*1.0)/((1.0*xSize)/2.0) * 68 + 15),((tmpSize*1.0)/((1.0*xSize)/2.0) * 72 + 15),((tmpSize*1.0)/((1.0*xSize)/2.0) * 81 + 15) )
			endif
		next y
	next x
	
	get image imgNum,0,0,xSize,ySize,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function BlockEndTexture(imgNum as integer)
	local xSize as integer
	local ySize as integer
	
	local colorOff as integer
	local BWScale as integer
	local sqrMaxSize as integer
	
	local tmpXa as integer
	local tmpYa as integer
	local tmpXb as integer
	local tmpYb as integer
	
	cls rgb(0,0,0)
	
	xSize = 255
	ySize = 255
	sqrMaxSize = 100
	
	BWScale = 100
	colorOff = 5
	
	create bitmap 1, xSize+40, ySize+40
	set current bitmap 1
	
	cls rgb(175,175,175)
	
	for n = 1 to 100
		tmpColor = rnd(BWScale) - BWScale/2 + 200
		ink rgb(tmpColor + rnd(colorOff), tmpColor + rnd(colorOff), tmpColor + rnd(colorOff)),0
		
		tmpXa = rnd(xSize+40)
		tmpYa = rnd(ySize+40)
		tmpXb = rnd(sqrMaxSize)
		tmpYb = rnd(sqrMaxSize)
		
		box tmpXa, tmpYa, tmpXa+tmpXb, tmpYa+tmpYb
	next n
	
	`End target hole...
	for x = 1 to xSize
		for y = 1 to ySize
			tmpSize = sqrt((x-xSize/2)^2+(y-ySize/4)^2)
			if tmpSize < int(ySize/10.0)
				dot x+20, y+20, rgb(((tmpSize*1.0)/((1.0*xSize)/2.0) * 68 + 15),((tmpSize*1.0)/((1.0*xSize)/2.0) * 72 + 15),((tmpSize*1.0)/((1.0*xSize)/2.0) * 81 + 15) )
			endif
		next y
	next x
	
	get image imgNum,20,20,xSize+20,ySize+20,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function createXwingfighter(objnum as integer, size as float)

	local tmpImg as integer
	local tmpLmb as integer
	local tmpObj as integer
	local tmpMesh as integer
	local tmpMeshII as integer
	local tmpMeshIII as integer
	
	`base object...
	make object plain objnum, 0, 0
	scale object objnum, 100,100,100
	
	tmpObj = freeObject()
	tmpMesh = freeMesh()
	
	tmpLmb = 0
	
	`main body...
	MemblockMeshTCone(tmpMesh, 6, 2, 6, 20)
	inc tmpLmb
	add limb objnum, tmpLmb, tmpMesh
	rotate limb objnum, tmpLmb, 90,0,90
	offset limb objnum, tmpLmb, 0,0,-10
	scale limb objNum, tmpLmb,100,100,150
	texture limb objNum, tmpLmb,XwingImg  
	delete mesh tmpMesh
	
	MemblockMeshCone(tmpMesh, 6, 6, 2)
	inc tmpLmb
	add limb objnum, tmpLmb, tmpMesh
	rotate limb objnum, tmpLmb, 90,180,90
	offset limb objnum, tmpLmb, 0,0,-10
	scale limb objNum, tmpLmb,100,100,150
	texture limb objNum, tmpLmb,XwingImg  
	delete mesh tmpMesh
	
	`stub end...
	MemblockMeshTCone(tmpMesh, 6, 2, 4, 2)
	inc tmpLmb
	add limb objnum, tmpLmb, tmpMesh
	rotate limb objnum, tmpLmb, -90,0,90
	offset limb objnum, tmpLmb, 0,0,10
	scale limb objNum, tmpLmb,100,100,150
	texture limb objNum, tmpLmb,XwingImg 
	delete mesh tmpMesh
	
	MemblockMeshTCone(tmpMesh, 6, 4, 2, 4)
	inc tmpLmb
	add limb objnum, tmpLmb, tmpMesh
	rotate limb objnum, tmpLmb, -90,0,90
	offset limb objnum, tmpLmb, 0,0,14
	scale limb objNum, tmpLmb,100,100,150
	texture limb objNum, tmpLmb,XwingImg  
	
	delete mesh tmpMesh
	
	`cap on the end...
	MemblockMeshCone(tmpMesh, 6, 2, 1)
	inc tmpLmb
	add limb objnum, tmpLmb, tmpMesh
	rotate limb objnum, tmpLmb, -270,0,90
	offset limb objnum, tmpLmb, 0,0,14
	scale limb objNum, tmpLmb,100,100,150
	texture limb objNum, tmpLmb,XwingImg  
	delete mesh tmpMesh
	
	`cockpit...
	MemblockMeshCone(tmpMesh, 6, 5, 3.5)
	inc tmpLmb
	add limb objnum, tmpLmb, tmpMesh
	`rotate limb objnum, 5, -270,0,90
	scale limb objnum, tmpLmb, 90, 100,200
	offset limb objnum, tmpLmb, 0,0,2
	
	tmpImg = freeImage()
	ColorTexture(tmpImg, 32, 32, 32)
	texture limb objnum, tmpLmb, tmpImg
	delete mesh tmpMesh
	
	`------------------------------------------------
	`########## fine above this point ###############
	`------------------------------------------------
	
	`a solid colored texture:
	tmpImg = freeImage()
	ColorTexture(tmpImg, 192, 192, 192)
	
	`wings Ahoy!!!
	`first WING >>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
		make object box tmpObj, 20,0.25,5
		make mesh from object tmpMesh, tmpObj
		delete object tmpObj
		
		inc tmpLmb
		add limb objnum, tmpLmb, tmpMesh
		offset limb objnum, tmpLmb, 10,2,-5
		rotate limb objnum, tmpLmb, 0, -10, 10
		texture limb objnum, tmpLmb, XwingImg
		
		`now for wingtips and engines
		
		`meshes ----------------------------------------
		delete mesh tmpMesh
		MemblockMeshCone(tmpMesh, 5, 1, 12)
		
		tmpMeshII = freeMesh()
		`and engines ... wow... to many limbs, ya know Xwings are a LOT more complicated than TIE fighters
		MemblockMeshHalfTCone(tmpMeshII, 8, 5, 5, 7)
		
		tmpMeshIII = freeMesh()
		MemblockMeshHalfTCone(tmpMeshIII, 8, 0, 5, -1)
		`-----------------------------------------------
		
		`now construct ---------------------------------
			`one wing tip...
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			offset limb objnum, tmpLmb,10,0,-2
			rotate limb objnum, tmpLmb,90,0,0
			texture limb objnum, tmpLmb, tmpImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			offset limb objnum, tmpLmb,10,0,-2
			rotate limb objnum, tmpLmb,90,180,0
			scale limb objnum, tmpLmb,100,20,100
			texture limb objnum, tmpLmb, tmpImg
			
			delete mesh tmpMesh
			make object plain tmpObj,5,6
			make mesh from object tmpMesh,tmpObj
			delete object tmpObj
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			rotate limb objnum, tmpLmb, 90,0,0
			offset limb objnum, tmpLmb, 0,0,-1.5
			texture limb objnum, tmpLmb, XwingImg
			
			
			`engine...
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshII
			offset limb objnum, tmpLmb,0,0,-4.5
			rotate limb objnum, tmpLmb,90,0,90
			texture limb objnum, tmpLmb, XwingImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshIII
			offset limb objnum, tmpLmb,0,0,2.5
			rotate limb objnum, tmpLmb,90,0,90
			texture limb objnum, tmpLmb, bladeImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshIII
			offset limb objnum, tmpLmb,0,0,-4.5
			rotate limb objnum, tmpLmb,-90,0,90
			scale limb objnum,tmpLmb,100,0,100
			texture limb objnum, tmpLmb, bladeImg
			
			link limb objnum, tmpLmb-6, tmpLmb-5
			link limb objnum, tmpLmb-6, tmpLmb-4
			link limb objnum, tmpLmb-6, tmpLmb-3
			link limb objnum, tmpLmb-6, tmpLmb-2
			link limb objnum, tmpLmb-6, tmpLmb-1
			link limb objnum, tmpLmb-6, tmpLmb
		`-----------------------------------------------
		
		`clean up...
			delete mesh tmpMesh
			delete mesh tmpMeshII
			delete mesh tmpMeshIII
		`...........
	`>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>>
	
	
	`Second Wing <<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
		make object box tmpObj, 20,0.25,5
		make mesh from object tmpMesh, tmpObj
		delete object tmpObj
		
		inc tmpLmb
		add limb objnum, tmpLmb, tmpMesh
		offset limb objnum, tmpLmb, 10,-2,-5
		rotate limb objnum, tmpLmb, 0, -10, -10
		texture limb objnum, tmpLmb, XwingImg
		
				`now for wingtips and engines
		
		`meshes ----------------------------------------
		delete mesh tmpMesh
		MemblockMeshCone(tmpMesh, 5, 1, 12)
		
		tmpMeshII = freeMesh()
		`and engines ... wow... to many limbs, ya know Xwings are a LOT more complicated than TIE fighters
		MemblockMeshHalfTCone(tmpMeshII, 8, 5, 5, 7)
		
		tmpMeshIII = freeMesh()
		MemblockMeshHalfTCone(tmpMeshIII, 8, 0, 5, -1)
		`-----------------------------------------------
		
		`now construct ---------------------------------
			`one wing tip...
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			offset limb objnum, tmpLmb,10,0,-2
			rotate limb objnum, tmpLmb,90,0,0
			texture limb objnum, tmpLmb, tmpImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			offset limb objnum, tmpLmb,10,0,-2
			rotate limb objnum, tmpLmb,90,180,0
			scale limb objnum, tmpLmb,100,20,100
			texture limb objnum, tmpLmb, tmpImg
			
			delete mesh tmpMesh
			make object plain tmpObj,5,6
			make mesh from object tmpMesh,tmpObj
			delete object tmpObj
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			rotate limb objnum, tmpLmb, -90,0,0
			offset limb objnum, tmpLmb, 0,0,-1.5
			texture limb objnum, tmpLmb, XwingImg
			
			`engine...
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshII
			offset limb objnum, tmpLmb,0,0,-4.5
			rotate limb objnum, tmpLmb,90,0,-90
			texture limb objnum, tmpLmb, XwingImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshIII
			offset limb objnum, tmpLmb,0,0,2.5
			rotate limb objnum, tmpLmb,90,0,-90
			texture limb objnum, tmpLmb, bladeImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshIII
			offset limb objnum, tmpLmb,0,0,-4.5
			rotate limb objnum, tmpLmb,-90,0,-90
			scale limb objnum,tmpLmb,100,0,100
			texture limb objnum, tmpLmb, bladeImg
			
			link limb objnum, tmpLmb-6, tmpLmb-5
			link limb objnum, tmpLmb-6, tmpLmb-4
			link limb objnum, tmpLmb-6, tmpLmb-3
			link limb objnum, tmpLmb-6, tmpLmb-2
			link limb objnum, tmpLmb-6, tmpLmb-1
			link limb objnum, tmpLmb-6, tmpLmb
		`-----------------------------------------------
		
		`clean up...
			delete mesh tmpMesh
			delete mesh tmpMeshII
			delete mesh tmpMeshIII
		`...........
	`<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<
	
	`Third Wing #####################################
		make object box tmpObj, 20,0.25,5
		make mesh from object tmpMesh, tmpObj
		delete object tmpObj
		
		inc tmpLmb
		add limb objnum, tmpLmb, tmpMesh
		offset limb objnum, tmpLmb, -10,-2,-5
		rotate limb objnum, tmpLmb, 0, 10, 10
		texture limb objnum, tmpLmb, XwingImg
		
		`now for wingtips and engines
		
		`meshes ----------------------------------------
		delete mesh tmpMesh
		MemblockMeshCone(tmpMesh, 5, 1, 12)
		
		tmpMeshII = freeMesh()
		`and engines ... wow... to many limbs, ya know Xwings are a LOT more complicated than TIE fighters
		MemblockMeshHalfTCone(tmpMeshII, 8, 5, 5, 7)
		
		tmpMeshIII = freeMesh()
		MemblockMeshHalfTCone(tmpMeshIII, 8, 0, 5, -1)
		`-----------------------------------------------
		
		`now construct ---------------------------------
			`one wing tip...
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			offset limb objnum, tmpLmb,-10,0,-2
			rotate limb objnum, tmpLmb,90,0,0
			texture limb objnum, tmpLmb, tmpImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			offset limb objnum, tmpLmb,-10,0,-2
			rotate limb objnum, tmpLmb,90,180,0
			scale limb objnum, tmpLmb,100,20,100
			texture limb objnum, tmpLmb, tmpImg
			
			delete mesh tmpMesh
			make object plain tmpObj,5,6
			make mesh from object tmpMesh,tmpObj
			delete object tmpObj
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			rotate limb objnum, tmpLmb, -90,0,0
			offset limb objnum, tmpLmb, 0,0,-1.5
			texture limb objnum, tmpLmb, XwingImg
			
			`engine...
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshII
			offset limb objnum, tmpLmb,0,0,-4.5
			rotate limb objnum, tmpLmb,90,0,-90
			texture limb objnum, tmpLmb, XwingImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshIII
			offset limb objnum, tmpLmb,0,0,2.5
			rotate limb objnum, tmpLmb,90,0,-90
			texture limb objnum, tmpLmb, bladeImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshIII
			offset limb objnum, tmpLmb,0,0,-4.5
			rotate limb objnum, tmpLmb,-90,0,-90
			scale limb objnum,tmpLmb,100,0,100
			texture limb objnum, tmpLmb, bladeImg
			
			link limb objnum, tmpLmb-6, tmpLmb-5
			link limb objnum, tmpLmb-6, tmpLmb-4
			link limb objnum, tmpLmb-6, tmpLmb-3
			link limb objnum, tmpLmb-6, tmpLmb-2
			link limb objnum, tmpLmb-6, tmpLmb-1
			link limb objnum, tmpLmb-6, tmpLmb
		`-----------------------------------------------
		
		`clean up...
			delete mesh tmpMesh
			delete mesh tmpMeshII
			delete mesh tmpMeshIII
		`...........
	`################################################
	
	
	
	`fourth Wing ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
		make object box tmpObj, 20,0.25,5
		make mesh from object tmpMesh, tmpObj
		delete object tmpObj
		
		inc tmpLmb
		add limb objnum, tmpLmb, tmpMesh
		offset limb objnum, tmpLmb, -10,2,-5
		rotate limb objnum, tmpLmb, 0, 10, -10
		texture limb objnum, tmpLmb, XwingImg
		
						`now for wingtips and engines
		
		`meshes ----------------------------------------
		delete mesh tmpMesh
		MemblockMeshCone(tmpMesh, 5, 1, 12)
		
		tmpMeshII = freeMesh()
		`and engines ... wow... to many limbs, ya know Xwings are a LOT more complicated than TIE fighters
		MemblockMeshHalfTCone(tmpMeshII, 8, 5, 5, 7)
		
		tmpMeshIII = freeMesh()
		MemblockMeshHalfTCone(tmpMeshIII, 8, 0, 5, -1)
		`-----------------------------------------------
		
		`now construct ---------------------------------
			`one wing tip...
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			offset limb objnum, tmpLmb,-10,0,-2
			rotate limb objnum, tmpLmb,90,0,0
			texture limb objnum, tmpLmb, tmpImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			offset limb objnum, tmpLmb,-10,0,-2
			rotate limb objnum, tmpLmb,90,180,0
			scale limb objnum, tmpLmb,100,20,100
			texture limb objnum, tmpLmb, tmpImg
			
			delete mesh tmpMesh
			make object plain tmpObj,5,6
			make mesh from object tmpMesh,tmpObj
			delete object tmpObj
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMesh
			rotate limb objnum, tmpLmb, 90,0,0
			offset limb objnum, tmpLmb, 0,0,-1.5
			texture limb objnum, tmpLmb, XwingImg
			
			`engine...
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshII
			offset limb objnum, tmpLmb,0,0,-4.5
			rotate limb objnum, tmpLmb,90,0,90
			texture limb objnum, tmpLmb, XwingImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshIII
			offset limb objnum, tmpLmb,0,0,2.5
			rotate limb objnum, tmpLmb,90,0,90
			texture limb objnum, tmpLmb, bladeImg
			
			inc tmpLmb
			add limb objnum, tmpLmb, tmpMeshIII
			offset limb objnum, tmpLmb,0,0,-4.5
			rotate limb objnum, tmpLmb,-90,0,90
			scale limb objnum,tmpLmb,100,0,100
			texture limb objnum, tmpLmb, bladeImg
			
			link limb objnum, tmpLmb-6, tmpLmb-5
			link limb objnum, tmpLmb-6, tmpLmb-4
			link limb objnum, tmpLmb-6, tmpLmb-3
			link limb objnum, tmpLmb-6, tmpLmb-2
			link limb objnum, tmpLmb-6, tmpLmb-1
			link limb objnum, tmpLmb-6, tmpLmb
		`-----------------------------------------------
		
		`clean up...
			delete mesh tmpMesh
			delete mesh tmpMeshII
			delete mesh tmpMeshIII
		`...........
	`^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^
	
	scale object objnum, size*2.50,size*2.50,size*2.50
	set object cull objnum, 1


	set object diffuse objnum, rgb(0,0,0)
	set object emissive objnum, rgb(175,175,175)
	
	`tmp--------------
		set object collision to boxes objnum
	`-----------------
	
	remstart
	local angle as float
	local tmpTex as integer
	angle = 0
	
	do
		inc angle, 0.1
		position camera sin(angle)*25, 20, cos(angle)*25
		point camera 0,0,0
		sync
	loop
	end
	remend
	
endfunction

function createTIEfighter(objnum as integer, size as float)
		local tmpObj as integer
	local tmpMesh as integer
	
	`base object...
	make object sphere objnum, 5
	scale object objnum, 100,100,100
	texture object objnum, gridImg
	
	tmpObj = freeObject()
	tmpMesh = freeMesh()
	make object cylinder tmpObj, 100
	make mesh from object tmpMesh, tmpObj
	delete object tmpObj
	
	add limb objnum, 1, tmpMesh : delete mesh tmpMesh
	scale limb objnum,1, 2,10,2
	rotate limb objnum,1,90,90,0
	
	tmpImg = freeImage()
	ColorTexture(tmpImg, 64, 64, 70)
	texture limb objnum, 1, tmpImg
	
	`square part of wings...
	`make object plain tmpObj, 5, 10
	MemblockMeshPlain(tmpMesh, 5, 10)
	
	add limb objnum, 2, tmpMesh
	offset limb objnum, 2, -5,0,0
	rotate limb objnum, 2, 0,90,90
	texture limb objnum, 2,gridImg
	
	add limb objnum, 3, tmpMesh
	offset limb objnum, 3, 5,0,0
	rotate limb objnum, 3, 0,90,90
	texture limb objnum, 3,gridImg
	
	delete mesh tmpMesh
	
	`now the trapazoidal sides...
	MemblockMeshTrapazoid(tmpMesh, 10, 5, 5)
	
	add limb objnum, 4, tmpMesh
	offset limb objnum, 4, -5,5,0
	rotate limb objnum, 4, 0,0,90
	texture limb objnum, 4,gridImg
	
	add limb objnum, 5, tmpMesh
	offset limb objnum, 5, -5,-5,0
	rotate limb objnum, 5, 0,180,90
	texture limb objnum, 5,gridImg
	
	add limb objnum, 6, tmpMesh
	offset limb objnum, 6, 5,5,0
	rotate limb objnum, 6, 0,0,90
	texture limb objnum, 6,gridImg
	
	add limb objnum, 7, tmpMesh
	offset limb objnum, 7, 5,-5,0
	rotate limb objnum, 7, 0,180,90
	texture limb objnum, 7,gridImg


	scale object objnum, size*10.0,size*10.0,size*10.0
	
	set object collision to boxes objnum

	remstart
	local angle as float
	angle = 0
	do
		inc angle, 0.1
		position camera sin(angle)*25, 20, cos(angle)*25
		point camera 0,0,0
		sync
	loop
	end
	remend
endfunction

function createSkyBox(objNum as integer, size)
	local tmpObj as integer
	local tmpMesh as integer
	
	make object plain objnum, 0,0
	
	tmpObj = freeObject()
	tmpMesh = freeMesh()
	
	make object plain tmpObj, 100,100
	make mesh from object tmpMesh,tmpObj
	delete object tmpObj
	
	`sides----------
	add limb objnum, 1, tmpMesh
	offset limb objnum, 1, 0,0,-50
	
	add limb objnum, 2, tmpMesh
	offset limb objnum, 2, 0,0,50
	rotate limb objnum, 2, 0,180,0
	
	add limb objnum, 3, tmpMesh
	offset limb objnum, 3, 50,0,0
	rotate limb objnum, 3, 0,270,0
	
	add limb objnum, 4, tmpMesh
	offset limb objnum, 4, -50,0,0
	rotate limb objnum, 4, 0,90,0
	`-------------
	
	`top
	add limb objnum, 5, tmpMesh
	offset limb objnum, 5, 0,50,0
	rotate limb objnum, 5, 90,0,0
	
	`bottom
	add limb objnum, 6, tmpMesh
	offset limb objnum, 6, 0,-50,0
	rotate limb objnum, 6, 270,0,0
	
	delete mesh tmpMesh
	
	scale object objNum, size, size, size
	set object light objNum, 0
	set object fog objNum, 0
	
endfunction

function MemblockMeshCone(mesh as integer, density as integer, size as float, height as float)
	local memblock as integer
   local vertexCount as integer
   local offset as integer

   memblock = FreeMemblock()

   make memblock memblock, 12 + (32 * density * 3)

   write memblock dword memblock, 0, 275
   write memblock dword memblock, 4, 32
   write memblock dword memblock, 8, density * 3
   offset = 12

   for i = 1 to density

      `write poly one-------------------------------------
         writeVertex275(memblock, offset   , sin((i-1.0)*360.0/density)*size/2.0,      0, cos((i-1.0)*360.0/density)*size/2.0,   cos((i-1.0)*360.0/density*1.0), 0, sin((i-1.0)*360.0/density), (i-1.0)/density    , 1.0)
         writeVertex275(memblock, offset+32, sin((i*1.0)*360.0/density)*size/2.0,      0, cos((i*1.0)*360.0/density)*size/2.0,   cos((i*1.0)*360.0/density*1.0), 0, sin((i*1.0)*360.0/density), (i*1.0)/density    , 1.0)
         writeVertex275(memblock, offset+64, 0                                  , height, 0                                  ,   cos((i*1.0)*360.0/density*1.0), 0, sin((i*1.0)*360.0/density), (i-1.0)/(density-1), 0.0)
         inc offset, 96
   next i

   make mesh from memblock mesh, memblock

   delete memblock memblock
endfunction

function MemblockMeshTrapazoid(mesh as integer, widthA as float, widthB as float, height as float)
	local memblock as integer
   local vertexCount as integer
   local offset as integer
   
   local highestWidth as float
   
   if widthA >= widthB then highestWidth = widthA
   if widthB >= widthA then highestWidth = widthB

   memblock = FreeMemblock()

   make memblock memblock, 12 + (32 * 4 * 3)

   write memblock dword memblock, 0, 275
   write memblock dword memblock, 4, 32
   write memblock dword memblock, 8, 12
   offset = 12

      `write poly one and two  and invert-------------------------------------
      	`fliped UV
         writeVertex275(memblock, offset    , height/-2.0, 0, widthA/-2.0, 0,  1, 0, 0.5 - widthA/(highestWidth*2.0), 1.0)
         writeVertex275(memblock, offset+32 , height/-2.0, 0, widthA/2.0 , 0,  1, 0, 0.5 + widthA/(highestWidth*2.0), 1.0)
         writeVertex275(memblock, offset+64 , height/2.0 , 0, widthB/-2.0, 0,  1, 0, 0.5 - widthB/(highestWidth*2.0), 0.0)
	                                                                                    
			inc offset, 96                                                                
                                                                                       	
			writeVertex275(memblock, offset    , height/-2.0, 0, widthA/2.0 , 0,  1, 0, 1.0, 0.5 + widthA/(highestWidth*2.0))
         writeVertex275(memblock, offset+32 , height/2.0 , 0, widthB/2.0,  0,  1, 0, 0.0, 0.5 + widthB/(highestWidth*2.0))
         writeVertex275(memblock, offset+64 , height/2.0 , 0, widthB/-2.0, 0,  1, 0, 0.0, 0.5 - widthB/(highestWidth*2.0))
                                                                                       
         inc offset, 96                                                                
                                                                                       
         writeVertex275(memblock, offset    , height/-2.0, 0, widthA/2.0 , 0, -1, 0, 0.5 + widthA/(highestWidth*2.0), 1.0)
         writeVertex275(memblock, offset+32 , height/-2.0, 0, widthA/-2.0, 0, -1, 0, 0.5 - widthA/(highestWidth*2.0), 1.0)
         writeVertex275(memblock, offset+64 , height/2.0 , 0, widthB/-2.0, 0, -1, 0, 0.5 - widthB/(highestWidth*2.0), 0.0)
                                                                                       
			inc offset, 96                                                                
			                                                                              
			writeVertex275(memblock, offset    , height/2.0 , 0, widthB/2.0,  0, -1, 0, 0.0, 0.5 + widthB/(highestWidth*2.0))
			writeVertex275(memblock, offset+32 , height/-2.0, 0, widthA/2.0 , 0, -1, 0, 1.0, 0.5 + widthA/(highestWidth*2.0))
         writeVertex275(memblock, offset+64 , height/2.0 , 0, widthB/-2.0, 0, -1, 0, 0.0, 0.5 - widthB/(highestWidth*2.0))

   make mesh from memblock mesh, memblock

   delete memblock memblock
endfunction


function MemblockMeshPlain(mesh as integer, width as float, height as float)
	local memblock as integer
   local vertexCount as integer
   local offset as integer

   memblock = FreeMemblock()

   make memblock memblock, 12 + (32 * 4 * 3)

   write memblock dword memblock, 0, 275
   write memblock dword memblock, 4, 32
   write memblock dword memblock, 8, 12
   offset = 12

      `write poly one and two  and invert-------------------------------------
         writeVertex275(memblock, offset    , height/-2.0, 0, width/-2.0, 0,  1, 0, 0.0, 1.0)
         writeVertex275(memblock, offset+32 , height/-2.0, 0, width/2.0 , 0,  1, 0, 1.0, 1.0)
         writeVertex275(memblock, offset+64 , height/2.0 , 0, width/-2.0, 0,  1, 0, 0.0, 0.0)
	                                                                                    
			inc offset, 96                                                                
                                                                                       
			writeVertex275(memblock, offset    , height/-2.0, 0, width/2.0 , 0,  1, 0, 1.0, 1.0)
         writeVertex275(memblock, offset+32 , height/2.0 , 0, width/2.0,  0,  1, 0, 1.0, 0.0)
         writeVertex275(memblock, offset+64 , height/2.0 , 0, width/-2.0, 0,  1, 0, 0.0, 0.0)
                                                                                       
         inc offset, 96                                                                
                                                                                       
         writeVertex275(memblock, offset    , height/-2.0, 0, width/2.0 , 0, -1, 0, 1.0, 1.0)
         writeVertex275(memblock, offset+32 , height/-2.0, 0, width/-2.0, 0, -1, 0, 0.0, 1.0)
         writeVertex275(memblock, offset+64 , height/2.0 , 0, width/-2.0, 0, -1, 0, 0.0, 0.0)
                                                                                       
			inc offset, 96                                                                
			                                                                              
			writeVertex275(memblock, offset    , height/2.0 , 0, width/2.0,  0, -1, 0, 1.0, 0.0)
			writeVertex275(memblock, offset+32 , height/-2.0, 0, width/2.0 , 0, -1, 0, 1.0, 1.0)
         writeVertex275(memblock, offset+64 , height/2.0 , 0, width/-2.0, 0, -1, 0, 0.0, 0.0)

   make mesh from memblock mesh, memblock

   delete memblock memblock
endfunction


function MemblockMeshTCone(mesh as integer, density as integer, topSize as float, btmSize as float, height as float)
	local memblock as integer
   local vertexCount as integer
   local offset as integer

   memblock = FreeMemblock()

   make memblock memblock, 12 + (32 * density * 6)

   write memblock dword memblock, 0, 275
   write memblock dword memblock, 4, 32
   write memblock dword memblock, 8, density * 6
   offset = 12

   for i = 1 to density

      `write poly one and two-------------------------------------
         writeVertex275(memblock, offset    , sin((i-1.0)*360.0/density)*topSize/2.0, height, cos((i-1.0)*360.0/density)*topSize/2.0,   cos((i-1.0)*360.0/density*1.0), 0, sin((i-1.0)*360.0/density), (i-1.0)/density, 0.0)
         writeVertex275(memblock, offset+32 , sin((i-1.0)*360.0/density)*btmSize/2.0,      0, cos((i-1.0)*360.0/density)*btmSize/2.0,   cos((i-1.0)*360.0/density*1.0), 0, sin((i-1.0)*360.0/density), (i-1.0)/density, 1.0)
         writeVertex275(memblock, offset+64 , sin((i*1.0)*360.0/density)*topSize/2.0, height, cos((i*1.0)*360.0/density)*topSize/2.0,   cos((i*1.0)*360.0/density*1.0), 0, sin((i*1.0)*360.0/density), (i*1.0)/density, 0.0)

         writeVertex275(memblock, offset+96 , sin((i-1.0)*360.0/density)*btmSize/2.0,      0, cos((i-1.0)*360.0/density)*btmSize/2.0,   cos((i-1.0)*360.0/density*1.0), 0, sin((i-1.0)*360.0/density), (i-1.0)/density, 1.0)
         writeVertex275(memblock, offset+128, sin((i*1.0)*360.0/density)*btmSize/2.0,      0, cos((i*1.0)*360.0/density)*btmSize/2.0,   cos((i*1.0)*360.0/density*1.0), 0, sin((i*1.0)*360.0/density), (i*1.0)/density, 1.0)
         writeVertex275(memblock, offset+160, sin((i*1.0)*360.0/density)*topSize/2.0, height, cos((i*1.0)*360.0/density)*topSize/2.0,   cos((i*1.0)*360.0/density*1.0), 0, sin((i*1.0)*360.0/density), (i*1.0)/density, 0.0)
         inc offset, 192
   next i

   make mesh from memblock mesh, memblock

   delete memblock memblock
endfunction


function MemblockMeshHalfTCone(mesh as integer, density as integer, topSize as float, btmSize as float, height as float)
	local memblock as integer
   local vertexCount as integer
   local offset as integer

   memblock = FreeMemblock()

   make memblock memblock, 12 + (32 * density * 6)

   write memblock dword memblock, 0, 275
   write memblock dword memblock, 4, 32
   write memblock dword memblock, 8, density * 6
   offset = 12

   for i = 1 to density

      `write poly one and two-------------------------------------
         writeVertex275(memblock, offset    , sin((i-1.0)*180.0/density)*topSize/2.0, height, cos((i-1.0)*180.0/density)*topSize/2.0,   cos((i-1.0)*360.0/density*1.0), 0, sin((i-1.0)*360.0/density), (i-1.0)/density, 0.0)
         writeVertex275(memblock, offset+32 , sin((i-1.0)*180.0/density)*btmSize/2.0,      0, cos((i-1.0)*180.0/density)*btmSize/2.0,   cos((i-1.0)*360.0/density*1.0), 0, sin((i-1.0)*360.0/density), (i-1.0)/density, 1.0)
         writeVertex275(memblock, offset+64 , sin((i*1.0)*180.0/density)*topSize/2.0, height, cos((i*1.0)*180.0/density)*topSize/2.0,   cos((i*1.0)*360.0/density*1.0), 0, sin((i*1.0)*360.0/density), (i*1.0)/density, 0.0)

         writeVertex275(memblock, offset+96 , sin((i-1.0)*180.0/density)*btmSize/2.0,      0, cos((i-1.0)*180.0/density)*btmSize/2.0,   cos((i-1.0)*360.0/density*1.0), 0, sin((i-1.0)*360.0/density), (i-1.0)/density, 1.0)
         writeVertex275(memblock, offset+128, sin((i*1.0)*180.0/density)*btmSize/2.0,      0, cos((i*1.0)*180.0/density)*btmSize/2.0,   cos((i*1.0)*360.0/density*1.0), 0, sin((i*1.0)*360.0/density), (i*1.0)/density, 1.0)
         writeVertex275(memblock, offset+160, sin((i*1.0)*180.0/density)*topSize/2.0, height, cos((i*1.0)*180.0/density)*topSize/2.0,   cos((i*1.0)*360.0/density*1.0), 0, sin((i*1.0)*360.0/density), (i*1.0)/density, 0.0)
         inc offset, 192
   next i

   make mesh from memblock mesh, memblock

   delete memblock memblock
endfunction



function writeVertex275(memblock, offset, x#, y#, z#,  nx#, ny#, nz#,  u#, v#)
      write memblock float memblock, offset + 0, x#
      write memblock float memblock, offset + 4, y#
      write memblock float memblock, offset + 8, z#

      `write normal data
      write memblock float memblock, offset + 12, nx#
      write memblock float memblock, offset + 16, ny#
      write memblock float memblock, offset + 20, nz#

      `write UV information
      write memblock float memblock, offset + 24, u#
      write memblock float memblock, offset + 28, v#
endfunction

function buildTurret(index)
	

	turrets(index).objNumBox = freeObject()
	make object box turrets(index).objNumBox, 2.5,2.5,2.5
	texture object turrets(index).objNumBox, trenchTexture
	set object emissive turrets(index).objNumBox, rgb(100,100,100)
	
	turrets(index).objNumStand = freeObject()
	make object box turrets(index).objNumStand, 5,15,5
	texture object turrets(index).objNumStand, trenchTexture
	set object emissive turrets(index).objNumStand, rgb(100,100,100)

	
	tmpMesh = freeMesh()
	MemblockMeshTCone(tmpMesh, 8, 0.75,0.75,4)
	turrets(index).objNum = freeObject()
	make object turrets(index).objNum, tmpMesh, trenchTexture
	`make object cone turrets(index).objNum, 1
	`scale object turrets(index).objNum,75,400,75
	texture object turrets(index).objNum, trenchTexture
	point object turrets(index).objNum, 0,0,10
	delete mesh tmpMesh
	
	MemblockMeshCone(tmpMesh, 8, 0.75,-3)
	add limb turrets(index).objNum, 1, tmpMesh
	offset limb turrets(index).objNum,1, 0,4,0
	texture limb turrets(index).objNum,1,trenchTexture
	
	show limb turrets(index).objNum,1
	delete mesh tmpMesh
	
	rotate object turrets(index).objNum, 90,0,0
	fix object pivot turrets(index).objNum
	
	`set object cull turrets(index).objNum,1

	remstart	
	local angle as float
	local tmpTex as integer
	angle = 0
	
	do
		inc angle, 0.1
		position camera sin(angle)*4, 0.5, cos(angle)*7
		point camera 0,0,0
		sync
	loop
	end
	remend
	
	turrets(index).exist = 0
	
	hide object turrets(index).objNum
	hide object turrets(index).objNumBox
	hide object turrets(index).objNumStand
	
endfunction


function createTurret(xpos as float, ypos as float, zpos as float, orient as integer)
	local index as integer
	
	index = freeTurret()
	
	if index <> -1
		position object turrets(index).objNumBox, xpos, ypos, zpos
		show object turrets(index).objNum
		show object turrets(index).objNumBox
		set object collision on turrets(index).objNumBox
		set object collision on turrets(index).objNum
		
		turrets(index).exist = 1
		
		if orient = 1
			turrets(index).orient = 1
		endif
		
		if orient = 2
			turrets(index).orient =0
			show object turrets(index).objNumStand
			position object turrets(index).objNumStand, xpos, ypos - 8.75, zpos
		endif
		
		if orient = 0
			turrets(index).orient = 0
		endif
		
		turrets(index).reload = turretFireRate + getTime()
		
		turrets(index).target = TurretSelectRebelShip()
		
		`need to 'select' target
	endif
endfunction

function updateTurrets(camZ as float, spacing as float)
	for n = 1 to turretMax
		if turrets(n).exist = 1
			position object turrets(n).objnum, object position x(turrets(n).objNumBox), object position y(turrets(n).objNumBox), object position z(turrets(n).objNumBox)
			TurretSelectTarget(turrets(n).objNum, n)
			`move object turrets(n).objnum, 2.5
			
			if turrets(n).orient = 0
				rotate object turrets(n).objnumBox, 0,object angle y(turrets(n).objNum),0
			else
				rotate object turrets(n).objnumBox, object angle x(turrets(n).objNum),0,0
			endif
			
			`tmp code --------------
				`if rnd(50) = 1 then fireBlast(turrets(n).objNum, 0, 0, 0, 0)
			`-----------------------
			
			if turrets(n).reload < getTime()
				turrets(n).reload = turretFireRate + getTime() + rnd(300)
				fireBlast(turrets(n).objNum, 0, 0, 0, 0, 1)
			endif
			
			if camZ - spacing*trenchLength > object position z(turrets(n).objnumBox) then hideTurret(n)
		endif
	next n
endfunction

function hideTurret(index)
	hide object turrets(index).objNum
	hide object turrets(index).objNumBox
	set object collision off turrets(index).objNumBox
	set object collision off turrets(index).objNum
	`hide object turrets(index).objNumStand
	turrets(index).exist = 0
	turrets(index).target = 0
endfunction

function resetTurrets()
	for n = 1 to turretMax
		hide object turrets(n).objNum
		hide object turrets(n).objNumBox
		set object collision off turrets(n).objNumBox
		set object collision off turrets(n).objNum
		hide object turrets(n).objNumStand
		turrets(n).exist = 0
		turrets(n).target = 0
	next n
endfunction

function TurretSelectTarget(objnum, index)
	if turrets(index).target > 0

		point object objnum, object position x(turrets(index).target), object position y(turrets(index).target), object position z(turrets(index).target)+turretLead
		
		`text 100,100+(index-1)*15, "Pointing turret...  " + str$(turrets(index).target)
	endif
endfunction

function freeTurret()
	local i as integer
	local found as integer
	
	repeat
		inc i
		if turrets(i).exist=0 and object visible(turrets(i).objNumStand) = 0 then found=1
	until found = 1 or i >= turretMax
	if found = 0
		i = 0
		repeat
			inc i
			if turrets(i).exist=0 then found=1
		until found = 1 or i >= turretMax
		if found = 0 then i = -1
	else
		exitfunction i
	endif
endfunction i

`automaticaly controled (computer controled) ships...

function createAutoShips()
	`loop through, build objects, initialize data...
	for n = 1 to maxShips
	
		autoShips(n).objnum = freeObject()
		autoShips(n).exist = 0
		autoShips(n).reload = 0
		autoShips(n).controlType = AIcontrol
		autoShips(n).intersectUpdate = 0
		
		autoShips(n).roll = 0
		autoShips(n).incoming = 0
		autoShips(n).newPathOverride = 0
		autoShips(n).autoPathX = 0.0
		autoShips(n).autoPathY = 5.0
		autoShips(n).target = 0
		autoShips(n).health = 100
		
		`rebel or empire ship...
		if n <= maxShips/2
			autoships(n).side = EmpireShip
			createTIEfighter(autoShips(n).objnum, empireShipSize)
		else
			autoShips(n).side = RebelShip
			createXwingfighter(autoShips(n).objnum, rebelShipSize)
		endif
		
		rotate object autoShips(n).objnum, 0,0,0
		hide object autoShips(n).objnum
	next n
	
	remstart
	`tmp ------------------------
	autoShips(1).exist = 1
	autoShips(1).controlType = PlayerControl
	show object autoShips(1).objnum
	`----------------------------
	remend
	
endfunction

function updateAutoShips()
	for n = 1 to maxShips
		if autoShips(n).exist = 1
			
			if autoShips(n).incoming = 0
				`update ships...
				if autoShips(n).controlType = PlayerControl
					controlPlayer(n)
				else
					controlAI(n)
				endif
			else
				controlAI(n)
			endif
			
			`reset variable
			autoShips(n).newPathOverride = 0
			
			autoShipCollision(n)
		endif
	next n
endfunction

function autoShipCollision(ship as integer)
	if object collision(autoShips(ship).objnum,0) > 0
		position object autoShips(ship).objnum, object position x(autoShips(ship).objnum)-get object collision x(),_
																 object position y(autoShips(ship).objnum)-get object collision y(),_
																 object position z(autoShips(ship).objnum)-get object collision z()
		`so if it's hit something then manual overide new path
		autoShips(ship).newPathOverride = 1
	endif
	
	`simple wall collision
	if autoShips(ship).incoming = 0 `this way it can 'fly in' but not out
		if object position y(autoShips(ship).objnum) > trenchCeil then position object autoShips(ship).objnum, object position x(autoShips(ship).objnum), trenchCeil, object position z(autoShips(ship).objnum)
	endif
	if object position y(autoShips(ship).objnum) < 0.2 then position object autoShips(ship).objnum, object position x(autoShips(ship).objnum), 0.2, object position z(autoShips(ship).objnum)
		
	if object position x(autoShips(ship).objnum) > 4.8 then position object autoShips(ship).objnum, 4.8, object position y(autoShips(ship).objnum), object position z(autoShips(ship).objnum)
	if object position x(autoShips(ship).objnum) < -4.8 then position object autoShips(ship).objnum, -4.8, object position y(autoShips(ship).objnum), object position z(autoShips(ship).objnum)
	
	`autopath constraining - that way they don't TRY to fly out...
	if autoShips(ship).autoPathY > trenchCeil then autoShips(ship).autoPathX = trenchCeil
	if autoShips(ship).autoPathY < 0.2 then autoShips(ship).autoPathY = 0.2
		
	if autoShips(ship).autoPathX > 4.8 then autoShips(ship).autoPathX = 4.8
	if autoShips(ship).autoPathX < -4.8 then autoShips(ship).autoPathX = -4.8
	
	`check to see if ships are to far ahead or behind of the camera...
	if object position z(autoShips(ship).objnum) > camera position z() + 300 or object position z(autoShips(ship).objnum) < camera position z() - 300
		if (autoShips(ship).side = EmpireShip and autoShips(playerShip).side = RebelShip)
			position object autoShips(ship).objnum, 0, 20, camera position z() - StartSepDist - 2 + rnd(4)
			autoShips(ship).incoming = 1
			newMsg(ship, "Commin Back to get ya you rebel scum!")
		else
			if (autoShips(ship).side = RebelShip and autoShips(playerShip).side = EmpireShip)
				position object autoShips(ship).objnum, 0, 20, camera position z() + StartSepDist - 2 + rnd(4)
				autoShips(ship).incoming = 1
				newMsg(ship, "Death to the empire!")
			else
				position object autoShips(ship).objnum, 0, 20, camera position z() - 2 + rnd(4)
				autoShips(ship).incoming = 1
				newMsg(ship, "We shall not leave one of our own to die!")
			endif
		endif
	endif
	
	`hmm... well we want our ships to 'reset' if they get past the exhaust port
	if object position z(autoShips(ship).objnum) > winDistance - 20
		if autoShips(ship).autoPathY < 10.5 then autoShips(ship).autoPathY = 10.5
	endif
	
	`over the port...
	if object position z(autoShips(ship).objnum) >= winDistance
		if object position y(autoShips(ship).objnum) < 10.5 then position object autoShips(ship).objnum, object position x(autoShips(ship).objnum), 10.5, object position z(autoShips(ship).objnum)
	endif
endfunction

function autoCamera(ship)
	position camera object position x(autoShips(ship).objnum)+camOffHorz,_
							object position y(autoShips(ship).objnum)+camOffVert,_
							object position z(autoShips(ship).objnum)+camOffZ
							
	rotate camera 0,0,0
	
	if freeRotToggle = 1
		rotate camera camRotX, camRotY, camRotZ
	else
		rotate camera object angle x(autoShips(ship).objnum), object angle y(autoShips(ship).objnum), object angle z(autoShips(ship).objnum)
		pitch camera up camRotX
		turn camera right camRotY
		roll camera right camRotZ
	endif
	

endfunction

function countAutoShips(side)
	local qty as integer = 0
	for n = 1 to maxShips
		if autoShips(n).exist = 1 and autoShips(n).side = side
			inc qty
		endif
	next n
endfunction qty

function killShip(ship)

	autoShips(ship).exist = 0
	autoShips(ship).reload = 0
	autoShips(ship).controlType = AIcontrol
	autoShips(ship).intersectUpdate = 0
		
	autoShips(ship).roll = 0
	autoShips(ship).incoming = 0
	autoShips(ship).newPathOverride = 0
	autoShips(ship).autoPathX = 0.0
	autoShips(ship).autoPathY = 5.0
	autoShips(ship).target = 0
	autoShips(ship).health = 100
	hide object autoShips(ship).objNum
	set object collision off autoShips(ship).objNum
endfunction

function controlPlayer(ship as integer)
	local curX as float
	local curY as float
	local curZ as float
	
	curX = object angle x(autoShips(ship).objnum)
	curY = object angle y(autoShips(ship).objnum)
	curZ = object angle z(autoShips(ship).objnum)
	
	`pitch up...
	if codeState(keyPitchDown) = keyHoldDown
		if curX + timeValue(pitchSpeed) > 15
			curX = 15
		else
			curX = curX + timeValue(pitchSpeed)
		endif
	endif
	
	`pitch down...
	if codeState(keyPitchUp) = keyHoldDown
		if curX - timeValue(pitchSpeed) < -15
			curX = -15
		else
			curX = curX - timeValue(pitchSpeed)
		endif
	endif
	
	`pitch back to normal if no key is pressed
	if codeState(keyPitchDown) = keyHoldUp and codeState(keyPitchUp) = keyHoldUp
		if abs(curX) > timeValue(pitchSpeed)
			if curX > 0
				curX = curX - timeValue(pitchSpeed)
			else
				curX = curX + timeValue(pitchSpeed)
			endif
		else
			curX = 0
		endif
	endif
	
	
	`Turn Left...
	if codeState(keyRollRight) = keyHoldDown
		if curY + timeValue(turnSpeed) > 15
			curY = 15
		else
			curY =  curY + timeValue(turnSpeed)
		endif
	endif
	
	`Turn Right...
	if codeState(keyRollLeft) = keyHoldDown
		if curY - timeValue(turnSpeed) < -15
			curY = -15
		else
			curY = curY - timeValue(turnSpeed)
		endif
	endif
	
	
	`Turn back to normal if no key is pressed
	if codeState(keyRollLeft) = keyHoldUp and codeState(keyRollRight) = keyHoldUp
		if abs(curY) > timeValue(turnSpeed)

			if curY > 0
				curY = curY - timeValue(turnSpeed)
			else
				curY = curY + timeValue(turnSpeed)
			endif
		else
			curY = 0
		endif
	endif

	
	`updated rotations...
	rotate object autoShips(ship).objnum, curX, curY, curZ
	
	`wana slide dude?
	if codeState(keySlideUp) = keyHoldDown
		move object up autoShips(ship).objnum, timeValue(moveSpeed/6.0)
	endif

	if codeState(keySlideDown) = keyHoldDown
		move object down autoShips(ship).objnum, timeValue(moveSpeed/6.0)
	endif
	
	if codeState(keySlideLeft) = keyHoldDown
		zrotate object autoShips(ship).objnum, 0
		move object left autoShips(ship).objnum, timeValue(moveSpeed/6.0)
		if autoShips(ship).roll + timeValue(rollSpeed) > 15
			autoShips(ship).roll = 15.0
		else
			autoShips(ship).roll = autoShips(ship).roll + timeValue(rollSpeed)
		endif
		zrotate object autoShips(ship).objnum, autoShips(ship).roll
	endif
	
	if codeState(keySlideRight) = keyHoldDown
		zrotate object autoShips(ship).objnum, 0
		move object right autoShips(ship).objnum, timeValue(moveSpeed/6.0)
		if autoShips(ship).roll - timeValue(rollSpeed) < -15
			autoShips(ship).roll = -15.0
		else
			autoShips(ship).roll = autoShips(ship).roll - timeValue(rollSpeed)
		endif
		zrotate object autoShips(ship).objnum, autoShips(ship).roll
	endif
	
	`roll back to zero
	if codeState(keySlideRight) = keyHoldUp and codeState(keySlideLeft) = keyHoldUp
		if abs(autoShips(ship).roll) > timeValue(rollSpeed)
			if autoShips(ship).roll > 0
				autoShips(ship).roll = autoShips(ship).roll - timeValue(rollSpeed)
			else
				autoShips(ship).roll = autoShips(ship).roll + timeValue(rollSpeed)
			endif
		else
			autoShips(ship).roll = 0
		endif
		
		zrotate object autoShips(ship).objnum, autoShips(ship).roll
	endif
	
	`warn enemy ships, I'm behind you!
	tmpInt = nearShip(ship,3.0)
	if tmpInt > 0 and autoShips(ship).target = 0
		autoShips(ship).target = tmpInt
		autoShips(autoShips(ship).target).underFire = 1
		newMsg(ship, "In my Sights")
	else
		if autoShips(ship).target > 0 and tmpInt <= 0
			autoShips(autoShips(ship).target).underFire = 0
			autoShips(ship).target = 0
		endif
	endif
	
	`continuious firetype
	if codeState(keyFire) = keyHoldDown
		if getTime() - autoShips(ship).reload > 0
		
			if autoShips(ship).side = EmpireShip
				fireBlast(autoShips(ship).objnum, EmpireShip, 0,-0.1, 1.5,1)
				fireBlast(autoShips(ship).objnum, EmpireShip, 0, 0.1, 1.5,1)
			else
				fireBlast(autoShips(ship).objnum, RebelShip, 0,-0.1, 1.5,1)
				fireBlast(autoShips(ship).objnum, RebelShip, 0, 0.1, 1.5,1)
			endif
			
			autoShips(ship).reload = getTime() + fireRate
		endif
	endif
	
	`movin forward
	if codeState(keyForward) = keyHoldDown
		if autoShips(ship).vel + timeValue(accSpeed) > moveSpeed
			autoShips(ship).vel = moveSpeed
		else
			autoShips(ship).vel = autoShips(ship).vel + timeValue(accSpeed)
		endif
	else
		if autoShips(ship).vel - timeValue(accSpeed) <= 0
			autoShips(ship).vel = 0
		else
			autoShips(ship).vel = autoShips(ship).vel - timeValue(accSpeed/2.0)
		endif
	endif
	
	move object autoShips(ship).objnum, timeValue(autoShips(ship).vel)


endfunction

function controlAI(ship as integer)
	local tmpDist as float
	local tmp2 as float
	local sanityCheck as integer
	local tmpX as float
	local tmpY as float
	local tmpZ as float
	local tmpInt as integer
	
	`I need this up here, in case I need a new path Override...
	if autoShips(ship).target > 0
		autoShips(ship).autoPathX = object position x(autoShips(autoShips(ship).target).objnum)
		autoShips(ship).autoPathY = object position y(autoShips(autoShips(ship).target).objnum)
		if getTime() - autoShips(ship).engageTime > 7000
			autoShips(autoShips(ship).target).underFire = 0
			autoShips(ship).target = 0
			autoShips(ship).newPathOverride = 1
		endif
	endif
	
	if autoShips(ship).underFire > 0
		`slightly modify path every now and then to 'evade' the attack, more realistic like
		if rnd(underFireEvadeChance) = 1
			autoShips(ship).autoPathX = autoShips(ship).autoPathX - EvadeAmnt + rnd(EvadeAmnt * 20)/10.0
			autoShips(ship).autoPathY = autoShips(ship).autoPathY - EvadeAmnt + rnd(EvadeAmnt * 20)/10.0
		endif	
	endif
	
	`check to see if the current path will make them hit something...
	if getTime() - autoShips(ship).intersectUpdate > 0
		autoShips(ship).intersectUpdate = getTime() + fireRate * 2
		
		`slight path wandering affect, stops that monotone straight flying
		if rnd(pathChangeChance) = 1
			autoShips(ship).autoPathX = autoShips(ship).autoPathX - EvadeAmnt/2.0 + rnd(EvadeAmnt * 10)/10.0
			autoShips(ship).autoPathY = autoShips(ship).autoPathY - EvadeAmnt/2.0 + rnd(EvadeAmnt * 10)/10.0
		endif
		
		tmpDist = intersectBridge(autoShips(ship).autoPathX+cSize,_
									autoShips(ship).autoPathY+cSize,_
									object position z(autoShips(ship).objnum)-1.0,_
									autoShips(ship).autoPathX+cSize,_
									autoShips(ship).autoPathY+cSize,_
									(object position z(autoShips(ship).objnum) + lookAheadDist))
									
		tmp2 = intersectBridge(autoShips(ship).autoPathX-cSize,_
									autoShips(ship).autoPathY+cSize,_
									object position z(autoShips(ship).objnum)-1.0,_
									autoShips(ship).autoPathX-cSize,_
									autoShips(ship).autoPathY+cSize,_
									(object position z(autoShips(ship).objnum) + lookAheadDist))
									
		if tmp2 < tmpDist and tmp2 > 0.01 then tmpDist = tmp2
		
		tmp2 = intersectBridge(autoShips(ship).autoPathX-cSize,_
									autoShips(ship).autoPathY-cSize,_
									object position z(autoShips(ship).objnum)-1.0,_
									autoShips(ship).autoPathX-cSize,_
									autoShips(ship).autoPathY-cSize,_
									(object position z(autoShips(ship).objnum) + lookAheadDist))
									
		if tmp2 < tmpDist and tmp2 > 0.01 then tmpDist = tmp2
		
		tmp2 = intersectBridge(autoShips(ship).autoPathX+cSize,_
									autoShips(ship).autoPathY-cSize,_
									object position z(autoShips(ship).objnum)-1.0,_
									autoShips(ship).autoPathX+cSize,_
									autoShips(ship).autoPathY-cSize,_
									(object position z(autoShips(ship).objnum) + lookAheadDist))
									
		if tmp2 < tmpDist and tmp2 > 0.01 then tmpDist = tmp2
		
		tmp2 = intersectBridge(autoShips(ship).autoPathX,_
									autoShips(ship).autoPathY,_
									object position z(autoShips(ship).objnum)-1.0,_
									autoShips(ship).autoPathX,_
									autoShips(ship).autoPathY,_
									(object position z(autoShips(ship).objnum) + lookAheadDist))
									
		if tmp2 < tmpDist and tmp2 > 0.01 then tmpDist = tmp2
						
						
		tmp2 = intesectTurret(autoShips(ship).autoPathX,_
									autoShips(ship).autoPathY,_
									object position z(autoShips(ship).objnum)-1.0,_
									autoShips(ship).autoPathX,_
									autoShips(ship).autoPathY,_
									(object position z(autoShips(ship).objnum) + lookAheadDist))	
		remstart
		show object 1000
		position object 1000, object position x(autoShips(ship).objnum),_
									object position y(autoShips(ship).objnum),_
									object position z(autoShips(ship).objnum) + moveSpeed*50

		for n = 1 to 1
				center text screen width()/2, screen height()/2, "Tmp Dist = " + str$(tmpDist)
				center text screen width()/2, screen height()/2+15, "X = " + str$(object position x(autoShips(ship).objnum))
				center text screen width()/2, screen height()/2+30, "Y = " + str$(object position y(autoShips(ship).objnum))
				`sync
		next n
		remend
		
		
		
		if tmpDist > 0.001 and tmpDist <= lookAheadDist or tmp2 > 0 or autoShips(ship).newPathOverride = 1
			`ok course correction needed
			sanityCheck = 0
			repeat
				inc sanityCheck
				tmpX = -4.8+(rnd(9.6))
				tmpY = (rnd(10))+0.1
				tmpZ = object position z(autoShips(ship).objnum)
				tmpDist = intersectBridge(tmpX,tmpY,tmpZ,tmpX,tmpY,tmpZ + moveSpeed*50)
			until tmpDist < 0.001 or sanityCheck > 10
			
			`now set the new destination path...
			autoShips(ship).autoPathX = tmpX
			autoShips(ship).autoPathY = tmpY
			
			`randomly fire guns for effect (but only when changing path so as to get a 'strafing' effect
			if rnd(randBurstChance) = 1
				if autoBurst(ship) = 1
					newMsg(ship, "Sendin out the Prayer!")
				endif
			endif
			
			`since we are going to hit something, disengage...
			autoShips(autoShips(ship).target).underFire = 0
			autoShips(ship).target = 0
			
			remstart
			for n = 1 to 15
				center text screen width()/2, screen height()/2+45, "New Path selected " + str$(ship) + " pathX: " + str$(tmpX) + " pathY: " + str$(tmpY)
				sync
			next n
			remend
		endif
		
	endif
	
	`are we close or what to that exaust port =)
	if object position z(autoShips(ship).objNum) >= winDistance - 100 and object position z(autoShips(ship).objNum) < winDistance - 90 and autoShips(ship).side = RebelShip
		autoShips(ship).autoPathX = -1 + rnd(20)/10.0
		autoShips(ship).autoPathY = 6+rnd(20)/10.0
	endif
	
	`if we are realy close, FIRE!
	if object position z(autoShips(ship).objNum) >= winDistance - 50 and autoShips(ship).side = RebelShip
		if getTime() - autoShips(ship).reload > 0 and autoShips(ship).numTorpedos > 0
			fireBlast(autoShips(ship).objnum, RebelShip, 0,-0.1, 1.5,2)
			fireBlast(autoShips(ship).objnum, RebelShip, 0, 0.1, 1.5,2)
			autoShips(ship).reload = getTime() + fireRate
			autoShips(ship).numTorpedos = autoShips(ship).numTorpedos - 2
			newMsg(ship, "Torpedos away!")
		endif
	endif
	
	if autoShips(ship).incoming = 0
		
		`if tmp2 > 0 then we know we are aiming for a turret, FIRE!!!
		if tmp2 > 0 and autoShips(ship).side = RebelShip
			if autoBurst(ship) = 1
				newMsg(ship, "Metalic metal turret pulp to be!")
			endif
		endif
		
		`fire guns in bursts for the AI, not continues streams or single shots, bursts.
		if autoShips(ship).autoBurst > 0
			if getTime() - autoShips(ship).reload > 0
			
				if autoShips(ship).side = EmpireShip
					fireBlast(autoShips(ship).objnum, EmpireShip, 0,-0.1, 1.5,1)
					fireBlast(autoShips(ship).objnum, EmpireShip, 0, 0.1, 1.5,1)
				else
					fireBlast(autoShips(ship).objnum, RebelShip, 0,-0.1, 1.5,1)
					fireBlast(autoShips(ship).objnum, RebelShip, 0, 0.1, 1.5,1)
				endif
				
				autoShips(ship).reload = getTime() + fireRate
				dec autoShips(ship).autoBurst
			endif
		endif
		
		`ho hoo hoooo enemy ship realy close in front of us... FIRE!
		tmpInt = nearShip(ship,1.0)
		if tmpInt > 0 and autoShips(ship).target = tmpInt
			if autoBurst(ship) = 1
				newMsg(ship, "Arrr... Bombs Away!")
				autoShips(autoShips(ship).target).underFire = 1
			endif
		endif
		
		`goody goody goody =) there's an enemy ship near in front of us =)
		tmpInt = nearShip(ship,3.0)
		if tmpInt > 0 and autoShips(ship).target = 0 and getTime() - autoShips(ship).engageTime > 8000
			autoShips(ship).target = tmpInt
			autoShips(ship).engageTime = getTime()
			newMsg(ship, "In my Sights")
		endif
		
	endif
	`now the actual steering
	`slidein up and down right and left
	if fuzzyEqual(object position y(autoShips(ship).objnum), autoShips(ship).autoPathY, pathFuzzy) = 0 and object position y(autoShips(ship).objnum) < autoShips(ship).autoPathY
		move object up autoShips(ship).objnum, timeValue(moveSpeed/6.0)
	endif

	if fuzzyEqual(object position y(autoShips(ship).objnum), autoShips(ship).autoPathY, pathFuzzy) = 0 and object position y(autoShips(ship).objnum) > autoShips(ship).autoPathY
		move object down autoShips(ship).objnum, timeValue(moveSpeed/6.0)
	endif
	
	if fuzzyEqual(object position x(autoShips(ship).objnum), autoShips(ship).autoPathX, pathFuzzy) = 0 and object position x(autoShips(ship).objnum) < autoShips(ship).autoPathX
		zrotate object autoShips(ship).objnum, 0
		move object right autoShips(ship).objnum, timeValue(moveSpeed/6.0)
		if autoShips(ship).roll - timeValue(rollSpeed) < -15
			autoShips(ship).roll = -15.0
		else
			autoShips(ship).roll = autoShips(ship).roll - timeValue(rollSpeed)
		endif
		zrotate object autoShips(ship).objnum, autoShips(ship).roll
	endif
	
	if fuzzyEqual(object position x(autoShips(ship).objnum), autoShips(ship).autoPathX, pathFuzzy) = 0 and object position x(autoShips(ship).objnum) > autoShips(ship).autoPathX
		zrotate object autoShips(ship).objnum, 0
		move object left autoShips(ship).objnum, timeValue(moveSpeed/6.0)
		if autoShips(ship).roll + timeValue(rollSpeed) > 15
			autoShips(ship).roll = 15.0
		else
			autoShips(ship).roll = autoShips(ship).roll + timeValue(rollSpeed)
		endif
		zrotate object autoShips(ship).objnum, autoShips(ship).roll
	endif
	
	`roll back to zero
	if fuzzyEqual(object position x(autoShips(ship).objnum), autoShips(ship).autoPathX, pathFuzzy) = 1
		if abs(autoShips(ship).roll) > timeValue(rollSpeed)
			if autoShips(ship).roll > 0
				autoShips(ship).roll = autoShips(ship).roll - timeValue(rollSpeed)
			else
				autoShips(ship).roll = autoShips(ship).roll + timeValue(rollSpeed)
			endif
		else
			autoShips(ship).roll = 0
		endif
		
		zrotate object autoShips(ship).objnum, autoShips(ship).roll
	endif
	
	if fuzzyEqual(object position x(autoShips(ship).objnum), autoShips(ship).autoPathX, pathFuzzy) = 1 and fuzzyEqual(object position y(autoShips(ship).objnum), autoShips(ship).autoPathY, pathFuzzy) = 1
		if autoShips(ship).incoming = 1
			autoShips(ship).incoming = 0
			if autoShips(ship).controlType = playerControl
				newMsg(ship, "Entry complete. Controls transfered to player.")
			else
				newMsg(ship, "Commin in the game...")
			endif
		endif
	endif
	
	
	`hmm... velocity Check...
	if autoShips(ship).vel + timeValue(accSpeed) > moveSpeed
		autoShips(ship).vel = moveSpeed
	else
		autoShips(ship).vel = autoShips(ship).vel + timeValue(accSpeed)
	endif
	
	move object autoShips(ship).objnum, timeValue(autoShips(ship).vel)
	
	remstart
	`tmp-------------------------
		position camera object position x(autoShips(ship).objnum),_
							object position y(autoShips(ship).objnum)+0.4,_
							object position z(autoShips(ship).objnum)-0.8
							
		text 100,100,"Player Z: " + str$(object position z(autoShips(ship).objnum))
	`----------------------------
	remend
endfunction

function autoBurst(ship)
	local rtrn as integer = 0
	if autoShips(ship).autoBurst = 0 and getTime() - autoShips(ship).autoBreload > AutoBReloadTime
		autoShips(ship).autoBurst = 2 + rnd(3)
		autoShips(ship).autoBreload = getTime()
		rtrn = 1
	endif
endfunction rtrn

function fuzzyEqual(value1 as float, value2 as float, fuzzyFactor as float)
	local rtrn as integer = 0
	if value1 < value2 + fuzzyFactor and value1 > value2 - fuzzyFactor then rtrn = 1
endfunction rtrn

function resetShips()
	for n = 1 to maxShips
		autoShips(n).exist = 0
		autoShips(n).reload = 0
		autoShips(n).controlType = AIcontrol
		autoShips(n).intersectUpdate = 0
		
		autoShips(n).roll = 0
		autoShips(n).incoming = 0
		autoShips(n).newPathOverride = 0
		autoShips(n).autoPathX = 0.0
		autoShips(n).autoPathY = 5.0
		autoShips(n).target = 0
		autoShips(n).health = 100
		
		`rebel or empire ship...
		if n <= maxShips/2
			autoships(n).side = EmpireShip
		else
			autoShips(n).side = RebelShip
		endif
		
		rotate object autoShips(n).objnum, 0,0,0
		hide object autoShips(n).objnum
	next n
endfunction


function AddEmpireShip(position as float, control as integer)
	local num as integer
	num = FreeEmpireShip()
	if num > 0
		autoShips(num).exist = 1
		autoShips(num).incoming = 1
		autoShips(num).controlType = control
		autoShips(num).health = 100
		autoShips(num).vel = 0
		show object autoShips(num).objNum
		position object autoShips(num).objNum, -4.0+rnd(80.0)/10.0, 55+rnd(10), position
		set object collision on autoShips(num).objNum
		newMsg(num, "Death to the Jedi!")
	endif
endfunction num

function AddRebelShip(position as float, control as integer)
	local num as integer
	num = FreeRebelShip()
	if num > 0
		autoShips(num).exist = 1
		autoShips(num).incoming = 1
		autoShips(num).controlType = control
		autoShips(num).health = 100
		autoShips(num).vel = 0
		autoShips(num).numTorpedos = 4
		show object autoShips(num).objNum
		position object autoShips(num).objNum, -4.0+rnd(80.0)/10.0, 35+rnd(10), position
		set object collision on autoShips(num).objNum
		newMsg(num, "For the glory of the Old Republic!")
	endif
endfunction num

function TurretSelectRebelShip()
	local i as integer
	local j as integer
	local found as integer = 0
	local obj as integer
	
	i = maxShips/2
	repeat
		inc i
		if autoShips(i).exist = 1 then inc found
	until i >= maxShips
	
	obj = 0
	if found > 0
		i = maxShips/2
		`text 10,40,"found = " + str$(found)
		found = rnd(found-1)+1
		`text 10,55,"rnd(found) = " + str$(found)
		j = 0
		repeat
			inc i
			if autoShips(i).exist = 1 then inc j
			if j >= found then obj = autoShips(i).objNum
		until obj > 0
		
	endif

endfunction obj

function playerChange(side as integer)
	local i as integer
	local j as integer
	local found as integer = 0
	local obj as integer
	
	i = 0
	repeat
		inc i
		if autoShips(i).exist = 1 and autoShips(i).side = side then inc found
	until i >= maxShips
	
	obj = 0
	if found > 0

		i = 0
		`text 10,40,"found = " + str$(found)
		found = rnd(found-1)+1
		`text 10,55,"rnd(found) = " + str$(found)
		j = 0
		repeat
			inc i
			if autoShips(i).exist = 1 and autoShips(i).side = side  then inc j
			if j >= found then obj = i
		until obj > 0
		
	endif
endfunction i

function FreeEmpireShip()
	local i as integer = 0
	local found as integer = 0
	
	repeat
		inc i
		if autoShips(i).exist = 0 then found = 1
	until i >= maxShips/2 or found = 1

	if found = 0 then i = -1
endfunction i

function FreeRebelShip()
	local i as integer
	local found as integer = 0
	
	i = maxShips/2
	repeat
		inc i
		if autoShips(i).exist = 0 then found = 1
	until i >= maxShips or found = 1
	
	if found = 0 then i = -1
endfunction i

function makeBooms()
	local tmpMesh as integer
	`local tmpObj as integer
	
	for n = 1 to maxBooms
		tmpMesh = FreeMesh()
		`tmpObj = FreeObject()
		
		`make object sphere tmpObj, 100, 10, 10
		booms(n).scale = 0.001
		booms(n).exist = 0
		booms(n).BoomObj = FreeObject()
		make object sphere booms(n).BoomObj, 100, 10, 10
		texture object booms(n).BoomObj, explodeImg
		ghost object on booms(n).BoomObj
		set object light booms(n).BoomObj, 1
		set object emissive booms(n).BoomObj, rgb(255,255,150)
		set object diffuse booms(n).BoomObj, rgb(255,255,150)
		set object ambient booms(n).BoomObj, rgb(255,255,150)
		set object cull booms(n).BoomObj, 0
		
		booms(n).shockObj = FreeObject()
		MemblockMeshPlain(tmpMesh, 100, 100)
		
		make object booms(n).shockObj, tmpMesh, sWaveImg
		ghost object on booms(n).shockObj
		set object light booms(n).shockObj, 0
		
		set object collision off booms(n).shockObj
		set object collision off booms(n).BoomObj
		
		hide object booms(n).shockObj
		hide object booms(n).BoomObj
		
	next n
endfunction

function resetBooms()
	for n = 1 to maxBooms
		booms(n).scale = 0.001
		booms(n).exist = 0
		hide object booms(n).shockObj
		hide object booms(n).BoomObj
	next n
endfunction

function explode(object as integer)
	local index as integer
	
	for x = 1 to 3
		
		index = freeBoom()
		
		if index > 0
			booms(index).exist = 1
			booms(index).scale = 0.5
			booms(index).scale2 = 3.0
			
			show object booms(index).BoomObj
			show object booms(index).shockObj
			
			position object booms(index).BoomObj, object position x(object), object position y(object), object position z(object)
			position object booms(index).shockObj, object position x(object), object position y(object), object position z(object)
		
			scale object booms(index).shockObj, booms(index).scale2,booms(index).scale2,booms(index).scale2
			scale object booms(index).BoomObj, booms(index).scale,booms(index).scale,booms(index).scale
		endif

	next x
endfunction

function updateExplode()
	for n = 1 to maxBooms
		if booms(n).exist = 1
			booms(n).scale =  booms(n).scale * 1.10
			booms(n).scale2 =  booms(n).scale2 * 1.15
			scale object booms(n).shockObj, booms(n).scale2,booms(n).scale2,booms(n).scale2
			fade object booms(n).shockObj, 200-scale2*4.0
			scale object booms(n).BoomObj, booms(n).scale,booms(n).scale,booms(n).scale
			fade object booms(n).shockObj, 200-scale*(200.0/35.0)
			
			if booms(n).scale2 > 50
				hide object booms(n).shockObj
			endif
			if booms(n).scale > 35
				hide object booms(n).BoomObj
				booms(n).exist = 0
			endif
			
			`text 400,400,"BOOM!!!!"
		endif
	next n
endfunction

function freeBoom()
	local i as integer
	local found as integer
	
	repeat
		inc i
		if booms(i).exist = 0 then found = 1
	until found = 1 or i >= maxBooms
	
	if found = 0 then i = -1
endfunction i

function updateMessages()
	if msgpanalVisible = 1
		if hasMessagePanel = 1
			paste sprite msgPanImg,0,0
		endif
		
		ink rgb(200,140,0),0
		for n = 1 to maxMessages
			text 5,5 + (n-1)*15, messages(n)
		next n
	endif
	
	`paste image msgUpImg, 20,0
	`paste image msgDownImg, 0,0
	
	if timer() - messagesLastUpdate > 1000 then shiftMessages()
endfunction

function shiftMessages()
	for n = 0 to maxMessages-1
		messages(n) = messages(n+1)
	next n
	
	messagesLastUpdate = timer()
	messages(maxMessages) = ""
endfunction

function clearMsgs()
	for n = 0 to maxMessages
		messages(n) = ""
	next n
endfunction

function newMsg(ship as integer, msg as string)
	local tmp as string
	if messages(maxMessages) <> ""
		shiftMessages()
	endif
	
	if ship > maxShips
		select ship
			case 99
				tmp = "System: "
			endcase
			case 100
				tmp = "Turret: "
			endcase
		endselect
	else
		if ship > (maxShips/2)
			tmp = "Rebel " + str$(ship-maxShips/2) + ": "
		else
			tmp = "Empire " + str$(ship) + ": "
		endif
	endif
	
	msg = tmp + msg
	
	if msg <> messages(maxMessages-1)
		messages(maxMessages) = msg
	endif
endfunction

function intro()
	local tmpMesh as integer
	local SWImg as integer
	local SWstoryImg as integer
	local logoPlain as integer
	local SWstoryObj as integer
	local skipIntro as integer
	local deathStarImg as integer
	local deathStarObj as integer
	
	skipIntro = 0
	
	`space
	position camera 0,2000,0
	point camera 0,2000,1
	position object SkyBoxNum, 0,2000,0
	
	SWImg = freeImage()
	starWarsLogo(SWImg)
	deathStarImg = freeImage()
	DeathStarTexture(deathStarImg)
	
	deathStarObj = freeObject()
	make object sphere deathStarObj, 20, 15,15
	texture object deathStarObj, deathStarImg 
	position object deathStarObj, 30,2000,-20
	
	
	logoPlain = freeObject()
	make object plain logoPlain, 100, 100
	texture object logoPlain, SWImg
	set object transparency logoPlain, 1
	position object logoPlain,0,2000, -1
	set object light logoPlain, 0
	set object emissive logoPlain,rgb(255,255,0)
	set object fog logoPlain,0
	
	SWstoryImg = freeImage()
	introTextStory(SWstoryImg)
	
		SWstoryObj = freeObject()
		
		make object plain SWstoryObj, 100, 100
		texture object SWstoryObj, SWstoryImg
		scale object SWstoryObj,100,300,100
		set object transparency SWstoryObj, 1
		position object SWstoryObj,0,1950, 1
		rotate object SWstoryObj,60,0,0
		move object down SWstoryObj, 100
		set object emissive SWstoryObj,rgb(255,255,0)
		set object diffuse SWstoryObj,rgb(255,255,0)
		set object cull SWstoryObj,0
		`ghost object on  SWstoryObj

	
	
	`A long time ago in a galaxy far,
	`far away...
	set text font "verdana"

	set text size 18
	
	for n = 1 to 255
		if skipIntro = 1 then exit
		cls
		ink RGB(0,int(128.0*((n*1.0)/255.0)),int(192.0*((n*1.0)/255.0))),0
		text screen width()/2-125,screen height()/2,"A long time ago in a galaxy far,"
		text screen width()/2-125,screen height()/2+15,"far away..."
		if escapekey() = 1 then skipIntro = -1
		if escapekey() = 0 and skipIntro = -1 then skipIntro = 1
		sync
	next n
	
	time = getTime()
	while getTime() - time < 2000 and skipIntro <= 0
		cls
		ink RGB(0,128,192),0
		text screen width()/2-125,screen height()/2,"A long time ago in a galaxy far,"
		text screen width()/2-125,screen height()/2+15,"far away..."
		if escapekey() = 1 then skipIntro = -1
		if escapekey() = 0 and skipIntro = -1 then skipIntro = 1
		sync
	endwhile
	
	for n = 255 to 1 step -1
		if skipIntro = 1 then exit
		cls
		ink RGB(0,int(128.0*((n*1.0)/255.0)),int(192.0*((n*1.0)/255.0))),0
		text screen width()/2-125,screen height()/2,"A long time ago in a galaxy far,"
		text screen width()/2-125,screen height()/2+15,"far away..."
		if escapekey() = 1 then skipIntro = -1
		if escapekey() = 0 and skipIntro = -1 then skipIntro = 1
		sync
	next n
	
	
	time = getTime()
	while getTime() - time < 3000 and skipIntro <= 0
		`paste image SWImg, 0,0
		position object logoPlain, 0, 2000, object position z(logoPlain) + 1.0
		scale object logoPlain,100*(time*1.0+5000-getTime()*1.0)/5000.0,100*(time*1.0+5000-getTime()*1.0)/5000.0,100
		if escapekey() = 1 then skipIntro = -1
		if escapekey() = 0 and skipIntro = -1 then skipIntro = 1
		sync
	endwhile
	
	delete object logoPlain
	delete image SWImg
	
	`workin on this...
	`time = timer()
	while object position z(SWstoryObj) < 300 and skipIntro <= 0
		move object up SWstoryObj, 0.03
		if escapekey() = 1 then skipIntro = -1
		if escapekey() = 0 and skipIntro = -1 then skipIntro = 1
		`paste image deathStarImg, 0,0
		sync
	endwhile
	
	delete object SWstoryObj
	delete image SWstoryImg
	
	while object position z(deathStarObj) < 200 and skipIntro <= 0
		position object deathStarObj, -15, 1985, object position z(deathStarObj) + 0.05
		rotate object deathStarObj,0,225,0
		if escapekey() = 1 then skipIntro = -1
		if escapekey() = 0 and skipIntro = -1 then skipIntro = 1
		sync
	endwhile
	
	delete object deathStarObj
	delete image deathStarImg
	
	
	set text font "verdana"

	set text size 18
endfunction

function rebelWinVid()
	local deathStarImg as integer
	local deathStarObj as integer
	
	set text font "verdana"

	set text size 18
	
	`space
	position camera 0,2000,0
	point camera 0,2000,1
	position object SkyBoxNum, 0,2000,0
	
	deathStarImg = freeImage()
	DeathStarTexture(deathStarImg)
	
	deathStarObj = freeObject()
	make object sphere deathStarObj, 20, 15,15
	texture object deathStarObj, deathStarImg
	position object deathStarObj, -15,1990,40
	rotate object deathStarObj,0,225,0
	
	resetBooms()
	
	for n = 1 to 100
		yrotate object deathStarObj,object angle y(deathStarObj) + 0.1
		sync
	next n
	
	FPS_UpdateIndependent()
	time = getTime()
	
	GameSpeed = 30
	
	while getTime() - time < 4000
		`paste image SWImg, 0,0
		FPS_UpdateIndependent()
		updateExplode()
		
		yrotate object deathStarObj,object angle y(deathStarObj) + 0.1
		
		if (getTime() - time) < 3000 and rnd(20) = 1
			explode(deathStarObj)
		else
			if (getTime() - time) > 2000 and object visible(deathStarObj) = 1
				hide object deathStarObj
				for n = 1 to 5
					explode(deathStarObj)
				next n
			endif
		endif
		
		sync
		sync
	endwhile
	
	delete object deathStarObj
	delete image deathStarImg
	
	GameSpeed = 60
	
	for n = 1 to 255
		ink RGB(0,int(128.0*((n*1.0)/255.0)),int(192.0*((n*1.0)/255.0))),0
		text screen width()/2-125,screen height()/2,"Deathstar Destroyed..."
		sync
	next n
	
	time = getTime()
	while  getTime() - time < 1000
		ink RGB(0,128,192),0
		text screen width()/2-125,screen height()/2,"Deathstar Destroyed..."
		sync
	endwhile
	
	for n = 255 to 1 step -1
		ink RGB(0,int(128.0*((n*1.0)/255.0)),int(192.0*((n*1.0)/255.0))),0
		text screen width()/2-125,screen height()/2,"Deathstar Destroyed..."
		sync
	next n
endfunction

function EmpireWinVid()
	set text font "verdana"

	set text size 18
	`space
	position camera 0,2000,0
	point camera 0,2000,1
	position object SkyBoxNum, 0,2000,0
	
	for n = 1 to 255
		ink RGB(0,int(128.0*((n*1.0)/255.0)),int(192.0*((n*1.0)/255.0))),0
		text screen width()/2-125,screen height()/2,"Rebel Base Destroyed..."
		sync
	next n
	
	time = getTime()
	while  getTime() - time < 1000
		ink RGB(0,128,192),0
		text screen width()/2-125,screen height()/2,"Rebel Base Destroyed..."
		sync
	endwhile
	
	for n = 255 to 1 step -1
		ink RGB(0,int(128.0*((n*1.0)/255.0)),int(192.0*((n*1.0)/255.0))),0
		text screen width()/2-125,screen height()/2,"Rebel Base Destroyed..."
		sync
	next n
endfunction

function menu()
	local prmpt as string
	local xWingObj as integer
	local TIEObj as integer
	
	xWingObj = freeObject()
	createXwingfighter(XWingObj, 5.0)
	
	TIEObj = freeObject()
	createTIEfighter(TIEObj, 3.0)
	
	`space
	position camera 0,2000,0
	point camera 0,2000,1
	position object SkyBoxNum, 0,2000,0
	
	while object position z(TIEObj) < 15
		position object TIEObj, 6, 2000, object position z(TIEObj) + 0.5
		position object xWingObj, -6, 2000, object position z(xWingObj) + 0.5
		`rotate object deathStarObj,0,225,0
		`if escapekey() = 1 then skipIntro = -1
		`if escapekey() = 0 and skipIntro = -1 then skipIntro = 1
		`paste image deathStarImg, 0,0
		if escapekey() = 1 then end
		sync
	endwhile
	
	while mouseclick() = 0 
		yrotate object TIEObj, object angle y(TIEObj) + 0.1
		yrotate object XWingObj, object angle y(XWingObj) + 0.1
		
		if mousex() > screen width()/2
			set object emissive TIEObj, rgb(128,128,128)
			set object emissive XWingObj, rgb(0,0,0)
			set object diffuse TIEObj, rgb(128,128,128)
			set object diffuse XWingObj, rgb(0,0,0)
			prmpt = "The path of darkness, TIE fighters"
		else
			set object emissive XWingObj, rgb(128,128,128)
			set object emissive TIEObj, rgb(0,0,0)
			set object diffuse XWingObj, rgb(128,128,128)
			set object diffuse TIEObj, rgb(0,0,0)
			prmpt = "The path of the Jedi, Xwing fighters"
		endif
		
		ink RGB(0,128,192),0
		center text screen width()/2, 10, prmpt
		if escapekey() = 1 then end
		sync
	endwhile
	
	if mousex() > screen width()/2
		playerShip = AddEmpireShip(15.0, playerControl)
		
		for n = 1 to 4
			AddEmpireShip(15.0+rnd(5), AIcontrol)
		next n
		
		for n = 1 to 5
			AddRebelShip(30.0+rnd(5), AIcontrol)
		next n
		
	else
		playerShip = AddRebelShip(30.0, playerControl)
		
		for n = 1 to 5
			AddEmpireShip(15.0+rnd(5), AIcontrol)
		next n
		
		for n = 1 to 4
			AddRebelShip(30.0+rnd(5), AIcontrol)
		next n
	endif
	
	while object position z(TIEObj) > -1
		position object TIEObj, 6, 2000, object position z(TIEObj) - 0.5
		position object xWingObj, -6, 2000, object position z(xWingObj) - 0.5
		`rotate object deathStarObj,0,225,0
		`if escapekey() = 1 then skipIntro = -1
		`if escapekey() = 0 and skipIntro = -1 then skipIntro = 1
		`paste image deathStarImg, 0,0
		if escapekey() = 1 then end
		sync
	endwhile
	
	delete object TIEObj
	delete object xWingObj
	
	
	
endfunction


function starWarsLogo(imgNum)
	
	local xSize as integer
	local ySize as integer

	xSize = 400
	ySize = 400

	create bitmap 1, xSize, ySize
	set current bitmap 1
	
	cls rgb(0, 0, 0)
	
	set text font "Arial Black"
	set text to bold
	set text size 75
	
	ink rgb(255,255,0),0
	
	center text 200,25,"STAR"
	center text 200,75,"WARS"
	
	set text to normal
	
	ink rgb(0,0,0),0
	center text 200,25,"STAR"
	center text 200,75,"WARS"
	
	`blur bitmap 1, 2
	
	get image imgNum,0,0,xSize,ySize,1
	
	delete bitmap 1
	set current bitmap 0
	
endfunction

function introTextStory(imgNum)
	local xSize as integer
	local ySize as integer
	local tmp as integer

	xSize = 330
	ySize = 840

	create bitmap 1, xSize, ySize
	set current bitmap 1
	
	cls rgb(0, 0, 0)
	
	set text font "verdana"
	set text size 40
	
	ink rgb(255,255,0),0
	
	center text 150,10,"'Trench Runner'"
	set text size 20
	tmp = txtPrnt(45 ,"Once upon a time we were all newbies, ")
	tmp = txtPrnt(tmp,"trying to figure out what you could do ")
	tmp = txtPrnt(tmp,"with the humble text command, and ")
	tmp = txtPrnt(tmp,"after finally mastering it, moving on to ")
	tmp = txtPrnt(tmp,"the equally humble yet more ")
	tmp = txtPrnt(tmp,"challenging commands of 'make object ")
	tmp = txtPrnt(tmp,"box' until the mastering of those ")
	tmp = txtPrnt(tmp,"commands is complete.  Once there ")
	tmp = txtPrnt(tmp,"we can rule the world! We said, and ")
	tmp = txtPrnt(tmp,"off we went to build the next ")
	tmp = txtPrnt(tmp,"successful MMORPG! Oh the joy of ")
	tmp = txtPrnt(tmp,"those good old days, but fortunately ")
	tmp = txtPrnt(tmp,"some of us realized our limits and set ")
	tmp = txtPrnt(tmp,"our sights on something lower that we ")
	tmp = txtPrnt(tmp,"could actually finish or accomplish, and ")
	tmp = txtPrnt(tmp,"some others set their sights on ")
	tmp = txtPrnt(tmp,"something higher than what they think ")
	tmp = txtPrnt(tmp,"they can do, and succeed! And by that ")
	tmp = txtPrnt(tmp,"they became that much better.")
	tmp = txtPrnt(tmp,"")
	tmp = txtPrnt(tmp,"So anyways there's this Deathstar, a ")
	tmp = txtPrnt(tmp,"starship the size of your average moon ")
	tmp = txtPrnt(tmp,"that has this big huge cannon that can ")
	tmp = txtPrnt(tmp,"destroy a planet, well guess what? ")
	tmp = txtPrnt(tmp,"This big huge starship found the rebels ")
	tmp = txtPrnt(tmp,"base, and well if they get close enough ")
	tmp = txtPrnt(tmp,"there's not going to be a rebel base ")
	tmp = txtPrnt(tmp,"much longer, not to mention the moon ")
	tmp = txtPrnt(tmp,"that the base is on…  So well these ")
	tmp = txtPrnt(tmp,"rebels have somehow got their hands ")
	tmp = txtPrnt(tmp,"on the plans of how to build the ")
	tmp = txtPrnt(tmp,"Deathstar and found a weak spot, the ")
	tmp = txtPrnt(tmp,"exhaust ports for its huge reactor, fire ")
	tmp = txtPrnt(tmp,"a photon torpedo or two down the ")
	tmp = txtPrnt(tmp,"tubes and the reactor will overload and ")
	tmp = txtPrnt(tmp,"poof! No more Deathstar, the only ")
	tmp = txtPrnt(tmp,"catch is that you have to fly small one ")
	tmp = txtPrnt(tmp,"man fighters down this trench filled ")
	tmp = txtPrnt(tmp,"with obstacles and turrets blasting ")
	tmp = txtPrnt(tmp,"down your throats and numerous")
	tmp = txtPrnt(tmp,"empire TIE fighters shooting up your ")
	tmp = txtPrnt(tmp,"tail... ")
	tmp = txtPrnt(tmp,"")
	tmp = txtPrnt(tmp,"Or should you chose the side of ")
	tmp = txtPrnt(tmp,"the empire you get to fly down and ")
	tmp = txtPrnt(tmp,"blast those rebel scum to pieces before ")
	tmp = txtPrnt(tmp,"they get to the exhaust ports and blow ")
	tmp = txtPrnt(tmp,"this thing into little chunks...")
	tmp = txtPrnt(tmp,"")
	tmp = txtPrnt(tmp,"")
	tmp = txtPrnt(tmp,"Choose well, and may the force be ")
	tmp = txtPrnt(tmp,"with you. ")
	
	
	`blur bitmap 1, 2
	mirror bitmap 1
	
	get image imgNum,0,0,xSize,ySize,0
	
	delete bitmap 1
	set current bitmap 0
endfunction

function txtPrnt(n,txt as string)
	text 0,n,txt
	inc n, 15
endfunction n

DesiredFPS = 60
StartTime = Timer()
Do
	`Put all of the commands to run the program here
	`Multiply all movement by CPUSpeed#
	Sync
	CPUSpeed# = GetTimerCOnstant(StartTime,DesiredFPS)
	StartTime = Timer()
loop

Function GetTimerConstant(StartTime,DesiredFPS)
	EndTime = Timer()
	FrameTime = EndTime-StartTime
	FramesPerSecond# = (1000.0/FrameTime)
	TimerConstant# = DesiredFPS/FramesPerSecond#
endfunction TimerConstant#

Tinkergirl - Nice smooth camera and ship movement. Simple but good looking trench. The x-wing cockpit just pushes it ahead of RiiDii's entry.

Ric - Fantastic fun, great graphics, smooth control, played it for ages.

CPU - I doubt anyone will disagree with the winner here. There was so much aceness in this entry it couldn't not win. The intro, the graphics, the pilot chat, all first class. I think it deserves to go in the Showcase forum instead of the challenge thread though :)

backdrop on
color backdrop rgb(205,205,205)
autocam off
sync on
position camera 50,20,-40

cube=free_sprite()
make_button(cube,"cube",50,20,50,10)
box_=free_sprite()
make_button(box_,"box",50,20,102,10)
sphere=free_sprite()
make_button(sphere,"sphere",50,20,154,10)
cone=free_sprite()
make_button(cone,"cone",50,20,206,10)
cylinder=free_sprite()
make_button(cylinder,"cylinder",50,20,258,10)

make matrix 1,100,100,20,20

ink 0,0

do

pick=pick_sprite(cube,cylinder)

gosub process_events

text 0,0,str$(pick)

sync
loop

function make_button(spritenumber,btext$,bwidth#,bheight#,bx,by)


create bitmap 1,screen width(),screen height()
for n#=0.0 to bheight#
grey#=(140*n#/bheight#)+100
ink rgb(grey#,grey#,grey#),0
line 0,n#,bwidth#,n#
next n#
for n#=2.0 to bheight#-2
grey#=(140-140*n#/bheight#)+100
ink rgb(grey#,grey#,grey#),0
line 2,n#,bwidth#-2,n#
next n#
ink rgb(205,205,255),0
set text font "arial"
set text size 14
text bwidth#/2.0-text width(btext$)/2,bheight#/2.0-text height(btext$)/2.0,btext$

get image spritenumber,0,0,bwidth#,bheight#,1
delete bitmap 1

sprite spritenumber,bx,by,spritenumber

endfunction

function free_sprite

repeat
inc n
until sprite exist(n)=0

endfunction n

function pick_sprite(lower,upper)

for spritenumber=lower to upper
if mousex()>=sprite x(spritenumber) and mousex()<=sprite x(spritenumber)+sprite width(spritenumber) and mousey()>=sprite y(spritenumber) and mousey()<=sprite y(spritenumber)+sprite height(spritenumber)
pick=spritenumber
if mouseclick()=1
  set sprite diffuse spritenumber,200,200,200
else
  set sprite diffuse spritenumber,255,255,255
endif
endif
next spritenumber

endfunction pick

process_events:

if pick>0 and mouseclick()=1 and mousedown=0
 selection=pick
 mousedown=1
else selection=0
endif

if mousedown=1 and mouseclick()=0 then mousedown=0


object=free_object()

if selection>0

if selection=cube then make object cube object,5
if selection=box_ then make object box object,7,5,3
if selection=sphere then make object sphere object,5,10,10
if selection=cone then make object cone object,5
if selection=cylinder then make object cylinder object,5

position object object,rnd(100),2.5,rnd(100)
color object object,rgb(rnd(255),rnd(255),rnd(255))

endif

return

function free_object

repeat
inc n
until object exist(n)=0

endfunction n