OK Phil
I made this just for you.
This will show you how to use curveangle like I was talking about.
This sample makes a matrix for a scene...
Then it makes a cube to chase you...
Then a hidden control cube for the chasing cube...
Then a hidden control cube for the camera rotation...
Then it uses the arrow keys to move the camera around...
Then has the cube chase you.
Very easy.
This will do what you want it to do.
Turn into the desired direction gradually.
`basic set up
sync on : sync rate 40
autocam off : randomize timer()
`make a scene to look at
make matrix 1,1000,1000,25,25
randomize matrix 1,20
set matrix wireframe off 1
for a=1 to 25
for b=1 to 25
set matrix normal 1,a,b,rnd(360),rnd(360),rnd(360)
next b
next a
update matrix 1
`make something to chase you and a hidden control object
make object cube 1,30
scale object 1,80,100,180
color object 1,rgb(250,200,40)
position object 1,500,20,800
make object cube 2,30
hide object 2
position object 2,500,20,800
`position camera and make a hidden control object
make object cube 3,30
hide object 3
position object 3,500,20,500
point object 3,500,20,800
position camera 500,20,500
point camera 500,20,800
`our loop
do
`control the camera using curveangle
if rightkey()=1 then yrotate object 3,wrapvalue(object angle y(3)+5)
if leftkey()=1 then yrotate object 3,wrapvalue(object angle y(3)-5)
if upkey()=1 then move camera 3
if downkey()=1 then move camera -3
yrotate camera curveangle(object angle y(3),camera angle y(),10)
position object 3,camera position x(),20,camera position z()
`handle chasing
point object 2,camera position x(),20,camera position z()
yrotate object 1,curveangle(object angle y(2),object angle y(1),100)
move object 1,1
position object 2,object position x(1),20,object position z(1)
`of course we sync
sync
loop
Enjoy.
Randi
