Sorry your browser is not supported!

disable systemkeys
disable escapekey
hide mouse
sync on

`Create World Map (water=0 : grass=1 : town=2 : woods=3 : cave=4)
DIM map(4,4)
map(0,0)=0 : map(1,0)=1 : map(2,0)=1 : map(3,0)=3 : map(4,0)=4
map(0,1)=0 : map(1,1)=2 : map(2,1)=2 : map(3,1)=3 : map(4,1)=3
map(0,2)=2 : map(1,2)=2 : map(2,2)=2 : map(3,2)=1 : map(4,2)=1
map(0,3)=1 : map(1,3)=1 : map(2,3)=3 : map(3,3)=3 : map(4,3)=0
map(0,4)=0 : map(1,4)=3 : map(2,4)=3 : map(3,4)=3 : map(4,4)=0

`Create Player
DIM Pstat(5)
Pstat(0)=1 : `fighting
Pstat(1)=0 : `weapon
Pstat(2)=0 : `magic
Pstat(3)=0 : `spell
Pstat(4)=30 : `HPmax
Pstat(5)=Pstat(4) : `HP
Px=1 : Py=1 : `player start position
slot=0
item=0
item$=""
action$=""

EnemyHP = 0
EnemyFight# = 0.0

randomize timer()

`--------------------------
` MAIN PROGRAM
`--------------------------
REPEAT
cls
print "Map Reference: "; Px; ", "; Py
if Py-1>=0 then print "To the NORTH is the "; ~map_info(map(Px,Py-1)) : `North
if Px+1<=4 then print "To the EAST is the "; ~map_info(map(Px+1,Py)) : `East
if Py+1<=4 then print "To the SOUTH is the "; ~map_info(map(Px,Py+1)) : `South
if Px-1>=0 then print "To the WEST is the "; ~map_info(map(Px-1,Py)) : `West
print
print "You are standing in the "; ~map_info(map(Px,Py)) : `Location
If action$ <> "" then cls : Print action$
input "> "; com$ : gosub command

If action$ <> "" then cls : Print action$ : wait key
if item=0 then action$=""

sync
UNTIL close=1

undim map(4,4)
undim Pstat(5)
END

`--------------------------
` FUNCTIONS
`--------------------------
FUNCTION ~map_info(tile)
   SELECT tile
      case 0 : tile$="sea" : endcase
      case 1 : tile$="grassland" : endcase
      case 2 : tile$="town" : endcase
      case 3 : tile$="forest" : endcase
      case 4 : tile$="cave" : endcase
   ENDSELECT
ENDFUNCTION tile$

`--------------------------
` GOSUBS
`--------------------------
command:
SELECT upper$(com$)
   Case "NORTH"
      If Py-1>=0
         If Map(Px,Py-1)>0 then Py=Py-1 : item=0 else action$ = "You can't swim."
      else
         action$ = "You can't travel there."
      endif
   Endcase
   Case "EAST"
      If Px+1<=4
         If Map(Px+1,Py)>0 then Px=Px+1 : item=0 : else action$ = "You can't swim."
      else
         action$ = "You can't travel there."
      endif
   Endcase
   Case "SOUTH"
      If Py+1<=4
         If Map(Px,Py+1)>0 then Py=Py+1 : item=0 else action$ = "You can't swim."
      else
         action$ = "You can't travel there."
      endif
   Endcase
   Case "WEST"
      If Px-1>=0
         If Map(Px-1,Py)>0 then Px=Px-1 : item=0 else action$ = "You can't swim."
      else
         action$ = "You can't travel there."
      endif
   Endcase
   Case "SEARCH"
      if rnd(3)=0
         gosub get_item
         action$ = "You found a level "+str$(item_pts)+" "+item$+". "
         if Pstat(slot) >0 then action$ = action$+"You already have a level "+str$(Pstat(slot))+" "+item$+", taking this one will replace it."
      else
         action$ = "You find nothing of interest."
      endif
   Endcase
   Case "ACCEPT"
      if item>0
         action$ = "You took the "+item$+"."
         Pstat(slot) = item_pts
         item=0 : item_pts=0 : slot=0 : item$=""
      else
         action$ = "There is nothing to take."
      endif
   Endcase
   Case "STATS" : action$ = "PLAYER STATS:  Fighting: "+str$(Pstat(0))+"  Weapon: "+str$(Pstat(1))+"  Magic: "+str$(Pstat(2))+"  Spell: "+str$(Pstat(3))+"  HP Max: "+str$(Pstat(4))+"  HP: "+str$(Pstat(5)) : endcase
   Case "EXIT" : close=1 : endcase
   Case "" : endcase
   Case Default : action$ = "OUCH!! You could have someone's eye out with your typing! (Command not understood)" : endcase
ENDSELECT
RETURN

get_item:
   item=rnd(1)+1
   SELECT item
      Case 1 : item$="WEAPON" : slot=1 : Endcase
      Case 2 : item$="SPELL" : slot=3 : Endcase
`      Case 2 : item$="HP POTION" : slot=5 : Endcase
   ENDSELECT
   item_pts = rnd(9)+1
RETURN