Sorry your browser is not supported!

do
	color = SBChooseColor(rgb(255, 255, 255), 0)
	ink color, 0
	print "New color"
	wait key
loop
end

function SBChooseColor(defaultColor, memCustomColors)

	`Get handle
	dll = 0
	repeat : inc dll : until dll exist(dll) = 0
	load dll "user32.dll", dll
	handle = call dll(dll, "GetForegroundWindow")
	delete dll dll
	
	`Get comdlg
	load dll "comdlg32.dll", dll
	
	`Create memblocks
	mem = 0
	repeat : inc mem : until memblock exist(mem) = 0

	`Flags
	flags = 0x00000100 + 0x00000002 + 0x00000001 : `CC_ANYCOLOR + CC_FULLOPEN + CC_RGBINIT

	`Default 16 colors
	if memCustomColors > 0
		ptr2 = get memblock ptr(memCustomColors)
	else
	
		`Create a new color
		mem2 = mem
		repeat : inc mem2 : until memblock exist(mem2) = 0
		
		make memblock mem2, 16*4
		ptr2 = get memblock ptr(mem2)
	endif

	size = 36
	
	`Create memblock
	make memblock mem, size
	ptr = get memblock ptr(mem)
	write memblock dword mem, 0, size
	write memblock dword mem, 4, handle : `Owner
	write memblock dword mem, 8, 0 : `Instance
	
	write memblock byte mem, 12, rgbr(defaultColor) : `Initial color and result color
	write memblock byte mem, 13, rgbg(defaultColor)
	write memblock byte mem, 14, rgbb(defaultColor)
	write memblock byte mem, 15, 0

	write memblock dword mem, 16, ptr2
	write memblock dword mem, 20, flags

	write memblock dword mem, 24, 0
	write memblock dword mem, 28, 0
	write memblock dword mem, 32, 0

	`Call DLL
	r = call dll(dll, "ChooseColorA", ptr)

	`Get the color
	color = rgb(memblock byte(mem, 12), memblock byte(mem, 13), memblock byte(mem, 14))

	`Delete memblocks
	delete memblock mem
	if memCustomColors = 0 then delete memblock mem2
	
	`Delete dll
	delete dll dll

endfunction color

#constant DLL_KERNEL32 1

` Get foreground window handle
load dll "user32.dll", 1
handle = call dll(1, "GetForegroundWindow")
delete dll 1

` Make some memory and zero-set it
lpcc = make memory(36)
lpCustColors = make memory(16*4)
fill memory lpcc, 0, 36
fill memory lpCustColors, 0, 16*4
tempPtr = lpcc

` Set COLORREF structure data
*tempPtr = 36 : inc tempPtr, 4 ` lStructSize
*tempPtr = handle ` hwndOwner
tempPtr = lpcc + 16
*tempPtr = lpCustColors : inc tempPtr, 4 ` lpCustColors
*tempPtr = 0x00000100 || 0x00000002 || 0x00000001 ` Flags

` Main loop

do

   ` Make buffer for function call parameters
   ptr = make memory(4)
   *ptr = lpcc

   ` Call ChooseColorA in its own thread
   callPtr = CallThreadedDLLFunction("comdlg32.dll", "ChooseColorA", ptr, 4)

   ` Wait for call to complete
   print "Waiting for user to select color..."
   repeat
   until CallIsComplete(callPtr)

   ` Set new color
   tempPtr = lpcc+12
   ink rgb((*tempPtr) && 0xFF, ((*tempPtr) && 0xFF00) >> 8, ((*tempPtr) && 0xFF0000) >> 16), 0

   print "New color selected"
   wait key

loop

function CallThreadedDLLFunction(dllName as string, funcName as string, paramPtr as dword, paramSize as dword)
   local callDataPtr as dword
   local codePtr as dword
   local tempPtr as dword
   local tempPtr2 as dword

   if not dll exist(DLL_KERNEL32) then load dll "kernel32.dll", DLL_KERNEL32

   dllHandle = call dll(DLL_KERNEL32, "LoadLibraryA", dllName)
   procAddr = call dll(DLL_KERNEL32, "GetProcAddress", dllHandle, funcName)

   kernel32Handle = call dll(DLL_KERNEL32, "GetModuleHandleA", "kernel32.dll")
   freeLibrary = call dll(DLL_KERNEL32, "GetProcAddress", kernel32Handle, "FreeLibrary")

   callDataPtr = make memory((paramSize/4 * 5) + 52)
   codePtr = callDataPtr + 8
   tempPtr = codePtr

   tempPtr2 = paramPtr + paramSize - 4
   for x = 1 to paramSize/4
      *tempPtr = 0x68 : inc tempPtr
      *tempPtr = *tempPtr2 : inc tempPtr, 4
      dec tempPtr2, 4
   next x

   *tempPtr = 0xB8 : inc tempPtr
   *tempPtr = procAddr : inc tempPtr, 4
   *tempPtr = 0xD0FF : inc tempPtr, 2
   *tempPtr = 0x05C7 : inc tempPtr, 2
   *tempPtr = callDataPtr : inc tempPtr, 4
   *tempPtr = 1 : inc tempPtr, 4
   *tempPtr = 0x68 : inc tempPtr
   *tempPtr = dllHandle : inc tempPtr, 4
   *tempPtr = 0xB8 : inc tempPtr
   *tempPtr = freeLibrary : inc tempPtr, 4
   *tempPtr = 0xD0FF : inc tempPtr, 2
   *tempPtr = 0xC2 || (4 << 8) : inc tempPtr, 3

   *callDataPtr = 0
   tempPtr = callDataPtr + 4
   *tempPtr = paramPtr

   call dll DLL_KERNEL32, "CreateThread", 0, 0, codePtr, 0, 0, 0

endfunction callDataPtr

function CallIsComplete(callDataPtr as dword)
   if (*callDataPtr) = 0 then exitfunction 0

   tempPtr = callDataPtr + 4
   if (*tempPtr) then delete memory *tempPtr
   delete memory callDataPtr
endfunction 1