[DBP] Mouse Plugin - Function collection for better mouse-control

Author

Message

Mr Kohlenstoff

18

Years of Service

User Offline

Joined: 7th Jun 2006

Location: Germany

Posted: 10th Jun 2007 01:06 Edited at: 10th Jun 2007 02:18

Link

Hi,

I've made this functions today, because I was a bit bored... this function collection, called "mouse plugin" (short "mop", also the mainly used prefix at the beginning of all used functions, arrays, types and variables), can handle different mouse-operations, and offers different features for your programs.
It's easy to implement, you just have to include the code and then you can use the functions.
At the beginning you should call "StartMop()" to setup all variables etc.

Features:
-Management of Mouse-Position and -Movement
-Click-Management for right mousebutton, left button and the wheel (Key pressed, click started, click stopped, editable doubleclick (time-delay between two clicks, both clicks on the same position etc.))
-Field/Zone-Functions (Create different Trigger-Zones and easily check if they are hovered or clicked)
-Mouse can be locked at a defined position (usefull for shooters etc)
-Simple Drag-and-Drop-System

Anyone can use the code, if he wants, and edit it, and can name me in the credits - if he wants.. doesn't really matter, I'd just be happy if I could help someone with it...

The functions:

rem **This function have to be called before all other mop-functions. Without it other functions will crash
rem   or return wrong values
function StartMop()
   global mop_x as integer `mouse-x
   global mop_y as integer `mouse-y
   global mop_mx as integer `move-x
   global mop_my as integer `move-y
   global mop_mz as integer `move-z
   global mop_left   as integer `mouseclick left
   global mop_right  as integer `mouseclick right
   global mop_top    as integer `mouse-wheel pressed
   global mop_nleft     as integer `leftbutton new pressed
   global mop_nright    as integer
   global mop_ntop      as integer
   global mop_lleft  as integer `leftbutton was pressed last round
   global mop_lright as integer
   global mop_ltop   as integer
   global mop_lcl as integer `last left-click (timer)
   global mop_lcr as integer
   global mop_lct as integer
   global mop_lclx as integer `x-pos of the last click
   global mop_lcly as integer
   global mop_lcrx as integer
   global mop_lcry as integer
   global mop_lctx as integer
   global mop_lcty as integer
   global mop_dcl    as integer `double-click left
   global mop_dcr    as integer
   global mop_dct    as integer
   global mop_dcDelay   as dword `Double-click-delay (time between to clicks)
   global mop_dcSamePos as boolean `if both clicks have to be on the same position
   mop_dcDelay = 250
   mop_dcSamePos = 1
   rem Drag&Drop
   global mop_dragged as boolean
   global mop_dragstartx as integer
   global mop_dragstarty as integer
   global mop_dragdifx as integer
   global mop_dragdify as integer
   global mop_dragrelx as integer
   global mop_dragrely as integer
   rem Mouse-Locking
   global mop_locked as boolean
   global mop_LockX as integer
   global mop_LockY as integer
   rem Zones
   global mop_Zones as integer
   global mop_ZoneFillColor as dword
   global mop_ZoneBorderColor as dword
   global mop_ZoneTextColor as dword
   dim mop_Zone(-1) as mop_ZoneType
   mop_Zones = -1
   mop_ZoneBorderColor = rgb(255,255,255)
   mop_ZoneFillColor = rgb(128,128,128)
   mop_ZoneTextColor = rgb(255,0,0)
endfunction

type mop_ZoneType
      x1 as integer
      y1 as integer
      x2 as integer
      y2 as integer
   endtype

function mop_SetDoubleClickDelay(time)
   mop_dcDelay = time
endfunction

function mop_SetDoubleClickSamePos(SamePos as boolean)
   mop_dcSamePos = SamePos
endfunction

function mop_Update()
   mx = mousex()
   my = mousey()
   mop_mx = mx-mop_x
   mop_my = my-mop_y
   mop_mz = mousemovez()
   mop_x = mx
   mop_y = my
   rem Lock mouse
   if mop_Locked = 1
      position mouse mop_LockX, mop_LockY
   endif
   rem Buttons pressed
   mc = mouseclick()
   left =  ((mc=1) or (mc=3) or (mc=5))
   right = ((mc=2) or (mc=3) or (mc=6))
   top   = ((mc=4) or (mc=5) or (mc=6))
   if mc=7 then left=1 : right=1 : top=1
   rem Left button -----
   if mop_dcl = 1 then mop_dcl = 0
   if left = 1 `left pressed
      if mop_nleft=1 then mop_nleft = 0
      if mop_lleft=0 then mop_nleft = 1
      mop_left = 1
   else `left is not pressed
      lc = mop_lcl : lcx = mop_lclx : lcy = mop_lcly
      if mop_lleft = 1 `left was pressed last round
         mop_left = 0
         mop_nleft = -1
         mop_lclx = mop_x : mop_lcly = mop_y
         mop_lcl = timer()
         if (((timer()-lc)<=mop_dcdelay) and ((lcx=mop_x) and (lcy=mop_y) or (mop_dcSamePos=0))) then mop_dcl = 1 else mop_dcl = 0
      else `left was not pressed
         mop_nleft = 0
      endif
   endif
   mop_lleft = mop_left
   rem right button -----
   if mop_dcr = 1 then mop_dcr = 0
   if right = 1 `right pressed
      if mop_nright=1 then mop_nright = 0
      if mop_lright=0 then mop_nright = 1
      mop_right = 1
   else `right is not pressed
      lc = mop_lcr : lcx = mop_lcrx : lcy = mop_lcry
      if mop_lright = 1 `right was pressed last round
         mop_right = 0
         mop_nright = -1
         mop_lcrx = mop_x : mop_lcry = mop_y
         mop_lcr = timer()
         if (((timer()-lc)<=mop_dcdelay) and ((lcx=mop_x) and (lcy=mop_y) or (mop_dcSamePos=0))) then mop_dcr = 1 else mop_dcr = 0
      else `right was not pressed
         mop_nright = 0
      endif
   endif
   mop_lright = mop_right
   rem top button -----
   if mop_dct = 1 then mop_dct = 0
   if top = 1 `top pressed
      if mop_ntop=1 then mop_ntop = 0
      if mop_ltop=0 then mop_ntop = 1
      mop_top = 1
   else `top is not pressed
      lc = mop_lct : lcx = mop_lctx : lcy = mop_lcty
      if mop_ltop = 1 `top was pressed last round
         mop_top = 0
         mop_ntop = -1
         mop_lctx = mop_x : mop_lcty = mop_y
         mop_lct = timer()
         if (((timer()-lc)<=mop_dcdelay) and ((lcx=mop_x) and (lcy=mop_y) or (mop_dcSamePos=0))) then mop_dct = 1 else mop_dct = 0
      else `top was not pressed
         mop_ntop = 0
      endif
   endif
   mop_ltop = mop_top
   rem End of this part  -----
endfunction

function mop_PosX()
endfunction mop_x

function mop_PosY()
endfunction mop_y

function mop_MoveX()
endfunction mop_mx

function mop_MoveY()
endfunction mop_my

function mop_MoveZ()
endfunction mop_mz

function mop_Click(Button)
   select Button
      case 1 : exitfunction mop_left  : endcase
      case 2 : exitfunction mop_right : endcase
      case 3 : exitfunction mop_top   : endcase
   endselect
endfunction 0

function mop_NewClick(Button)
   select Button
      case 1 : exitfunction mop_nleft  : endcase
      case 2 : exitfunction mop_nright : endcase
      case 3 : exitfunction mop_ntop   : endcase
   endselect
endfunction 0

function mop_DoubleClick(Button)
   select Button
      case 1 : exitfunction mop_dcl  : endcase
      case 2 : exitfunction mop_dcr  : endcase
      case 3 : exitfunction mop_dct  : endcase
   endselect
endfunction 0

function mop_InField(x1,y1,x2,y2)
   if mop_y <= y2
      if mop_y => y1
         if mop_x <= x2
            if mop_x => x1
               exitfunction 1
            endif
         endif
      endif
   endif
endfunction 0

function mop_CreateZone(x1,y1,w,h)
   x2 = x1+w
   y2 = y1+h
   inc mop_Zones
   array insert at bottom mop_Zone(0), mop_Zones
   mop_Zone(mop_Zones).x1 = x1
   mop_Zone(mop_Zones).y1 = y1
   mop_Zone(mop_Zones).x2 = x2
   mop_Zone(mop_Zones).y2 = y2
endfunction mop_Zones

function mop_GetZoneX(ID)
   x = mop_Zone(ID).x1
endfunction x

function mop_GetZoneY(ID)
   y = mop_Zone(ID).y1
endfunction y

function mop_GetZoneX2(ID)
   x2 = mop_Zone(ID).x2
endfunction x2

function mop_GetZoneY2(ID)
   y2 = mop_Zone(ID).y2
endfunction y2

function mop_GetZoneWidth(ID)
   w = mop_Zone(ID).x2 - mop_Zone(ID).x1
endfunction w

function mop_GetZoneHeight(ID)
   h = mop_Zone(ID).y2 - mop_Zone(ID).y1
endfunction h

function mop_PositionZone(ID,X,Y)
   w = mop_Zone(ID).x2-mop_Zone(ID).x1
   h = mop_Zone(ID).y2-mop_Zone(ID).y1
   mop_Zone(ID).x1 = x
   mop_Zone(ID).y1 = y
   mop_Zone(ID).x2 = x+w
   mop_Zone(ID).y2 = y+h
endfunction

function mop_RelPositionZone(ID,xadd,yadd)
   inc mop_Zone(ID).x1, xadd
   inc mop_Zone(ID).y1, yadd
   inc mop_Zone(ID).x2, xadd
   inc mop_Zone(ID).y2, yadd
endfunction

function mop_InZone(ID)
   if mop_y <= mop_Zone(ID).y2
      if mop_y => mop_Zone(ID).y1
         if mop_x <= mop_Zone(ID).x2
            if mop_x => mop_Zone(ID).x1
               exitfunction 1
            endif
         endif
      endif
   endif
endfunction 0

function mop_ShowZone(ID,t$,Filled as byte) `Info> Filled: 0=lines, 1=box, 2=lines+box
   if Filled > 0
      ink mop_ZoneFillColor, 0
      box mop_Zone(ID).x1+1, mop_Zone(ID).y1+1, mop_Zone(ID).x2, mop_Zone(ID).y2
   endif
   if Filled <> 1
      ink mop_ZoneBorderColor, 0
      line mop_Zone(ID).x1,mop_Zone(ID).y1,mop_Zone(ID).x2,mop_Zone(ID).y1
      line mop_Zone(ID).x1,mop_Zone(ID).y1,mop_Zone(ID).x1,mop_Zone(ID).y2
      line mop_Zone(ID).x2,mop_Zone(ID).y2,mop_Zone(ID).x1,mop_Zone(ID).y2
      line mop_Zone(ID).x2,mop_Zone(ID).y2,mop_Zone(ID).x2,mop_Zone(ID).y1
   endif
   if t$<>""
      ink mop_ZoneTextColor, 0
      center text mop_Zone(ID).x1+(mop_Zone(ID).x2-mop_Zone(ID).x1)/2, mop_Zone(ID).y1+(mop_Zone(ID).y2-mop_Zone(ID).y1)/2-text size()/2, t$
   endif
endfunction

function mop_SetZoneColors(Txt as dword, Fill as dword, Border as dword)
   mop_ZoneTextColor    = Txt
   mop_ZoneFillColor    = Fill
   mop_ZoneBorderColor  = Border
endfunction

function mop_LockMouse(x,y)
   mop_Locked = 1
   mop_LockX = x
   mop_LockY = y
endfunction

function mop_UnlockMouse()
   mop_Locked = 0
endfunction

function mop_GetLocked()
endfunction mop_Locked

function mop_GetLockX()
endfunction mop_LockX

function mop_GetLockY()
endfunction mop_LockY

function mop_GetDoubleClickSamePos()
endfunction mop_dcSamePos

function mop_GetDoubleClickDelay()
endfunction mop_dcDelay

function mop_Drag()
   mop_dragged = 1
   mop_dragstartx = mop_x
   mop_dragstarty = mop_y
endfunction

function mop_DragObject(ObjX,ObjY)
   mop_dragged = 1
   mop_dragrelx = mop_x-ObjX
   mop_dragrely = mop_y-ObjY
endfunction

function mop_GetDraggedObjectX()
   x = mop_x - mop_dragrelx
endfunction x

function mop_GetDraggedObjectY()
   y = mop_y - mop_dragrely
endfunction y

function mop_Drop()
   mop_dragged = 0
   mop_dragdifx = mop_x-mop_dragstartx
   mop_dragdify = mop_y-mop_dragstarty
endfunction

function mop_GetDragged()
endfunction mop_dragged

function mop_GetDragX()
endfunction mop_dragstartx

function mop_GetDragY()
endfunction mop_dragstarty

function mop_GetDropXDif()
endfunction mop_dragdifx

function mop_GetDropYDif()
endfunction mop_dragdify

+ Code Snippet



rem **This function have to be called before all other mop-functions. Without it other functions will crash
rem   or return wrong values
function StartMop()
   global mop_x as integer `mouse-x
   global mop_y as integer `mouse-y
   global mop_mx as integer `move-x
   global mop_my as integer `move-y
   global mop_mz as integer `move-z
   global mop_left   as integer `mouseclick left
   global mop_right  as integer `mouseclick right
   global mop_top    as integer `mouse-wheel pressed
   global mop_nleft     as integer `leftbutton new pressed
   global mop_nright    as integer
   global mop_ntop      as integer
   global mop_lleft  as integer `leftbutton was pressed last round
   global mop_lright as integer
   global mop_ltop   as integer
   global mop_lcl as integer `last left-click (timer)
   global mop_lcr as integer
   global mop_lct as integer
   global mop_lclx as integer `x-pos of the last click
   global mop_lcly as integer
   global mop_lcrx as integer
   global mop_lcry as integer
   global mop_lctx as integer
   global mop_lcty as integer
   global mop_dcl    as integer `double-click left
   global mop_dcr    as integer
   global mop_dct    as integer
   global mop_dcDelay   as dword `Double-click-delay (time between to clicks)
   global mop_dcSamePos as boolean `if both clicks have to be on the same position
   mop_dcDelay = 250
   mop_dcSamePos = 1
   rem Drag&Drop
   global mop_dragged as boolean
   global mop_dragstartx as integer
   global mop_dragstarty as integer
   global mop_dragdifx as integer
   global mop_dragdify as integer
   global mop_dragrelx as integer
   global mop_dragrely as integer
   rem Mouse-Locking
   global mop_locked as boolean
   global mop_LockX as integer
   global mop_LockY as integer
   rem Zones
   global mop_Zones as integer
   global mop_ZoneFillColor as dword
   global mop_ZoneBorderColor as dword
   global mop_ZoneTextColor as dword
   dim mop_Zone(-1) as mop_ZoneType
   mop_Zones = -1
   mop_ZoneBorderColor = rgb(255,255,255)
   mop_ZoneFillColor = rgb(128,128,128)
   mop_ZoneTextColor = rgb(255,0,0)
endfunction

   type mop_ZoneType
      x1 as integer
      y1 as integer
      x2 as integer
      y2 as integer
   endtype

function mop_SetDoubleClickDelay(time)
   mop_dcDelay = time
endfunction

function mop_SetDoubleClickSamePos(SamePos as boolean)
   mop_dcSamePos = SamePos
endfunction

function mop_Update()
   mx = mousex()
   my = mousey()
   mop_mx = mx-mop_x
   mop_my = my-mop_y
   mop_mz = mousemovez()
   mop_x = mx
   mop_y = my
   rem Lock mouse
   if mop_Locked = 1
      position mouse mop_LockX, mop_LockY
   endif
   rem Buttons pressed
   mc = mouseclick()
   left =  ((mc=1) or (mc=3) or (mc=5))
   right = ((mc=2) or (mc=3) or (mc=6))
   top   = ((mc=4) or (mc=5) or (mc=6))
   if mc=7 then left=1 : right=1 : top=1
   rem Left button -----
   if mop_dcl = 1 then mop_dcl = 0
   if left = 1 `left pressed
      if mop_nleft=1 then mop_nleft = 0
      if mop_lleft=0 then mop_nleft = 1
      mop_left = 1
   else `left is not pressed
      lc = mop_lcl : lcx = mop_lclx : lcy = mop_lcly
      if mop_lleft = 1 `left was pressed last round
         mop_left = 0
         mop_nleft = -1
         mop_lclx = mop_x : mop_lcly = mop_y
         mop_lcl = timer()
         if (((timer()-lc)<=mop_dcdelay) and ((lcx=mop_x) and (lcy=mop_y) or (mop_dcSamePos=0))) then mop_dcl = 1 else mop_dcl = 0
      else `left was not pressed
         mop_nleft = 0
      endif
   endif
   mop_lleft = mop_left
   rem right button -----
   if mop_dcr = 1 then mop_dcr = 0
   if right = 1 `right pressed
      if mop_nright=1 then mop_nright = 0
      if mop_lright=0 then mop_nright = 1
      mop_right = 1
   else `right is not pressed
      lc = mop_lcr : lcx = mop_lcrx : lcy = mop_lcry
      if mop_lright = 1 `right was pressed last round
         mop_right = 0
         mop_nright = -1
         mop_lcrx = mop_x : mop_lcry = mop_y
         mop_lcr = timer()
         if (((timer()-lc)<=mop_dcdelay) and ((lcx=mop_x) and (lcy=mop_y) or (mop_dcSamePos=0))) then mop_dcr = 1 else mop_dcr = 0
      else `right was not pressed
         mop_nright = 0
      endif
   endif
   mop_lright = mop_right
   rem top button -----
   if mop_dct = 1 then mop_dct = 0
   if top = 1 `top pressed
      if mop_ntop=1 then mop_ntop = 0
      if mop_ltop=0 then mop_ntop = 1
      mop_top = 1
   else `top is not pressed
      lc = mop_lct : lcx = mop_lctx : lcy = mop_lcty
      if mop_ltop = 1 `top was pressed last round
         mop_top = 0
         mop_ntop = -1
         mop_lctx = mop_x : mop_lcty = mop_y
         mop_lct = timer()
         if (((timer()-lc)<=mop_dcdelay) and ((lcx=mop_x) and (lcy=mop_y) or (mop_dcSamePos=0))) then mop_dct = 1 else mop_dct = 0
      else `top was not pressed
         mop_ntop = 0
      endif
   endif
   mop_ltop = mop_top
   rem End of this part  -----
endfunction

function mop_PosX()
endfunction mop_x

function mop_PosY()
endfunction mop_y

function mop_MoveX()
endfunction mop_mx

function mop_MoveY()
endfunction mop_my

function mop_MoveZ()
endfunction mop_mz

function mop_Click(Button)
   select Button
      case 1 : exitfunction mop_left  : endcase
      case 2 : exitfunction mop_right : endcase
      case 3 : exitfunction mop_top   : endcase
   endselect
endfunction 0

function mop_NewClick(Button)
   select Button
      case 1 : exitfunction mop_nleft  : endcase
      case 2 : exitfunction mop_nright : endcase
      case 3 : exitfunction mop_ntop   : endcase
   endselect
endfunction 0

function mop_DoubleClick(Button)
   select Button
      case 1 : exitfunction mop_dcl  : endcase
      case 2 : exitfunction mop_dcr  : endcase
      case 3 : exitfunction mop_dct  : endcase
   endselect
endfunction 0

function mop_InField(x1,y1,x2,y2)
   if mop_y <= y2
      if mop_y => y1
         if mop_x <= x2
            if mop_x => x1
               exitfunction 1
            endif
         endif
      endif
   endif
endfunction 0

function mop_CreateZone(x1,y1,w,h)
   x2 = x1+w
   y2 = y1+h
   inc mop_Zones
   array insert at bottom mop_Zone(0), mop_Zones
   mop_Zone(mop_Zones).x1 = x1
   mop_Zone(mop_Zones).y1 = y1
   mop_Zone(mop_Zones).x2 = x2
   mop_Zone(mop_Zones).y2 = y2
endfunction mop_Zones

function mop_GetZoneX(ID)
   x = mop_Zone(ID).x1
endfunction x

function mop_GetZoneY(ID)
   y = mop_Zone(ID).y1
endfunction y

function mop_GetZoneX2(ID)
   x2 = mop_Zone(ID).x2
endfunction x2

function mop_GetZoneY2(ID)
   y2 = mop_Zone(ID).y2
endfunction y2

function mop_GetZoneWidth(ID)
   w = mop_Zone(ID).x2 - mop_Zone(ID).x1
endfunction w

function mop_GetZoneHeight(ID)
   h = mop_Zone(ID).y2 - mop_Zone(ID).y1
endfunction h

function mop_PositionZone(ID,X,Y)
   w = mop_Zone(ID).x2-mop_Zone(ID).x1
   h = mop_Zone(ID).y2-mop_Zone(ID).y1
   mop_Zone(ID).x1 = x
   mop_Zone(ID).y1 = y
   mop_Zone(ID).x2 = x+w
   mop_Zone(ID).y2 = y+h
endfunction

function mop_RelPositionZone(ID,xadd,yadd)
   inc mop_Zone(ID).x1, xadd
   inc mop_Zone(ID).y1, yadd
   inc mop_Zone(ID).x2, xadd
   inc mop_Zone(ID).y2, yadd
endfunction

function mop_InZone(ID)
   if mop_y <= mop_Zone(ID).y2
      if mop_y => mop_Zone(ID).y1
         if mop_x <= mop_Zone(ID).x2
            if mop_x => mop_Zone(ID).x1
               exitfunction 1
            endif
         endif
      endif
   endif
endfunction 0

function mop_ShowZone(ID,t$,Filled as byte) `Info> Filled: 0=lines, 1=box, 2=lines+box
   if Filled > 0
      ink mop_ZoneFillColor, 0
      box mop_Zone(ID).x1+1, mop_Zone(ID).y1+1, mop_Zone(ID).x2, mop_Zone(ID).y2
   endif
   if Filled <> 1
      ink mop_ZoneBorderColor, 0
      line mop_Zone(ID).x1,mop_Zone(ID).y1,mop_Zone(ID).x2,mop_Zone(ID).y1
      line mop_Zone(ID).x1,mop_Zone(ID).y1,mop_Zone(ID).x1,mop_Zone(ID).y2
      line mop_Zone(ID).x2,mop_Zone(ID).y2,mop_Zone(ID).x1,mop_Zone(ID).y2
      line mop_Zone(ID).x2,mop_Zone(ID).y2,mop_Zone(ID).x2,mop_Zone(ID).y1
   endif
   if t$<>""
      ink mop_ZoneTextColor, 0
      center text mop_Zone(ID).x1+(mop_Zone(ID).x2-mop_Zone(ID).x1)/2, mop_Zone(ID).y1+(mop_Zone(ID).y2-mop_Zone(ID).y1)/2-text size()/2, t$
   endif
endfunction

function mop_SetZoneColors(Txt as dword, Fill as dword, Border as dword)
   mop_ZoneTextColor    = Txt
   mop_ZoneFillColor    = Fill
   mop_ZoneBorderColor  = Border
endfunction

function mop_LockMouse(x,y)
   mop_Locked = 1
   mop_LockX = x
   mop_LockY = y
endfunction

function mop_UnlockMouse()
   mop_Locked = 0
endfunction

function mop_GetLocked()
endfunction mop_Locked

function mop_GetLockX()
endfunction mop_LockX

function mop_GetLockY()
endfunction mop_LockY

function mop_GetDoubleClickSamePos()
endfunction mop_dcSamePos

function mop_GetDoubleClickDelay()
endfunction mop_dcDelay

function mop_Drag()
   mop_dragged = 1
   mop_dragstartx = mop_x
   mop_dragstarty = mop_y
endfunction

function mop_DragObject(ObjX,ObjY)
   mop_dragged = 1
   mop_dragrelx = mop_x-ObjX
   mop_dragrely = mop_y-ObjY
endfunction

function mop_GetDraggedObjectX()
   x = mop_x - mop_dragrelx
endfunction x

function mop_GetDraggedObjectY()
   y = mop_y - mop_dragrely
endfunction y

function mop_Drop()
   mop_dragged = 0
   mop_dragdifx = mop_x-mop_dragstartx
   mop_dragdify = mop_y-mop_dragstarty
endfunction

function mop_GetDragged()
endfunction mop_dragged

function mop_GetDragX()
endfunction mop_dragstartx

function mop_GetDragY()
endfunction mop_dragstarty

function mop_GetDropXDif()
endfunction mop_dragdifx

function mop_GetDropYDif()
endfunction mop_dragdify

My actual example-code is really bad written, but while I'm writing on a new, better one I'll post this here:

set display mode 800,600,32
sync on : sync rate 0
set window on

StartMop()
mop_SetDoubleClickDelay(300)
SamePos = 1

EndButton = mop_CreateZone(300,400,100,25)
Toggle = mop_CreateZone(300,5,100,25)

do
   cls
   Mop_Update()
   print "FPS: ", screen fps()
   print
   print "MouseX: ", mop_posx()
   print "MouseY: ", mop_posy()
   print
   print "Move-X: ", mop_MoveX()
   print "Move-Y: ", mop_MoveY()
   print "Move-Z: ", mop_MoveZ()
   print
   print "Mouseclick: ", mouseclick()
   print "Left:  ", mop_Click(1)
   print "Right: ", mop_Click(2)
   print "Top:   ", mop_Click(3)
   print
   print "Newclick:"
   print "Left:  ", mop_NewClick(1)
   print "Right: ", mop_NewClick(2)
   print "Top:   ", mop_NewClick(3)
   print
   print "Doubleclick:"
   print "SamePos: ", mop_GetDoubleClickSamePos()
   print "Delay:   ", mop_GetDoubleClickDelay()
   print "Left:  ", mop_DoubleClick(1)
   print "Right: ", mop_DoubleClick(2)
   print "Top:   ", mop_DoubleClick(3)
   print
   print "Zone:"
   print "Hover: ", mop_InZone(EndButton)
   print
   print "-Use RMB/TMB to move Button"
   print "-Doubleclick for events"
   print "-Press 'Toggle' to change SamePos"
   rem Double-Click-Events
   mop_ShowZone(Toggle,"Toggle",0)
   if mop_InZone(Toggle) and mop_NewClick(1)=1 then SamePos = 1-SamePos
   mop_SetDoubleclickSamePos(SamePos)
   if mop_DoubleClick(1)=1 : for x = 1 to 10 : print rnd(99) : sync : wait 100 : next x : endif
   if mop_DoubleClick(2)=1 then for x = 1 to 30 : cls rnd(0xFFFFFF) : sync : wait 10 : next x
   if mop_DoubleClick(3)=1 `lock/unlock mouse
      if mop_GetLocked()=1
         mop_UnlockMouse()
      else
         mop_LockMouse(mop_posx(),mop_posy())
      endif
   endif
   rem End-Event
   mop_ShowZone(EndButton,"End",2)
   if mop_NewClick(1)=1 and mop_InZone(EndButton) then end
   if spacekey() then mop_PositionZone(EndButton,mousex(),mousey())
   rem Drag&Drop Button (rightkey)
      rem Drag
      if mop_NewClick(2)=1 and mop_InZone(EndButton)
         LastX = mop_PosX() : LastY = mop_PosY() : Selected1 = 1
      else
      rem Drop
         if mop_NewClick(2)=-1 and Selected1 = 1
            _xdif = mop_PosX()-LastX
            _ydif = mop_PosY()-LastY
            mop_RelPositionZone(EndButton,_xdif,_ydif)
            Selected1 = 0
         endif
      endif
      rem Show Line
      if mop_Click(2)=1 and Selected1=1 then line mop_PosX(),mop_PosY(),LastX, LastY
   rem Drag&Drop Button (topkey)
      rem Drag
      if mop_NewClick(3)=1 and mop_InZone(EndButton)
         XDif = mop_PosX()-mop_Zone(EndButton).x1
         YDif = mop_PosY()-mop_Zone(EndButton).y1
         Selected2 = 1
      else
      rem Drop
         if mop_Click(3)=1 and Selected2=1
            mop_PositionZone(EndButton,mop_PosX()-XDif,mop_PosY()-YDif)
         else
            Selected2 = 0
         endif
      endif
   rem Drag&Drop toggle-Button
      rem Drag
      if (mop_NewClick(2)=1) and (mop_InZone(Toggle)=1)
         mop_DragObject(mop_GetZoneX(Toggle),mop_GetZoneY(Toggle))
      endif
      rem Position/Drop
      if mop_GetDragged()=1
         if mop_NewClick(2)=-1 then mop_Drop()
         mop_PositionZone(Toggle,mop_GetDraggedObjectX(),mop_GetDraggedObjectY())
      endif

sync
loop

+ Code Snippet

set display mode 800,600,32
sync on : sync rate 0
set window on

StartMop()
mop_SetDoubleClickDelay(300)
SamePos = 1

EndButton = mop_CreateZone(300,400,100,25)
Toggle = mop_CreateZone(300,5,100,25)

do
   cls
   Mop_Update()
   print "FPS: ", screen fps()
   print
   print "MouseX: ", mop_posx()
   print "MouseY: ", mop_posy()
   print
   print "Move-X: ", mop_MoveX()
   print "Move-Y: ", mop_MoveY()
   print "Move-Z: ", mop_MoveZ()
   print
   print "Mouseclick: ", mouseclick()
   print "Left:  ", mop_Click(1)
   print "Right: ", mop_Click(2)
   print "Top:   ", mop_Click(3)
   print
   print "Newclick:"
   print "Left:  ", mop_NewClick(1)
   print "Right: ", mop_NewClick(2)
   print "Top:   ", mop_NewClick(3)
   print
   print "Doubleclick:"
   print "SamePos: ", mop_GetDoubleClickSamePos()
   print "Delay:   ", mop_GetDoubleClickDelay()
   print "Left:  ", mop_DoubleClick(1)
   print "Right: ", mop_DoubleClick(2)
   print "Top:   ", mop_DoubleClick(3)
   print
   print "Zone:"
   print "Hover: ", mop_InZone(EndButton)
   print
   print "-Use RMB/TMB to move Button"
   print "-Doubleclick for events"
   print "-Press 'Toggle' to change SamePos"
   rem Double-Click-Events
   mop_ShowZone(Toggle,"Toggle",0)
   if mop_InZone(Toggle) and mop_NewClick(1)=1 then SamePos = 1-SamePos
   mop_SetDoubleclickSamePos(SamePos)
   if mop_DoubleClick(1)=1 : for x = 1 to 10 : print rnd(99) : sync : wait 100 : next x : endif
   if mop_DoubleClick(2)=1 then for x = 1 to 30 : cls rnd(0xFFFFFF) : sync : wait 10 : next x
   if mop_DoubleClick(3)=1 `lock/unlock mouse
      if mop_GetLocked()=1
         mop_UnlockMouse()
      else
         mop_LockMouse(mop_posx(),mop_posy())
      endif
   endif
   rem End-Event
   mop_ShowZone(EndButton,"End",2)
   if mop_NewClick(1)=1 and mop_InZone(EndButton) then end
   if spacekey() then mop_PositionZone(EndButton,mousex(),mousey())
   rem Drag&Drop Button (rightkey)
      rem Drag
      if mop_NewClick(2)=1 and mop_InZone(EndButton)
         LastX = mop_PosX() : LastY = mop_PosY() : Selected1 = 1
      else
      rem Drop
         if mop_NewClick(2)=-1 and Selected1 = 1
            _xdif = mop_PosX()-LastX
            _ydif = mop_PosY()-LastY
            mop_RelPositionZone(EndButton,_xdif,_ydif)
            Selected1 = 0
         endif
      endif
      rem Show Line
      if mop_Click(2)=1 and Selected1=1 then line mop_PosX(),mop_PosY(),LastX, LastY
   rem Drag&Drop Button (topkey)
      rem Drag
      if mop_NewClick(3)=1 and mop_InZone(EndButton)
         XDif = mop_PosX()-mop_Zone(EndButton).x1
         YDif = mop_PosY()-mop_Zone(EndButton).y1
         Selected2 = 1
      else
      rem Drop
         if mop_Click(3)=1 and Selected2=1
            mop_PositionZone(EndButton,mop_PosX()-XDif,mop_PosY()-YDif)
         else
            Selected2 = 0
         endif
      endif
   rem Drag&Drop toggle-Button
      rem Drag
      if (mop_NewClick(2)=1) and (mop_InZone(Toggle)=1)
         mop_DragObject(mop_GetZoneX(Toggle),mop_GetZoneY(Toggle))
      endif
      rem Position/Drop
      if mop_GetDragged()=1
         if mop_NewClick(2)=-1 then mop_Drop()
         mop_PositionZone(Toggle,mop_GetDraggedObjectX(),mop_GetDraggedObjectY())
      endif

   sync
loop

The code shows the main-features. For example, you can drag and drop the two buttons, using the right/top mousebutton.
Also much information about the mouse is showed on the screen.
I know, that most of the features are easy to do in dark basic, but for example the doubleclick-management is something I often wished to have, and didn't really know how to do it. (I think it's also possible to do it over windows DLLs.. but I'm not sure)

So I'm going to write another example-code now.

I'd apreciate criticism, questions, feature-ideas etc., thanks.

Mr Kohlenstoff

Edit:

I made a new demo-program, the code is better structured, and most features are used again.

Here the code:

rem Display settings
set display mode 1024,768,32
sync on : sync rate 0
randomize timer()

rem Start Mouse-Plugin
StartMoP()

rem Create different zones for the menu
x = 412 : y = 200 : dis = 100 : w = 200 : h = 40
NewGame  = mop_CreateZone(x,y,w,h)
LoadGame = mop_CreateZone(x,y+dis,w,h)
Options  = mop_CreateZone(x,y+dis*2,w,h)
Credits  = mop_CreateZone(x,y+dis*3,w,h)
EndGame  = mop_CreateZone(x,y+dis*5,w,h)
Help     = mop_CreateZone(10,10,150,30)
rem Change the Zone-Colors
mop_SetZoneColors(rgb(255,255,255),rgb(0,0,200),rgb(255,255,255))

rem Main-Loop
do
   rem Clear screen
   cls

rem Headline
   center text 512,40,"Main-Menu"

rem Update Mouse-Plugin
   mop_Update()

rem Show Zones
   style = 2 `This is the style, in which the zones are drawn, 0,1 and 2 are possible
   mop_ShowZone(NewGame,"SamePos: "+str$(mop_GetDoubleClickSamePos()),style)
   if mop_GetLocked()=1 then load$ = "Doubleclick" else load$ = "Click me!"
   mop_ShowZone(LoadGame,load$,style)
   if (mop_GetDragged()=1 and Dragged=Options) then opt$ = "Drop me!" else opt$ = "Drag me!"
   mop_ShowZone(Options,opt$,style)
   mop_ShowZone(Credits,"Change Colors",style)
   mop_ShowZone(EndGame,"End",style)
   mop_ShowZone(Help,"Click/Drag",0)

rem Events
   gosub MouseEvents

rem Render screen
   sync
loop

rem Labels

MouseEvents:
      rem Simple button-clicks
      if mop_NewClick(1)=1
         rem End
         if mop_InZone(EndGame)
            end
         endif
         rem change colors if credits-button is pressed
         if mop_InZone(Credits)
            c1 = rgb(rnd(255),rnd(255),rnd(255))
            c2 = rnd(0xFFFFFF)
            c3 = rnd(0xFFFFFF)
            mop_SetZoneColors(c1,c2,c3)
         endif
         rem Load Game-Button -> mouse is locked, until user doubleclicks
         if mop_InZone(LoadGame) and mop_GetLocked()=0
            mop_LockMouse(mop_PosX(),mop_PosY())
         endif
         rem New Game-Button -> DoubleClickSamePos is toggled (SamePos=1->both clicks have to hit the same pixel)
         if mop_InZone(NewGame) and mop_NewClick(1)
            mop_SetDoubleClickSamePos(1-mop_GetDoubleClickSamePos())
         endif
      endif

rem Doubleclick
      if mop_DoubleClick(1)
         rem Unlock mouse (if it's locked on the load-button)
         mop_UnlockMouse()
         rem Help-Button
         if mop_InZone(Help) then mop_RelPositionZone(Help,5-rnd(10),5-rnd(10))
      endif

rem Drag and Drop Options-Button
      if mop_NewClick(1)=1
         if mop_InZone(Options)=1
            Dragged = Options
            mop_DragObject(mop_GetZoneX(Options),mop_GetZoneY(Options))
         endif
      endif
      rem Positioning and Dropping
      if mop_GetDragged()=1 and Dragged = Options
         mop_PositionZone(Options,mop_GetDraggedObjectX(),mop_GetDraggedObjectY())
         rem Drop if mouse-click stops
         if mop_NewClick(1)=-1 then mop_Drop()
      endif

rem Other Drag-and-Drop-System
      if mop_NewClick(1)=1
         if mop_InZone(Help)=1
            Dragged = Help
            mop_Drag()
         endif
      endif
      rem Showing new Position
      if mop_GetDragged()=1 and Dragged = Help
         line mop_PosX(), mop_PosY(), mop_GetDragX(), mop_GetDragY()
         rem Drop
         if mop_NewClick(1)=-1
            mop_Drop()
            mop_RelPositionZone(Help,mop_GetDropXDif(),mop_GetDropYDif())
         endif
      endif
   return

+ Code Snippet

rem Display settings
set display mode 1024,768,32
sync on : sync rate 0
randomize timer()

rem Start Mouse-Plugin
StartMoP()


rem Create different zones for the menu
x = 412 : y = 200 : dis = 100 : w = 200 : h = 40
NewGame  = mop_CreateZone(x,y,w,h)
LoadGame = mop_CreateZone(x,y+dis,w,h)
Options  = mop_CreateZone(x,y+dis*2,w,h)
Credits  = mop_CreateZone(x,y+dis*3,w,h)
EndGame  = mop_CreateZone(x,y+dis*5,w,h)
Help     = mop_CreateZone(10,10,150,30)
rem Change the Zone-Colors
mop_SetZoneColors(rgb(255,255,255),rgb(0,0,200),rgb(255,255,255))


rem Main-Loop
do
   rem Clear screen
   cls

   rem Headline
   center text 512,40,"Main-Menu"

   rem Update Mouse-Plugin
   mop_Update()

   rem Show Zones
   style = 2 `This is the style, in which the zones are drawn, 0,1 and 2 are possible
   mop_ShowZone(NewGame,"SamePos: "+str$(mop_GetDoubleClickSamePos()),style)
   if mop_GetLocked()=1 then load$ = "Doubleclick" else load$ = "Click me!"
   mop_ShowZone(LoadGame,load$,style)
   if (mop_GetDragged()=1 and Dragged=Options) then opt$ = "Drop me!" else opt$ = "Drag me!"
   mop_ShowZone(Options,opt$,style)
   mop_ShowZone(Credits,"Change Colors",style)
   mop_ShowZone(EndGame,"End",style)
   mop_ShowZone(Help,"Click/Drag",0)

   rem Events
   gosub MouseEvents

   rem Render screen
   sync
loop


rem Labels

   MouseEvents:
      rem Simple button-clicks
      if mop_NewClick(1)=1
         rem End
         if mop_InZone(EndGame)
            end
         endif
         rem change colors if credits-button is pressed
         if mop_InZone(Credits)
            c1 = rgb(rnd(255),rnd(255),rnd(255))
            c2 = rnd(0xFFFFFF)
            c3 = rnd(0xFFFFFF)
            mop_SetZoneColors(c1,c2,c3)
         endif
         rem Load Game-Button -> mouse is locked, until user doubleclicks
         if mop_InZone(LoadGame) and mop_GetLocked()=0
            mop_LockMouse(mop_PosX(),mop_PosY())
         endif
         rem New Game-Button -> DoubleClickSamePos is toggled (SamePos=1->both clicks have to hit the same pixel)
         if mop_InZone(NewGame) and mop_NewClick(1)
            mop_SetDoubleClickSamePos(1-mop_GetDoubleClickSamePos())
         endif
      endif

      rem Doubleclick
      if mop_DoubleClick(1)
         rem Unlock mouse (if it's locked on the load-button)
         mop_UnlockMouse()
         rem Help-Button
         if mop_InZone(Help) then mop_RelPositionZone(Help,5-rnd(10),5-rnd(10))
      endif

      rem Drag and Drop Options-Button
      if mop_NewClick(1)=1
         if mop_InZone(Options)=1
            Dragged = Options
            mop_DragObject(mop_GetZoneX(Options),mop_GetZoneY(Options))
         endif
      endif
      rem Positioning and Dropping
      if mop_GetDragged()=1 and Dragged = Options
         mop_PositionZone(Options,mop_GetDraggedObjectX(),mop_GetDraggedObjectY())
         rem Drop if mouse-click stops
         if mop_NewClick(1)=-1 then mop_Drop()
      endif

      rem Other Drag-and-Drop-System
      if mop_NewClick(1)=1
         if mop_InZone(Help)=1
            Dragged = Help
            mop_Drag()
         endif
      endif
      rem Showing new Position
      if mop_GetDragged()=1 and Dragged = Help
         line mop_PosX(), mop_PosY(), mop_GetDragX(), mop_GetDragY()
         rem Drop
         if mop_NewClick(1)=-1
            mop_Drop()
            mop_RelPositionZone(Help,mop_GetDropXDif(),mop_GetDropYDif())
         endif
      endif
   return

And, finally, an image of this demo.

Have fun!

Visit the DBPro - Speed up your game-Thread. http://forum.thegamecreators.com/?m=forum_view&t=88661&b=1

Back to top

Profile PM Email

Mr Kohlenstoff

18

Years of Service

User Offline

Joined: 7th Jun 2006

Location: Germany

Posted: 10th Jun 2007 02:16

Link

I've created a Keywords-file for the functions.

If anyone uses them, he should create a file "MousePluginKeywords.ini" or something in "Editor\Keywords\" and paste this lines into it:

Quote: "StartMop=MousePlugin_Help.html=(*No Parameters*)
mop_SetDoubleClickDelay=MousePlugin_Help.html=(time)
mop_SetDoubleClickSamePos=MousePlugin_Help.html=(SamePos as boolean)
mop_Update=MousePlugin_Help.html=(*No Parameters*)
mop_PosX=MousePlugin_Help.html=(*No Parameters*)
mop_PosY=MousePlugin_Help.html=(*No Parameters*)
mop_MoveX=MousePlugin_Help.html=(*No Parameters*)
mop_MoveY=MousePlugin_Help.html=(*No Parameters*)
mop_MoveZ=MousePlugin_Help.html=(*No Parameters*)
mop_Click=MousePlugin_Help.html=(Button)
mop_NewClick=MousePlugin_Help.html=(Button)
mop_DoubleClick=MousePlugin_Help.html=(Button)
mop_InField=MousePlugin_Help.html=(x1,y1,x2,y2)
mop_CreateZone=MousePlugin_Help.html=(x1,y1,w,h)
mop_GetZoneX=MousePlugin_Help.html=(ID)
mop_GetZoneY=MousePlugin_Help.html=(ID)
mop_GetZoneX2=MousePlugin_Help.html=(ID)
mop_GetZoneY2=MousePlugin_Help.html=(ID)
mop_GetZoneWidth=MousePlugin_Help.html=(ID)
mop_GetZoneHeight=MousePlugin_Help.html=(ID)
mop_PositionZone=MousePlugin_Help.html=(ID,X,Y)
mop_RelPositionZone=MousePlugin_Help.html=(ID,xadd,yadd)
mop_InZone=MousePlugin_Help.html=(ID)
mop_ShowZone=MousePlugin_Help.html=(ID,t$,Filled as boolean)
mop_SetZoneColors=MousePlugin_Help.html=(Txt as dword, Fill as dword, Border as dword)
mop_LockMouse=MousePlugin_Help.html=(x,y)
mop_UnlockMouse=MousePlugin_Help.html=(*No Parameters*)
mop_GetLocked=MousePlugin_Help.html=(*No Parameters*)
mop_GetLockX=MousePlugin_Help.html=(*No Parameters*)
mop_GetLockY=MousePlugin_Help.html=(*No Parameters*)
mop_GetDoubleClickSamePos=MousePlugin_Help.html=(*No Parameters*)
mop_GetDoubleClickDelay=MousePlugin_Help.html=(*No Parameters*)
mop_Drag=MousePlugin_Help.html=(*No Parameters*)
mop_DragObject=MousePlugin_Help.html=(ObjX,ObjY)
mop_GetDraggedObjectX=MousePlugin_Help.html=(*No Parameters*)
mop_GetDraggedObjectY=MousePlugin_Help.html=(*No Parameters*)
mop_Drop=MousePlugin_Help.html=(*No Parameters*)
mop_GetDragged=MousePlugin_Help.html=(*No Parameters*)
mop_GetDragX=MousePlugin_Help.html=(*No Parameters*)
mop_GetDragY=MousePlugin_Help.html=(*No Parameters*)
mop_GetDropXDif=MousePlugin_Help.html=(*No Parameters*)
mop_GetDropYDif=MousePlugin_Help.html=(*No Parameters*)
"

I think I'm also going to create a small help file, including an overview about all the functions in one table.

Visit the DBPro - Speed up your game-Thread. http://forum.thegamecreators.com/?m=forum_view&t=88661&b=1

Back to top

Profile PM Email

vorconan

18

Years of Service

User Offline

Joined: 4th Nov 2006

Location: Wales

Posted: 10th Jun 2007 08:36

Link

Looks really really good, thanks, I'll need these.

Back to top

Profile PM Email

Mr Kohlenstoff

18

Years of Service

User Offline

Joined: 7th Jun 2006

Location: Germany

Posted: 11th Jun 2007 18:13

Link

OK, thanks for the comment.. any ideas for new features?

Visit the DBPro - Speed up your game-Thread. http://forum.thegamecreators.com/?m=forum_view&t=88661&b=1

Back to top

Profile PM Email

vorconan

18

Years of Service

User Offline

Joined: 4th Nov 2006

Location: Wales

Posted: 13th Jun 2007 23:57

Link

I think it's fairly well built at the moment, maybe some sort of rotate command to keep you going? Just an idea, might come in useful

Back to top

Profile PM Email

jason p sage

17

Years of Service

User Offline

Joined: 10th Jun 2007

Location: Ellington, CT USA

Posted: 14th Jun 2007 00:48

Link

I like what you've done from examining the code. The code is clean enough to read and seems fairly easy to understand - which is a credit to you and in no way takes away from the work that you put into it.

In Short: Good Job!

Why I popped into your thread is because I'm writing my own input routines, and I was looking for a programmable user input source - so you can program a game to map almost ANY CONTROL to ALMOST any game action - JoyX, MouseY, Left Arrow Key etc.

I have a decent start, and seeing how your code is in here - I presume its ok to nag it and do what I want with it right?

I'm thinkning I already have MANY of your global variables defined already - for things like MouseX, Y etc. By merging the two "systems" to share variables, etc. It could become QUITE powerful as a user input solution.

One of the biggest drawbacks I found in User Input in DarkBasic - is that in order to get SMOOTH KEYBOARD (often functioning smooth multi-key press stuff also ..cuz a$=inkey$() doesn't cut it for many gample situations...i digress) ... In order to get smoother Keyboard input you need to use SCANCODE and KEYSTATE commands. Point is that to scan the WHOLE keyboard (101 KeyS) its SLOW - So part of my Whole Mapping thing is to allow you to set up say 10 actions that you are looking for to keep the overhead low as possible - by limiting the "scan for input" routine to only scan for what you need/expect. Note that you can scan for as much as you want also... like the part where you actually ask the user to enter the key, mouse, or joystick you want to control Shooting.

well, good day.

Know way to many languages - Master of none

Back to top

Profile PM Email Website

Mr Kohlenstoff

18

Years of Service

User Offline

Joined: 7th Jun 2006

Location: Germany

Posted: 14th Jun 2007 14:36 Edited at: 14th Jun 2007 14:45

Link

@vorcanon: What exactly do you mean with rotation.. I'm not sure what I could rotate there.

@jason: You can, of course, do with my code what you want, and include it in your project if you want.
Do you check the keystates everytime an update-function is called? Then, of course, it would be slow, but you could just call the keystate-function if the code uses your, for example, "CapslockKeyPressed"-Function.. as far as I understood this could maybe solve the performance-problem, but I'm not sure. ^^

Thanks for the comments so far. I've just seen another thread (I think in the DBP-Board) where I read that it's possible to change the function calls with constants, so that you can e.g. write "mop_SetDoubleClickDelay 200" instead of using this brackets...
(Was this thread btw: http://forum.thegamecreators.com/?m=forum_view&t=108125&b=1&p=0 )
So I think I'm going to include some of this constants now, and then maybe create a small overview-helpfile.

Edit: I testet using the constant function-names, but theres a problem when you call other functions in the parameters, so for example "mop_PositionZone mop_PosX(), mop_PosY()" causes an error... so I think I won't include this constants and let it as it is.

Visit the DBPro - Speed up your game-Thread. http://forum.thegamecreators.com/?m=forum_view&t=88661&b=1

Back to top

Profile PM Email

jason p sage

17

Years of Service

User Offline

Joined: 10th Jun 2007

Location: Ellington, CT USA

Posted: 14th Jun 2007 18:48

Link

Hello Mr Kohlenstoff!

You understand just find. Scanning the whole keyboard for all possible scancodes is slow.

So, to answer your question (sort of) "(Jason,) Do you check the keystates everytime an update-function is called?"

I did once. It was to slow. So I did some research and modified things a bit.

First of all - my goal is to make one "Get User Input" function that handles EVERYTHING I need handled in whatever MAIN LOOP I'm using to run a game or menu etc. Tall Order? Yeah - but I think I nailed it!

I managed to create a small group of functions that REALLY are great for managing user input of any sort, the ability to map any user input to any "action" and this "action" separation from the ACTUAL user input makes it a PERFECT system for being able to write code that can be shared by the game player and other game characters - which implies its a cool way to control AI and game plyer in similiar fashion!

This has come together nicely and its WAY easier than it sounds (I SWEAR!) Now all I need to do is merge your mouse "helper" functions with the infrastructure I've built. I am VERY excited about this.

The key to the whole speed thing of checking all keyboard codes etc. is to obviously limit the number of "checks" to only those you absolutely need.

Searching for 5 to 10 keys is MUCH faster than searching for 101 when in the context of a game play main loop.

I implemented dynamic arrays to allow adding as little or as many user input things you want to check for.

I found code similiar to what I was doing on a lesser scale that was very helpful. (By "lesser" I only mean that mine includes keyboard, joystick, mouse and control devices and the example I'm referring to only did the keys and did not have the "User Input" to "Action" mapping I'm referring to above.

(this is the one "Keystate Monitor" : http://forum.thegamecreators.com/?m=forum_view&t=107531&b=6)

So in short: You add the stuff you want to scan/poll albeit keyboard keys, mousex, mousey, mousez, mousemovedx, joystick x, joystick button 1, etc. and you just call GetUserInput() and it handles it for you - but in a simplified manner compared to the above referenced KeyState Monitor which has KeyEnabled/KeyDelay, KeyIsAToggleSwitch, etc.

I took this KeyEnabled/KeyDelay, KeyIsAToggleSwitch, functionality and implemented it in my "Action" area. So, how it all works it you FIRST add ACTIONS to your game:
Shoot Gun, Shoot Laser, Forward, Backward, "Sprint/Run", etc. Each Action You create gets a #.

+ Code Snippet

` iAddAction - Adds a action to be monitored/configured, and returns the
`              Action's assigned ID which is actually the index poistion in the
`              garAction() Array.
`
`   p_bEnabled: 1=True, 0=False
`
`   p_bToggle: Toggle specifies whether the action is a toggle Switch. (0=No, 1=Yes)
`
`   p_iDelayInMilliseconds: is just that. To make a delayed action, an action that cannot
`                           occur until the length of Time in milliseconds passes. Passing
`                           0 = immediately - no delay.
````````````````````````````````````````````````````
` Declaration: Function iAddAction(p_bEnabled, p_bToggle, p_iDelayInMilliSeconds)


``` Sample:
iShootGun = iAddAction(True, False,500)

You THEN add things for the "GetUserInput()" to poll using " syntax like this:

+ Code Snippet

iAddInputPoll(cnJoystick, cnJoystickButton1, iShootGun)"

Then in your main loop you check the actions you are immediately
concerned with - like things the user can do - such as Shoot gun.

You simply check if garAction(iShootGun).bActionRequested=TRUE

What is nice is that bActionRequested is only TRUE IF all conditions met, in this case, when a bullet has not been fired or the half second (500 milli sec) delay has expired... etc.

Then its your responsiblity to clear this flag because you MIGHT not want to clear this flag if its a toggle action - depend on implementation - but so far the code is looking good and I'm willing to share it after I implement your mouse functions and do some more testing and do any optimizations that are necessary to make it easy to use and fast.

So I'm mid way done accomplishing the following:

1

ne User Input routine for all devices that is fast
2:Ability to manage game actions for both player and AI
3:Ability to map any user input control to any game action (think of those config screens in decent games that let you pick what keys do what and if you want to use joystick or mouse etc)

For those of you who might be reading this and are not programming gurus - which I'm NOT claiming to be by the way - one of the main programming matras is to separate "functionality" from "User Interface" and in a game this seems like it could not possibly apply but in many ways these routines accomplish this to some degree and to a larger degree they put a line in the sand between "what the game does and the player can do in the game" and "how the user actually interacts with the game".

Know way to many languages - Master of none

Back to top

Profile PM Email Website

The ARRAYinator

19

Years of Service

User Offline

Joined: 13th Aug 2005

Location:

Posted: 18th Jun 2007 22:59

Link

Very Nice! Im pretty sure I can find a use for this in gamescape as there's a ton of mouse stuff left to be dealt with. Thanks!

Back to top

Profile PM Website

Mr Kohlenstoff

18

Years of Service

User Offline

Joined: 7th Jun 2006

Location: Germany

Posted: 19th Jun 2007 15:29

Link

@Jason: Sounds really interesting, I think now I understand what your functions are made for..

Looking forward to see my mouse-functions cooperating with it.

@Arrayinator: Thanks for the comment.. no problem. Also nice to see the functions in such a big, promising project.

Visit the DBPro - Speed up your game-Thread. http://forum.thegamecreators.com/?m=forum_view&t=88661&b=1

Back to top

Profile PM Email

The ARRAYinator

19

Years of Service

User Offline

Joined: 13th Aug 2005

Location:

Posted: 19th Jun 2007 20:22 Edited at: 19th Jun 2007 20:23

Link

thanks alot MR. K The functions are actually quite helpful and have been used in my latest editon to Gamscape which is a true 3d mouse where you basically can drag the mouse across the terrains and raise points from any angle which makes the workflow 1000 times better. Im going to post a little video demonstration later for the heck of it so be sure to check it out. These will definetly be useful functions to have around thanks!

Back to top

Profile PM Website

Sorry your browser is not supported!

Code Snippets / [DBP] Mouse Plugin - Function collection for better mouse-control