I would suggest grabbing an image of the text, making a 3D plane (plain) and texturing the plane with the image. You could then position it at the limb coordinates. The plain with the text on it turns because you are using the limb coordinates, but you could easily change that so that it is positioned based upon the object's coordinates.
Here you go:
Rem Project: text test1
Rem Created: 12/1/2007 9:41:24 AM
Rem ***** Main Source File *****
sync on : sync rate 0
set text font "arial" : set text size 176
set text to bold : set text transparent
SET DISPLAY MODE 1024, 768, 32
SET CAMERA RANGE 0,.1, 200000
SET AMBIENT LIGHT 0
stardistancex#=rnd(100)+50
stardistancez#=rnd(100)+50
starborbitrate#=10/(stardistancex#+stardistancez#)
stardistancebx#=(stardistancex#/5)*-1
stardistancebz#=(stardistancez#/5)*-1
`grav center
MAKE OBJECT SPHERE 1, 10
position object 1, 0,0,0
HIDE OBJECT 1
MAKE OBJECT SPHERE 2, 10
make mesh from object 1,2
add limb 2,1,1
link limb 2,0,1
offset limb 2,1,stardistancex#,0,stardistancez#
MAKE OBJECT SPHERE 3, 10
make mesh from object 2,3
add limb 3,1,2
link limb 3,0,1
offset limb 3,1,stardistancebx#,0,stardistancebz#
HIDE LIMB 3, 0
hide limb 2, 0
cls
a$="Alpha Centari A"
ink rgb(255,0,0),0
text 0,0,a$
get image 1,0,0,text width(a$)+1,text height(a$)+1
cls
make object plain 4,text width(a$),text height(a$)
yrotate object 4,310
texture object 4,1
ghost object on 4
set object ambient 4,100
a$="Alpha Centari B"
ink rgb(255,255,255),0
text 0,0,a$
get image 2,0,0,text width(a$)+1,text height(a$)+1
cls
make object plain 5,text width(a$),text height(a$)
yrotate object 5,310
texture object 5,2
ghost object on 5
set object ambient 5,100
do
sun1posx#=limb POSITION X(3,1)
sun1posy#=limb POSITION y(3,1)
sun1posz#=limb POSITION z(3,1)
sun2posx#=limb POSITION X(2,1)
sun2posy#=limb POSITION y(2,1)
sun2posz#=limb POSITION z(2,1)
limb1y#=LIMB ANGLE Y(2, 0)
limb2y#=LIMB ANGLE Y(3, 0)
ROTATE LIMB 2, 0, 0, limb1y#+starborbitrate#, 0
ROTATE LIMB 3, 0, 0, limb2y#+starborbitrate#, 0
`starname1$="Alpha Centari A"
`starname2$="Alpha Centari B"
sun1scrposx#= OBJECT SCREEN X(2)
sun1scrposy#= OBJECT SCREEN Y(2)
sun2scrposx#= OBJECT SCREEN X(3)
sun2scrposy#= OBJECT SCREEN Y(3)
`center TEXT sun1scrposx#,sun1scrposy#, starname1$
`center TEXT sun2scrposx#,sun2scrposy#, starname2$
`set cursor sun2scrposx#,sun2scrposy#
`print starname2$
position object 4,sun2posx#,sun2posy#,sun2posz#
position object 5,sun1posx#,sun1posy#,sun1posz#
set cursor 20,20
print "sun1scrposx#-",sun1scrposx#
set cursor 20,30
print "sun1scrposy#-",sun1scrposy#
set cursor 20,40
print "sun2scrposx#-",sun2scrposx#
set cursor 20,50
print "sun2scrposy#-",sun2scrposy#
position camera sun1posx#-155, 5, sun1posz#+155
point camera sun2posx#,0,sun2posz#
sync
loop
end
I slowed it down a little and changed one of the text colors to red so that you could easily see where one is passing before the other.
Hope this helps.
LB
