Sorry your browser is not supported!

REM Project: telnet client
REM Created: 6/1/2007 2:32:14 PM
REM
REM ***** Main Source File *****
REM
remstart
    These are from the include file, winerror.h These error codes can be used with the
    functions FormatSystemMessage and MessageBox to make better error reporting.
remend

#constant NO_ERROR                          = 0
#constant ERROR_NOT_SUPPORTED               = 50
#constant ERROR_INVALID_PARAMETER           = 87
#constant ERROR_INSUFFICIENT_BUFFER         = 122

remstart
    These are declared in iprtrmib.h and used by iphlpapi.dll
remend

type IPADDRROW
    dwAddr          as dword
    dwIndex         as dword
    dwMask          as dword
    dwBCastAddr     as dword
    dwReasmSize     as dword
    unused1         as word
    unused2         as word
endtype

dim ipaddress() as IPADDRROW

global tempdll as integer = 1
global dwdllreturn as dword = 0x00000000
global tempblk as integer = 1
global sort as boolean = 0
global nomakememoryblk as integer = 2
global ptr as dword = 0x00000000
global ptrsize as dword = 0x0000
global numaddresses as integer = 0
global i as integer = 0

remstart
Here are some typedefs from the Windows DLL iphlpapi.dll This is a great dll that can
cause you a great deal of grief. It can configure alot, and it will provide alot of
information, as well. There are literally dozens of other dlls that have networking
functionality, including legacy drivers for ancient systems. If you are serious about
writing substantial online systems, you will want the Platform SDK and it would also
help to Wiki TCP/IP, and all of the attendant protocols.

The way IP addresses are returned by Windows is typical of other Windows information
gathering APIs. You get back something that is not quite fixed in size, yet structured
in a way that favors C/C++. Not surprising, since the bulk of Windows is C/C++. In this
small example I show how I take what is important to me from that. The function call
GetIpAddrTable works like many Windows functions in that it requires a pointer to a
buffer, and a pointer to the size of the buffer. These functions will fail when the
buffer is too small, but they all return the required size, which is nice. There are
also functions that have related function to get the required size. They are handled a
little differently. I realize that the code looks messy, but it is a useful template,
nonetheless.

typedef struct _MIB_IPADDRROW
{
    DWORD dwAddr;
    DWORD dwIndex;
    DWORD dwMask;
    DWORD dwBCastAddr;
    DWORD dwReasmSize;
    unsigned short unused1;
    unsigned short unused2;
} MIB_IPADDRROW, *PMIB_IPADDRROW;

typedef struct _MIB_IPADDRTABLE
{
    DWORD dwNumEntries;
    MIB_IPADDRROW table[ANY_SIZE];
} MIB_IPADDRTABLE, *PMIB_IPADDRTABLE;

remend

sync off
autocam off
empty array ipaddress()         rem Voodoo. I want to be sure the array is virginal.
load dll "iphlpapi.dll", tempdll
make memblock tempblk, 256
ptr = get memblock ptr(tempblk)
fill memory ptr, 0x00, 256
make memblock nomakememoryblk, 4
ptrsize = get memblock ptr(nomakememoryblk)

remstart Buffer is 256, which is plenty in most cases, unless you have multiple
         cards, or software that uses some sort of ip masquerading. I can just
         call it on my machine, but 256 will be too small at some point; sooner
         rather than later! This is a good example of writing a routine that you
         know will fail. It is sometimes better to control when it fails, so that
         you can take appropriate action.
remend

*ptrsize = 0    rem Pretend buffer is too small.
dwdllreturn = call dll(tempdll, "GetIpAddrTable", ptr, ptrsize, sort)
if dwdllreturn = ERROR_INSUFFICIENT_BUFFER
    delete memblock tempblk
    make memblock tempblk, *ptrsize
    ptr = get memblock ptr(tempblk)
    fill memory ptr, 0x00, *ptrsize
    dwdllreturn = call dll(tempdll, "GetIpAddrTable", ptr, ptrsize, sort)
endif

remstart
    Now the buffer contains the number of IP addresses, followed by an array of
    MIB_ADDRROW structures. I want the MIB_ADDRROW structures, so I duplicated
    the structure in DBPro, and have a dynamic array waitng to be filled. This
    must be done in a memberwise manner. Not really a problem, but surely a source
    of confusion at first to programmers. Just watch for now and take a dramamine.
remend

if dwdllreturn = NO_ERROR
    numaddresses = *ptr     rem Save the number of IP addresses.
    inc ptr, 4              rem move the pointer to the first MIB_ADDROW structure.
    for i = 0 to numaddresses - 1
        array insert at bottom ipaddress()  rem Make a new structure (UDT).
        ipaddress().dwAddr = *ptr           rem Memberwise assignment using a pointer.
        inc ptr, 4                          rem Some people have problems with this
        ipaddress().dwIndex = *ptr          rem because DBPro does not always know
        inc ptr, 4                          rem what ptr is pointing at. In this case
        ipaddress().dwMask = *ptr           rem since the source is DWORDS/WORDS, and
        inc ptr, 4                          rem the destination is known, all is well
        ipaddress().dwBCastAddr = *ptr      rem as long as we increment the pointer
        inc ptr, 4                          rem properly.
        ipaddress().dwReasmSize = *ptr
        inc ptr, 4
        ipaddress().unused1 = *ptr
        inc ptr, 2
        ipaddress().unused2 = *ptr
        inc ptr, 2
    next i
endif

remstart
    Here is some Three Card Monte that is typical of heterogenous network programming.
    What? Heterogenous. The Internet is composed of many different types of subnets
    with different type of computers attached. Our machines use Little-Endian byte
    ordering (LSB first), sometimes referred to as Intel format. The other one,
    Big-Endian is called Motorola format. (PC vs. Mac again) Windows has alot of helper
    functions for reordering bytes, and also there is a function to make strings from
    IP addresses, and parse then into bytes, too. If you apsire to cross-platform
    development that includes Mac, for example...you need to get these routines
    under your belt, but fast. I am just reversing the bytes of a dword and making a
    string from that.
remend

for i = 0 to array count(ipaddress())
    print "IP Address " + str$(i) + ": " + ...
          str$(ipaddress(i).dwAddr && 0x000000ff) + "." + ...
          str$((ipaddress(i).dwAddr && 0x0000ff00) >> 8) + "." + ...
          str$((ipaddress(i).dwAddr && 0x00ff0000) >> 16) + "." + ...
          str$((ipaddress(i).dwAddr && 0xff000000) >> 24)
next i

do
    rem
loop
delete dll tempdll
delete memblock tempblk
delete memblock nomakememoryblk
end

#constant NO_ERROR                          = 0
#constant ERROR_NOT_SUPPORTED               = 50
#constant ERROR_INVALID_PARAMETER           = 87
#constant ERROR_INSUFFICIENT_BUFFER         = 122

type IPADDRROW
    dwAddr          as dword
    dwIndex         as dword
    dwMask          as dword
    dwBCastAddr     as dword
    dwReasmSize     as dword
    unused1         as word
    unused2         as word
endtype

dim ipaddress() as IPADDRROW
global i as integer

sync off
autocam off

GetIPAddressTable()
for i = -1 to array count(ipaddress()) + 2
    print GetIPAddressString(i)
next i

do
    rem
loop
end

function GetIPAddressString(address as integer)
    local buildstr as string

    buildstr = str$(address) + " is an invalid IP Address Table entry."
    if address  > -1 and address <= array count(ipaddress())
        buildstr = str$(ipaddress(address).dwAddr && 0x000000ff) + "." + ...
          str$((ipaddress(address).dwAddr && 0x0000ff00) >> 8) + "." + ...
          str$((ipaddress(address).dwAddr && 0x00ff0000) >> 16) + "." + ...
          str$((ipaddress(address).dwAddr && 0xff000000) >> 24)
    endif
endfunction buildstr

function GetIPAddressTable()
    local tempdll as integer = 1
    local dwdllreturn as dword = 0x00000000
    local sort as boolean = 0
    local nomakememoryblk as integer = 1
    local tempblk as integer = 2
    local ptr as dword = 0x00000000
    local ptrsize as dword = 0x0000
    local numaddresses as integer = 0
    local i as integer = 0

    while dll exist(tempdll) and tempdll < 255
        inc tempdll
    endwhile
    if tempdll > 255
        exitfunction
    endif
    while memblock exist(nomakememoryblk) and nomakememoryblk < 32768
        inc nomakememoryblk
    endwhile
    if nomakememoryblk > 32767
        exitfunction
    endif
    tempblk = nomakememoryblk + 1
    while memblock exist(tempblk) and tempblk < 32768
        inc tempblk
    endwhile
    if tempblk > 32768
        exitfunction
    endif
    load dll "iphlpapi.dll", tempdll
    empty array ipaddress()
    make memblock nomakememoryblk, 4
    ptrsize = get memblock ptr(nomakememoryblk)
    *ptrsize = 0
    dwdllreturn = call dll(tempdll, "GetIpAddrTable", 0x00000000, ptrsize, sort)
    make memblock tempblk, *ptrsize
    ptr = get memblock ptr(tempblk)
    fill memory ptr, 0x00, *ptrsize
    dwdllreturn = call dll(tempdll, "GetIpAddrTable", ptr, ptrsize, sort)
    if dwdllreturn = NO_ERROR
        numaddresses = *ptr
        inc ptr, 4
        for i = 0 to numaddresses - 1
            array insert at bottom ipaddress()
            ipaddress().dwAddr = *ptr
            inc ptr, 4
            ipaddress().dwIndex = *ptr
            inc ptr, 4
            ipaddress().dwMask = *ptr
            inc ptr, 4
            ipaddress().dwBCastAddr = *ptr
            inc ptr, 4
            ipaddress().dwReasmSize = *ptr
            inc ptr, 4
            ipaddress().unused1 = *ptr
            inc ptr, 2
            ipaddress().unused2 = *ptr
            inc ptr, 2
        next i
    endif
    delete dll tempdll
    delete memblock tempblk
    delete memblock nomakememoryblk
endfunction

typedef struct _MIB_IPADDRROW
{
    DWORD dwAddr;
    DWORD dwIndex;
    DWORD dwMask;
    DWORD dwBCastAddr;
    DWORD dwReasmSize;
    unsigned short unused1;
    unsigned short unused2;
} MIB_IPADDRROW, *PMIB_IPADDRROW;

typedef struct _MIB_IPADDRTABLE
{
    DWORD dwNumEntries;
    MIB_IPADDRROW table[ANY_SIZE];
} MIB_IPADDRTABLE, *PMIB_IPADDRTABLE;

Members
dwAddr 
Specifies the IP address. 
dwIndex 
Specifies the index of the interface associated with this IP
 address. 
dwMask 
Specifies the subnet mask for the IP address. 
dwBCastAddr 
Specifies the broadcast address. A broadcast address is typically
 the IP address with the host portion set to either all zeros or
 all ones. 
dwReasmSize 
Specifies the maximum re-assembly size for received datagrams. 
unused1 
This member is reserved. 
unused2 
This member is reserved. 

The Win32 Internet Extensions, or WinInet, provide access to common
Internet protocols, including gopher, FTP, and HTTP. Using WinInet,
you can write Internet client applications at a higher level of
programming, without having to deal with WinSock, TCP/IP, or the
details of specific Internet protocols. WinInet provides a consistent
set of functions for all three protocols, with a familiar Win32 API
interface. This consistency minimizes code changes you need to make
if the underlying protocol changes (for example, from FTP to HTTP). 

Visual C++ provides two ways for you to use WinInet. You can call
the Win32 Internet functions directly (see the OLE documentation in
the Platform SDK for more information) or you can use WinInet through
the MFC WinInet classes.

You can use WinInet to: 

Download HTML pages. 
HTTP is a protocol used to transfer HTML pages from a server to a
client browser. 

Send FTP requests to upload or download files or get directory listings. 
A typical request is an anonymous logon to download a file. 

Use gopher's menu system for accessing resources on the Internet. 
Menu items can be several types, including other menus, an indexed
database you can search, a newsgroup, or a file. 

For all three protocols, you establish a connection, make requests to
the server, and close the connection.

The MFC WinInet classes make it easy to: 

Read information from HTTP, FTP, and gopher servers as easily as reading
files from a hard drive. 
Use HTTP, FTP, and gopher protocols without programming directly to WinSock
or TCP/IP. 
Developers who use the Win32 Internet functions do not need to be familiar
with TCP/IP or Windows Sockets. You can still program at the socket level,
using WinSock and TCP/IP protocols directly, but it's even easier to use
the MFC WinInet classes to access HTTP, FTP, and gopher protocols across
the Internet. For many common operations, developers do not need to know
the details of the particular protocol they are using. 

Many operations that can be performed by your computer as a client to
other computers on the Internet can take a long time. The speed of these
operations is usually limited by the speed of your network connection, but
they can also be affected by other network traffic and the complexity of
the operation. Connecting to a remote FTP server, for example, requires
that your computer first look up the name of that server to find its
address. Your application will then attempt to connect to the server at
that address. Once the connection is opened, your computer and the remote
server will initiate a conversation with the file transfer protocol before
you can actually use the connection to retrieve files. 

See Also
Win32 Internet Extensions (WinInet) | How MFC Makes It Easier to Create
Internet Client Applications

<html>
<head>
<title>IP Address String goes here.</title>
<meta name="GENERATOR" content="Microsoft Visual Studio .NET 7.1">
<meta name="vs_targetSchema" content="http://schemas.microsoft.com/intellisense/ie5">
Also, you can define a meta string of your own, and put it here, if you want.
</head>
<body>
Naturally, here is also fair game.
</body>
</html>

REM Project: wiseclient
REM Created: 6/7/2007 10:49:55 AM
REM
REM ***** Main Source File *****
REM
#constant NO_ERROR                          = 0
#constant ERROR_NOT_SUPPORTED               = 50
#constant ERROR_INVALID_PARAMETER           = 87
#constant ERROR_INSUFFICIENT_BUFFER         = 122

#constant MESSAGE_ID_NAME           = 0
#constant MESSAGE_ID_STRING         = 0
#constant MESSAGE_ID_LOGONPWD       = 251
#constant MESSAGE_ID_LOGONNAME      = 252
#constant MESSAGE_ID_IFF            = 253
#constant MESSAGE_NACK              = 254
#constant MESSAGE_ACK               = 255

#constant INTERNET_OPEN_TYPE_PRECONFIG                    = 0
#constant INTERNET_OPEN_TYPE_DIRECT                       = 1
#constant INTERNET_OPEN_TYPE_PROXY                        = 3
#constant INTERNET_OPEN_TYPE_PRECONFIG_WITH_NO_AUTOPROXY  = 4

#constant INTERNET_FLAG_ASYNC       = 0x10000000
#constant INTERNET_FLAG_FROM_CACHE  = 0x01000000
#constant INTERNET_FLAG_OFFLINE     = INTERNET_FLAG_FROM_CACHE

#constant INTERNET_INVALID_PORT_NUMBER    = 0
#constant INTERNET_DEFAULT_FTP_PORT       = 21
#constant INTERNET_DEFAULT_GOPHER_PORT    = 70
#constant INTERNET_DEFAULT_HTTP_PORT      = 80
#constant INTERNET_DEFAULT_HTTPS_PORT     = 443
#constant INTERNET_DEFAULT_SOCKS_PORT     = 1080

#constant INTERNET_SERVICE_FTP    = 1
#constant INTERNET_SERVICE_GOPHER = 2
#constant INTERNET_SERVICE_HTTP   = 3

#constant HTTP_QUERY_CONTENT_LENGTH     = 5
#constant HTTP_QUERY_FLAG_NUMBER        = 0x20000000
#constant FLAG_ICC_FORCE_CONNECTION     = 0x00000001

type IPADDRROW
    dwAddr          as dword
    dwIndex         as dword
    dwMask          as dword
    dwBCastAddr     as dword
    dwReasmSize     as dword
    unused1         as word
    unused2         as word
endtype

dim ipaddress() as IPADDRROW

global i as integer
global wininet as integer = 0
global hInternet as dword = 0x00000000
global hHTTPRequest as dword = 0x00000000
global hHTTPSession as dword = 0x00000000
global memory as integer = 0
global ptr as dword = 0x00000000
global result as integer = 0
global appname as string
global clientname as string
global remoteserver as string

appname = appname$()
clientname = "Wise Client"

sync off
autocam off
set text transparent
set text font "terminal"
set text size 14
set text to bold

InitializeWinInet()
remoteserver = HTTPGetRemoteServerAddress("geocities.com", ...
                                          "/mtb61275/dbpro/test.htm")
GetIPAddressTable()
print clientname
print remoteserver

do
    rem
loop
dwreturn = call dll(wininet, "InternetCloseHandle", hInternet)
delete dll wininet
if memory > 0
    if memblock exist(memory)
        delete memblock memory
    endif
endif
end

function GetIPAddressString(address as integer)
    local buildstr as string

    buildstr = str$(address) + " is an invalid IP Address Table entry."
    if address  > -1 and address <= array count(ipaddress())
        buildstr = str$(ipaddress(address).dwAddr && 0x000000ff) + "." + ...
          str$((ipaddress(address).dwAddr && 0x0000ff00) >> 8) + "." + ...
          str$((ipaddress(address).dwAddr && 0x00ff0000) >> 16) + "." + ...
          str$((ipaddress(address).dwAddr && 0xff000000) >> 24)
    endif
endfunction buildstr

function GetIPAddressTable()
    local tempdll as integer = 1
    local dwdllreturn as dword = 0x00000000
    local sort as boolean = 0
    local nomakememoryblk as integer = 1
    local tempblk as integer = 2
    local ptr as dword = 0x00000000
    local ptrsize as dword = 0x0000
    local numaddresses as integer = 0
    local i as integer = 0

    while dll exist(tempdll) and tempdll < 255
        inc tempdll
    endwhile
    if tempdll > 255
        exitfunction
    endif
    while memblock exist(nomakememoryblk) and nomakememoryblk < 32768
        inc nomakememoryblk
    endwhile
    if nomakememoryblk > 32767
        exitfunction
    endif
    tempblk = nomakememoryblk + 1
    while memblock exist(tempblk) and tempblk < 32768
        inc tempblk
    endwhile
    if tempblk > 32768
        exitfunction
    endif
    load dll "iphlpapi.dll", tempdll
    empty array ipaddress()
    make memblock nomakememoryblk, 4
    ptrsize = get memblock ptr(nomakememoryblk)
    *ptrsize = 0
    dwdllreturn = call dll(tempdll, "GetIpAddrTable", 0x00000000, ptrsize, sort)
    make memblock tempblk, *ptrsize
    ptr = get memblock ptr(tempblk)
    fill memory ptr, 0x00, *ptrsize
    dwdllreturn = call dll(tempdll, "GetIpAddrTable", ptr, ptrsize, sort)
    if dwdllreturn = NO_ERROR
        numaddresses = *ptr
        inc ptr, 4
        for i = 0 to numaddresses - 1
            array insert at bottom ipaddress()
            ipaddress().dwAddr = *ptr
            inc ptr, 4
            ipaddress().dwIndex = *ptr
            inc ptr, 4
            ipaddress().dwMask = *ptr
            inc ptr, 4
            ipaddress().dwBCastAddr = *ptr
            inc ptr, 4
            ipaddress().dwReasmSize = *ptr
            inc ptr, 4
            ipaddress().unused1 = *ptr
            inc ptr, 2
            ipaddress().unused2 = *ptr
            inc ptr, 2
        next i
    endif
    delete dll tempdll
    delete memblock tempblk
    delete memblock nomakememoryblk
endfunction

function HTTPGetRemoteServerAddress(host as string, document as string)
    local buildstr as string
    local dwreturn as dword = 0x00000000
    local ptrbytesread as dword = 0x00000000
    local buffer as dword = 0x00000000

    buildstr = "Unable to connect to " + host
    if hInternet <> 0
        hHTTPSession = call dll(wininet, "InternetConnectA", hInternet, ...
                                host, INTERNET_DEFAULT_HTTP_PORT, 0x00000000, ...
                                0x00000000, INTERNET_SERVICE_HTTP, 0x00000000, ...
                                0x00000000)
        if hHTTPSession = 0
            rem error
        else
            hHTTPRequest = call dll(wininet, "HttpOpenRequestA", hHTTPSession, ...
                                    0x00000000, document, 0x00000000, 0x00000000, ...
                                    0x00000000, 0x00000000, 0x00000000)
            if hHTTPRequest = 0
                rem error
            else
                dwreturn = call dll(wininet, "HttpSendRequestA", hHTTPRequest, ...
                                    0x00000000, 0x00000000, 0x00000000, ...
                                    0x00000000)
                if dwreturn <> 1
                    rem error
                else
                    ptrbytesread = make memory(4)
                    fill memory ptrbytesread, 0x00, 4
                    buffer = get memblock ptr(memory)
                    dwreturn = call dll(wininet, "InternetReadFile", ...
                                        hHTTPRequest, buffer, 2048, ptrbytesread)
                    inc buffer, *ptrbytesread
                    dwreturn = *ptrbytesread
                    while dwreturn <> 0
                        dwreturn = call dll(wininet, "InternetReadFile", ...
                                            hHTTPRequest, buffer, 2048, ptrbytesread)
                        inc buffer, *ptrbytesread
                        dwreturn = *ptrbytesread
                    endwhile
                    buildstr = jzMakeDBString(memory)
                    delete memory ptrbytesread
                endif
                dwreturn = call dll(wininet, "InternetCloseHandle", hHTTPRequest)
            endif
            dwreturn = call dll(wininet, "InternetCloseHandle", hHTTPSession)
        endif
    endif
endfunction buildstr

function InitializeWinInet()
    local dwreturn as dword

    wininet = jzGetNextAvailableDLLID(0, 1)
    load dll "wininet.dll", wininet
    dwreturn = call dll(wininet, "InternetAttemptConnect", 0x00000000)
    if dwreturn <> 0
        hInternet = 0x00000000
    else
        hInternet = call dll(wininet, "InternetOpenA", appname, ...
                             INTERNET_OPEN_TYPE_PRECONFIG, 0x00000000, 0x00000000, ...
                             0x00000000)
        memory = jzGetNextAvailableMemblockID(1)
        make memblock memory, 32768
        ptr = get memblock ptr(memory)
    endif
endfunction

function jzGetNextAvailableDLLID(bDown as boolean, seed as integer)
   local temp = seed

   if seed < 1 or seed > 255 then exitfunction -1
   do
      if dll exist(temp) = 0 then exitfunction temp
      if bDown = 1
         dec temp
      else
         inc temp
      endif
      if temp < 1 or temp > 255 then exitfunction -1
   loop
endfunction -1

function jzGetNextAvailableMemblockID(seed as integer)
   local temp = seed

   if seed < 1 then exitfunction -1
   do
      if memblock exist(temp) = 0 then exitfunction temp
      inc temp
      if temp < 0 then exitfunction -1
   loop
endfunction -1

function jzMakeDBString(cstring_blockID as integer)
    local ivalue as integer
    local icount as integer
    local offset as integer
    local buildstr as string

    offset = 0
    icount = 0
    buildstr = ""
    ivalue = memblock byte(cstring_blockID, offset)
    while ivalue > 0
        buildstr = buildstr + chr$(ivalue)
        inc offset
        inc icount
        if icount > 32767 then exitfunction buildstr
        ivalue = memblock byte(cstring_blockID, offset)
    endwhile
endfunction buildstr

REM Project: wiseclient
REM Created: 6/7/2007 10:49:55 AM
REM
REM ***** Main Source File *****
REM
#constant NO_ERROR                          = 0
#constant ERROR_NOT_SUPPORTED               = 50
#constant ERROR_INVALID_PARAMETER           = 87
#constant ERROR_INSUFFICIENT_BUFFER         = 122

#constant MESSAGE_ID_NAME           = 0
#constant MESSAGE_ID_STRING         = 0
#constant MESSAGE_ID_LOGONPWD       = 251
#constant MESSAGE_ID_LOGONNAME      = 252
#constant MESSAGE_ID_IFF            = 253
#constant MESSAGE_NACK              = 254
#constant MESSAGE_ACK               = 255

#constant INTERNET_OPEN_TYPE_PRECONFIG                    = 0
#constant INTERNET_OPEN_TYPE_DIRECT                       = 1
#constant INTERNET_OPEN_TYPE_PROXY                        = 3
#constant INTERNET_OPEN_TYPE_PRECONFIG_WITH_NO_AUTOPROXY  = 4

#constant INTERNET_FLAG_ASYNC       = 0x10000000
#constant INTERNET_FLAG_FROM_CACHE  = 0x01000000
#constant INTERNET_FLAG_OFFLINE     = INTERNET_FLAG_FROM_CACHE

#constant INTERNET_INVALID_PORT_NUMBER    = 0
#constant INTERNET_DEFAULT_FTP_PORT       = 21
#constant INTERNET_DEFAULT_GOPHER_PORT    = 70
#constant INTERNET_DEFAULT_HTTP_PORT      = 80
#constant INTERNET_DEFAULT_HTTPS_PORT     = 443
#constant INTERNET_DEFAULT_SOCKS_PORT     = 1080

#constant INTERNET_SERVICE_FTP    = 1
#constant INTERNET_SERVICE_GOPHER = 2
#constant INTERNET_SERVICE_HTTP   = 3

#constant HTTP_QUERY_CONTENT_LENGTH     = 5
#constant HTTP_QUERY_FLAG_NUMBER        = 0x20000000
#constant FLAG_ICC_FORCE_CONNECTION     = 0x00000001

#constant TAG_DELIMIT_BEGIN             = "<"
#constant TAG_DELIMIT_END               = ">"
#constant TAG_CLOSE                     = "/"

type IPADDRROW
    dwAddr          as dword
    dwIndex         as dword
    dwMask          as dword
    dwBCastAddr     as dword
    dwReasmSize     as dword
    unused1         as word
    unused2         as word
endtype

dim ipaddress() as IPADDRROW

global i as integer
global wininet as integer = 0
global cruntime as integer = 0
global hInternet as dword = 0x00000000
global hHTTPRequest as dword = 0x00000000
global hHTTPSession as dword = 0x00000000
global memory as integer = 0
global ptr as dword = 0x00000000
global result as integer = 0
global appname as string
global clientname as string
global remoteserver as string

appname = appname$()
clientname = "Wise Client"

sync off
autocam off
set text transparent
set text font "terminal"
set text size 14
set text to bold

GetIPAddressTable()
InitializeCRuntime()
InitializeWinInet()
remoteserver = HTTPGetRemoteServerAddress("geocities.com", ...
                                          "/mtb61275/dbpro/test.htm")
print clientname
print GetHTMLTagContent("<title>", remoteserver)

do
    rem
loop
dwreturn = call dll(wininet, "InternetCloseHandle", hInternet)
delete dll wininet
if memory > 0
    if memblock exist(memory)
        delete memblock memory
    endif
endif
delete dll cruntime
end

function GetIPAddressString(address as integer)
    local buildstr as string

    buildstr = str$(address) + " is an invalid IP Address Table entry."
    if address  > -1 and address <= array count(ipaddress())
        buildstr = str$(ipaddress(address).dwAddr && 0x000000ff) + "." + ...
          str$((ipaddress(address).dwAddr && 0x0000ff00) >> 8) + "." + ...
          str$((ipaddress(address).dwAddr && 0x00ff0000) >> 16) + "." + ...
          str$((ipaddress(address).dwAddr && 0xff000000) >> 24)
    endif
endfunction buildstr

function GetIPAddressTable()
    local tempdll as integer = 1
    local dwdllreturn as dword = 0x00000000
    local sort as boolean = 0
    local nomakememoryblk as integer = 1
    local tempblk as integer = 2
    local ptr as dword = 0x00000000
    local ptrsize as dword = 0x0000
    local numaddresses as integer = 0
    local i as integer = 0

    while dll exist(tempdll) and tempdll < 255
        inc tempdll
    endwhile
    if tempdll > 255
        exitfunction
    endif
    while memblock exist(nomakememoryblk) and nomakememoryblk < 32768
        inc nomakememoryblk
    endwhile
    if nomakememoryblk > 32767
        exitfunction
    endif
    tempblk = nomakememoryblk + 1
    while memblock exist(tempblk) and tempblk < 32768
        inc tempblk
    endwhile
    if tempblk > 32768
        exitfunction
    endif
    load dll "iphlpapi.dll", tempdll
    empty array ipaddress()
    make memblock nomakememoryblk, 4
    ptrsize = get memblock ptr(nomakememoryblk)
    *ptrsize = 0
    dwdllreturn = call dll(tempdll, "GetIpAddrTable", 0x00000000, ptrsize, sort)
    make memblock tempblk, *ptrsize
    ptr = get memblock ptr(tempblk)
    fill memory ptr, 0x00, *ptrsize
    dwdllreturn = call dll(tempdll, "GetIpAddrTable", ptr, ptrsize, sort)
    if dwdllreturn = NO_ERROR
        numaddresses = *ptr
        inc ptr, 4
        for i = 0 to numaddresses - 1
            array insert at bottom ipaddress()
            ipaddress().dwAddr = *ptr
            inc ptr, 4
            ipaddress().dwIndex = *ptr
            inc ptr, 4
            ipaddress().dwMask = *ptr
            inc ptr, 4
            ipaddress().dwBCastAddr = *ptr
            inc ptr, 4
            ipaddress().dwReasmSize = *ptr
            inc ptr, 4
            ipaddress().unused1 = *ptr
            inc ptr, 2
            ipaddress().unused2 = *ptr
            inc ptr, 2
        next i
    endif
    delete dll tempdll
    delete memblock tempblk
    delete memblock nomakememoryblk
endfunction

function HTTPGetRemoteServerAddress(host as string, document as string)
    local buildstr as string
    local dwreturn as dword = 0x00000000
    local ptrbytesread as dword = 0x00000000
    local buffer as dword = 0x00000000

    buildstr = "Unable to connect to " + host
    if hInternet <> 0
        hHTTPSession = call dll(wininet, "InternetConnectA", hInternet, ...
                                host, INTERNET_DEFAULT_HTTP_PORT, 0x00000000, ...
                                0x00000000, INTERNET_SERVICE_HTTP, 0x00000000, ...
                                0x00000000)
        if hHTTPSession = 0
            rem error
        else
            hHTTPRequest = call dll(wininet, "HttpOpenRequestA", hHTTPSession, ...
                                    0x00000000, document, 0x00000000, 0x00000000, ...
                                    0x00000000, 0x00000000, 0x00000000)
            if hHTTPRequest = 0
                rem error
            else
                dwreturn = call dll(wininet, "HttpSendRequestA", hHTTPRequest, ...
                                    0x00000000, 0x00000000, 0x00000000, ...
                                    0x00000000)
                if dwreturn <> 1
                    rem error
                else
                    ptrbytesread = make memory(4)
                    fill memory ptrbytesread, 0x00, 4
                    buffer = get memblock ptr(memory)
                    dwreturn = call dll(wininet, "InternetReadFile", ...
                                        hHTTPRequest, buffer, 2048, ptrbytesread)
                    inc buffer, *ptrbytesread
                    dwreturn = *ptrbytesread
                    while dwreturn <> 0
                        dwreturn = call dll(wininet, "InternetReadFile", ...
                                            hHTTPRequest, buffer, 2048, ptrbytesread)
                        inc buffer, *ptrbytesread
                        dwreturn = *ptrbytesread
                    endwhile
                    buildstr = jzMakeDBString(memory)
                    delete memory ptrbytesread
                endif
                dwreturn = call dll(wininet, "InternetCloseHandle", hHTTPRequest)
            endif
            dwreturn = call dll(wininet, "InternetCloseHandle", hHTTPSession)
        endif
    endif
endfunction buildstr

function InitializeCRuntime()
    cruntime = jzGetNextAvailableDLLID(0, 1)
    load dll "msvcrt.dll", cruntime
endfunction

function InitializeWinInet()
    local dwreturn as dword

    wininet = jzGetNextAvailableDLLID(0, 1)
    load dll "wininet.dll", wininet
    dwreturn = call dll(wininet, "InternetAttemptConnect", 0x00000000)
    if dwreturn <> 0
        hInternet = 0x00000000
    else
        hInternet = call dll(wininet, "InternetOpenA", appname, ...
                             INTERNET_OPEN_TYPE_PRECONFIG, 0x00000000, 0x00000000, ...
                             0x00000000)
        memory = jzGetNextAvailableMemblockID(1)
        make memblock memory, 32768
        ptr = get memblock ptr(memory)
    endif
endfunction

function GetHTMLTagContent(nexttag as string, source as string)
    local buildstr as string
    local tagclosestr as string
    local teststr as string
    local tag_open as boolean
    local tag_closed as boolean
    local srclen as integer
    local taglen as integer
    local tagcloselen as integer
    local start as integer
    local stop as integer
    local ireturn as integer
    local j as integer

    buildstr = "Tag not found."
    if mid$(nexttag, 1) <> TAG_DELIMIT_BEGIN
        nexttag = TAG_DELIMIT_BEGIN + nexttag
    endif
    if mid$(nexttag, len(nexttag)) <> TAG_DELIMIT_END
        nexttag = nexttag + TAG_DELIMIT_END
    endif
    tag_open = 0
    tag_closed = 0
    start = 0
    stop = 0
    srclen = len(source)
    taglen = len(nexttag)
    tagclosestr = TAG_DELIMIT_BEGIN
    tagclosestr = tagclosestr + TAG_CLOSE
    tagclosestr = tagclosestr + right$(nexttag, taglen - 1)
    tagcloselen = len(tagclosestr)
    for j = 1 to srclen
        if tag_open = 0
            if mid$(source, j) = TAG_DELIMIT_BEGIN
                teststr = right$(source, srclen - (j - 1))
                ireturn = call dll(cruntime, "_strnicmp", nexttag, teststr, taglen)
                if ireturn = 0
                    tag_open = 1
                    start = j - 1
                endif
            endif
        else
            if tag_closed = 0
                if mid$(source, j) = TAG_DELIMIT_BEGIN
                    teststr = right$(source, srclen - (j - 1))
                    ireturn = call dll(cruntime, "_strnicmp", tagclosestr, ...
                                       teststr, tagcloselen)
                    if ireturn = 0
                        tag_closed = 1
                        stop = j + tagcloselen - 1
                    endif
                endif
            endif
        endif
    next j
    if start > 0 and stop > start
        buildstr = right$(source, srclen - start)
        j = len(buildstr)
        buildstr = left$(buildstr, j - (srclen - stop))
        j = len(buildstr)
        buildstr = right$(buildstr, j - taglen)
        j = len(buildstr)
        buildstr = left$(buildstr, j - tagcloselen)
    endif
endfunction buildstr

function jzGetNextAvailableDLLID(bDown as boolean, seed as integer)
   local temp as integer  = seed

   if seed < 1 or seed > 255 then exitfunction -1
   do
      if dll exist(temp) = 0 then exitfunction temp
      if bDown = 1
         dec temp
      else
         inc temp
      endif
      if temp < 1 or temp > 255 then exitfunction -1
   loop
endfunction -1

function jzGetNextAvailableMemblockID(seed as integer)
   local temp as integer  = seed

   if seed < 1 then exitfunction -1
   do
      if memblock exist(temp) = 0 then exitfunction temp
      inc temp
      if temp < 0 then exitfunction -1
   loop
endfunction -1

function jzMakeDBString(cstring_blockID as integer)
    local ivalue as integer
    local icount as integer
    local offset as integer
    local buildstr as string

    offset = 0
    icount = 0
    buildstr = ""
    ivalue = memblock byte(cstring_blockID, offset)
    while ivalue > 0
        buildstr = buildstr + chr$(ivalue)
        inc offset
        inc icount
        if icount > 32767
            exitfunction buildstr
        endif
        ivalue = memblock byte(cstring_blockID, offset)
    endwhile
endfunction buildstr