The DB Classic Programming Challenge Thread

Author

Message

29 games

18

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 28th Jul 2010 02:20

Link

Yep, this is still alive.

Sorry this has taken so long, I've been trying to learn some stuff for work and I had a stag party at the weekend where, among other things, we did ninja star and axe throwing. Which was a cool as it sounds.

Anyway, we have three entries and I think all of them have merit.

Sinani201:
OK, it didn't quite work and it wasn't finished but I feel you're getting close. I liked the layout (you were right about the colours and the font type) and I also liked the way that choosing the character class influenced the character's weapon choices, I thought this was a nice touch that gave the character another layer of depth.

I don't do any text based stuff so this one was really interesting for me.

Lucky 13:
First you get the bonus point because the character could be saved. Again you had a nice clean layout. I like the general approach you took, using arrow keys to do all the selecting. However, it still didn't work quite right as I think you might have missed read the code snippet I posted. You had:

+ Code Snippet

if up = 0
   up = 1
   if upkey() : dec sel : if sel < 1 then sel = 1 : endif
else
   if upkey() = 0 then up = 0
endif

Where it should have been:

+ Code Snippet

if up = 0
   up = 1
   if upkey() : dec sel : if sel < 1 then sel = 1 : endif
endif
if upkey() = 0 then up = 0

The "if upkey() = 0 then up = 0" bit is a line all by itself and does not go after an "else" statement.

I've re-jigged your code and you should see that it works more smoothly and more consistently

remstart
*******************************************************
*           DBC Programming Challenge                 *
*******************************************************
*           RPG Character Maker                       *
*******************************************************
*           "Sons of Anarchy Character Maker"         *
*******************************************************
*           By Lucky 13                               *
*******************************************************
*           Date Created: 13/07/2010                  *
*******************************************************
remend

rem Declare Arrays
dim stat$(10)
dim stats(11)
dim fact$(13)

rem Use setup() and reset() functions to initialise the data for the arrays
setup()
reset()

rem The main loop of the program
main_loop:
sel = 1
total = 10

do
cls
gosub control
draw(sel,total)
sync
loop

rem Control gosub
control:

rem Up key and down key range restricted to first and last options respectively
if up = 0
   up = 1
   if upkey() : dec sel : if sel < 1 then sel = 1 : endif
endif                         :`end the first if statement here.
if upkey() = 0 then up = 0    :`this line does not go after an "else" command. It's just a line on its own.

if down = 0
   down = 1
   if downkey() : inc sel : if sel > 12 then sel = 12 : endif
endif
if downkey() = 0 then down = 0

rem Right key will behave differently according to which option is currently selected.
if right = 0
   right = 1
   if rightkey()

rem If the option the user wants to change is a stat (sel > 2), the program will first check whether the
      rem total will exceed the maximum number of allowed points. If this is fine, the user can add
      rem points to that stat, if it isn't - they can't. The total number of points used by the user
      rem is constantly tracked to ensure the restrictions are adhered to.
      if sel > 2
         inc total
         if total > 30
            total = 30
         else
            stat = stats(sel - 2)
            inc stat
            if stat > 5 : stat = 5 : dec total : endif
            stats(sel - 2) = stat
         endif
      endif

rem If the selected option is #2 - "Faction" (sel = 2) then this will cycle through all of the factions.
      if sel = 2
         stat = stats(0)
         inc stat
         if stat > 12 then stat = 0
         stats(0) = stat
      endif
   endif
endif
if rightkey() = 0 then right = 0

rem Similar to right key, left key will behave differently according to which option is currently selected.
if left = 0
   left = 1
   if leftkey()

rem If the option is a stat option, the user will be able to decrease it as long as it is not less than 1.
      rem If changing the stat decreases it below 1 then it will be reset to 1 and the user will not be able to
      rem decrease its value. Total variable is tracked to ensure the user receives any points they decide to
      rem remove from a stat.
      if sel > 2
         if stats(sel - 2) = 1
            stats(sel - 2) = 1
         else
            stat = stats(sel - 2)
            dec stat
            if stat < 1 then stat = 1
            stats(sel - 2) = stat
            if total > 10 then dec total
         endif
      endif

rem If the user is amending the Faction stat, they can cycle through the factions in the opposite direction
      rem to the right key cycle.
      if sel = 2
         stat = stats(0)
         dec stat
         if stat < 0 then stat = 12
         stats(0) = stat
      endif
   endif
endif
if leftkey() = 0 then left = 0

rem Code for accepting input from the keyboard for amending the name. The code method I've used does depend on
rem the knowledge of scancodes. However, a quick search of the TGC Forum presents several resources for getting
rem these codes quickly.
rem The inital IF/THEN checks to see whether a key is being pressed
if scancode() > 0

rem The seconc IF/THEN checks whether the user has selected option 1 (sel = 1) so that the keyboard input will
   rem edit the string.
   if sel = 1

rem Adds the input to the existing string if the scancode is a letter.
      if scancode() > 15 and scancode() < 54 or scancode() > 1 and scancode() < 14
         if scancode() = 28 or scancode() = 42
            stat$(0) = stat$(0)
         else
            stat$(0) = stat$(0) + inkey$()

rem Checks to see whether the length of the name is longer than 32 characters and tapers accordingly.
            if len(stat$(0)) > 32 then stat$(0) = left$(stat$(0),32)
         endif
      endif

if scancode() = 57 then stat$(0) = stat$(0) + inkey$()

rem A check for input from the Backspace key for the deletion of characters
      if scancode() = 14

rem Providing the length of the string is greater than 1, it will remove the last character.
         if len(stat$(0)) > 0
            stat$(0) = left$(stat$(0),len(stat$(0)) - 1)
         endif
      endif
   endif
endif

rem Run the save routine if the return key is pressed and restart the program.
if returnkey() = 1
   if len(stat$(0)) > 0
      save()
      goto main_loop
   endif
endif

rem Run the end routine if the escape key is pressed.
if escapekey() = 1 then end
return

rem A function for setting up the program.
function setup()

rem System options
sync on
sync rate 30
disable escapekey

rem ** Creating the pips **
rem Clears the screen and ensures that red is the colour of choice.
cls
ink rgb(255,0,0),rgb(0,0,0)

rem A FOR/NEXT loop for creating the images we'll use for the sprites.
a = 0
for b = 1 to 45 step 11
   box b,1,b + 9,10
   inc a
   get image a,1,1,b + 9,10
next make

rem Reset the colour to black and white
ink rgb(255,255,255),rgb(0,0,0)

rem Sets the sprites to their correct positions and with the correct images.
cls
y = -18
for row = 1 to 10
   inc y,12
   sprite row,30,y,1
next row

rem Fill the arrays declared at the top of the program with the required data.
rem This first array defines the different names of the stats the user can amend.
stat$(1) = "Attack"
stat$(2) = "Defence"
stat$(3) = "Speed"
stat$(4) = "Strength"
stat$(5) = "Charisma"
stat$(6) = "Stealth"
stat$(7) = "Intelligence"
stat$(8) = "Weapons"
stat$(9) = "Motorcycle"
stat$(10) = "Mechanics"

rem The second array defines the factions that the user can be a member of.
fact$(0) = "Sons of Anarchy"
fact$(1) = "Mayans"
fact$(2) = "Cacuzza Family"
fact$(3) = "Lin Triad"
fact$(4) = "Russian Mafia"
fact$(5) = "League Of American Nationalists"
fact$(6) = "Nordics"
fact$(7) = "One-Niners"
fact$(8) = "Militia"
fact$(9) = "True IRA"
fact$(10) = "Charming Police Department"
fact$(11) = "ATF"
fact$(12) = "Townsperson"
fact$(13) = "Old Lady"
endfunction

rem A reset function.
function reset()

rem Reset the character Name to "Character".
stat$(0) = "Character"

rem Reset the stats all to 1.
for fill = 1 to 10
   stats(fill) = 1
next fill

rem Reset the Faction to "Townsperson"
stats(0) = 12
endfunction

rem A function to draw all of the information on screen.
function draw(sel,total)

rem A FOR/NEXT loop for drawing the sprites to screen according to the number stored in the stats array.
y = 49 : for pip = 1 to 10 : inc y,15 : sprite pip,90,y,stats(pip) : next pip

rem A series of IF/THEN statements that decides whether an arrow ("->") is printed next to the field names that
rem were defined in the stat$ array. If the option is not selected then no arrow is printed but spaces are placed
rem to ensure alignment.
if sel = 1 : set cursor 1,16 : print "-> Name (Max. 32): ";stat$(0) : else : set cursor 1,16 : print "    Name (Max. 32): ";stat$(0) : endif
if sel = 2 : set cursor 1,31 : print "-> Faction: ";fact$(stats(0)) : else : set cursor 1,31 : print "    Faction: ";fact$(stats(0)) : endif
if sel = 3 : set cursor 1,61 : print "-> ";stat$(1) : else : set cursor 1,61 : print "    ";stat$(1) : endif
if sel = 4 : set cursor 1,76 : print "-> ";stat$(2) : else : set cursor 1,76 : print "    ";stat$(2) : endif
if sel = 5 : set cursor 1,91 : print "-> ";stat$(3) : else : set cursor 1,91 : print "    ";stat$(3) : endif
if sel = 6 : set cursor 1,106 : print "-> ";stat$(4) : else : set cursor 1,106 : print "    ";stat$(4) : endif
if sel = 7 : set cursor 1,121 : print "-> ";stat$(5) : else : set cursor 1,121 : print "    ";stat$(5) : endif
if sel = 8 : set cursor 1,136 : print "-> ";stat$(6) : else : set cursor 1,136 : print "    ";stat$(6) : endif
if sel = 9 : set cursor 1,151 : print "-> ";stat$(7) : else : set cursor 1,151 : print "    ";stat$(7) : endif
if sel = 10 : set cursor 1,166 : print "-> ";stat$(8) : else : set cursor 1,166 : print "    ";stat$(8) : endif
if sel = 11 : set cursor 1,181 : print "-> ";stat$(9) : else : set cursor 1,181 : print "    ";stat$(9) : endif
if sel = 12 : set cursor 1,196 : print "-> ";stat$(10) : else : set cursor 1,196 : print "    ";stat$(10) : endif

rem a FOR/NEXT to print the total number of points allocated to each stat at the end of the each stat row.
y = 46 : for show = 1 to 10 : inc y,15 : set cursor sprite x(show) + 70,y : print "(";stats(show);")" : next show

rem Print commands for tracking total allocated points.
set cursor 1,226
print "Total Points Allocated (Max. 30): ";total

rem Print commands for informing user of control instructions.
set cursor 1,256
print "**  Control Instructions  **"
print "Up/Down Cursor Keys - Navigates between options."
print "Type name of character using keyboard."
print "Backspace Key - Deletes unwanted characters in Name field."
print "Right/Left Cursor Keys - Amends stat accordingly"
print "Enter Key - Export to CSV File"
print "Escape Key - End Program"
endfunction

rem A function for saving the data to file.
function save()

rem Checks to see whether the file exists and deletes it if so.
if file exist(stat$(0) + ".csv") = 1 then delete file stat$(0) + ".csv"

rem Routines for creating 2 lines for export to a CSV (comma seperated text file).
header$ = "Name"
data$ = stat$(0)
for save = 1 to 10
   header$ = header$ + ", " + stat$(save)
   data$ = data$ + ", " + str$(stats(save))
next save

rem Open to write the strings to a CSV.
open to write 1,stat$(0) + ".csv"
   write string 1,header$
   write string 1,data$
close file 1

rem Use the reset function to reset the stats to their defaults.
reset()
endfunction

+ Code Snippet

remstart
*******************************************************
*           DBC Programming Challenge                 *
*******************************************************
*           RPG Character Maker                       *
*******************************************************
*           "Sons of Anarchy Character Maker"         *
*******************************************************
*           By Lucky 13                               *
*******************************************************
*           Date Created: 13/07/2010                  *
*******************************************************
remend


rem Declare Arrays
dim stat$(10)
dim stats(11)
dim fact$(13)

rem Use setup() and reset() functions to initialise the data for the arrays
setup()
reset()

rem The main loop of the program
main_loop:
sel = 1
total = 10

do
cls
gosub control
draw(sel,total)
sync
loop

rem Control gosub
control:

rem Up key and down key range restricted to first and last options respectively
if up = 0
   up = 1
   if upkey() : dec sel : if sel < 1 then sel = 1 : endif
endif                         :`end the first if statement here.
if upkey() = 0 then up = 0    :`this line does not go after an "else" command. It's just a line on its own.

if down = 0
   down = 1
   if downkey() : inc sel : if sel > 12 then sel = 12 : endif
endif
if downkey() = 0 then down = 0


rem Right key will behave differently according to which option is currently selected.
if right = 0
   right = 1
   if rightkey()

      rem If the option the user wants to change is a stat (sel > 2), the program will first check whether the
      rem total will exceed the maximum number of allowed points. If this is fine, the user can add
      rem points to that stat, if it isn't - they can't. The total number of points used by the user
      rem is constantly tracked to ensure the restrictions are adhered to.
      if sel > 2
         inc total
         if total > 30
            total = 30
         else
            stat = stats(sel - 2)
            inc stat
            if stat > 5 : stat = 5 : dec total : endif
            stats(sel - 2) = stat
         endif
      endif

      rem If the selected option is #2 - "Faction" (sel = 2) then this will cycle through all of the factions.
      if sel = 2
         stat = stats(0)
         inc stat
         if stat > 12 then stat = 0
         stats(0) = stat
      endif
   endif
endif
if rightkey() = 0 then right = 0


rem Similar to right key, left key will behave differently according to which option is currently selected.
if left = 0
   left = 1
   if leftkey()

      rem If the option is a stat option, the user will be able to decrease it as long as it is not less than 1.
      rem If changing the stat decreases it below 1 then it will be reset to 1 and the user will not be able to
      rem decrease its value. Total variable is tracked to ensure the user receives any points they decide to
      rem remove from a stat.
      if sel > 2
         if stats(sel - 2) = 1
            stats(sel - 2) = 1
         else
            stat = stats(sel - 2)
            dec stat
            if stat < 1 then stat = 1
            stats(sel - 2) = stat
            if total > 10 then dec total
         endif
      endif

      rem If the user is amending the Faction stat, they can cycle through the factions in the opposite direction
      rem to the right key cycle.
      if sel = 2
         stat = stats(0)
         dec stat
         if stat < 0 then stat = 12
         stats(0) = stat
      endif
   endif
endif
if leftkey() = 0 then left = 0


rem Code for accepting input from the keyboard for amending the name. The code method I've used does depend on
rem the knowledge of scancodes. However, a quick search of the TGC Forum presents several resources for getting
rem these codes quickly.
rem The inital IF/THEN checks to see whether a key is being pressed
if scancode() > 0

   rem The seconc IF/THEN checks whether the user has selected option 1 (sel = 1) so that the keyboard input will
   rem edit the string.
   if sel = 1

      rem Adds the input to the existing string if the scancode is a letter.
      if scancode() > 15 and scancode() < 54 or scancode() > 1 and scancode() < 14
         if scancode() = 28 or scancode() = 42
            stat$(0) = stat$(0)
         else
            stat$(0) = stat$(0) + inkey$()

            rem Checks to see whether the length of the name is longer than 32 characters and tapers accordingly.
            if len(stat$(0)) > 32 then stat$(0) = left$(stat$(0),32)
         endif
      endif

      if scancode() = 57 then stat$(0) = stat$(0) + inkey$()

      rem A check for input from the Backspace key for the deletion of characters
      if scancode() = 14

         rem Providing the length of the string is greater than 1, it will remove the last character.
         if len(stat$(0)) > 0
            stat$(0) = left$(stat$(0),len(stat$(0)) - 1)
         endif
      endif
   endif
endif

rem Run the save routine if the return key is pressed and restart the program.
if returnkey() = 1
   if len(stat$(0)) > 0
      save()
      goto main_loop
   endif
endif

rem Run the end routine if the escape key is pressed.
if escapekey() = 1 then end
return

rem A function for setting up the program.
function setup()

rem System options
sync on
sync rate 30
disable escapekey

rem ** Creating the pips **
rem Clears the screen and ensures that red is the colour of choice.
cls
ink rgb(255,0,0),rgb(0,0,0)

rem A FOR/NEXT loop for creating the images we'll use for the sprites.
a = 0
for b = 1 to 45 step 11
   box b,1,b + 9,10
   inc a
   get image a,1,1,b + 9,10
next make

rem Reset the colour to black and white
ink rgb(255,255,255),rgb(0,0,0)

rem Sets the sprites to their correct positions and with the correct images.
cls
y = -18
for row = 1 to 10
   inc y,12
   sprite row,30,y,1
next row

rem Fill the arrays declared at the top of the program with the required data.
rem This first array defines the different names of the stats the user can amend.
stat$(1) = "Attack"
stat$(2) = "Defence"
stat$(3) = "Speed"
stat$(4) = "Strength"
stat$(5) = "Charisma"
stat$(6) = "Stealth"
stat$(7) = "Intelligence"
stat$(8) = "Weapons"
stat$(9) = "Motorcycle"
stat$(10) = "Mechanics"

rem The second array defines the factions that the user can be a member of.
fact$(0) = "Sons of Anarchy"
fact$(1) = "Mayans"
fact$(2) = "Cacuzza Family"
fact$(3) = "Lin Triad"
fact$(4) = "Russian Mafia"
fact$(5) = "League Of American Nationalists"
fact$(6) = "Nordics"
fact$(7) = "One-Niners"
fact$(8) = "Militia"
fact$(9) = "True IRA"
fact$(10) = "Charming Police Department"
fact$(11) = "ATF"
fact$(12) = "Townsperson"
fact$(13) = "Old Lady"
endfunction

rem A reset function.
function reset()

rem Reset the character Name to "Character".
stat$(0) = "Character"

rem Reset the stats all to 1.
for fill = 1 to 10
   stats(fill) = 1
next fill

rem Reset the Faction to "Townsperson"
stats(0) = 12
endfunction

rem A function to draw all of the information on screen.
function draw(sel,total)

rem A FOR/NEXT loop for drawing the sprites to screen according to the number stored in the stats array.
y = 49 : for pip = 1 to 10 : inc y,15 : sprite pip,90,y,stats(pip) : next pip

rem A series of IF/THEN statements that decides whether an arrow ("->") is printed next to the field names that
rem were defined in the stat$ array. If the option is not selected then no arrow is printed but spaces are placed
rem to ensure alignment.
if sel = 1 : set cursor 1,16 : print "-> Name (Max. 32): ";stat$(0) : else : set cursor 1,16 : print "    Name (Max. 32): ";stat$(0) : endif
if sel = 2 : set cursor 1,31 : print "-> Faction: ";fact$(stats(0)) : else : set cursor 1,31 : print "    Faction: ";fact$(stats(0)) : endif
if sel = 3 : set cursor 1,61 : print "-> ";stat$(1) : else : set cursor 1,61 : print "    ";stat$(1) : endif
if sel = 4 : set cursor 1,76 : print "-> ";stat$(2) : else : set cursor 1,76 : print "    ";stat$(2) : endif
if sel = 5 : set cursor 1,91 : print "-> ";stat$(3) : else : set cursor 1,91 : print "    ";stat$(3) : endif
if sel = 6 : set cursor 1,106 : print "-> ";stat$(4) : else : set cursor 1,106 : print "    ";stat$(4) : endif
if sel = 7 : set cursor 1,121 : print "-> ";stat$(5) : else : set cursor 1,121 : print "    ";stat$(5) : endif
if sel = 8 : set cursor 1,136 : print "-> ";stat$(6) : else : set cursor 1,136 : print "    ";stat$(6) : endif
if sel = 9 : set cursor 1,151 : print "-> ";stat$(7) : else : set cursor 1,151 : print "    ";stat$(7) : endif
if sel = 10 : set cursor 1,166 : print "-> ";stat$(8) : else : set cursor 1,166 : print "    ";stat$(8) : endif
if sel = 11 : set cursor 1,181 : print "-> ";stat$(9) : else : set cursor 1,181 : print "    ";stat$(9) : endif
if sel = 12 : set cursor 1,196 : print "-> ";stat$(10) : else : set cursor 1,196 : print "    ";stat$(10) : endif

rem a FOR/NEXT to print the total number of points allocated to each stat at the end of the each stat row.
y = 46 : for show = 1 to 10 : inc y,15 : set cursor sprite x(show) + 70,y : print "(";stats(show);")" : next show

rem Print commands for tracking total allocated points.
set cursor 1,226
print "Total Points Allocated (Max. 30): ";total

rem Print commands for informing user of control instructions.
set cursor 1,256
print "**  Control Instructions  **"
print "Up/Down Cursor Keys - Navigates between options."
print "Type name of character using keyboard."
print "Backspace Key - Deletes unwanted characters in Name field."
print "Right/Left Cursor Keys - Amends stat accordingly"
print "Enter Key - Export to CSV File"
print "Escape Key - End Program"
endfunction

rem A function for saving the data to file.
function save()

rem Checks to see whether the file exists and deletes it if so.
if file exist(stat$(0) + ".csv") = 1 then delete file stat$(0) + ".csv"

rem Routines for creating 2 lines for export to a CSV (comma seperated text file).
header$ = "Name"
data$ = stat$(0)
for save = 1 to 10
   header$ = header$ + ", " + stat$(save)
   data$ = data$ + ", " + str$(stats(save))
next save

rem Open to write the strings to a CSV.
open to write 1,stat$(0) + ".csv"
   write string 1,header$
   write string 1,data$
close file 1

rem Use the reset function to reset the stats to their defaults.
reset()
endfunction

Latch:
Very nice looking entry. However, if I set the character endurance to 1 they end up with no hitpoints (same is true for wisdom and magic points) which I'm guessing would mean they would be dead before they started. There was also no character class / profession.

Now comes the tricky bit, I've got to decide who's won.

Winner:

+ Code Snippet

Lucky 13

Mainly because there was a good number of professions and skills to choose from, making for a deeper character
and it was depth of character which I originally put down as my main scoring criteria.

Back to top

Profile PM Email

Lucky 13

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 28th Jul 2010 13:27

Link

Awesome!

I never win stuff!

Yes, I re-read your original suggestion and your revised code is definitely smoother than what I'd put in. I foolishly assumed that putting the code after an "else" would garner the same result. Thanks 29 steps.

Next challenge will be up soon.

Back to top

Profile PM

Libervurto

17

Years of Service

User Offline

Joined: 30th Jun 2006

Location: On Toast

Posted: 28th Jul 2010 16:44 Edited at: 28th Jul 2010 16:45

Link

Quote: "I've had a quick read through the rules and didn't catch anything about any requirements for an entry's code to have remarks. I just wondered whether people prefer to have them or not? Cheers."

If you didn't used to use remarks open one of your old programs and see how long it takes you to work out what it does. That will answer your question

I think you can tell more about someone's experience from their remarks than their actual code.

I can't enter any challenges as I'm still without windows

At least I have my calculator for making games on

Back to top

Profile PM Email

Lucky 13

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 2nd Aug 2010 22:37 Edited at: 2nd Aug 2010 22:38

Link

Quote: "I think you can tell more about someone's experience from their remarks than their actual code."

And what do my remarks tell you about me?

Sorry, guys. Been very busy but I think I have an original challenge for you.

Right, here goes.

** NEW CHALLENGE **
Name: Curling
Main Challenge: Attempt to create a small game based on the sport of Curling.
Main Marking Points: Physics is the big marking point here but anyone who can strike the right balance of simulation and fun will take the prize.

Bonus Challenge: If you find the main challenge too easy, extra marks are up for grabs to - (A) the most attractive looking program and (B) anyone who can take the basic principles and put a spin on it. For example, inserting power-ups into the picture.

Deadline - 22nd of August 2010

Good luck, guys.

Back to top

Profile PM

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 3rd Aug 2010 20:52

Link

This might be a bit tough for many. It's rare that complete sims/programs/games get any entries in these challenges.

Enjoy your day.

Back to top

Profile PM

Lucky 13

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 3rd Aug 2010 22:30

Link

Ok, I'll tweak it: -

** REVISED CHALLENGE **
Name: Ice Physics
Main Challenge: Attempt to either accurately simulate or give the illusion of ice physics.
Main Marking Points: Whether it's a hockey puck, a curling stone, a human being, an avatar - it doesn't matter. The person who can impress with their ability to create something that slides across screen, within a rink or similar in a realistic way will get the nod.

Bonus Marks: Anyone who can add any extra fun elements, (possibly a mini-game?), will get bonus points.

Deadline - 22nd of August 2010

Hope this challenge is better and more reasonable.

Back to top

Profile PM

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 4th Aug 2010 00:57 Edited at: 4th Aug 2010 00:57

Link

Hmm, does this remind anyone else of the first DBC contest?

I like the challenge though.

"Any sufficiently advanced technology is indistinguishable from magic" ~ Arthur C. Clarke

Back to top

Profile PM Email Website

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 6th Aug 2010 00:47

Link

And Congratulations lucky 13!

@Phaelax
I was in diapers back then. Exactly, how OLD are you? Just kidding!

- but I think the first actual DBC contest might have been before I even knew about DBC. What was the contest?

Enjoy your day.

Back to top

Profile PM

Sinani201

17

Years of Service

User Offline

Joined: 16th Apr 2007

Location: Aperture Science Enrichment Center

Posted: 6th Aug 2010 08:11

Link

It was a contest to make a cool-looking clock (you could have just gone to the first page to check what it was). I'm not sure what ice has to do with that. I don't think he meant to post in the DBP challenge thread because the challenge over there is to make a GUI...

Back to top

Profile PM

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 6th Aug 2010 11:41

Link

I didn't think he meant the challenges, I thought he meant an actual DBC community contest.

Enjoy your day.

Back to top

Profile PM

Lucky 13

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 6th Aug 2010 21:19

Link

Cheers, Latch.

Well, I definitely haven't looked elsewhere for inspiration. If it is similar, it's purely by coincidence.

Besides, is anyone thinking about entering?

Back to top

Profile PM

pictionaryjr

15

Years of Service

User Offline

Joined: 12th Mar 2009

Location:

Posted: 6th Aug 2010 23:39

Link

i can prolly whip up a quick entry. shouldn't be too hard

TEAM REQUEST FORUMS

Back to top

Profile PM Email

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 11th Aug 2010 03:14

Link

The first contest as I recall was some kind of skiing contest or something. Most entries were about sledding or snow boarding.

Latch, I thought you were close to my age. I still have a few years left before 30 hits me in the face.

"Any sufficiently advanced technology is indistinguishable from magic" ~ Arthur C. Clarke

Back to top

Profile PM Email Website

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 11th Aug 2010 03:37

Link

Quote: "Latch, I thought you were close to my age. I still have a few years left before 30 hits me in the face."

I was kidding around.

I was looking for the showcase page when you mentioned the contest because that used to have the contest entries posted for the early DBC challenges - but, no showcase page any more...

Enjoy your day.

Back to top

Profile PM

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 21st Aug 2010 21:10

Link

No ice sliding entries? I'm behind in a few things but it may be possible to still get something in - eventually...

Enjoy your day.

Back to top

Profile PM

Lucky 13

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 22nd Aug 2010 20:53 Edited at: 22nd Aug 2010 20:56

Link

Oh, no entries...

Is it worth extending the deadline?

Back to top

Profile PM

Sinani201

17

Years of Service

User Offline

Joined: 16th Apr 2007

Location: Aperture Science Enrichment Center

Posted: 23rd Aug 2010 07:22

Link

My new PC is coming in 3 days. I might be able to cook up something by then, but it might take a while...

Look at your sig. Now look at mine. Now look at your sig. Now look at mine. Now look at your sig. Now BACK TO MINE.

Back to top

Profile PM

29 games

18

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 23rd Aug 2010 19:19

Link

If you extend the deadline a week, I might be able to do something.

Back to top

Profile PM Email

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 24th Aug 2010 03:04

Link

Here's the start of an entry. Use the arrows keys to slide the box around.

remstart
   ==============================================================
   =  Title  : sliding object
   =  Author : latch
   =  Date   : 08/23/2010
   =  Update :
   =  Version: .01
   ==============================================================
   Comments    Sliding object.  Use arrow keys to move.  The longer
               you hold the key the faster the object moves.
               Let go of the key the object will slide.
   ==============================================================
remend

rem =============================================================
rem = SET UP DISPLAY
rem =============================================================
   autocam off
   set display mode 800,600,32
   sync on
   sync rate 60
   hide mouse

rem =============================================================
rem = MAIN
rem =============================================================
_main:
   gosub _init
   do
      gosub _move_object

sync
   loop

end

rem =============================================================
rem = SUBROUTINES - PROCEDURES
rem =============================================================
   _init:
      rem make a matrix for reference
      make matrix 1,5000,5000,25,25

rem make an object to slide around
      make object cube 1,25
      position object 1,2500,13,2500

rem position camera
      position camera 2500,200,2500
      xrotate camera 90

return

rem =============================================================
rem = FUNCTIONS
rem =============================================================
   _move_object:
      rem use arrow keys to move object around
      lrspeed#=curvevalue((rightkey()-leftkey())*20.0,lrspeed#,100)
      udspeed#=curvevalue((upkey()-downkey())*20.0,udspeed#,100)

rem reposition object
      position object 1,object position x(1)+lrspeed#,object position y(1),object position z(1)+udspeed#

rem have camera follow
      position camera object position x(1),200,object position z(1)
   return

rem =============================================================
rem = DATA STATEMENTS
rem =============================================================

+ Code Snippet

remstart
   ==============================================================
   =  Title  : sliding object
   =  Author : latch
   =  Date   : 08/23/2010
   =  Update :
   =  Version: .01
   ==============================================================
   Comments    Sliding object.  Use arrow keys to move.  The longer
               you hold the key the faster the object moves.
               Let go of the key the object will slide.
   ==============================================================
remend

rem =============================================================
rem = SET UP DISPLAY
rem =============================================================
   autocam off
   set display mode 800,600,32
   sync on
   sync rate 60
   hide mouse

rem =============================================================
rem = MAIN
rem =============================================================
_main:
   gosub _init
   do
      gosub _move_object

      sync
   loop

   end

rem =============================================================
rem = SUBROUTINES - PROCEDURES
rem =============================================================
   _init:
      rem make a matrix for reference
      make matrix 1,5000,5000,25,25

      rem make an object to slide around
      make object cube 1,25
      position object 1,2500,13,2500

      rem position camera
      position camera 2500,200,2500
      xrotate camera 90

   return


rem =============================================================
rem = FUNCTIONS
rem =============================================================
   _move_object:
      rem use arrow keys to move object around
      lrspeed#=curvevalue((rightkey()-leftkey())*20.0,lrspeed#,100)
      udspeed#=curvevalue((upkey()-downkey())*20.0,udspeed#,100)

      rem reposition object
      position object 1,object position x(1)+lrspeed#,object position y(1),object position z(1)+udspeed#

      rem have camera follow
      position camera object position x(1),200,object position z(1)
   return



rem =============================================================
rem = DATA STATEMENTS
rem =============================================================

Enjoy your day.

Back to top

Profile PM

TheComet

16

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 27th Aug 2010 15:20

Link

I thought the first challenge was a wacky alarm clock challenge?

Anyway, I might make something too

I have a little time this weekend. And don't worry, it usually takes about 2-3 weeks before anything pops up in code snippets here.

TheComet

Back to top

Profile PM Email Website

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 9th Sep 2010 17:07

Link

Let's have some ice...

This needs a bit of work. No real physics here, just using the built in curvevalue function. Move the blue puck around with the mouse and hit the red puck.

remstart
   ==============================================================
   =  Title  : pucks
   =  Author : latch
   =  Date   : 09/09/2010
   =  Update :
   =  Version: .01
   ==============================================================
   Comments    Rem move blue puck to collide with red puck
   ==============================================================
remend

rem =============================================================
rem = SET UP DISPLAY
rem =============================================================
   autocam off
   set display mode 800,600,32
   sync on
   sync rate 60

rem =============================================================
rem = MAIN
rem =============================================================
_main:
   gosub _init

do
      gosub _control_blue_puck
      gosub _check_for_collision

sync
   loop

end

rem =============================================================
rem = SUBROUTINES - PROCEDURES
rem =============================================================
   _init:
      rem make pucks
      gosub _make_puck

rem get the center of sprites
      sp2cx=sprite width(2)/2
      sp2cy=sprite height(2)/2
      sp1cx=sprite width(1)/2
      sp1cy=sprite height(1)/2
   return
`================================================================
   _make_puck:
      rem red puck
      ink rgb(255,0,32),0
      for r=0 to 31
         circle 31,31,r
         circle 32,31,r
      next r
      get image 1,0,0,64,64
      sync
      sprite 1,10,10,1

cls

rem blue puck
      ink 255,0
      for r=0 to 31
         circle 31,31,r
         circle 32,31,r
      next r
      get image 2,0,0,64,64
      sync
      sprite 2,mousex(),mousey(),2
      cls
   return
`================================================================
   _control_blue_puck:
      rem get center of sprite 2
      mx=mousex() : my=mousey()
      sp2x=mx-sp2cx
      sp2y=my-sp2cy

rem position the sprite where the mouse is
      sprite 2,sp2x,sp2y,2
   return
`================================================================
   _check_for_collision:
      rem calculate the direciton blue is moving
      mmx=mousemovex()
      mmy=mousemovey()
      `ang#=atanfull(mmy,mmx)

rem has blue hit red?
      if sprite hit(2,1)
         xspeed#=mmx
         yspeed#=mmy
      endif

rem figure out position  of red sprite
      xspeed#=curvevalue(0,xspeed#,60)
      yspeed#=curvevalue(0,yspeed#,70)

rem fine tune the floats
      if abs(xspeed#) < .6 then xspeed#=0
      if abs(yspeed#) < .6 then yspeed#=0

posx=sprite x(1) + xspeed#
      posy=sprite y(1) + yspeed#

rem reverse direction if hitting a wall
      if posx <= 0
         posx=0
         xspeed#=0-xspeed#
      endif
      if posx >= (screen width()-sprite width(1))
         posx = (screen width()-sprite width(1))
         xspeed#=0-xspeed#
      endif
      if posy <= 0
         posy = 0
         yspeed#=0-yspeed#
      endif
      if posy >= (screen height()-sprite height(1))
         posy = (screen height()-sprite height(1))
         yspeed#=0-yspeed#
      endif

rem place sprite at new location
      sprite 1,posx,posy,1

return

+ Code Snippet

remstart
   ==============================================================
   =  Title  : pucks
   =  Author : latch
   =  Date   : 09/09/2010
   =  Update :
   =  Version: .01
   ==============================================================
   Comments    Rem move blue puck to collide with red puck
   ==============================================================
remend

rem =============================================================
rem = SET UP DISPLAY
rem =============================================================
   autocam off
   set display mode 800,600,32
   sync on
   sync rate 60

rem =============================================================
rem = MAIN
rem =============================================================
_main:
   gosub _init

   do
      gosub _control_blue_puck
      gosub _check_for_collision

      sync
   loop

   end

rem =============================================================
rem = SUBROUTINES - PROCEDURES
rem =============================================================
   _init:
      rem make pucks
      gosub _make_puck

      rem get the center of sprites
      sp2cx=sprite width(2)/2
      sp2cy=sprite height(2)/2
      sp1cx=sprite width(1)/2
      sp1cy=sprite height(1)/2
   return
`================================================================
   _make_puck:
      rem red puck
      ink rgb(255,0,32),0
      for r=0 to 31
         circle 31,31,r
         circle 32,31,r
      next r
      get image 1,0,0,64,64
      sync
      sprite 1,10,10,1

      cls

      rem blue puck
      ink 255,0
      for r=0 to 31
         circle 31,31,r
         circle 32,31,r
      next r
      get image 2,0,0,64,64
      sync
      sprite 2,mousex(),mousey(),2
      cls
   return
`================================================================
   _control_blue_puck:
      rem get center of sprite 2
      mx=mousex() : my=mousey()
      sp2x=mx-sp2cx
      sp2y=my-sp2cy

      rem position the sprite where the mouse is
      sprite 2,sp2x,sp2y,2
   return
`================================================================
   _check_for_collision:
      rem calculate the direciton blue is moving
      mmx=mousemovex()
      mmy=mousemovey()
      `ang#=atanfull(mmy,mmx)

      rem has blue hit red?
      if sprite hit(2,1)
         xspeed#=mmx
         yspeed#=mmy
      endif

      rem figure out position  of red sprite
      xspeed#=curvevalue(0,xspeed#,60)
      yspeed#=curvevalue(0,yspeed#,70)

      rem fine tune the floats
      if abs(xspeed#) < .6 then xspeed#=0
      if abs(yspeed#) < .6 then yspeed#=0

      posx=sprite x(1) + xspeed#
      posy=sprite y(1) + yspeed#

      rem reverse direction if hitting a wall
      if posx <= 0
         posx=0
         xspeed#=0-xspeed#
      endif
      if posx >= (screen width()-sprite width(1))
         posx = (screen width()-sprite width(1))
         xspeed#=0-xspeed#
      endif
      if posy <= 0
         posy = 0
         yspeed#=0-yspeed#
      endif
      if posy >= (screen height()-sprite height(1))
         posy = (screen height()-sprite height(1))
         yspeed#=0-yspeed#
      endif

      rem place sprite at new location
      sprite 1,posx,posy,1

   return

Enjoy your day.

Back to top

Profile PM

29 games

18

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 14th Sep 2010 00:42

Link

That's pretty cool, Latch. Bad pun, I know but it's getting close to my bed time.

I had a go at doing a curling demo. The code's a bit of a mess but here it is anyway.

`curling demo
`29 Games
`13 Sept 2010

`Press space bar to start and the stone will move foward on its own
`Position sweeper (the green box) using mouse, press LMB and move mouse left and right in a "sweeping" motion.
`If the stone goes over the markers dropped then the friction will be
`reduce and the stone will curl toward the marker.

`x and z position of sweeper maker
dim marker#(1000,2)

`general set up
sync on
sync rate 65
hide mouse
set camera range 1, 3000
randomize timer()
cls

`constants
mid = screen width()/2
radius# = 20.0
max_xbrush# = 20

`make rink
make matrix 1, 100,2000,2,10
position matrix 1, -50,0,0

`make curling stone
make object cylinder 1, radius#*2
scale object 1,100,25,100
ghost object on 1

`make bush
make object box 2, 10,10,10
color object 2, rgb(0,250,0)

`make sweeper marker
make object cylinder 3, 5
scale object 3,100,10,100
color object 3, rgb(100,100,250)

`starting values
start = 0

spd# = 3.0                          :`initial speed of stone
repeat
   ang_mod# = rnd(12)/3.0           :`initial direction of stone's movement
until ang_mod# <> 3
ang# = wrapvalue(358 + ang_mod#)

`main loop
do

if spacekey() = 1 then start = 1

if start = 1
      `set value for friction
      friction# = 0.004

`controls to position brush
      xbrush# = xbrush# + mousemovex()/2
      if xbrush# < max_xbrush#*-1 then xbrush# = max_xbrush#*-1
      if xbrush# > max_xbrush# then xbrush# = max_xbrush#

`controls for sweeping brush
      sweep = abs( mousemovex() )
      if mouseclick() = 1
         if sweep > 1
            `colour the brush red
            color object 2, rgb(250,0,0)
            `drop marker
            make static object 3
            count = count + 1
            marker#(count,1) = xstone#+xbrush#
            marker#(count,2) = zstone#+50
         else
            color object 2, rgb(0,250,0)
         endif
      endif

`the marker
      for i = 1 to count
         if marker#(i,2) > zstone#
            `caculate distance between stone and marker
            distance# = sqrt( (marker#(i,1)-xstone#)^2 + (marker#(i,2)-zstone#)^2 )

`if marker is close enough to stone then reduce friction and curl stone toward marker
            if distance# < radius#
               friction# = friction# - 0.0007
               if friction# < 0.001 then friction# = 0.001
               if marker#(i,1) - xstone# > 0.0 then ang# = ang# + 0.01 else ang# = ang# - 0.01
            endif
         endif
      next i

`calculate speed of stone
      spd# = spd# - friction#
      if spd# <= 0.0 then spd# = 0.0

`calculate x and z velocities of stone
      zvel# = spd#*cos(ang#)
      xvel# = spd#*sin(ang#)

`calculate new position
      if spd# <> 0.0
         zstone# = zstone# + zvel#
         xstone# = xstone# + xvel#
      endif
   endif

`position stone, brush and camera
   position object 1, xstone#, 5, zstone#
   position object 2, xstone#+xbrush#, 5, zstone#+50
   position object 3, xstone#+xbrush#, 0, zstone#+50
   position camera xstone#, 50, zstone# - 100
   point camera xstone#, 0, zstone# + 10

`print stuff
   set cursor 0,0
   print "Press space bar to start and the stone will move foward on its own."
   print "Position sweeper (the green box) using mouse, press LMB and move mouse left and right"
   print "in a rapind 'sweeping' motion. This will then drop markers on the rink."
   print "If the stone goes over the markers then the friction will be reduce and the"
   print "stone will curl toward the marker."
   print
   print "distance stone has moved = ", zstone#
   print "distance stone is from centre line = ", xstone#

sync

loop

end

+ Code Snippet

`curling demo
`29 Games
`13 Sept 2010

`Press space bar to start and the stone will move foward on its own
`Position sweeper (the green box) using mouse, press LMB and move mouse left and right in a "sweeping" motion.
`If the stone goes over the markers dropped then the friction will be
`reduce and the stone will curl toward the marker.



`x and z position of sweeper maker
dim marker#(1000,2)

`general set up
sync on
sync rate 65
hide mouse
set camera range 1, 3000
randomize timer()
cls


`constants
mid = screen width()/2
radius# = 20.0
max_xbrush# = 20

`make rink
make matrix 1, 100,2000,2,10
position matrix 1, -50,0,0

`make curling stone
make object cylinder 1, radius#*2
scale object 1,100,25,100
ghost object on 1

`make bush
make object box 2, 10,10,10
color object 2, rgb(0,250,0)

`make sweeper marker
make object cylinder 3, 5
scale object 3,100,10,100
color object 3, rgb(100,100,250)

`starting values
start = 0

spd# = 3.0                          :`initial speed of stone
repeat
   ang_mod# = rnd(12)/3.0           :`initial direction of stone's movement
until ang_mod# <> 3
ang# = wrapvalue(358 + ang_mod#)




`main loop
do

   if spacekey() = 1 then start = 1

   if start = 1
      `set value for friction
      friction# = 0.004

      `controls to position brush
      xbrush# = xbrush# + mousemovex()/2
      if xbrush# < max_xbrush#*-1 then xbrush# = max_xbrush#*-1
      if xbrush# > max_xbrush# then xbrush# = max_xbrush#

      `controls for sweeping brush
      sweep = abs( mousemovex() )
      if mouseclick() = 1
         if sweep > 1
            `colour the brush red
            color object 2, rgb(250,0,0)
            `drop marker
            make static object 3
            count = count + 1
            marker#(count,1) = xstone#+xbrush#
            marker#(count,2) = zstone#+50
         else
            color object 2, rgb(0,250,0)
         endif
      endif

      `the marker
      for i = 1 to count
         if marker#(i,2) > zstone#
            `caculate distance between stone and marker
            distance# = sqrt( (marker#(i,1)-xstone#)^2 + (marker#(i,2)-zstone#)^2 )

            `if marker is close enough to stone then reduce friction and curl stone toward marker
            if distance# < radius#
               friction# = friction# - 0.0007
               if friction# < 0.001 then friction# = 0.001
               if marker#(i,1) - xstone# > 0.0 then ang# = ang# + 0.01 else ang# = ang# - 0.01
            endif
         endif
      next i

      `calculate speed of stone
      spd# = spd# - friction#
      if spd# <= 0.0 then spd# = 0.0

      `calculate x and z velocities of stone
      zvel# = spd#*cos(ang#)
      xvel# = spd#*sin(ang#)

      `calculate new position
      if spd# <> 0.0
         zstone# = zstone# + zvel#
         xstone# = xstone# + xvel#
      endif
   endif

   `position stone, brush and camera
   position object 1, xstone#, 5, zstone#
   position object 2, xstone#+xbrush#, 5, zstone#+50
   position object 3, xstone#+xbrush#, 0, zstone#+50
   position camera xstone#, 50, zstone# - 100
   point camera xstone#, 0, zstone# + 10

   `print stuff
   set cursor 0,0
   print "Press space bar to start and the stone will move foward on its own."
   print "Position sweeper (the green box) using mouse, press LMB and move mouse left and right"
   print "in a rapind 'sweeping' motion. This will then drop markers on the rink."
   print "If the stone goes over the markers then the friction will be reduce and the"
   print "stone will curl toward the marker."
   print
   print "distance stone has moved = ", zstone#
   print "distance stone is from centre line = ", xstone#

   sync

loop

end

Happy curling.

Back to top

Profile PM Email

Libervurto

17

Years of Service

User Offline

Joined: 30th Jun 2006

Location: On Toast

Posted: 20th Sep 2010 19:33

Link

Sorry to butt in but I just had a good idea for a challenge.

AI Leaper
Make an AI character that can move along a platform and jump over randomly placed gaps. You cannot store the location of the gaps, they must be sensed by the AI.

Back to top

Profile PM Email

Sinani201

17

Years of Service

User Offline

Joined: 16th Apr 2007

Location: Aperture Science Enrichment Center

Posted: 21st Sep 2010 07:43

Link

I really like that idea... I'm in.

Look at your sig. Now look at mine. Now look at your sig. Now look at mine. Now look at your sig. Now BACK TO MINE.

Back to top

Profile PM

pictionaryjr

15

Years of Service

User Offline

Joined: 12th Mar 2009

Location:

Posted: 28th Sep 2010 05:00

Link

here's the simplest way i could think to do it

+ Code Snippet

sync on : sync rate 0 : cls
dim plat(64)
for p=0 to 64 : plat(p)=1 : next p
y=470
do
inc count
if count=2
   for p=0 to 63
    plat(p)=plat(p+1)
   next p
   if rnd(3)=0
      plat(64)=0
   else
      plat(64)=1
   endif
   count=0
endif
ink rgb(0,255,0),0
for p=0 to 63
   if plat(p)=1 then box p*10,474,(p*10)+9,479
next p
ink rgb(0,0,255),0
circle 15,y,4
if point(25,477)=0
   y=460
else
   y=470
endif
cls
loop

TEAM REQUEST FORUMS

Back to top

Profile PM Email

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 16th Oct 2010 05:20

Link

Not bad pictionary jr.

Enjoy your day.

Back to top

Profile PM

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 19th Nov 2010 22:16

Link

Here's another attempt at resurrecting the challenges.

How about a 3D demo of some kind?

The goal is to create a 3D scene of any kind. You can use outside media as well. The media doesn't have to be programatically or procedurally generated. You can use sound, music, 3D models, anything.

Keep it short, keep the file size down. The total media cannot exceed 4 megabytes.

The scene can be anything you like. It should not be a game. There should be some kind of camera work. Try and use any effects you can think of: fade in and out, fog, particles, anything.

The scene/demo must be run from DBC code. You cannot render the whole scene in a 3d app such as Blender, 3dsmax, anim8or, etc. and just play a movie.

You can make a demo of a logo where you have 3d text appear on the screen. You could do a scene of a landscape with the camera moving around. You could have the perspective of a plane flying through the clouds. You could have an animal walking around or eating or doing other animal things. Anything your imagination can come up with. It could be a fake cut scene for the next blockbuster game.

Does this seem interesting to anyone?

Enjoy your day.

Back to top

Profile PM

Phaelax

DBPro Master

21

Years of Service

User Offline

Joined: 16th Apr 2003

Location: Metropia

Posted: 23rd Nov 2010 00:22

Link

Even the Pro board is having trouble keeping the challenge thread alive.

"Only the educated are free" ~Epictetus
"Imagination is more important than knowledge..." ~Einstein

Back to top

Profile PM Email Website

29 games

18

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 29th Nov 2010 23:19

Link

Yes, the challenges on both boards do seem to have died a little bit.

I'll see if I can come up with something. Probably won't use external media though.

Back to top

Profile PM Email

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 3rd Dec 2010 22:22

Link

cool. It'd be interesting if others joined in and came up with some ideas for title screens, or camera drive bys etc.

Enjoy your day.

Back to top

Profile PM

TheComet

16

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 4th Dec 2010 02:56

Link

Maybe do something with effects? Make the coolest effect, this can be 2D or 3D, explosions/fire/swirl/smoke/distortion etc...

TheComet

Back to top

Profile PM Email Website

Ashingda 27

16

Years of Service

User Offline

Joined: 15th Feb 2008

Location:

Posted: 4th Dec 2010 03:47 Edited at: 4th Dec 2010 03:49

Link

Maybe people may not be as interested in the challenges because they don't see themselves exercising it in the near future.

There were a few challenges a while back that really caught my attention because it was something I thought was fun or found useful, something I'll most likely be using now, soon, or in the future. Something like an HP bar that shows Current HP / Max HP and a bar that properly displays the HP amount is an example.

Attachments

Login to view attachments

Back to top

Profile PM Email

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 5th Dec 2010 01:18

Link

Quote: "Maybe do something with effects? Make the coolest effect, this can be 2D or 3D, explosions/fire/swirl/smoke/distortion etc."

Sounds good to me!

Quote: "Maybe people may not be as interested in the challenges because they don't see themselves exercising it in the near future."

Is that why you're not interested in the challenges?

Enjoy your day.

Back to top

Profile PM

Ashingda 27

16

Years of Service

User Offline

Joined: 15th Feb 2008

Location:

Posted: 5th Dec 2010 02:16

Link

Quote: "Is that why you're not interested in the challenges?"

Pretty much, yes. Cant really control my interests, my interests controls me.

Back to top

Profile PM Email

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 5th Dec 2010 02:55

Link

Quote: "Quote: "Is that why you're not interested in the challenges?"
Pretty much, yes. Cant really control my interests, my interests controls me."

So wouldn't making a cut scene, or a special effect, or using media in a program be things that one would "see themselves exercising ... in the near future" - especially with a programming language geared towards 3d and general game making?

Personally, I really liked the very short and sweet brain teaser/programming skill challenges. Larger programming endeavors are only interesting when there are many participants.

Enjoy your day.

Back to top

Profile PM

Ashingda 27

16

Years of Service

User Offline

Joined: 15th Feb 2008

Location:

Posted: 5th Dec 2010 03:33 Edited at: 5th Dec 2010 03:35

Link

Well I am only speaking for myself personally and I'm sure others do not share the same thoughts is why I said "Maybe". Currently "explosions/fire/swirl/smoke/distortion" isn't really on my list of things to do. It's not that these are not practical, I'm just using a different type of media at the moment.

I have not yet really dived into 3d programing as I'm still learning how to make a simple game work first. After this current project is completed I will finally going to start focusing on 3d, then I'd be more interested in 3d challenges.

Back to top

Profile PM Email

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 5th Dec 2010 09:06

Link

Quote: "Well I am only speaking for myself personally and I'm sure others do not share the same thoughts is why I said "Maybe""

I just wondered what you thought since you seem to explore lots of different techniques in graphic programming.

Enjoy your day.

Back to top

Profile PM

29 games

18

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 14th Dec 2010 23:00

Link

I think the challenges may be following a natural path. At the start there were a lot of simple things to do, then people get experienced so the challenges get a bit more involved. These then take more time which puts experienced people off, who at this point may have their own projects on the go, and the new comers are put off because the challenge is too complicated for them.

Anyhow, this is my go at Latch's challenge. It's a cut scene of a figure running (no media required) and jumping an obstacle.

`Cut Scene Demo
`By 29 Games
`14 December 2010

`This demo is basic scene of a figure running
`The figure jumps and slides at cetain times
`Obstacles are placed to coincide with the jump
`and slide to make it look as if the figure is
`dodging the obstacles.

`There are no controls, just run the program.

gosub SET_UP
gosub STARTING_VARIABLES
gosub MAKE_OBJECTS
gosub CAMERA_VARIABLES

_main_loop:

start_time = timer()
repeat

time = timer() - start_time

`figure runs and camera spirals inward
   if time <= 2500

`move runner foward
      zply# = zply# + zvel#

position object 1, xply#, yply#, zply#
      loop object 1, 1, 43

`camera spirals toward runner
      c_ang_x# = curvevalue(ang_x_2#, c_ang_x#, 50.0)    :`determine angle of camera about x axis
      c_ang_y# = curvevalue(ang_y_2#, c_ang_y#, 100.0)   :`determine angle of camera about y axis
      c_dis# = curvevalue(dis_2#, c_dis#, 50.0)          :`determine distance of camera from runner

position camera xply#, yply#, zply#       :`position camera on runner
      yrotate camera wrapvalue(c_ang_y#)        :`angle camera about y axis
      xrotate camera wrapvalue(c_ang_x#)        :`angle camera about x axis
      move camera c_dis#                        :`move camera out from runner
      point camera xply#, yply#, zply#          :`point camera at runner

endif

`figure runs and camera spirals out
   if time > 2500 and time <= 4000

`move runner forward
      zply# = zply# + zvel#

position object 1, xply#, yply#, zply#
      loop object 1, 1, 43

`camera spirals out from player
      c_ang_x# = curvevalue(ang_x_3#, c_ang_x#, 50.0)
      c_ang_y# = curvevalue(ang_y_3#, c_ang_y#, 100.0)
      c_dis# = curvevalue(dis_3#, c_dis#, 50.0)

position camera xply#, yply#, zply#
      yrotate camera wrapvalue(c_ang_y#)
      xrotate camera wrapvalue(c_ang_x#)
      move camera c_dis#
      point camera xply#, yply#, zply#

endif

`figures runs and jumps and camera spirals outward
   if time > 4000 and time <= 8000

`move runner forward
      zply# = zply# + zvel#

`at this point in time figure jumps
      if time >= 5985 and time < 6015
         yvel# = 2.0                :`apply upward velocity
         play object 1, 71,71       :`play jump pose
      endif

yvel# = yvel# - 0.1           :`apply gravity to upward velocity
      yply# = yply# + yvel#         :`calculate velocity in y direction
      if yply# <= hgt*0.6           :`player touches ground again
         yply# = hgt*0.6
         yvel# = 0
      endif

`play touch down animation if player is falling downward
      if yvel# < 0 then play object 1, 71,100

position object 1, xply#, yply#, zply#
      if yply# <= hgt*0.6 then loop object 1, 1, 43      :`play running animation if runner is on the ground

`show and move obstacle 2
      show object 3
      move object 3, xvel_3#

`camera spirals outward
      c_ang_y# = curvevalue(ang_y_4#, c_ang_y#, 100.0)
      c_dis# = curvevalue(dis_4#, c_dis#, 50.0)

position camera xply#, yply#, zply#
      yrotate camera wrapvalue(c_ang_y#)
      xrotate camera wrapvalue(c_ang_x#)
      move camera c_dis#
      point camera xply#, yply#, zply#

endif

if time > 8000

`move runner
      zply# = zply# + zvel#

`runner slides under 2nd obstacle at a certain time
      if time < 9000
         loop object 1, 1, 43
      else
         `runner slides under 2nd obstacle at time > 9000 milli seconds
         xrotate object 1, wrapvalue(-45)
         yrotate object 1, wrapvalue(270)
         zrotate object 1, wrapvalue(0)
         yply# = hgt*0.2
         play object 1, 61,61       :`sliding pose
      endif

position object 1, xply#, yply#, zply#

`move obstacle 2
      move object 3, xvel_3#

`spiral camera around runner
      c_ang_x# = curvevalue(ang_x_5#, c_ang_x#, 10.0)
      c_ang_y# = curvevalue(ang_y_5#, c_ang_y#, 100.0)
      c_dis# = curvevalue(dis_5#, c_dis#, 50.0)

position camera xply#, yply#, zply#
      yrotate camera wrapvalue(c_ang_y#)
      xrotate camera wrapvalue(c_ang_x#)
      move camera c_dis#
      point camera xply#, yply#, zply#

endif

sync

until time > 12000

end

SET_UP:

`set display mode 1024,768,16
   sync on
   sync rate 65
   hide mouse
   set camera range 1,3000
   randomize timer()

return

STARTING_VARIABLES:

`values for runner
   hgt = 50             :`height
   zvel# = 4.0          :`z velocity
   xply# = 0            :`x position
   yply# = hgt*0.6      :`y position
   zply# = 0            :`z position

`values for second obstacle
   xvel_3# = 5          :`x velocity

return

MAKE_OBJECTS:

make matrix 1, 1000,4000,10,30
   position matrix 1,-500,0,0

`make runner and animate runner
   MAKE_OBJECT_FIGURE(1,hgt)
   color object 1,rgb(200,50,50)
   set object ambient 1, rgb(30,20,40)
   xrotate object 1,20
   ANIMATE_FIGURE(1)
   set object speed 1, 30
   position object 1, xply#,yply#,zply#

`make first obstacle
   make object box 2, 1000,20,70
   color object 2, rgb(0,100,0)
   position object 2, 0,10,1540

`make second obstacle
   make object box 3, 80,150,500
   make object box 4, 80,120,100 : make mesh from object 1,4 : add limb 3,1,1 : offset limb 3,1, 0,-15,340 : delete object 4 : delete mesh 1
   color object 3, rgb(100,100,100) : set object ambient 3, rgb(100,100,200)
   make object box 4, 60,20,220 : make mesh from object 1,4 : add limb 3,2,1 : offset limb 3,2, 0,-85,280 : delete object 4 : delete mesh 1
   color limb 3,2, rgb(60,60,60)
   for i = 3 to 7
      make object cylinder 4, 40 : scale object 4, 100,200,100 : make mesh from object 1,4 : add limb 3,i,1 : color limb 3,i, rgb(20,20,20)
      delete object 4 : delete mesh 1
   next i
   offset limb 3,3, 0,-95,-220 : rotate limb 3,3, 0,0,90
   offset limb 3,4, 0,-95,-170 : rotate limb 3,4, 0,0,90
   offset limb 3,5, 0,-95,200  : rotate limb 3,5, 0,0,90
   offset limb 3,6, 0,-95,250  : rotate limb 3,6, 0,0,90
   offset limb 3,7, 0,-95,365  : rotate limb 3,7, 0,0,90

yrotate object 3, 270
   position object 3, 1700,115,2350
   hide object 3

return

CAMERA_VARIABLES:

`camera values
   ang_x_1# = 30.0  :  ang_y_1# = 180.0+360.0 :  ang_z_1# = 45.0  :  dis_1# = -3000.0
   ang_x_2# = 1.0  :  ang_y_2# = 60.0  :  ang_z_2# = ang_z_1#  :  dis_2# = -100.0
   ang_x_3# = ang_x_2#  :  ang_y_3# = ang_y_2#  :  ang_z_3# = ang_z_2#  :  dis_3# = dis_2#
   ang_x_4# = ang_x_3#  :  ang_y_4# = 300.0  :  ang_z_4# = ang_z_3#  :  dis_4# = -300.0
   ang_x_5# = 1.0  :  ang_y_5# = 500.0  :  ang_z_5# = ang_z_4#  :  dis_5# = -150.0
   `starting camera values
   c_ang_x# = ang_x_1#  :  c_ang_y# = ang_y_1#  :  c_ang_z# = ang_z_1#  :  c_dis# = dis_1#

return

function ANIMATE_FIGURE(n):

`running animation
   POSE_FIGURE(n,1) : set object keyframe n,1       :`full run right foot forward
   POSE_FIGURE(n,2) : set object keyframe n,8       :`half run right foot forward
   POSE_FIGURE(n,3) : set object keyframe n,15      :`half run right foot down
   POSE_FIGURE(n,4) : set object keyframe n,22      :`full run left foot forward
   POSE_FIGURE(n,5) : set object keyframe n,29      :`half run left foot forward
   POSE_FIGURE(n,6) : set object keyframe n,36      :`half run left foot down
   POSE_FIGURE(n,1) : set object keyframe n,43      :`full run right foot forward

`slide
   POSE_FIGURE(n,7) : set object keyframe n,61      :`slide

`hurdle
   POSE_FIGURE(n,11) : set object keyframe n,71    :`hurdle
   POSE_FIGURE(n,1) : set object keyframe n,100    :`full run right foot forward

endfunction

function POSE_FIGURE(num,p)

if p = 0 then restore _pose_data_00    :`standing
   `poses for running
   if p = 1 then restore _pose_data_01    :`full run right foot forward
   if p = 2 then restore _pose_data_02    :`half run right foot forward
   if p = 3 then restore _pose_data_03    :`half run right foot down
   if p = 4 then restore _pose_data_04    :`full run left foot forward
   if p = 5 then restore _pose_data_05    :`half run left foot forward
   if p = 6 then restore _pose_data_06    :`half run left foot down

`poses for slide and controlled fall
   if p = 7 then restore _pose_data_07    :`slide
   if p = 8 then restore _pose_data_08    :`controlled fall

if p = 9 then restore _pose_data_09    :`controlled land
   if p = 10 then restore _pose_data_10   :`crouch

if p = 11 then restore _pose_data_11   :`hurdle

`rotate limbs
   for i = 1 to 11
      read ax,ay,az
      rotate limb num,i, wrapvalue(ax),wrapvalue(ay),wrapvalue(az)
   next i

`standing
   _pose_data_00:
   data 0, 0, 0    :` 1 mid_body
   data 0, 0, 0    :` 2 up_body
   data 0, 0, 0    :` 3 head
   data 0, 0, 0    :` 4 up_arm left
   data 0, 0, 0    :` 5 up_arm right
   data 0, 0, 0    :` 6 lo_arm left
   data 0, 0, 0    :` 7 lo_arm right
   data 0, 0, 0    :` 8 up_leg left
   data 0, 0, 0    :` 9 up_leg right
   data 0, 0, 0    :` 10 lo_leg left
   data 0, 0, 0    :` 11 lo_leg right
   `full run right foot forward
   _pose_data_01:
   data 0, 30, 0     :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, -30, 0    :` 3 head
   data -45, 0, 0    :` 4 up_arm left
   data 90, 0, 0     :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data 30, 0, 0     :` 8 up_leg left
   data -60, 0, 0    :` 9 up_leg right
   data 90, 0, 0     :` 10 lo_leg left
   data 0, 0, 0      :` 11 lo_leg right
   `half run right foot forward
   _pose_data_02:
   data 0, 10, 0     :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, -10, 0    :` 3 head
   data -3, 0, 0     :` 4 up_arm left
   data 37, 0, 0     :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data 0, 0, 0      :` 8 up_leg left
   data -30, 0, 0    :` 9 up_leg right
   data 90, 0, 0     :` 10 lo_leg left
   data 0, 0, 0      :` 11 lo_leg right
   `half run right foot down
   _pose_data_03:
   data 0, -10, 0    :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, 10, 0     :` 3 head
   data 37, 0, 0     :` 4 up_arm left
   data -3, 0, 0     :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data -30, 0, 0    :` 8 up_leg left
   data 0, 0, 0      :` 9 up_leg right
   data 90, 0, 0     :` 10 lo_leg left
   data 0, 0, 0      :` 11 lo_leg right
   `full run left foot forward
   _pose_data_04:
   data 0, -30, 0    :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, 30, 0     :` 3 head
   data 90, 0, 0     :` 4 up_arm left
   data -45, 0, 0    :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data -60, 0, 0    :` 8 up_leg left
   data 30, 0, 0     :` 9 up_leg right
   data 0, 0, 0      :` 10 lo_leg left
   data 90, 0, 0     :` 11 lo_leg right
   `half run left foot forward
   _pose_data_05:
   data 0, -10, 0    :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, 10, 0     :` 3 head
   data 37, 0, 0     :` 4 up_arm left
   data -3, 0, 0     :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data -30, 0, 0    :` 8 up_leg left
   data 0, 0, 0      :` 9 up_leg right
   data 0, 0, 0      :` 10 lo_leg left
   data 90, 0, 0     :` 11 lo_leg right
   `half run left foot down
   _pose_data_06:
   data 0, 10, 0     :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, -10, 0    :` 3 head
   data -3, 0, 0     :` 4 up_arm left
   data 37, 0, 0     :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data 0, 0, 0      :` 8 up_leg left
   data -30, 0, 0    :` 9 up_leg right
   data 0, 0, 0      :` 10 lo_leg left
   data 90, 0, 0     :` 11 lo_leg right

_pose_data_07:
   data 30, 60, 0    :` 1 mid_body
   data 10, 0, 0     :` 2 up_body
   data 10, 10, 0    :` 3 head
   data 90, 0, -30   :` 4 up_arm left
   data -90, -60, 0  :` 5 up_arm right
   data 0, 0, 0      :` 6 lo_arm left
   data -45, 0, 0    :` 7 lo_arm right
   data -100, -30, 0 :` 8 up_leg left
   data 0, 0, 30     :` 9 up_leg right
   data 100, 0, 0     :` 10 lo_leg left
   data 0, 0, 0      :` 11 lo_leg right

_pose_data_08:
   data 10, 0, 0     :` 1 mid_body
   data 10, 0, 0     :` 2 up_body
   data 10, 0, 0     :` 3 head
   data 0, -30, -100 :` 4 up_arm left
   data 0, 30, 100   :` 5 up_arm right
   data 0, 0, 0      :` 6 lo_arm left
   data 0, 0, 0      :` 7 lo_arm right
`   data -100, 0, 0   :` 8 up_leg left
   data 0, 0, 0   :` 8 up_leg left
   data 0, 0, 0      :` 9 up_leg right
`   data 100, 0, 0    :` 10 lo_leg left
   data 0, 0, 0    :` 10 lo_leg left
   data 0, 0, 0      :` 11 lo_leg right

_pose_data_09:
   data 30, 0, 0    :` 1 mid_body
   data 30, 0, 0    :` 2 up_body
   data 30, 0, 0    :` 3 head
   data 0, -30, -100 :` 4 up_arm left
   data 0, 30, 100   :` 5 up_arm right
   data 0, 0, 0    :` 6 lo_arm left
   data 0, 0, 0    :` 7 lo_arm right
   data -100, 0, 0    :` 8 up_leg left
   data -20, 0, 0    :` 9 up_leg right
   data 110, 0, 0    :` 10 lo_leg left
   data 110, 0, 0    :` 11 lo_leg right

_pose_data_10:
   data 30, 0, 0    :` 1 mid_body
   data 0, 0, 0    :` 2 up_body
   data -30, 0, 0    :` 3 head
   data -30, 0, 0     :` 4 up_arm left
   data -30, 0, 0     :` 5 up_arm right
   data 0, 0, 0     :` 6 lo_arm left
   data 0, 0, 0     :` 7 lo_arm right
   data -100, 0, 0    :` 8 up_leg left
   data -20, 0, 0    :` 9 up_leg right
   data 110, 0, 0    :` 10 lo_leg left
   data 110, 0, 0    :` 11 lo_leg right

_pose_data_11:
   data 15, 0, 0    :` 1 mid_body
   data 15, 0, 0    :` 2 up_body
   data -30, 0, 0    :` 3 head
   data 0, -30, -100 :` 4 up_arm left
   data 0, 30, 100   :` 5 up_arm right
   data 0, 0, 0    :` 6 lo_arm left
   data 0, 0, 0    :` 7 lo_arm right
   data -10, 0, 0    :` 8 up_leg left
   data -100, 0, 0    :` 9 up_leg right
   data 100, 0, 0    :` 10 lo_leg left
   data 0, 0, 0    :` 11 lo_leg right

endfunction

function MAKE_OBJECT_FIGURE(num,size)

`the bottom of the figure's feet are 0.6*size from the object position of the figure

dim p#(8,24)

`write figure vertex data to array
   restore _figure_part_data
   for i = 1 to 8
      for j = 1 to 24
         read p#(i,j)
         p#(i,j) = p#(i,j)*size
      next j
   next i

`create meshes for body parts
   for i = 1 to 8
      MAKE_MESH_8_POINTS(i, p#(i,1),p#(i,2),p#(i,3), p#(i,4),p#(i,5),p#(i,6), p#(i,7),p#(i,8),p#(i,9), p#(i,10),p#(i,11),p#(i,12), p#(i,13),p#(i,14),p#(i,15), p#(i,16),p#(i,17),p#(i,18), p#(i,19),p#(i,20),p#(i,21), p#(i,22),p#(i,23),p#(i,24))
   next i

`create object and add limbs        limb numbers
   make object num,1,0              :` 0 lo_body1
   add limb num,1,2                 :` 1 mid_body
   add limb num,2,3                 :` 2 up_body
   add limb num,3,4                 :` 3 head
   add limb num,4,5                 :` 4 up_arm left
   add limb num,5,5                 :` 5 up_arm right
   add limb num,6,6                 :` 6 lo_arm left
   add limb num,7,6                 :` 7 lo_arm right
   add limb num,8,7                 :` 8 up_leg left
   add limb num,9,7                 :` 9 up_leg right
   add limb num,10,8                :` 10 lo_leg left
   add limb num,11,8                :` 11 lo_leg right

`delete meshes
   for i = 1 to 8
      delete mesh i
   next i

`position limbs and link limbs
   offset limb num,1, 0*size,0.148*size,0*size                                 :` 1 mid_body
   link limb num,2,1:   offset limb num,2, 0*size,0.106*size,0*size            :` 2 up_body
   link limb num,3,2:   offset limb num,3, 0*size,0.052*size,0*size            :` 3 head
   link limb num,4,2:   offset limb num,4, -0.18*size,0.0*size,0*size          :` 4 up_arm left
   link limb num,5,2:   offset limb num,5, 0.18*size,0.0*size,0*size           :` 5 up_arm right
   link limb num,6,4:   offset limb num,6, 0*size,-0.148*size,-0.03*size       :` 6 lo_arm left
   link limb num,7,5:   offset limb num,7, 0*size,-0.148*size,-0.03*size       :` 7 lo_arm right
   offset limb num,8, -0.075*size,-0.04*size,0*size                            :` 8 up_leg left
   offset limb num,9, 0.075*size,-0.04*size,0*size                             :` 9 up_leg right
   link limb num,10,8:  offset limb num,10, 0*size,-0.21*size,0.03*size        :` 10 lo_leg left
   link limb num,11,9:  offset limb num,11, 0*size,-0.21*size,0.03*size        :` 11 lo_leg right

`delete array from memory
   undim p#(8,24)

`data
   _figure_part_data:
   `vertex data lower body:
   data 0.03,-0.08,0.03,   -0.03,-0.08,0.03,   0.03,0.08,0.03,   -0.03,0.08,0.03
   data 0.03,-0.04,-0.06,  -0.03,-0.04,-0.06,  0.03,0.08,-0.03,  -0.03,0.08,-0.03
   `vertex data mid body:
   data 0.03,-0.033,0.03,  -0.03,-0.033,0.03,   0.1,0.033,0.045,   -0.1,0.033,0.045
   data 0.03,-0.033,-0.03, -0.03,-0.033,-0.03,  0.1,0.033,-0.045,  -0.1,0.033,-0.045
   `vertex data upper body:
   data 0.135,-0.037,0.045,  -0.135,-0.037,0.045,  0.135,0.037,0.045,  -0.135,0.037,0.045
   data 0.135,-0.037,-0.053, -0.135,-0.037,-0.053, 0.135,0.037,-0.1,   -0.135,0.037,-0.1
   `vertex data head:
   data 0.03,0.0,0.03,     -0.03,0.0,0.03,     0.03,0.094,0.03,   -0.03,0.094,0.03
   data 0.03,0.015,-0.03,  -0.03,0.015,-0.03,  0.03,0.094,-0.06,  -0.03,0.094,-0.06
   `vertex data upper arm:
   data 0.03,-0.083,0.03,  -0.03,-0.083,0.03,   0.03,0.027,0.03,  -0.03,0.027,0.03
   data 0.03,-0.143,-0.03, -0.03,-0.143,-0.03,  0.03,0.027,-0.03, -0.03,0.027,-0.03
   `vertex data lower arm:
   data 0.03,-0.175,0.06,   -0.03,-0.175,0.06, 0.03,-0.065,0.06,  -0.03,-0.065,0.06
   data 0.03,-0.175,0.00,   -0.03,-0.175,0.00, 0.03,-0.005,0.00,  -0.03,-0.005,0.00
   `vertex data upper leg:
   data 0.03,-0.205,0.03,  -0.03,-0.205,0.03,  0.03,0.04,0.03,   -0.03,0.04,0.03
   data 0.03,-0.145,-0.03, -0.03,-0.145,-0.03, 0.03,0.04,-0.03,  -0.03,0.04,-0.03
   `vertex data lower leg:
   data 0.060,-0.35,-0.00,  -0.060,-0.35,-0.00,  0.060,-0.005,-0.00,  -0.060,-0.005,-0.00
   data 0.060,-0.35,-0.14, -0.060,-0.35,-0.14, 0.060,-0.065,-0.07, -0.060,-0.065,-0.07

endfunction

function MAKE_MESH_8_POINTS(num, ax#,ay#,az#, bx#,by#,bz#, cx#,cy#,cz#, dx#,dy#,dz#, ex#,ey#,ez#, fx#,fy#,fz#, gx#,gy#,gz#, hx#,hy#,hz#)

`a = front right bottom, b = front left bottom, c = front right top, d = front left top
   `e = back right bottom, f = back left bottom, g = back right top, h = back left top

`there are six sides to a box
   num_sides = 6

`memblock number
   mem = 1
   `header values
   num_verts = num_sides * 4
   pos_verts = 32
   num_norms = num_verts
   pos_norms = num_verts*12 + pos_verts
   num_faces = num_sides*2
   pos_faces = pos_norms + num_norms*12
   size_faces = num_faces*7
   pos_uv = pos_faces + size_faces*4

`calculate size of memblock
   size_mem = 32 + (num_verts + num_norms)*12 + size_faces*4 + num_sides*32

`create the memblock
   make memblock mem, size_mem

`write header values to memblock
   write memblock dword mem, 0, num_verts
   write memblock dword mem, 4, pos_verts
   write memblock dword mem, 8, num_norms
   write memblock dword mem, 12, pos_norms
   write memblock dword mem, 16, num_faces
   write memblock dword mem, 20, pos_faces
   write memblock dword mem, 24, size_faces
   write memblock dword mem, 28, pos_uv

`write vertext data to memblock
   `front face
   write memblock float mem, 32,  ax# : write memblock float mem, 36,  ay# : write memblock float mem, 40,  az#  :   `0 vertex
   write memblock float mem, 44,  bx# : write memblock float mem, 48,  by# : write memblock float mem, 52,  bz#  :   `1 vertex
   write memblock float mem, 56,  cx# : write memblock float mem, 60,  cy# : write memblock float mem, 64,  cz#  :   `2 vertex
   write memblock float mem, 68,  dx# : write memblock float mem, 72,  dy# : write memblock float mem, 76,  dz#  :   `3 vertex
   `back face
   write memblock float mem, 80,  fx# : write memblock float mem, 84,  fy# : write memblock float mem, 88,  fz#  :   `4 vertex
   write memblock float mem, 92,  ex# : write memblock float mem, 96,  ey# : write memblock float mem, 100, ez#  :   `5 vertex
   write memblock float mem, 104, hx# : write memblock float mem, 108, hy# : write memblock float mem, 112, hz#  :   `6 vertex
   write memblock float mem, 116, gx# : write memblock float mem, 120, gy# : write memblock float mem, 124, gz#  :   `7 vertex
   `left face
   write memblock float mem, 128, bx# : write memblock float mem, 132, by# : write memblock float mem, 136, bz#  :   `8 vertex
   write memblock float mem, 140, fx# : write memblock float mem, 144, fy# : write memblock float mem, 148, fz#  :   `9 vertex
   write memblock float mem, 152, dx# : write memblock float mem, 156, dy# : write memblock float mem, 160, dz#  :   `10 vertex
   write memblock float mem, 164, hx# : write memblock float mem, 168, hy# : write memblock float mem, 172, hz#  :   `11 vertex
   `right face
   write memblock float mem, 176, ex# : write memblock float mem, 180, ey# : write memblock float mem, 184, ez#  :   `12 vertex
   write memblock float mem, 188, ax# : write memblock float mem, 192, ay# : write memblock float mem, 196, az#  :   `13 vertex
   write memblock float mem, 200, gx# : write memblock float mem, 204, gy# : write memblock float mem, 208, gz#  :   `14 vertex
   write memblock float mem, 212, cx# : write memblock float mem, 216, cy# : write memblock float mem, 220, cz#  :   `15 vertex
   `top face
   write memblock float mem, 224, hx# : write memblock float mem, 228, hy# : write memblock float mem, 232, hz#  :   `16 vertex
   write memblock float mem, 236, gx# : write memblock float mem, 240, gy# : write memblock float mem, 244, gz#  :   `17 vertex
   write memblock float mem, 248, dx# : write memblock float mem, 252, dy# : write memblock float mem, 256, dz#  :   `18 vertex
   write memblock float mem, 260, cx# : write memblock float mem, 264, cy# : write memblock float mem, 268, cz#  :   `19 vertex
   `bottom face
   write memblock float mem, 272, bx# : write memblock float mem, 276, by# : write memblock float mem, 280, bz#  :   `20 vertex
   write memblock float mem, 284, ax# : write memblock float mem, 288, ay# : write memblock float mem, 292, az#  :   `21 vertex
   write memblock float mem, 296, fx# : write memblock float mem, 300, fy# : write memblock float mem, 304, fz#  :   `22 vertex
   write memblock float mem, 308, ex# : write memblock float mem, 312, ey# : write memblock float mem, 316, ez#  :   `23 vertex

`write normal data to memblock
   restore _normdata
   for pos = pos_norms to pos_norms+(num_norms*12)-12 step 12
      read x,y,z
      write memblock float mem, pos, x
      write memblock float mem, pos+4, y
      write memblock float mem, pos+8, z
   next pos

`write face data to memblock
   restore _facedata
   for pos = pos_faces to pos_faces+(num_faces*28)-28 step 28
      read nvf, va,na, vb, nb, vc,nc
      write memblock dword mem, pos, nvf
      write memblock dword mem, pos+4, va
      write memblock dword mem, pos+8, na
      write memblock dword mem, pos+12, vb
      write memblock dword mem, pos+16, nb
      write memblock dword mem, pos+20, vc
      write memblock dword mem, pos+24, nc
   next pos

`write UV data to memblock
   restore _uvdata
   for pos = pos_uv to pos_uv+(num_sides*32)-32 step 32
      read ua#,va#, ub#,vb#, uc#,vc#, ud#,vd#
      write memblock float mem, pos, ua#
      write memblock float mem, pos+4, va#
      write memblock float mem, pos+8, ub#
      write memblock float mem, pos+12, vb#
      write memblock float mem, pos+16, uc#
      write memblock float mem, pos+20, vc#
      write memblock float mem, pos+24, ud#
      write memblock float mem, pos+28, vd#
   next pos

`create mesh then create object, delete mesh and memblock
   make mesh from memblock num, mem
   delete memblock 1

_normdata:
   data 0,0,1,  0,0,1,  0,0,1, 0,0,1         :`front
   data 0,0,-1,  0,0,-1,  0,0,-1,  0,0,-1    :`back
   data -1,0,0,  -1,0,0,  -1,0,0,  -1,0,0    :`left
   data 1,0,0,  1,0,0,  1,0,0,  1,0,0        :`right
   data 0,1,0,  0,1,0,  0,1,0,  0,1,0        :`top
   data 0,-1,0,  0,-1,0,  0,-1,0,  0,-1,0    :`bottom

_facedata:
   data 3,  0,0,  3,3,  1,1          :`front face 0
   data 3,  3,3,  0,0,  2,2          :`front face 1
   data 3,  4,4,  7,7,  5,5          :`back face 2
   data 3,  7,7,  4,4,  6,6          :`back face 3
   data 3,  8,8,  11,11,  9,9        :`left face 4
   data 3,  11,11,  8,8,  10,10      :`left face 5
   data 3,  12,12,  15,15,  13,13    :`right face 6
   data 3,  15,15,  12,12,  14,14    :`right face 7
   data 3,  16,16,  19,19,  17,17    :`top face 8
   data 3,  19,19,  16,16,  18,18    :`top face 9
   data 3,  20,20,  23,23,  21,21    :`bottom face 10
   data 3,  23,23,  20,20,  22,22    :`bottom face 11

_uvdata:
   data 0.03,0.47,  0.30,0.47,  0.03,0.03,  0.30,0.03   :`front
   data 0.03,0.97,  0.30,0.97,  0.03,0.53,  0.30,0.53   :`back
   data 0.36,0.47,  0.63,0.47,  0.36,0.03,  0.63,0.03   :`left
   data 0.36,0.97,  0.63,0.97,  0.36,0.53,  0.63,0.53   :`right
   data 0.69,0.47,  0.97,0.47,  0.69,0.03,  0.97,0.03   :`top
   data 0.69,0.97,  0.97,0.97,  0.69,0.53,  0.97,0.53   :`bottom

endfunction

+ Code Snippet

`Cut Scene Demo
`By 29 Games
`14 December 2010

`This demo is basic scene of a figure running
`The figure jumps and slides at cetain times
`Obstacles are placed to coincide with the jump
`and slide to make it look as if the figure is
`dodging the obstacles.

`There are no controls, just run the program.

gosub SET_UP
gosub STARTING_VARIABLES
gosub MAKE_OBJECTS
gosub CAMERA_VARIABLES


_main_loop:

start_time = timer()
repeat

   time = timer() - start_time

   `figure runs and camera spirals inward
   if time <= 2500

      `move runner foward
      zply# = zply# + zvel#

      position object 1, xply#, yply#, zply#
      loop object 1, 1, 43


      `camera spirals toward runner
      c_ang_x# = curvevalue(ang_x_2#, c_ang_x#, 50.0)    :`determine angle of camera about x axis
      c_ang_y# = curvevalue(ang_y_2#, c_ang_y#, 100.0)   :`determine angle of camera about y axis
      c_dis# = curvevalue(dis_2#, c_dis#, 50.0)          :`determine distance of camera from runner

      position camera xply#, yply#, zply#       :`position camera on runner
      yrotate camera wrapvalue(c_ang_y#)        :`angle camera about y axis
      xrotate camera wrapvalue(c_ang_x#)        :`angle camera about x axis
      move camera c_dis#                        :`move camera out from runner
      point camera xply#, yply#, zply#          :`point camera at runner


   endif

   `figure runs and camera spirals out
   if time > 2500 and time <= 4000

      `move runner forward
      zply# = zply# + zvel#

      position object 1, xply#, yply#, zply#
      loop object 1, 1, 43

      `camera spirals out from player
      c_ang_x# = curvevalue(ang_x_3#, c_ang_x#, 50.0)
      c_ang_y# = curvevalue(ang_y_3#, c_ang_y#, 100.0)
      c_dis# = curvevalue(dis_3#, c_dis#, 50.0)

      position camera xply#, yply#, zply#
      yrotate camera wrapvalue(c_ang_y#)
      xrotate camera wrapvalue(c_ang_x#)
      move camera c_dis#
      point camera xply#, yply#, zply#

   endif


   `figures runs and jumps and camera spirals outward
   if time > 4000 and time <= 8000


      `move runner forward
      zply# = zply# + zvel#

      `at this point in time figure jumps
      if time >= 5985 and time < 6015
         yvel# = 2.0                :`apply upward velocity
         play object 1, 71,71       :`play jump pose
      endif

      yvel# = yvel# - 0.1           :`apply gravity to upward velocity
      yply# = yply# + yvel#         :`calculate velocity in y direction
      if yply# <= hgt*0.6           :`player touches ground again
         yply# = hgt*0.6
         yvel# = 0
      endif

      `play touch down animation if player is falling downward
      if yvel# < 0 then play object 1, 71,100

      position object 1, xply#, yply#, zply#
      if yply# <= hgt*0.6 then loop object 1, 1, 43      :`play running animation if runner is on the ground

      `show and move obstacle 2
      show object 3
      move object 3, xvel_3#


      `camera spirals outward
      c_ang_y# = curvevalue(ang_y_4#, c_ang_y#, 100.0)
      c_dis# = curvevalue(dis_4#, c_dis#, 50.0)

      position camera xply#, yply#, zply#
      yrotate camera wrapvalue(c_ang_y#)
      xrotate camera wrapvalue(c_ang_x#)
      move camera c_dis#
      point camera xply#, yply#, zply#

   endif


   if time > 8000

      `move runner
      zply# = zply# + zvel#

      `runner slides under 2nd obstacle at a certain time
      if time < 9000
         loop object 1, 1, 43
      else
         `runner slides under 2nd obstacle at time > 9000 milli seconds
         xrotate object 1, wrapvalue(-45)
         yrotate object 1, wrapvalue(270)
         zrotate object 1, wrapvalue(0)
         yply# = hgt*0.2
         play object 1, 61,61       :`sliding pose
      endif

      position object 1, xply#, yply#, zply#

      `move obstacle 2
      move object 3, xvel_3#


      `spiral camera around runner
      c_ang_x# = curvevalue(ang_x_5#, c_ang_x#, 10.0)
      c_ang_y# = curvevalue(ang_y_5#, c_ang_y#, 100.0)
      c_dis# = curvevalue(dis_5#, c_dis#, 50.0)

      position camera xply#, yply#, zply#
      yrotate camera wrapvalue(c_ang_y#)
      xrotate camera wrapvalue(c_ang_x#)
      move camera c_dis#
      point camera xply#, yply#, zply#

   endif

   sync

until time > 12000

end


SET_UP:

   `set display mode 1024,768,16
   sync on
   sync rate 65
   hide mouse
   set camera range 1,3000
   randomize timer()

return


STARTING_VARIABLES:

   `values for runner
   hgt = 50             :`height
   zvel# = 4.0          :`z velocity
   xply# = 0            :`x position
   yply# = hgt*0.6      :`y position
   zply# = 0            :`z position

   `values for second obstacle
   xvel_3# = 5          :`x velocity

return


MAKE_OBJECTS:

   make matrix 1, 1000,4000,10,30
   position matrix 1,-500,0,0

   `make runner and animate runner
   MAKE_OBJECT_FIGURE(1,hgt)
   color object 1,rgb(200,50,50)
   set object ambient 1, rgb(30,20,40)
   xrotate object 1,20
   ANIMATE_FIGURE(1)
   set object speed 1, 30
   position object 1, xply#,yply#,zply#

   `make first obstacle
   make object box 2, 1000,20,70
   color object 2, rgb(0,100,0)
   position object 2, 0,10,1540

   `make second obstacle
   make object box 3, 80,150,500
   make object box 4, 80,120,100 : make mesh from object 1,4 : add limb 3,1,1 : offset limb 3,1, 0,-15,340 : delete object 4 : delete mesh 1
   color object 3, rgb(100,100,100) : set object ambient 3, rgb(100,100,200)
   make object box 4, 60,20,220 : make mesh from object 1,4 : add limb 3,2,1 : offset limb 3,2, 0,-85,280 : delete object 4 : delete mesh 1
   color limb 3,2, rgb(60,60,60)
   for i = 3 to 7
      make object cylinder 4, 40 : scale object 4, 100,200,100 : make mesh from object 1,4 : add limb 3,i,1 : color limb 3,i, rgb(20,20,20)
      delete object 4 : delete mesh 1
   next i
   offset limb 3,3, 0,-95,-220 : rotate limb 3,3, 0,0,90
   offset limb 3,4, 0,-95,-170 : rotate limb 3,4, 0,0,90
   offset limb 3,5, 0,-95,200  : rotate limb 3,5, 0,0,90
   offset limb 3,6, 0,-95,250  : rotate limb 3,6, 0,0,90
   offset limb 3,7, 0,-95,365  : rotate limb 3,7, 0,0,90

   yrotate object 3, 270
   position object 3, 1700,115,2350
   hide object 3

return

CAMERA_VARIABLES:

   `camera values
   ang_x_1# = 30.0  :  ang_y_1# = 180.0+360.0 :  ang_z_1# = 45.0  :  dis_1# = -3000.0
   ang_x_2# = 1.0  :  ang_y_2# = 60.0  :  ang_z_2# = ang_z_1#  :  dis_2# = -100.0
   ang_x_3# = ang_x_2#  :  ang_y_3# = ang_y_2#  :  ang_z_3# = ang_z_2#  :  dis_3# = dis_2#
   ang_x_4# = ang_x_3#  :  ang_y_4# = 300.0  :  ang_z_4# = ang_z_3#  :  dis_4# = -300.0
   ang_x_5# = 1.0  :  ang_y_5# = 500.0  :  ang_z_5# = ang_z_4#  :  dis_5# = -150.0
   `starting camera values
   c_ang_x# = ang_x_1#  :  c_ang_y# = ang_y_1#  :  c_ang_z# = ang_z_1#  :  c_dis# = dis_1#

return


function ANIMATE_FIGURE(n):

   `running animation
   POSE_FIGURE(n,1) : set object keyframe n,1       :`full run right foot forward
   POSE_FIGURE(n,2) : set object keyframe n,8       :`half run right foot forward
   POSE_FIGURE(n,3) : set object keyframe n,15      :`half run right foot down
   POSE_FIGURE(n,4) : set object keyframe n,22      :`full run left foot forward
   POSE_FIGURE(n,5) : set object keyframe n,29      :`half run left foot forward
   POSE_FIGURE(n,6) : set object keyframe n,36      :`half run left foot down
   POSE_FIGURE(n,1) : set object keyframe n,43      :`full run right foot forward

   `slide
   POSE_FIGURE(n,7) : set object keyframe n,61      :`slide

   `hurdle
   POSE_FIGURE(n,11) : set object keyframe n,71    :`hurdle
   POSE_FIGURE(n,1) : set object keyframe n,100    :`full run right foot forward


endfunction



function POSE_FIGURE(num,p)

   if p = 0 then restore _pose_data_00    :`standing
   `poses for running
   if p = 1 then restore _pose_data_01    :`full run right foot forward
   if p = 2 then restore _pose_data_02    :`half run right foot forward
   if p = 3 then restore _pose_data_03    :`half run right foot down
   if p = 4 then restore _pose_data_04    :`full run left foot forward
   if p = 5 then restore _pose_data_05    :`half run left foot forward
   if p = 6 then restore _pose_data_06    :`half run left foot down

   `poses for slide and controlled fall
   if p = 7 then restore _pose_data_07    :`slide
   if p = 8 then restore _pose_data_08    :`controlled fall

   if p = 9 then restore _pose_data_09    :`controlled land
   if p = 10 then restore _pose_data_10   :`crouch

   if p = 11 then restore _pose_data_11   :`hurdle

   `rotate limbs
   for i = 1 to 11
      read ax,ay,az
      rotate limb num,i, wrapvalue(ax),wrapvalue(ay),wrapvalue(az)
   next i

   `standing
   _pose_data_00:
   data 0, 0, 0    :` 1 mid_body
   data 0, 0, 0    :` 2 up_body
   data 0, 0, 0    :` 3 head
   data 0, 0, 0    :` 4 up_arm left
   data 0, 0, 0    :` 5 up_arm right
   data 0, 0, 0    :` 6 lo_arm left
   data 0, 0, 0    :` 7 lo_arm right
   data 0, 0, 0    :` 8 up_leg left
   data 0, 0, 0    :` 9 up_leg right
   data 0, 0, 0    :` 10 lo_leg left
   data 0, 0, 0    :` 11 lo_leg right
   `full run right foot forward
   _pose_data_01:
   data 0, 30, 0     :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, -30, 0    :` 3 head
   data -45, 0, 0    :` 4 up_arm left
   data 90, 0, 0     :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data 30, 0, 0     :` 8 up_leg left
   data -60, 0, 0    :` 9 up_leg right
   data 90, 0, 0     :` 10 lo_leg left
   data 0, 0, 0      :` 11 lo_leg right
   `half run right foot forward
   _pose_data_02:
   data 0, 10, 0     :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, -10, 0    :` 3 head
   data -3, 0, 0     :` 4 up_arm left
   data 37, 0, 0     :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data 0, 0, 0      :` 8 up_leg left
   data -30, 0, 0    :` 9 up_leg right
   data 90, 0, 0     :` 10 lo_leg left
   data 0, 0, 0      :` 11 lo_leg right
   `half run right foot down
   _pose_data_03:
   data 0, -10, 0    :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, 10, 0     :` 3 head
   data 37, 0, 0     :` 4 up_arm left
   data -3, 0, 0     :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data -30, 0, 0    :` 8 up_leg left
   data 0, 0, 0      :` 9 up_leg right
   data 90, 0, 0     :` 10 lo_leg left
   data 0, 0, 0      :` 11 lo_leg right
   `full run left foot forward
   _pose_data_04:
   data 0, -30, 0    :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, 30, 0     :` 3 head
   data 90, 0, 0     :` 4 up_arm left
   data -45, 0, 0    :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data -60, 0, 0    :` 8 up_leg left
   data 30, 0, 0     :` 9 up_leg right
   data 0, 0, 0      :` 10 lo_leg left
   data 90, 0, 0     :` 11 lo_leg right
   `half run left foot forward
   _pose_data_05:
   data 0, -10, 0    :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, 10, 0     :` 3 head
   data 37, 0, 0     :` 4 up_arm left
   data -3, 0, 0     :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data -30, 0, 0    :` 8 up_leg left
   data 0, 0, 0      :` 9 up_leg right
   data 0, 0, 0      :` 10 lo_leg left
   data 90, 0, 0     :` 11 lo_leg right
   `half run left foot down
   _pose_data_06:
   data 0, 10, 0     :` 1 mid_body
   data 0, 0, 0      :` 2 up_body
   data 0, -10, 0    :` 3 head
   data -3, 0, 0     :` 4 up_arm left
   data 37, 0, 0     :` 5 up_arm right
   data -90, 0, 0    :` 6 lo_arm left
   data -90, 0, 0    :` 7 lo_arm right
   data 0, 0, 0      :` 8 up_leg left
   data -30, 0, 0    :` 9 up_leg right
   data 0, 0, 0      :` 10 lo_leg left
   data 90, 0, 0     :` 11 lo_leg right

   _pose_data_07:
   data 30, 60, 0    :` 1 mid_body
   data 10, 0, 0     :` 2 up_body
   data 10, 10, 0    :` 3 head
   data 90, 0, -30   :` 4 up_arm left
   data -90, -60, 0  :` 5 up_arm right
   data 0, 0, 0      :` 6 lo_arm left
   data -45, 0, 0    :` 7 lo_arm right
   data -100, -30, 0 :` 8 up_leg left
   data 0, 0, 30     :` 9 up_leg right
   data 100, 0, 0     :` 10 lo_leg left
   data 0, 0, 0      :` 11 lo_leg right

   _pose_data_08:
   data 10, 0, 0     :` 1 mid_body
   data 10, 0, 0     :` 2 up_body
   data 10, 0, 0     :` 3 head
   data 0, -30, -100 :` 4 up_arm left
   data 0, 30, 100   :` 5 up_arm right
   data 0, 0, 0      :` 6 lo_arm left
   data 0, 0, 0      :` 7 lo_arm right
`   data -100, 0, 0   :` 8 up_leg left
   data 0, 0, 0   :` 8 up_leg left
   data 0, 0, 0      :` 9 up_leg right
`   data 100, 0, 0    :` 10 lo_leg left
   data 0, 0, 0    :` 10 lo_leg left
   data 0, 0, 0      :` 11 lo_leg right

   _pose_data_09:
   data 30, 0, 0    :` 1 mid_body
   data 30, 0, 0    :` 2 up_body
   data 30, 0, 0    :` 3 head
   data 0, -30, -100 :` 4 up_arm left
   data 0, 30, 100   :` 5 up_arm right
   data 0, 0, 0    :` 6 lo_arm left
   data 0, 0, 0    :` 7 lo_arm right
   data -100, 0, 0    :` 8 up_leg left
   data -20, 0, 0    :` 9 up_leg right
   data 110, 0, 0    :` 10 lo_leg left
   data 110, 0, 0    :` 11 lo_leg right

   _pose_data_10:
   data 30, 0, 0    :` 1 mid_body
   data 0, 0, 0    :` 2 up_body
   data -30, 0, 0    :` 3 head
   data -30, 0, 0     :` 4 up_arm left
   data -30, 0, 0     :` 5 up_arm right
   data 0, 0, 0     :` 6 lo_arm left
   data 0, 0, 0     :` 7 lo_arm right
   data -100, 0, 0    :` 8 up_leg left
   data -20, 0, 0    :` 9 up_leg right
   data 110, 0, 0    :` 10 lo_leg left
   data 110, 0, 0    :` 11 lo_leg right

   _pose_data_11:
   data 15, 0, 0    :` 1 mid_body
   data 15, 0, 0    :` 2 up_body
   data -30, 0, 0    :` 3 head
   data 0, -30, -100 :` 4 up_arm left
   data 0, 30, 100   :` 5 up_arm right
   data 0, 0, 0    :` 6 lo_arm left
   data 0, 0, 0    :` 7 lo_arm right
   data -10, 0, 0    :` 8 up_leg left
   data -100, 0, 0    :` 9 up_leg right
   data 100, 0, 0    :` 10 lo_leg left
   data 0, 0, 0    :` 11 lo_leg right


endfunction


function MAKE_OBJECT_FIGURE(num,size)

   `the bottom of the figure's feet are 0.6*size from the object position of the figure

   dim p#(8,24)

   `write figure vertex data to array
   restore _figure_part_data
   for i = 1 to 8
      for j = 1 to 24
         read p#(i,j)
         p#(i,j) = p#(i,j)*size
      next j
   next i

   `create meshes for body parts
   for i = 1 to 8
      MAKE_MESH_8_POINTS(i, p#(i,1),p#(i,2),p#(i,3), p#(i,4),p#(i,5),p#(i,6), p#(i,7),p#(i,8),p#(i,9), p#(i,10),p#(i,11),p#(i,12), p#(i,13),p#(i,14),p#(i,15), p#(i,16),p#(i,17),p#(i,18), p#(i,19),p#(i,20),p#(i,21), p#(i,22),p#(i,23),p#(i,24))
   next i

   `create object and add limbs        limb numbers
   make object num,1,0              :` 0 lo_body1
   add limb num,1,2                 :` 1 mid_body
   add limb num,2,3                 :` 2 up_body
   add limb num,3,4                 :` 3 head
   add limb num,4,5                 :` 4 up_arm left
   add limb num,5,5                 :` 5 up_arm right
   add limb num,6,6                 :` 6 lo_arm left
   add limb num,7,6                 :` 7 lo_arm right
   add limb num,8,7                 :` 8 up_leg left
   add limb num,9,7                 :` 9 up_leg right
   add limb num,10,8                :` 10 lo_leg left
   add limb num,11,8                :` 11 lo_leg right

   `delete meshes
   for i = 1 to 8
      delete mesh i
   next i

   `position limbs and link limbs
   offset limb num,1, 0*size,0.148*size,0*size                                 :` 1 mid_body
   link limb num,2,1:   offset limb num,2, 0*size,0.106*size,0*size            :` 2 up_body
   link limb num,3,2:   offset limb num,3, 0*size,0.052*size,0*size            :` 3 head
   link limb num,4,2:   offset limb num,4, -0.18*size,0.0*size,0*size          :` 4 up_arm left
   link limb num,5,2:   offset limb num,5, 0.18*size,0.0*size,0*size           :` 5 up_arm right
   link limb num,6,4:   offset limb num,6, 0*size,-0.148*size,-0.03*size       :` 6 lo_arm left
   link limb num,7,5:   offset limb num,7, 0*size,-0.148*size,-0.03*size       :` 7 lo_arm right
   offset limb num,8, -0.075*size,-0.04*size,0*size                            :` 8 up_leg left
   offset limb num,9, 0.075*size,-0.04*size,0*size                             :` 9 up_leg right
   link limb num,10,8:  offset limb num,10, 0*size,-0.21*size,0.03*size        :` 10 lo_leg left
   link limb num,11,9:  offset limb num,11, 0*size,-0.21*size,0.03*size        :` 11 lo_leg right

   `delete array from memory
   undim p#(8,24)


   `data
   _figure_part_data:
   `vertex data lower body:
   data 0.03,-0.08,0.03,   -0.03,-0.08,0.03,   0.03,0.08,0.03,   -0.03,0.08,0.03
   data 0.03,-0.04,-0.06,  -0.03,-0.04,-0.06,  0.03,0.08,-0.03,  -0.03,0.08,-0.03
   `vertex data mid body:
   data 0.03,-0.033,0.03,  -0.03,-0.033,0.03,   0.1,0.033,0.045,   -0.1,0.033,0.045
   data 0.03,-0.033,-0.03, -0.03,-0.033,-0.03,  0.1,0.033,-0.045,  -0.1,0.033,-0.045
   `vertex data upper body:
   data 0.135,-0.037,0.045,  -0.135,-0.037,0.045,  0.135,0.037,0.045,  -0.135,0.037,0.045
   data 0.135,-0.037,-0.053, -0.135,-0.037,-0.053, 0.135,0.037,-0.1,   -0.135,0.037,-0.1
   `vertex data head:
   data 0.03,0.0,0.03,     -0.03,0.0,0.03,     0.03,0.094,0.03,   -0.03,0.094,0.03
   data 0.03,0.015,-0.03,  -0.03,0.015,-0.03,  0.03,0.094,-0.06,  -0.03,0.094,-0.06
   `vertex data upper arm:
   data 0.03,-0.083,0.03,  -0.03,-0.083,0.03,   0.03,0.027,0.03,  -0.03,0.027,0.03
   data 0.03,-0.143,-0.03, -0.03,-0.143,-0.03,  0.03,0.027,-0.03, -0.03,0.027,-0.03
   `vertex data lower arm:
   data 0.03,-0.175,0.06,   -0.03,-0.175,0.06, 0.03,-0.065,0.06,  -0.03,-0.065,0.06
   data 0.03,-0.175,0.00,   -0.03,-0.175,0.00, 0.03,-0.005,0.00,  -0.03,-0.005,0.00
   `vertex data upper leg:
   data 0.03,-0.205,0.03,  -0.03,-0.205,0.03,  0.03,0.04,0.03,   -0.03,0.04,0.03
   data 0.03,-0.145,-0.03, -0.03,-0.145,-0.03, 0.03,0.04,-0.03,  -0.03,0.04,-0.03
   `vertex data lower leg:
   data 0.060,-0.35,-0.00,  -0.060,-0.35,-0.00,  0.060,-0.005,-0.00,  -0.060,-0.005,-0.00
   data 0.060,-0.35,-0.14, -0.060,-0.35,-0.14, 0.060,-0.065,-0.07, -0.060,-0.065,-0.07

endfunction


function MAKE_MESH_8_POINTS(num, ax#,ay#,az#, bx#,by#,bz#, cx#,cy#,cz#, dx#,dy#,dz#, ex#,ey#,ez#, fx#,fy#,fz#, gx#,gy#,gz#, hx#,hy#,hz#)

   `a = front right bottom, b = front left bottom, c = front right top, d = front left top
   `e = back right bottom, f = back left bottom, g = back right top, h = back left top

   `there are six sides to a box
   num_sides = 6

   `memblock number
   mem = 1
   `header values
   num_verts = num_sides * 4
   pos_verts = 32
   num_norms = num_verts
   pos_norms = num_verts*12 + pos_verts
   num_faces = num_sides*2
   pos_faces = pos_norms + num_norms*12
   size_faces = num_faces*7
   pos_uv = pos_faces + size_faces*4

   `calculate size of memblock
   size_mem = 32 + (num_verts + num_norms)*12 + size_faces*4 + num_sides*32

  `create the memblock
   make memblock mem, size_mem

   `write header values to memblock
   write memblock dword mem, 0, num_verts
   write memblock dword mem, 4, pos_verts
   write memblock dword mem, 8, num_norms
   write memblock dword mem, 12, pos_norms
   write memblock dword mem, 16, num_faces
   write memblock dword mem, 20, pos_faces
   write memblock dword mem, 24, size_faces
   write memblock dword mem, 28, pos_uv

   `write vertext data to memblock
   `front face
   write memblock float mem, 32,  ax# : write memblock float mem, 36,  ay# : write memblock float mem, 40,  az#  :   `0 vertex
   write memblock float mem, 44,  bx# : write memblock float mem, 48,  by# : write memblock float mem, 52,  bz#  :   `1 vertex
   write memblock float mem, 56,  cx# : write memblock float mem, 60,  cy# : write memblock float mem, 64,  cz#  :   `2 vertex
   write memblock float mem, 68,  dx# : write memblock float mem, 72,  dy# : write memblock float mem, 76,  dz#  :   `3 vertex
   `back face
   write memblock float mem, 80,  fx# : write memblock float mem, 84,  fy# : write memblock float mem, 88,  fz#  :   `4 vertex
   write memblock float mem, 92,  ex# : write memblock float mem, 96,  ey# : write memblock float mem, 100, ez#  :   `5 vertex
   write memblock float mem, 104, hx# : write memblock float mem, 108, hy# : write memblock float mem, 112, hz#  :   `6 vertex
   write memblock float mem, 116, gx# : write memblock float mem, 120, gy# : write memblock float mem, 124, gz#  :   `7 vertex
   `left face
   write memblock float mem, 128, bx# : write memblock float mem, 132, by# : write memblock float mem, 136, bz#  :   `8 vertex
   write memblock float mem, 140, fx# : write memblock float mem, 144, fy# : write memblock float mem, 148, fz#  :   `9 vertex
   write memblock float mem, 152, dx# : write memblock float mem, 156, dy# : write memblock float mem, 160, dz#  :   `10 vertex
   write memblock float mem, 164, hx# : write memblock float mem, 168, hy# : write memblock float mem, 172, hz#  :   `11 vertex
   `right face
   write memblock float mem, 176, ex# : write memblock float mem, 180, ey# : write memblock float mem, 184, ez#  :   `12 vertex
   write memblock float mem, 188, ax# : write memblock float mem, 192, ay# : write memblock float mem, 196, az#  :   `13 vertex
   write memblock float mem, 200, gx# : write memblock float mem, 204, gy# : write memblock float mem, 208, gz#  :   `14 vertex
   write memblock float mem, 212, cx# : write memblock float mem, 216, cy# : write memblock float mem, 220, cz#  :   `15 vertex
   `top face
   write memblock float mem, 224, hx# : write memblock float mem, 228, hy# : write memblock float mem, 232, hz#  :   `16 vertex
   write memblock float mem, 236, gx# : write memblock float mem, 240, gy# : write memblock float mem, 244, gz#  :   `17 vertex
   write memblock float mem, 248, dx# : write memblock float mem, 252, dy# : write memblock float mem, 256, dz#  :   `18 vertex
   write memblock float mem, 260, cx# : write memblock float mem, 264, cy# : write memblock float mem, 268, cz#  :   `19 vertex
   `bottom face
   write memblock float mem, 272, bx# : write memblock float mem, 276, by# : write memblock float mem, 280, bz#  :   `20 vertex
   write memblock float mem, 284, ax# : write memblock float mem, 288, ay# : write memblock float mem, 292, az#  :   `21 vertex
   write memblock float mem, 296, fx# : write memblock float mem, 300, fy# : write memblock float mem, 304, fz#  :   `22 vertex
   write memblock float mem, 308, ex# : write memblock float mem, 312, ey# : write memblock float mem, 316, ez#  :   `23 vertex

   `write normal data to memblock
   restore _normdata
   for pos = pos_norms to pos_norms+(num_norms*12)-12 step 12
      read x,y,z
      write memblock float mem, pos, x
      write memblock float mem, pos+4, y
      write memblock float mem, pos+8, z
   next pos

   `write face data to memblock
   restore _facedata
   for pos = pos_faces to pos_faces+(num_faces*28)-28 step 28
      read nvf, va,na, vb, nb, vc,nc
      write memblock dword mem, pos, nvf
      write memblock dword mem, pos+4, va
      write memblock dword mem, pos+8, na
      write memblock dword mem, pos+12, vb
      write memblock dword mem, pos+16, nb
      write memblock dword mem, pos+20, vc
      write memblock dword mem, pos+24, nc
   next pos

   `write UV data to memblock
   restore _uvdata
   for pos = pos_uv to pos_uv+(num_sides*32)-32 step 32
      read ua#,va#, ub#,vb#, uc#,vc#, ud#,vd#
      write memblock float mem, pos, ua#
      write memblock float mem, pos+4, va#
      write memblock float mem, pos+8, ub#
      write memblock float mem, pos+12, vb#
      write memblock float mem, pos+16, uc#
      write memblock float mem, pos+20, vc#
      write memblock float mem, pos+24, ud#
      write memblock float mem, pos+28, vd#
   next pos

   `create mesh then create object, delete mesh and memblock
   make mesh from memblock num, mem
   delete memblock 1

   _normdata:
   data 0,0,1,  0,0,1,  0,0,1, 0,0,1         :`front
   data 0,0,-1,  0,0,-1,  0,0,-1,  0,0,-1    :`back
   data -1,0,0,  -1,0,0,  -1,0,0,  -1,0,0    :`left
   data 1,0,0,  1,0,0,  1,0,0,  1,0,0        :`right
   data 0,1,0,  0,1,0,  0,1,0,  0,1,0        :`top
   data 0,-1,0,  0,-1,0,  0,-1,0,  0,-1,0    :`bottom

   _facedata:
   data 3,  0,0,  3,3,  1,1          :`front face 0
   data 3,  3,3,  0,0,  2,2          :`front face 1
   data 3,  4,4,  7,7,  5,5          :`back face 2
   data 3,  7,7,  4,4,  6,6          :`back face 3
   data 3,  8,8,  11,11,  9,9        :`left face 4
   data 3,  11,11,  8,8,  10,10      :`left face 5
   data 3,  12,12,  15,15,  13,13    :`right face 6
   data 3,  15,15,  12,12,  14,14    :`right face 7
   data 3,  16,16,  19,19,  17,17    :`top face 8
   data 3,  19,19,  16,16,  18,18    :`top face 9
   data 3,  20,20,  23,23,  21,21    :`bottom face 10
   data 3,  23,23,  20,20,  22,22    :`bottom face 11

   _uvdata:
   data 0.03,0.47,  0.30,0.47,  0.03,0.03,  0.30,0.03   :`front
   data 0.03,0.97,  0.30,0.97,  0.03,0.53,  0.30,0.53   :`back
   data 0.36,0.47,  0.63,0.47,  0.36,0.03,  0.63,0.03   :`left
   data 0.36,0.97,  0.63,0.97,  0.36,0.53,  0.63,0.53   :`right
   data 0.69,0.47,  0.97,0.47,  0.69,0.03,  0.97,0.03   :`top
   data 0.69,0.97,  0.97,0.97,  0.69,0.53,  0.97,0.53   :`bottom


endfunction

I've never done "camera work" before so for me this was something new.

Back to top

Profile PM Email

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 15th Dec 2010 09:08

Link

@29 games

Wow! That's a lot of fun! Really cool demo! I like the sliding under the 18 wheeler. I've gotta try and put something together...

Enjoy your day.

Back to top

Profile PM

29 games

18

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 22nd Dec 2010 00:53

Link

Glad you liked it, I was pretty pleased with the slide under the truck.

You should definitely post something.

Back to top

Profile PM Email

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 24th Dec 2010 20:30

Link

I should have something put together in a couple of days.

Enjoy your day.

Back to top

Profile PM

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 7th Jan 2011 03:35

Link

I know I'm double posting, but for two reasons:

1. I'm bumping this thread up in the hopes that it doesn't whither away

2. I'm wondering if anyone has a couple of ideas for a winter scene/demo. I've been thinking about a couple of things, not sure how they'd come off. But I have a little time right now to maybe try and pull off the current 3d challenge so 29 games posting isn't all alone

Enjoy your day.

Back to top

Profile PM

Libervurto

17

Years of Service

User Offline

Joined: 30th Jun 2006

Location: On Toast

Posted: 8th Jan 2011 13:06 Edited at: 8th Jan 2011 14:43

Link

I almost have my computer sorted out.

I'll be entering as soon as DB works!

[edit]
I got it working!(minus sound)
I'm away for the weekend but I'll be planning...

Everything worthwhile requires effort.

Back to top

Profile PM Email

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 22nd Jan 2011 10:44

Link

I finally have an idea to try for the 3d challenge. Now I have to turn the idea into code... Yikes!

Enjoy your day.

Back to top

Profile PM

Libervurto

17

Years of Service

User Offline

Joined: 30th Jun 2006

Location: On Toast

Posted: 22nd Jan 2011 11:57

Link

Wow 29 games, that's impressive!
Lot's of stuff for me to learn from in your code.

Everything worthwhile requires effort.

Back to top

Profile PM Email

TheComet

16

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 22nd Jan 2011 21:19

Link

How about a challenge that has to use a snowman in the most creative/fun way?

TheComet

Back to top

Profile PM Email Website

29 games

18

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 26th Jan 2011 19:50

Link

Quote: "Now I have to turn the idea into code... Yikes"

Yep, that's the difficult bit

@Obese, glad you liked my demo.

I've found the most fun way to use snowmen is to build them in front of someone's front door, ring the bell and then run away.

Back to top

Profile PM Email

Libervurto

17

Years of Service

User Offline

Joined: 30th Jun 2006

Location: On Toast

Posted: 26th Jan 2011 20:31

Link

I've been struggling to think of anything to make and I wont be able to enter now because of real world problems

, It's okay though I'll still be on the forums and back to hopefully, finally entering this challenge again next month.

Everything worthwhile requires effort.

Back to top

Profile PM Email

Latch

17

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 21st Feb 2011 01:36

Link

Ok. I finished something a couple weeks ago. Everything in it is done by code. There is no external media at all. The sound is done by creating a wave file header, writing it to disk, then writing bytes for the sound data and loading it all back in as a sound. I originally did this through memblocks but there are a lot of bugs with making sounds from memblocks and making memblocks from sounds. There's much better control by writing the info to disk and then loading it back as a sound.

The 3d models were done through memblocks and also by using DBC's built in primatives and adding pieces as limbs.

I'm most pleased with the textures. I managed some bump mapping by using an embossing algorithm. And with a little ghosting and layering, I got a nice weathered look to the wood.

I'm posting it as an exe... a demo. There is a monologue that tells the story of what's happening as the demo plays. The last line is "Why Won't this Dream end?" so let it run at least until you see that line. After which, press the 'C' key to toggle between manual and automatic camera control. You can then move the camera around using the mouse and the arrow keys.

Press F key to toggle screen FPS display. The demo is designed to run at 800x600x32 resolution at 60 FPS.

You will have the option to select your own resolution though the bit depth is limited to 32. The higher the resolution, the more the textures "pop". But, the slower the demo may run.

HEADPHONE WARNING:
If your volume is up too high, the sound can be a little load so be careful if you use head phones.

It takes a little time to setup the sounds and the graphics so there are a couple of black screen pauses while this stuff is being done. So if you are at a black screen, just sit tight, something should eventually happen. But if it doesn't happen in less than 2 or 3 minutes, something could be wrong.

Be aware, sound files are written to your hard drive and then deleted. The files are saved with the name "snd_noise.wav" so if you have any real files with that name that you want to keep in the same directory that you run the demo from, then either put the demo somewhere else, or move the files you want to keep so they don't get overwritten and/or deleted.

Demo attached

Enjoy your day.

Attachments

Login to view attachments

Back to top

Profile PM

29 games

18

Years of Service

User Offline

Joined: 23rd Nov 2005

Location: not entirely sure

Posted: 21st Feb 2011 23:42

Link

That's very impressive. It had a good atmosphere. I really liked the ship model, the textures were really good.

Does the dream have an ending? I didn't know how long to watch it for.

Back to top

Profile PM Email

Sorry your browser is not supported!

DarkBASIC Discussion / The DB Classic Programming Challenge Thread

Attachments

Attachments