circle math problem - GameCreators Forum

Author

Message

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 26th Dec 2007 18:03

Link

hey guys!

Ive been working on this game called "barrel patrol", but have come across a problem.

First let me describe the game:
You are a tank. You play inside a circle of fire, which you can not leave. In the middle of that circle are 25 barrels, which are attacked by the fierce aliens of the undergrounds. You have to guard the barrels for 3 minutes, trying to blow up as many aliens as you can, and making sure, they dont steel your barrels.

Heres the function for the circle math, to keep the player inside it:

rem get positions for function
midx#=500.0 : rem the middle x position of the matrix
midz#=500.0 : rem the middle z position of the matrix
x#=object position x(1000) : rem the x position of the player
z#=object position z(1000) : rem the z position of the player

rem the circle function
if circle(midx#,midz#,x#,z#)>240 : rem 240 is the radius of the maximum  
                                   rem distance the player can go, before 
                                   rem he/she goes out of the circle

rem here the trouble begins...(read on in my post)

rem *******************************************
rem *               FUNCTIONS                 *
rem *******************************************

function circle(midx#,midz#,x#,z#)

radius=sqrt(((x#-midx#)*(x#-midx#))*((z#-midz#)*(z#-midz#)))

`you dont need to know how this works, but if you do:
`the midx and midz indicate the positions of the centre of the circle
`if you subtract the midx and midz values from the x and z values, you get
`the distance of the player from the centre of the circle.
`now if you multiply the x-midx and the z-midz with them self, you do
`a triangle math indicating the tan value from the centre.
`if you multiply the two end results with one another, you add the tow
`triangles together and taking the square root of that result will give you
`the distance of the player from the centre(the radius)

endfunction radius

+ Code Snippet

rem get positions for function
midx#=500.0 : rem the middle x position of the matrix
midz#=500.0 : rem the middle z position of the matrix
x#=object position x(1000) : rem the x position of the player
z#=object position z(1000) : rem the z position of the player

rem the circle function
if circle(midx#,midz#,x#,z#)>240 : rem 240 is the radius of the maximum  
                                   rem distance the player can go, before 
                                   rem he/she goes out of the circle

rem here the trouble begins...(read on in my post)



rem *******************************************
rem *               FUNCTIONS                 *
rem *******************************************

function circle(midx#,midz#,x#,z#)

radius=sqrt(((x#-midx#)*(x#-midx#))*((z#-midz#)*(z#-midz#)))

`you dont need to know how this works, but if you do:
`the midx and midz indicate the positions of the centre of the circle
`if you subtract the midx and midz values from the x and z values, you get
`the distance of the player from the centre of the circle.
`now if you multiply the x-midx and the z-midz with them self, you do
`a triangle math indicating the tan value from the centre.
`if you multiply the two end results with one another, you add the tow
`triangles together and taking the square root of that result will give you
`the distance of the player from the centre(the radius)

endfunction radius

I have tried storing the old position of the player at the start of the loop, and if there is a collision(the radius is bigger than 240) it would position the player with the old positions instead of the new ones. But that made the player stick at the circle and not get loose again.

I have tried making the player bounce back until theres no collision, but then the weirdest thing you can possibly think of occured.

Finally, I just made the player die when it goes out of bounds, but that isnt fun anymore.

Does anyone know how to make a collision at the circle edge, without the errors at top occuring?

Many thanks!

Oooooops!!! I accidentally formated drive c.

Back to top

Profile PM Email Website

RUCCUS

21

Years of Service

User Offline

Joined: 11th Dec 2004

Location: Canada

Posted: 26th Dec 2007 19:12 Edited at: 26th Dec 2007 19:33

Link

You could get the distance the player is past the allowed radius, and move them back by that distance (plus whatever buffer you want, if you want one).

<EDIT>

Actually that will cause sticking too. What you need to do is effect the user's x and y component individually. Then check for collision on each axis. If there's a collision on the x axis, stop effecting it. If on the y, stop effecting it as well. This way, if there's a collision on the x but not the y, the user will "slide" along the radius of the circle because the y will still increase.

This is what I threw together for the initial idea I suggested, dont have time to change it to the other one, but Ill post it anyways, it has some useful math functions in there that might help you (using vectors is faster than doing your own trig).

TYPE field
   radius#,buffer#
   x#,y#
ENDTYPE

TYPE usr
   x#, y#, distance#, angle#
   direction
ENDTYPE

GLOBAL field AS field
field.radius# = 200
field.buffer# = 10
field.x# = SCREEN WIDTH()/2
field.y# = SCREEN HEIGHT()/2

GLOBAL usr AS usr
usr.x# = field.x#
usr.y# = field.y#

init()

DISABLE ESCAPEKEY:WHILE ESCAPEKEY() = 0
   move(0.5,1)
   collision()
   render()
ENDWHILE:END

FUNCTION init()
   BACKDROP ON:COLOR BACKDROP RGB(000,255,000)
   SYNC ON
   math_setup()
ENDFUNCTION

FUNCTION move(moveSpeed#, turnSpeed#)
   INC usr.angle#, (LEFTKEY() - RIGHTKEY()) * turnSpeed#
   usr.direction = UPKEY() - DOWNKEY()
   usr.x# = NEWXVALUE(usr.x#, usr.angle#, usr.direction * moveSpeed#)
   usr.y# = NEWZVALUE(usr.y#, usr.angle#, usr.direction * moveSpeed#)
ENDFUNCTION

FUNCTION collision()
   usr.distance# = math_getDist2D(usr.x#,usr.y#,field.x#,field.y#)
   IF usr.distance# > field.radius#
      usr.x# = NEWXVALUE(usr.x#, usr.angle# + 180, usr.distance# - field.radius#)
      usr.y# = NEWZVALUE(usr.y#, usr.angle# + 180, usr.distance# - field.radius#)
   ENDIF
ENDFUNCTION

FUNCTION render()
   CIRCLE usr.x#,usr.y#,10
   CIRCLE field.x#,field.y#,field.radius#
   SYNC
ENDFUNCTION

FUNCTION math_setup()
   `setup required vectors for distance calculations
   null = MAKE VECTOR2(2)
   #CONSTANT vecDist2D = 2
ENDFUNCTION

FUNCTION math_getDist2D(X1#,Y1#,X2#,Y2#)
   SET VECTOR2 vecDist2D,X1#-X2#,Y1#-Y2#
   dist# = LENGTH VECTOR2(vecDist2D)
ENDFUNCTION dist#

+ Code Snippet

TYPE field
   radius#,buffer#
   x#,y#
ENDTYPE

TYPE usr
   x#, y#, distance#, angle#
   direction
ENDTYPE

GLOBAL field AS field
field.radius# = 200
field.buffer# = 10
field.x# = SCREEN WIDTH()/2
field.y# = SCREEN HEIGHT()/2

GLOBAL usr AS usr
usr.x# = field.x#
usr.y# = field.y#

init()

DISABLE ESCAPEKEY:WHILE ESCAPEKEY() = 0
   move(0.5,1)
   collision()
   render()
ENDWHILE:END

FUNCTION init()
   BACKDROP ON:COLOR BACKDROP RGB(000,255,000)
   SYNC ON
   math_setup()
ENDFUNCTION

FUNCTION move(moveSpeed#, turnSpeed#)
   INC usr.angle#, (LEFTKEY() - RIGHTKEY()) * turnSpeed#
   usr.direction = UPKEY() - DOWNKEY()
   usr.x# = NEWXVALUE(usr.x#, usr.angle#, usr.direction * moveSpeed#)
   usr.y# = NEWZVALUE(usr.y#, usr.angle#, usr.direction * moveSpeed#)
ENDFUNCTION

FUNCTION collision()
   usr.distance# = math_getDist2D(usr.x#,usr.y#,field.x#,field.y#)
   IF usr.distance# > field.radius#
      usr.x# = NEWXVALUE(usr.x#, usr.angle# + 180, usr.distance# - field.radius#)
      usr.y# = NEWZVALUE(usr.y#, usr.angle# + 180, usr.distance# - field.radius#)
   ENDIF
ENDFUNCTION

FUNCTION render()
   CIRCLE usr.x#,usr.y#,10
   CIRCLE field.x#,field.y#,field.radius#
   SYNC
ENDFUNCTION

FUNCTION math_setup()
   `setup required vectors for distance calculations
   null = MAKE VECTOR2(2)
   #CONSTANT vecDist2D = 2
ENDFUNCTION

FUNCTION math_getDist2D(X1#,Y1#,X2#,Y2#)
   SET VECTOR2 vecDist2D,X1#-X2#,Y1#-Y2#
   dist# = LENGTH VECTOR2(vecDist2D)
ENDFUNCTION dist#

Sorry, no time to comment it.

Back to top

Profile PM Email Website

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 26th Dec 2007 19:44

Link

I`ll try it tomorrow, since I have to shut down but hey, thanks very much!!

Oooooops!!! I accidentally formated drive c.

Back to top

Profile PM Email Website

Libervurto

20

Years of Service

User Offline

Joined: 30th Jun 2006

Location: On Toast

Posted: 26th Dec 2007 21:47 Edited at: 26th Dec 2007 23:50

Link

@Ruccus
Your theory is good but unfortunately DBC can't do vectors

[edit]
Here's my solution.
I put it together as I wrote it so it might not be that great, but it does work

hide mouse
sync on

`Make Ring of Fire
RingX=320
RingY=240
RingR=200

`Make Player
PlayerX=RingX
PlayerY=RingY
PlayerR=10

Do
   `get input
   u=upkey():d=downkey():l=leftkey():r=rightkey()
   `Update player position movement from input
   PlayerX = CurveValue(PlayerX+(r*30)-(l*30),PlayerX,10)
   PlayerY = CurveValue(PlayerY+(d*30)-(u*30),PlayerY,10)

`Find the angle between the ring's centre and the player's position
   DistX = PlayerX-RingX
   DistY = PlayerY-RingY
   Angle = ATanFull(DistX,DistY)

`bind player inside ring
   Dist = sqrt(DistX^2 + DistY^2) : `find actual distance like a triangle
   If Dist>RingR
      `Find the ring's edge
      Xedge = sin(Angle)*RingR
      Yedge = cos(Angle)*RingR
      `put the player on the ring's edge
      PlayerX=Xedge+RingX : PlayerY=Yedge+RingY
   endif

circle RingX,RingY,RingR
   circle PlayerX,PlayerY,PlayerR

print "Player X: "; PlayerX ; "  Player Y: "; PlayerY
   print "Player X(from centre): "; DistX ; "  Player Y(from centre): "; DistY
   print "Player angle from center: " ; Angle
   print "Ring Edge X: "; Xedge ; "  Ring Edge Y: "; Yedge

sync : cls
Loop

+ Code Snippet

hide mouse
sync on

`Make Ring of Fire
RingX=320
RingY=240
RingR=200

`Make Player
PlayerX=RingX
PlayerY=RingY
PlayerR=10

Do
   `get input
   u=upkey():d=downkey():l=leftkey():r=rightkey()
   `Update player position movement from input
   PlayerX = CurveValue(PlayerX+(r*30)-(l*30),PlayerX,10)
   PlayerY = CurveValue(PlayerY+(d*30)-(u*30),PlayerY,10)

   `Find the angle between the ring's centre and the player's position
   DistX = PlayerX-RingX
   DistY = PlayerY-RingY
   Angle = ATanFull(DistX,DistY)

   `bind player inside ring
   Dist = sqrt(DistX^2 + DistY^2) : `find actual distance like a triangle
   If Dist>RingR
      `Find the ring's edge
      Xedge = sin(Angle)*RingR
      Yedge = cos(Angle)*RingR
      `put the player on the ring's edge
      PlayerX=Xedge+RingX : PlayerY=Yedge+RingY
   endif

   circle RingX,RingY,RingR
   circle PlayerX,PlayerY,PlayerR

   print "Player X: "; PlayerX ; "  Player Y: "; PlayerY
   print "Player X(from centre): "; DistX ; "  Player Y(from centre): "; DistY
   print "Player angle from center: " ; Angle
   print "Ring Edge X: "; Xedge ; "  Ring Edge Y: "; Yedge

   sync : cls
Loop

Back to top

Profile PM Email

demons breath

22

Years of Service

User Offline

Joined: 4th Oct 2003

Location: Surrey, UK

Posted: 27th Dec 2007 13:53

Link

An alternative; when it reaches one side of the circle have it come on the opposite side instead... Calculate the angle from the centre and simply reverse it so that it's just inside the opposite side (obviously not still touching it as that would defeat the point)

"A West Texas girl, just like me"
-Bush

Back to top

Profile PM Website

Bluestar4

20

Years of Service

User Offline

Joined: 19th Dec 2005

Location: USA

Posted: 27th Dec 2007 15:37

Link

I would think that a tank would suffer from fire damage if it goes into fire - why not simply let it take damage unti the player drives it back to the desired area ?

Sutter Soft
http://www.geocities.com/suttersoft

Back to top

Profile PM Email

Libervurto

20

Years of Service

User Offline

Joined: 30th Jun 2006

Location: On Toast

Posted: 27th Dec 2007 16:27

Link

Quote: "An alternative; when it reaches one side of the circle have it come on the opposite side instead... Calculate the angle from the centre and simply reverse it so that it's just inside the opposite side (obviously not still touching it as that would defeat the point)"

you mean the tank would magically appear on the other side of the ring?

Whatever you do the key is measuring how far the tank is from the centre of the circle

Back to top

Profile PM Email

heartbone

23

Years of Service

User Offline

Joined: 9th Nov 2002

Location:

Posted: 27th Dec 2007 16:57

Link

Save the previous position.
Move the object to the new position.
Calculate the new distance to center squared:
NDTCS#= (x#-midx#)*(x#-midx#) + (z#-midz#)*(z#-midz#)
If NDTCS# > (240*240) then
move object back to previous position and update the display.

I'm unique, just like everybody else.

Back to top

Profile PM Website

heartbone

23

Years of Service

User Offline

Joined: 9th Nov 2002

Location:

Posted: 27th Dec 2007 17:20

Link

If your tank can not go in reverse at that point, then you'll need additional logic at the move object back to previous position section.

I'm unique, just like everybody else.

Back to top

Profile PM Website

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 27th Dec 2007 21:30 Edited at: 27th Dec 2007 21:31

Link

Quote: "I would think that a tank would suffer from fire damage if it goes into fire - why not simply let it take damage unti the player drives it back to the desired area ?"

If you make it suffer fire damage, but still live, the tank would just keep on going through the fire. Then you get back to the problem with the collision...

Quote: "Save the previous position.
Move the object to the new position.
move object back to previous position and update the display."

if you do that mate, the tank will get stuck on the "ring of fire" and burn to death. Now I would rather be shot than be burned. (That isn`t the point of this thread...)

I have made the tank bounce back double the speed it came in, but that doesn`t look good:

+ Code Snippet

rem move the tank model
move object 1,5 : rem object 1 is the tank

rem get positions of tank and circle
midx#=500
midz#=500
x#=object position x(1)
z#=object position z(1)
r=240

rem if collision, bounce tank back double the amount it came in
if circle(midx#,midz#,x#,z#)>r : the function is declared in the first post
   move object 1,-10
endif

If I move it -5 instead of -10, it gets stuck. Now I think you are all thinking, why not bounce it back -6(or any other number smaller then -5)?

I you bounce it back smaller than it was before and the tank is right on the edge, it will back up into the the circle a little further next to it. And because it`s still a collision, it`s going to back itself away right out of the level.

Now lets all look at the possibility of putting collision boxes all around the circle. Firstly, it would take up tons of processing time. But secondly, I can use the "if object collision()=1" command:

+ Code Snippet

rem check for collision with the ring of fire
`lets say there are 32 collision boxes placed around the circle and I made
`32 objects around the circle carrying them
for t=2 to 33
   if object collision(1,t)=1
   dec x#,get object collision x()
   dec z#,get object collision z()
   position object 1,x#,10,z#
next t

I dont know what is more effective... What do you guys think of that?

Oooooops!!! I accidentally formated drive c.

Back to top

Profile PM Email Website

Latch

19

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 28th Dec 2007 04:36

Link

When I originally read this thread I put together an example and the saw that OBese87 had already posted one very similar and Ruccus had come up with the idea of adding a buffer, so I didn't post the example. After reading your last post, I'm confused as to what you want and don't want the tank to do.

You want the tank to stay within a certain radius from a center point, right?

If it goes beyond that radius, how do you want the tank to behave? I'll include the example I spoke of (modified for 3d). It doesn't use any collision, and I eliminated most of the floats to optimize a bit. When the tank reaches the outer edge, it will slide along the inside of the circle until it reaches the maximum it can go in either the x or z direction:

rem radial boundary example
rem by latch
rem 12,26,2007

sync on
sync rate 60
set display mode 800,600,32
autocam off
hide mouse

main:
gosub _init

do
   gosub _move_tank
   text 0,0,str$(screen fps())
   sync
loop

end

rem Procedures
_init:
   radius=350
   centerx=500
   centerz=500
   buffer=50

rem make a matrix
   make matrix 1,1000,1000,25,25

rem make a cone to serve as the tank
   make object cone 1,25
   xrotate object 1,90
   make mesh from object 1,1
   delete object 1
   make object 1,1,0
   delete mesh 1
   scale object 1,100,100,300

position object 1,centerx,13,centerz

rem make a visible boundary
   create bitmap 1,100,100
   ink rgb(255,0,0),0
   box 0,24,64,40
   get image 1,0,0,65,65
   delete bitmap 1
   rem texture cylinder for boundary
   make object cylinder 2,1
   texture object 2,1
   set object 2,1,1,0
   ghost object on 2
   position object 2,centerx,10,centerz
   scale object 2,70000,10000,70000

return

_move_tank:
   if upkey()=1 then move object 1,5
   if downkey()=1 then move object 1,-5
   `if leftkey()=1 then turn object left 1,2
   `if rightkey()=1 then turn object right 1,2
   if leftkey()=1 then yrotate object 1,wrapvalue(object angle y(1)-2)
   if rightkey()=1 then yrotate object 1,wrapvalue(object angle y(1)+2)

objx=object position x(1)
   objy=object position y(1)
   objz=object position z(1)

rem if the tank has moved beyond the radius, reset it's position using
   rem the radius-buffer and polar coordinates
   dist=distance_from_center(centerx,centerz,objx,objz)
   text 0,20,str$(radius-50)
   text 0,40,str$(dist)
   if test_distance(radius,buffer,dist)=1
      testang#=atanfull(objz-centerz,objx-centerx)
      newx#=(radius-buffer)*cos(testang#)+centerx
      newz#=(radius-buffer)*sin(testang#)+centerz
      objx=newx#
      objz=newz#
      position object 1,objx,objy,objz
   endif

set camera to follow objx,objy,objz,object angle y(1),150,50,5,0

return

Rem FUNCTIONS
function test_distance(radius,buffer,distance)
   result=0
   if distance >= radius-buffer then result=1
endfunction result

function distance_from_center(centerx,centery,posx,posy)
   dx=posx-centerx
   dy=posy-centery
   dist=sqrt((dx*dx)+(dy*dy))
endfunction dist

+ Code Snippet

rem radial boundary example
rem by latch
rem 12,26,2007

sync on
sync rate 60
set display mode 800,600,32
autocam off
hide mouse


main:
gosub _init

do
   gosub _move_tank
   text 0,0,str$(screen fps())
   sync
loop

end

rem Procedures
_init:
   radius=350
   centerx=500
   centerz=500
   buffer=50

   rem make a matrix
   make matrix 1,1000,1000,25,25

   rem make a cone to serve as the tank
   make object cone 1,25
   xrotate object 1,90
   make mesh from object 1,1
   delete object 1
   make object 1,1,0
   delete mesh 1
   scale object 1,100,100,300

   position object 1,centerx,13,centerz

   rem make a visible boundary
   create bitmap 1,100,100
   ink rgb(255,0,0),0
   box 0,24,64,40
   get image 1,0,0,65,65
   delete bitmap 1
   rem texture cylinder for boundary
   make object cylinder 2,1
   texture object 2,1
   set object 2,1,1,0
   ghost object on 2
   position object 2,centerx,10,centerz
   scale object 2,70000,10000,70000

return

_move_tank:
   if upkey()=1 then move object 1,5
   if downkey()=1 then move object 1,-5
   `if leftkey()=1 then turn object left 1,2
   `if rightkey()=1 then turn object right 1,2
   if leftkey()=1 then yrotate object 1,wrapvalue(object angle y(1)-2)
   if rightkey()=1 then yrotate object 1,wrapvalue(object angle y(1)+2)

   objx=object position x(1)
   objy=object position y(1)
   objz=object position z(1)

   rem if the tank has moved beyond the radius, reset it's position using
   rem the radius-buffer and polar coordinates
   dist=distance_from_center(centerx,centerz,objx,objz)
   text 0,20,str$(radius-50)
   text 0,40,str$(dist)
   if test_distance(radius,buffer,dist)=1
      testang#=atanfull(objz-centerz,objx-centerx)
      newx#=(radius-buffer)*cos(testang#)+centerx
      newz#=(radius-buffer)*sin(testang#)+centerz
      objx=newx#
      objz=newz#
      position object 1,objx,objy,objz
   endif

   set camera to follow objx,objy,objz,object angle y(1),150,50,5,0


return

Rem FUNCTIONS
function test_distance(radius,buffer,distance)
   result=0
   if distance >= radius-buffer then result=1
endfunction result

function distance_from_center(centerx,centery,posx,posy)
   dx=posx-centerx
   dy=posy-centery
   dist=sqrt((dx*dx)+(dy*dy))
endfunction dist

Enjoy your day.

Back to top

Profile PM

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 28th Dec 2007 09:52

Link

Quote: "After reading your last post, I'm confused as to what you want and don't want the tank to do."

I`m just thinking of a solution with collision boxes.

Your code works perfectly! Congratulations, you have solved my problem!

Thanks a lot, mate!

Oooooops!!! I accidentally formated drive c.

Back to top

Profile PM Email Website

Libervurto

20

Years of Service

User Offline

Joined: 30th Jun 2006

Location: On Toast

Posted: 28th Dec 2007 15:22

Link

@Latch
I like the cylinder boundary, was wondering what that was

I tried TDK's "inside-out" trick on it but this made it disappear some of the time

rem radial boundary example
rem by latch
rem 12,26,2007

sync on
sync rate 60
set display mode 800,600,32
autocam off
hide mouse

main:
gosub _init

do
   gosub _move_tank
   text 0,0,str$(screen fps())
   sync
loop

end

rem Procedures
_init:
   radius=350
   centerx=500
   centerz=500
   buffer=50

rem make a matrix
   make matrix 1,1000,1000,25,25

rem make a cone to serve as the tank
   make object cone 1,25
   xrotate object 1,90
   make mesh from object 1,1
   delete object 1
   make object 1,1,0
   delete mesh 1
   scale object 1,100,100,300

position object 1,centerx,13,centerz

rem make a visible boundary
   create bitmap 1,100,100
   ink rgb(255,0,0),0
   box 0,24,64,40
   get image 1,0,0,65,65
   delete bitmap 1
   rem texture cylinder for boundary
   make object cylinder 2,1
   texture object 2,1
`   set object 2,1,1,0
   ghost object on 2
   position object 2,centerx,10,centerz
   scale object 2,-70000,-10000,-70000

return

_move_tank:
   if upkey()=1 then move object 1,5
   if downkey()=1 then move object 1,-5
   `if leftkey()=1 then turn object left 1,2
   `if rightkey()=1 then turn object right 1,2
   if leftkey()=1 then yrotate object 1,wrapvalue(object angle y(1)-2)
   if rightkey()=1 then yrotate object 1,wrapvalue(object angle y(1)+2)

objx=object position x(1)
   objy=object position y(1)
   objz=object position z(1)

rem if the tank has moved beyond the radius, reset it's position using
   rem the radius-buffer and polar coordinates
   dist=distance_from_center(centerx,centerz,objx,objz)
   text 0,20,str$(radius-50)
   text 0,40,str$(dist)
   if test_distance(radius,buffer,dist)=1
      testang#=atanfull(objz-centerz,objx-centerx)
      newx#=(radius-buffer)*cos(testang#)+centerx
      newz#=(radius-buffer)*sin(testang#)+centerz
      objx=newx#
      objz=newz#
      position object 1,objx,objy,objz
   endif

set camera to follow objx,objy,objz,object angle y(1),150,50,5,0

return

Rem FUNCTIONS
function test_distance(radius,buffer,distance)
   result=0
   if distance >= radius-buffer then result=1
endfunction result

function distance_from_center(centerx,centery,posx,posy)
   dx=posx-centerx
   dy=posy-centery
   dist=sqrt((dx*dx)+(dy*dy))
endfunction dist

+ Code Snippet

rem radial boundary example
rem by latch
rem 12,26,2007

sync on
sync rate 60
set display mode 800,600,32
autocam off
hide mouse


main:
gosub _init

do
   gosub _move_tank
   text 0,0,str$(screen fps())
   sync
loop

end

rem Procedures
_init:
   radius=350
   centerx=500
   centerz=500
   buffer=50

   rem make a matrix
   make matrix 1,1000,1000,25,25

   rem make a cone to serve as the tank
   make object cone 1,25
   xrotate object 1,90
   make mesh from object 1,1
   delete object 1
   make object 1,1,0
   delete mesh 1
   scale object 1,100,100,300

   position object 1,centerx,13,centerz

   rem make a visible boundary
   create bitmap 1,100,100
   ink rgb(255,0,0),0
   box 0,24,64,40
   get image 1,0,0,65,65
   delete bitmap 1
   rem texture cylinder for boundary
   make object cylinder 2,1
   texture object 2,1
`   set object 2,1,1,0
   ghost object on 2
   position object 2,centerx,10,centerz
   scale object 2,-70000,-10000,-70000

return

_move_tank:
   if upkey()=1 then move object 1,5
   if downkey()=1 then move object 1,-5
   `if leftkey()=1 then turn object left 1,2
   `if rightkey()=1 then turn object right 1,2
   if leftkey()=1 then yrotate object 1,wrapvalue(object angle y(1)-2)
   if rightkey()=1 then yrotate object 1,wrapvalue(object angle y(1)+2)

   objx=object position x(1)
   objy=object position y(1)
   objz=object position z(1)

   rem if the tank has moved beyond the radius, reset it's position using
   rem the radius-buffer and polar coordinates
   dist=distance_from_center(centerx,centerz,objx,objz)
   text 0,20,str$(radius-50)
   text 0,40,str$(dist)
   if test_distance(radius,buffer,dist)=1
      testang#=atanfull(objz-centerz,objx-centerx)
      newx#=(radius-buffer)*cos(testang#)+centerx
      newz#=(radius-buffer)*sin(testang#)+centerz
      objx=newx#
      objz=newz#
      position object 1,objx,objy,objz
   endif

   set camera to follow objx,objy,objz,object angle y(1),150,50,5,0


return

Rem FUNCTIONS
function test_distance(radius,buffer,distance)
   result=0
   if distance >= radius-buffer then result=1
endfunction result

function distance_from_center(centerx,centery,posx,posy)
   dx=posx-centerx
   dy=posy-centery
   dist=sqrt((dx*dx)+(dy*dy))
endfunction dist

Back to top

Profile PM Email

Latch

19

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 29th Dec 2007 00:46

Link

@Obese
You know this one! I've seen you suggest it to others - SET OBJECT disable culling!

I think a negative size value of a primative reverses the normals (turns the light reflection inside out). If the object is giant and the camera remains inside of it (like a skybox or skysphere), whatever faces are in view will be shown. But in my ring example, sometimes the camera is outside of the object so the faces on the outside of the object aren't drawn - so it appears to disappear (because of culling). So disabling culling will work better for this small ring as opposed to the "inside out" cylinder.

Enjoy your day.

Back to top

Profile PM

Libervurto

20

Years of Service

User Offline

Joined: 30th Jun 2006

Location: On Toast

Posted: 29th Dec 2007 00:55 Edited at: 29th Dec 2007 00:56

Link

@Latch

Quote: "You know this one! I've seen you suggest it to others - SET OBJECT disable culling!"

haha I know I know

I just didn't know that's what you'd done to get that ring (aka I ran the program without looking at it

)
How come the top and bottom faces aren't visible?

Quote: "I think a negative size value of a primative reverses the normals (turns the light reflection inside out). If the object is giant and the camera remains inside of it (like a skybox or skysphere), whatever faces are in view will be shown. But in my ring example, sometimes the camera is outside of the object so the faces on the outside of the object aren't drawn - so it appears to disappear (because of culling). So disabling culling will work better for this small ring as opposed to the "inside out" cylinder."

hmm yeah I think I'll stick to disabling culling.

Back to top

Profile PM Email

Latch

19

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 29th Dec 2007 01:19

Link

Quote: "I just didn't know that's what you'd done to get that ring "

If you set ghosting on an object, anything black will be completely transparent, and anything colored will let other colors pass through (based on the lack of intensity of the r g and b values - white should be completely opaque). So I just drew a red line in a black box and used that as the texture for the cylinder. I ghosted the cylinder and only the red line shows.

The way the UV coords are on the cylinder, the line appears as a ring around the center of the object, and everything else is black.

Enjoy your day.

Back to top

Profile PM

Bluestar4

20

Years of Service

User Offline

Joined: 19th Dec 2005

Location: USA

Posted: 29th Dec 2007 11:59 Edited at: 29th Dec 2007 12:01

Link

+ Code Snippet

Thanks a lot, mate!

sorry didn't see this until after I posted

Sutter Soft
http://www.geocities.com/suttersoft

Back to top

Profile PM Email

TheComet

18

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 29th Dec 2007 17:04 Edited at: 29th Dec 2007 17:59

Link

Wow! I never thought of making a circle like that.

Here`s how I did it:

rem circle example
rem by thecomet
rem 29,12,2007

rem setup screen
sync on
sync rate 30
backdrop on
color backdrop rgb(255,255,255)
hide mouse

rem setup game
gosub _init

rem main loop
do

rem control game
gosub _control_camera
gosub _control_snowflakes

rem refresh screen
sync

rem end of main loop
loop

rem *******************************************
rem *             SUBROUTINES                 *
rem *******************************************

_init:

rem create a bitmap for the matrix
create bitmap 1,50,50
rem color bitmap white
for x=0 to 50
   for y=0 to 50
      ink rgb(255,255,255),0
      dot x,y
   next y
next x

rem make snow dots on it
ink rgb(0,255,255),0
for x=0 to 50
   for y=0 to 50
      if rnd(10)=0 then dot x,y
   next y
next x
get image 1,0,0,50,50
delete bitmap 1

rem make the matrix
make matrix 1,1000,1000,20,20
prepare matrix texture 1,1,2,2
fill matrix 1,0,1
randomize matrix 1,50

rem make hills around the matrix
for x=0 to 20
   for y=0 to 2
      set matrix height 1,x,y,rnd(100)+50
   next y
   for y=18 to 20
      set matrix height 1,x,y,rnd(100)+50
   next y
next x
for y=0 to 20
   for x=0 to 2
      set matrix height 1,x,y,rnd(100)+50
   next x
   for x=18 to 20
      set matrix height 1,x,y,rnd(100)+50
   next x
next y

rem made centre flat
for x=5 to 15
   for y=5 to 15
      set matrix height 1,x,y,0.0
   next y
next t
update matrix 1

rem make a red texture to save ram space
create bitmap 1,1,1
ink rgb(255,0,0)
dot 0,0
get image 3,0,0,1,1
delete bitmap 1

rem make a circle of fire:
for t=2 to 33
   make object plain t,50,50
   position object t,500,24,500
   texture object t,3
next t

rem explode objects into a circle
for t=2 to 33
   inc fy#,11.25 : fy#=wrapvalue(fy#)
   yrotate object t,fy#
   move object t,250
next t

rem make snowflakes
create bitmap 1,10,10
for x=0 to 10
   for y=0 to 10
      ink 0,0
      dot x,y
   next y
next x
for x=4 to 6
   for y=4 to 6
      ink rgb(255,255,255),0
      dot x,y
   next y
next x
get image 2,0,0,5,5
delete bitmap 1
for t=58 to 61
   make object plain t,800,800
   position object t,500,399,500
   texture object t,2
   set object t,1,0,0
   scale object texture t,64,64
   ghost object on t
   yrotate object t,y#
   inc y#,45 : y#=wrapvalue(y#)
next t

return

_control_camera:

a#=wrapvalue(a#+0.3)
position camera newxvalue(500,a#,300),100,newzvalue(500,a#,300)
point camera 500,0,500

return

_control_snowflakes:

for t=58 to 61
   scroll object texture t,0.0001,-0.03
next t

return

+ Code Snippet

rem circle example
rem by thecomet
rem 29,12,2007



rem setup screen
sync on
sync rate 30
backdrop on
color backdrop rgb(255,255,255)
hide mouse

rem setup game
gosub _init

rem main loop
do

rem control game
gosub _control_camera
gosub _control_snowflakes

rem refresh screen
sync

rem end of main loop
loop





rem *******************************************
rem *             SUBROUTINES                 *
rem *******************************************

_init:

rem create a bitmap for the matrix
create bitmap 1,50,50
rem color bitmap white
for x=0 to 50
   for y=0 to 50
      ink rgb(255,255,255),0
      dot x,y
   next y
next x

rem make snow dots on it
ink rgb(0,255,255),0
for x=0 to 50
   for y=0 to 50
      if rnd(10)=0 then dot x,y
   next y
next x
get image 1,0,0,50,50
delete bitmap 1

rem make the matrix
make matrix 1,1000,1000,20,20
prepare matrix texture 1,1,2,2
fill matrix 1,0,1
randomize matrix 1,50

rem make hills around the matrix
for x=0 to 20
   for y=0 to 2
      set matrix height 1,x,y,rnd(100)+50
   next y
   for y=18 to 20
      set matrix height 1,x,y,rnd(100)+50
   next y
next x
for y=0 to 20
   for x=0 to 2
      set matrix height 1,x,y,rnd(100)+50
   next x
   for x=18 to 20
      set matrix height 1,x,y,rnd(100)+50
   next x
next y

rem made centre flat
for x=5 to 15
   for y=5 to 15
      set matrix height 1,x,y,0.0
   next y
next t
update matrix 1

rem make a red texture to save ram space
create bitmap 1,1,1
ink rgb(255,0,0)
dot 0,0
get image 3,0,0,1,1
delete bitmap 1

rem make a circle of fire:
for t=2 to 33
   make object plain t,50,50
   position object t,500,24,500
   texture object t,3
next t

rem explode objects into a circle
for t=2 to 33
   inc fy#,11.25 : fy#=wrapvalue(fy#)
   yrotate object t,fy#
   move object t,250
next t

rem make snowflakes
create bitmap 1,10,10
for x=0 to 10
   for y=0 to 10
      ink 0,0
      dot x,y
   next y
next x
for x=4 to 6
   for y=4 to 6
      ink rgb(255,255,255),0
      dot x,y
   next y
next x
get image 2,0,0,5,5
delete bitmap 1
for t=58 to 61
   make object plain t,800,800
   position object t,500,399,500
   texture object t,2
   set object t,1,0,0
   scale object texture t,64,64
   ghost object on t
   yrotate object t,y#
   inc y#,45 : y#=wrapvalue(y#)
next t

return

_control_camera:

a#=wrapvalue(a#+0.3)
position camera newxvalue(500,a#,300),100,newzvalue(500,a#,300)
point camera 500,0,500

return

_control_snowflakes:

for t=58 to 61
   scroll object texture t,0.0001,-0.03
next t

return

Oooooops!!! I accidentally formated drive c.

Back to top

Profile PM Email Website

Sorry your browser is not supported!

DarkBASIC Discussion / circle math problem