How to find out collision impact speed?

Author

Message

Bursar

15

Years of Service

User Offline

Joined: 17th Sep 2008

Location:

Posted: 5th Apr 2009 01:23

Link

I'm trying to discover a way of finding out if two objects have collided, and if one of the objects was traveling over a certain speed when the collision occurs, then I want to play a sound effect.

Currently, I've got this code:

+ Code Snippet

function check_for_bounce()
	local playBounce as integer
	playBounce = 0

	if phy get collision data() = 1 and phy get collision object a() = playerBallObj
		if PHY GET rigid body linear momentum x(playerBallObj) < -150 or PHY GET rigid body linear momentum x(playerBallObj) > 150
			playBounce = 1
		endif

		if PHY GET rigid body linear momentum y(playerBallObj) < -150 or PHY GET rigid body linear momentum y(playerBallObj) > 150
			playBounce = 1
		endif

		if PHY GET rigid body linear momentum z(playerBallObj) < -150 or PHY GET rigid body linear momentum z(playerBallObj) > 150
			playBounce = 1
		endif

		if playBounce = 1
			` requires Enhaced Audio Plugin
			play audio dinkSFX
		endif
	endif
endfunction

So that kind of works. If the playerBallObj is traveling at less than -150, or more than +150 when it collides with something, it plays the sound effect. Great.

However, if the ball is rolling along a surface and goes over that speed, then the sound is also played. That's not what I want. I just want to play the effect if the ball is moving at the appropriate speed, when it initially collides.

I've had a little monkey with PHY GET COLLISION NORMAL FORCE X, but it expects two integer values, and the help files don't tell me what they should be. I've tried feeding in PHY GET COLLISION OBJECT A and PHY GET COLLISION OBJECT B as the two values, but I always get 0 returned.

Because collision data is always being generated when the ball rolls along a surface, I'm not sure how to separate out the initial strikes of the ball.

Back to top

Profile PM

Orion1024

15

Years of Service

User Offline

Joined: 7th Mar 2009

Location: Dimensional Coordinates: 323.935.914.157

Posted: 5th Apr 2009 11:20

Link

Keep in mind that Dark Physics puts collision data on a stack, so you're supposed to empty the stack completely every program cycle. This is the recommended usage in the help file:

+ Code Snippet

while phy get collision data()
   a = phy get collision object a()
   b = phy get collision object b()
endwhile()

As you mentioned, there could be a lot of unnecessary collision data to retrieve due to collisions between the ball and ground (if all you want to test for is collision between a ball and another ball, etc). Honestly, I think it's easier to use Sparky's DLL for collison in conjunction with the phy get linear velocity, etc. That's what I did, anyway.

Looking for the vortex to another Earth

Back to top

Profile PM

HowDo

21

Years of Service

User Offline

Joined: 28th Nov 2002

Location: United Kingdom

Posted: 5th Apr 2009 13:20

Link

give this line ago, might do what you want, I found that the data tends to swap around.

+ Code Snippet

if phy get collision data() = 1 and phy get collision object a() = playerBallObj or phy get collision object b()=playerBallObj

Dark Physics makes any hot drink go cold.

Back to top

Profile PM

Duke E

15

Years of Service

User Offline

Joined: 10th Mar 2009

Location:

Posted: 6th Apr 2009 04:34

Link

The collision data only is pretty useless in these situations as the physics makes the ball jitter up and down over the surface. I use a raycast in a similar case as i need more than check a single plane. If you only have a flat surface you can just check the height of the ball off the surface.

Raycast from the ball a couple of units down, if the ray hits something you know you are close to the ground and set a variable for this, closetoground=true.
Then when you hit with collision data, play the sound and set another variable to hitground=true. If both are true, don't play any more sounds. When ball leaves ground by bouncing, rolling off a ledge or something (detected by the raycast) you set closetoground=false and hitground=false.

The drawback is the raycasting in dark physics isn't 100 percent.
I do the same as Orion1024, use Sparky's.

Regards

Back to top

Profile PM

Bursar

15

Years of Service

User Offline

Joined: 17th Sep 2008

Location:

Posted: 6th Apr 2009 10:45

Link

That doesn't help I'm afraid. If I was missing collisions, then I can see how checking for either a or b would help.

Here's a quick diagram of what I want:

The first picture is working correctly. As the ball is traveling over a certain speed, each time it bounces (the black 'sparks') it plays the Dink effect.

The second picture is how it's currently working. As the ball rolls down a slope, because the speed is picking up as the ball rolls, it plays the Dink effect constantly.

The third pic is how it should work. As it rolls down, no effect is played, and then when it hits the other line, the Dink effect should be played.

That's why I need to be able to get the force of the collision. I suspect Sparkys would suffer the same problem (unless that allows me to find out the force of a collision).

Unfortunately the maze is a 360 rotating one, so it's possible to hit 'the ground' from both sides. This means I would need to raycast in all directions, all the time.

Back to top

Profile PM

Duke E

15

Years of Service

User Offline

Joined: 10th Mar 2009

Location:

Posted: 6th Apr 2009 12:12

Link

Try a combination with torque detection maybe?

As the ball should be changing it's rotation very much when it hits something, the rotation changes should be low and pretty linear when it's rolling and accelerating.
But when it hits something the rotation should change profusely.

Just a teory, have'nt used the angular momentum or torque commands much, just to limit rotation.

Regards

Back to top

Profile PM

Orion1024

15

Years of Service

User Offline

Joined: 7th Mar 2009

Location: Dimensional Coordinates: 323.935.914.157

Posted: 6th Apr 2009 14:03

Link

It looks like the first parameter of the 'phy get collision normal force' command should be the ball object number and the second parameter needs to be zero. Here's an example I put together...

global camera_pitch as float: global camera_yaw as float

global x_force as float: global y_force as float: global z_force as float

#Constant COLLISION_THRESHOLD 400000000

#Constant GROUND_OBJECT_NUMBER 1: #Constant SPHERE_OBJECT_NUMBER 2
#Constant IMPACT_SOUND 1

#Constant A_KEY 30: #Constant S_KEY 31: #Constant Q_KEY 16: #Constant Z_KEY 44

#Constant FALSE 0: #Constant TRUE 1

Rem -------------------------------------------------------

Start_Physics()
Set_Display_Mode()
Set_Lighting_Parameters()
Set_Default_Camera_Location()
Create_Objects()
Load_Sounds()

Rem =======================================================

repeat

Tilt_Ground_Object()

if Check_For_Object_Collision(SPHERE_OBJECT_NUMBER) = TRUE then play sound IMPACT_SOUND

Set_Camera_Location()

phy update
   sync

until escapekey()
end

Rem =======================================================

function Start_Physics()

phy start
   phy set gravity 0, -100, 0

endfunction

Rem -------------------------------------------------------

function Set_Display_Mode()

set display mode desktop width(), desktop height(), 16
   sync on: sync rate 60

color backdrop rgb(64, 64, 64)
   hide mouse

endfunction

Rem -------------------------------------------------------

function Set_Lighting_Parameters()

set ambient light 10

make light 1
   set spot light 1, 60, 90
   position light 1, 200, 200, 200
   point light 1, 0, 0, 0

endfunction

Rem -------------------------------------------------------

function Set_Default_Camera_Location()

autocam off
   position camera 0, 50, 220

camera_pitch = 350
   camera_yaw   = 180

endfunction

Rem -------------------------------------------------------

function Set_Camera_Location()

camera_yaw = wrapvalue(camera_yaw + mousemovex() / 2)
   camera_pitch = wrapvalue(camera_pitch + mousemovey() / -2)

rotate camera 0, camera_yaw, 0
   pitch camera up camera_pitch

if upkey() then move camera 2
   if downkey() then move camera -2

text 0, screen height() - 90, "Camera X = " + str$(camera position x())
   text 0, screen height() - 75, "Camera Y = " + str$(camera position y())
   text 0, screen height() - 60, "Camera Z = " + str$(camera position z())
   text 0, screen height() - 30, "Camera Pitch = " + str$(camera_pitch)
   text 0, screen height() - 15, "Camera Yaw   = " + str$(camera_yaw)

endfunction

Rem -------------------------------------------------------

function Tilt_Ground_Object()

local x_angle as float: local z_angle as float

x_angle = object angle x(GROUND_OBJECT_NUMBER)
   z_angle = object angle z(GROUND_OBJECT_NUMBER)

if scancode() = A_KEY then phy set rigid body rotation GROUND_OBJECT_NUMBER, x_angle, 0, z_angle - .3
   if scancode() = S_KEY then phy set rigid body rotation GROUND_OBJECT_NUMBER, x_angle, 0, z_angle + .3
   if scancode() = Q_KEY then phy set rigid body rotation GROUND_OBJECT_NUMBER, x_angle - .3, 0, z_angle
   if scancode() = Z_KEY then phy set rigid body rotation GROUND_OBJECT_NUMBER, x_angle + .3, 0, z_angle

endfunction

Rem -------------------------------------------------------

function Check_For_Object_Collision(object_number as integer)

rem local x_force as float: local y_force as float: local z_force as float
local object_a as integer: local object_b as integer
local collision_result

while phy get collision data()
      object_a = phy get collision object a()
      object_b = phy get collision object b()

if object_a = object_number or object_b = object_number
         x_force = abs(phy get collision normal force x(SPHERE_OBJECT_NUMBER, 0))
         y_force = abs(phy get collision normal force y(SPHERE_OBJECT_NUMBER, 0))
         z_force = abs(phy get collision normal force z(SPHERE_OBJECT_NUMBER, 0))

if x_force > COLLISION_THRESHOLD or y_force > COLLISION_THRESHOLD or z_force > COLLISION_THRESHOLD then collision_result = TRUE
      endif
   endwhile

text screen width() / 2, 0,  "X Force = " + str$(x_force)
   text screen width() / 2, 15, "Y Force = " + str$(y_force)
   text screen width() / 2, 30, "Z Force = " + str$(z_force)

endfunction collision_result

Rem -------------------------------------------------------

function Create_Objects()

Rem - make a ground object
   make object box GROUND_OBJECT_NUMBER, 300, 1, 300
   color object GROUND_OBJECT_NUMBER, rgb(0, 92, 0)
   phy make rigid body static box GROUND_OBJECT_NUMBER

make object sphere SPHERE_OBJECT_NUMBER, 30
   position object SPHERE_OBJECT_NUMBER, 0, 100, 0
   color object SPHERE_OBJECT_NUMBER, rgb(0, 0, 192)
   phy make rigid body dynamic sphere SPHERE_OBJECT_NUMBER

endfunction

Rem -------------------------------------------------------

function Load_Sounds()

load sound "C:\Temp\Beep.wav", IMPACT_SOUND

endfunction

Rem -------------------------------------------------------

+ Code Snippet

global camera_pitch as float: global camera_yaw as float

global x_force as float: global y_force as float: global z_force as float

#Constant COLLISION_THRESHOLD 400000000

#Constant GROUND_OBJECT_NUMBER 1: #Constant SPHERE_OBJECT_NUMBER 2
#Constant IMPACT_SOUND 1

#Constant A_KEY 30: #Constant S_KEY 31: #Constant Q_KEY 16: #Constant Z_KEY 44

#Constant FALSE 0: #Constant TRUE 1

Rem -------------------------------------------------------

Start_Physics()
Set_Display_Mode()
Set_Lighting_Parameters()
Set_Default_Camera_Location()
Create_Objects()
Load_Sounds()

Rem =======================================================

repeat

   Tilt_Ground_Object()

   if Check_For_Object_Collision(SPHERE_OBJECT_NUMBER) = TRUE then play sound IMPACT_SOUND

   Set_Camera_Location()

   phy update
   sync

until escapekey()
end

Rem =======================================================

function Start_Physics()

   phy start
   phy set gravity 0, -100, 0

endfunction

Rem -------------------------------------------------------

function Set_Display_Mode()

   set display mode desktop width(), desktop height(), 16
   sync on: sync rate 60

   color backdrop rgb(64, 64, 64)
   hide mouse

endfunction

Rem -------------------------------------------------------

function Set_Lighting_Parameters()

   set ambient light 10

   make light 1
   set spot light 1, 60, 90
   position light 1, 200, 200, 200
   point light 1, 0, 0, 0

endfunction

Rem -------------------------------------------------------

function Set_Default_Camera_Location()

   autocam off
   position camera 0, 50, 220

   camera_pitch = 350
   camera_yaw   = 180

endfunction

Rem -------------------------------------------------------

function Set_Camera_Location()

   camera_yaw = wrapvalue(camera_yaw + mousemovex() / 2)
   camera_pitch = wrapvalue(camera_pitch + mousemovey() / -2)

   rotate camera 0, camera_yaw, 0
   pitch camera up camera_pitch

   if upkey() then move camera 2
   if downkey() then move camera -2

   text 0, screen height() - 90, "Camera X = " + str$(camera position x())
   text 0, screen height() - 75, "Camera Y = " + str$(camera position y())
   text 0, screen height() - 60, "Camera Z = " + str$(camera position z())
   text 0, screen height() - 30, "Camera Pitch = " + str$(camera_pitch)
   text 0, screen height() - 15, "Camera Yaw   = " + str$(camera_yaw)

endfunction

Rem -------------------------------------------------------

function Tilt_Ground_Object()

local x_angle as float: local z_angle as float

   x_angle = object angle x(GROUND_OBJECT_NUMBER)
   z_angle = object angle z(GROUND_OBJECT_NUMBER)

   if scancode() = A_KEY then phy set rigid body rotation GROUND_OBJECT_NUMBER, x_angle, 0, z_angle - .3
   if scancode() = S_KEY then phy set rigid body rotation GROUND_OBJECT_NUMBER, x_angle, 0, z_angle + .3
   if scancode() = Q_KEY then phy set rigid body rotation GROUND_OBJECT_NUMBER, x_angle - .3, 0, z_angle
   if scancode() = Z_KEY then phy set rigid body rotation GROUND_OBJECT_NUMBER, x_angle + .3, 0, z_angle

endfunction

Rem -------------------------------------------------------

function Check_For_Object_Collision(object_number as integer)

rem local x_force as float: local y_force as float: local z_force as float
local object_a as integer: local object_b as integer
local collision_result

   while phy get collision data()
      object_a = phy get collision object a()
      object_b = phy get collision object b()

      if object_a = object_number or object_b = object_number
         x_force = abs(phy get collision normal force x(SPHERE_OBJECT_NUMBER, 0))
         y_force = abs(phy get collision normal force y(SPHERE_OBJECT_NUMBER, 0))
         z_force = abs(phy get collision normal force z(SPHERE_OBJECT_NUMBER, 0))

         if x_force > COLLISION_THRESHOLD or y_force > COLLISION_THRESHOLD or z_force > COLLISION_THRESHOLD then collision_result = TRUE
      endif
   endwhile

   text screen width() / 2, 0,  "X Force = " + str$(x_force)
   text screen width() / 2, 15, "Y Force = " + str$(y_force)
   text screen width() / 2, 30, "Z Force = " + str$(z_force)

endfunction collision_result

Rem -------------------------------------------------------

function Create_Objects()

   Rem - make a ground object
   make object box GROUND_OBJECT_NUMBER, 300, 1, 300
   color object GROUND_OBJECT_NUMBER, rgb(0, 92, 0)
   phy make rigid body static box GROUND_OBJECT_NUMBER

   make object sphere SPHERE_OBJECT_NUMBER, 30
   position object SPHERE_OBJECT_NUMBER, 0, 100, 0
   color object SPHERE_OBJECT_NUMBER, rgb(0, 0, 192)
   phy make rigid body dynamic sphere SPHERE_OBJECT_NUMBER

endfunction

Rem -------------------------------------------------------

function Load_Sounds()

   load sound "C:\Temp\Beep.wav", IMPACT_SOUND

endfunction

Rem -------------------------------------------------------

I've made the x_force, y_force & z_force variables global so you can see their values. You'll need to adjust the 'COLLISION_THRESHOLD' constant depending on the global gravity, object mass and it's maximum velocity.

Looking for the vortex to another Earth

Back to top

Profile PM

tiresius

21

Years of Service

User Offline

Joined: 13th Nov 2002

Location: MA USA

Posted: 7th Apr 2009 00:15

Link

First off, I use Newton.

But I just thought out how to do this myself so I thought I'd share. If Orion1024's suggestion doesn't work give this a shot.

First you keep track of the player's last velocity vector. Then you subtract it from the player's current velocity vector. If the result of the vector distance is great enough, it is most likely that the player hit something at a good enough speed. I plan on increasing the volume of the hit sound based on the speed of impact.

I'm not a real programmer but I play one with DBPro!

Back to top

Profile PM Email

Bursar

15

Years of Service

User Offline

Joined: 17th Sep 2008

Location:

Posted: 7th Apr 2009 12:35

Link

Thanks a lot guys. I'll try out the code this evening.

Back to top

Profile PM

Sorry your browser is not supported!

Dark Physics & Dark A.I. & Dark Dynamix / How to find out collision impact speed?