[DBP] Turtle Based Fractal Trees

Author

Message

gbark

19

Years of Service

User Offline

Joined: 14th Oct 2005

Location: US - Virginia

Posted: 1st May 2009 08:29 Edited at: 1st May 2009 08:32

Link

Hey there,

Just a pretty simple demo, I was experimenting with recursive tree drawing fractals using turtle graphics with DBP, and was able to come up with some interesting looking fractal trees.

Here is the demo:

// Screen settings
sync on : sync rate 60

// Initialize LOGO variables
LOGO_Initialize()

// TREE VALUES - THESE VALUES SPECIFY THE LOOK OF THE TREES
#constant TOTAL_TREE_TYPES 5
global dim treeShape(TOTAL_TREE_TYPES) as treeShapeType
type treeShapeType
   branchFactor as float
   branchAngleLeft as float
   branchAngleRight as float
endtype

// TREE TYPE 1: STANDARD
treeShape(1).branchFactor = 0.6
treeShape(1).branchAngleLeft = 45
treeShape(1).branchAngleRight = 45

// TREE TYPE 2: BONZAI
treeShape(2).branchFactor = 0.7
treeShape(2).branchAngleLeft = 15
treeShape(2).branchAngleRight = 25

// TREE TYPE 3: WILLOW
treeShape(3).branchFactor = 0.7
treeShape(3).branchAngleLeft = 70
treeShape(3).branchAngleRight = 70

// TREE TYPE 4: PALM
treeShape(4).branchFactor = 0.6
treeShape(4).branchAngleLeft = 15
treeShape(4).branchAngleRight = 70

// TREE TYPE 5: PINE
treeShape(5).branchFactor = 0.7
treeShape(5).branchAngleLeft = 120
treeShape(5).branchAngleRight = 0

// Defaults for animated tree
treeType = 1         // Default tree type
size# = 100.0        // Tree size
branch# = 0.0        // Branch sway oscillation

// Main loop
do
   // Clear screen and show info
   cls
   set cursor 0, 0
   print "SCREEN FPS: "+str$(screen fps())
   print "ANIMATED FRACTAL TREE"
   print "L-Click to grow, R-Click to shrink"
   print "SPACE to change tree type"
   print "Hold CTRL for more branches (MAY CAUSE FPS DROP)"
   
   // Change type of tree with space
   space = spacekey()
   if space = 1 and spacePress = 0
      // Toggle tree types
      inc treeType
      if treeType > TOTAL_TREE_TYPES then dec treeType, TOTAL_TREE_TYPES
   endif
   spacePress = space

// Sway branches
   branch# = wrapvalue(branch# + 0.5)

// Grow / Shrink tree
   if mouseclick() = 1 then inc size#, 0.5
   if mouseclick() = 2 then dec size#, 0.5

// Draw tree
   FractalTree(mousex(), mousey(), 0, int(size#), treeShape(treeType).branchFactor+(controlkey()*0.1), treeShape(treeType).branchAngleLeft+sin(branch#), treeShape(treeType).branchAngleRight-sin(branch#))
   
   sync
loop

// Draw a fractal tree to the current bitmap
function FractalTree(x#, y#, ang#, size, branchFactor#, angLeft#, angRight#)

// If branchFactor# is not less than 1.0, then the branches cannot get any
   // smaller and the tree will never end, so don't allow that to happen
   if branchFactor# >= 1.0 then exitfunction
   
   // Set initial drawing position
   LOGO_Position(x#, y#, ang#)
   LOGO_PenDown()
   
   // Draw the first branch
   FractalTree_Branch(size, size, branchFactor#, angLeft#, angRight#)

endfunction

// Draw a branch of the fractal tree
function FractalTree_Branch(size, mainSize, branchFactor#, angLeft#, angRight#)

// End the branch if the size is too small
   if size <= 0 then exitfunction
   
   // Determine color of branch
   // (Fade from brown [bottom] to green [top])
   greenVal# = (mainSize*1.0 - size*3.0) / (mainSize*1.0)
   if greenVal# < 0.0 then greenVal# = 0.0
   ink rgb(128-128*greenVal#, 64+64*greenVal#, 0), 0
   
   // Move the turtle forward
   LOGO_Forward(size)
   
   // Draw the left branches
   LOGO_Left(angLeft#)
   FractalTree_Branch(size * branchFactor#, mainSize, branchFactor#, angLeft#, angRight#)
   
   // Draw the right branches
   LOGO_Right(angLeft#+angRight#)
   FractalTree_Branch(size * branchFactor#, mainSize, branchFactor#, angLeft#, angRight#)
   
   // Return to original position
   LOGO_PenUp()
   LOGO_Left(angRight#)
   LOGO_Back(size)
   LOGO_PenDown()

endfunction

// Setup global variables used by LOGO drawing system
function LOGO_Initialize()

// Variable set
   global LOGO as LOGOType
   
   // Default variables
   LOGO.x = 0
   LOGO.y = 0
   LOGO.angle = 0
   LOGO.penDown = 1

endfunction

// Put the pen down (draw lines as the turtle moves)
function LOGO_PenDown()

// Draw lines
   LOGO.penDown = 1

endfunction

// Put the pen up (don't draw lines as the turtle moves)
function LOGO_PenUp()

// Don't draw lines
   LOGO.penDown = 0

endfunction

// Absolutely position the turtle
function LOGO_Position(x#, y#, ang#)

// Position the turtle
   LOGO.x = x#
   LOGO.y = y#
   LOGO.angle = ang#
   
endfunction

// Move the turtle forward
function LOGO_Forward(dist#)

// Determine the angle (assume angle 0 = North)
   ang# = wrapvalue(LOGO.angle - 90)

// Determine destination offset
   dx# = dist# * cos(ang#)
   dy# = dist# * sin(ang#)
   
   // Draw the line
   if LOGO.penDown = 1 then line LOGO.x, LOGO.y, LOGO.x+dx#, LOGO.y+dy#
   
   // Move the turtle
   inc LOGO.x, dx#
   inc LOGO.y, dy#

endfunction

// Move the turtle backwards
function LOGO_Back(dist#)

LOGO_Forward(-dist#)

endfunction

// Spin left
function LOGO_Left(ang#)

LOGO_Right(-ang#)
   
endfunction

// Spin right
function LOGO_Right(ang#)

LOGO.angle = wrapvalue(LOGO.angle + ang#)
   
endfunction

// UDT for LOGO system
type LOGOType
   x as float
   y as float
   angle as float
   penDown as boolean
endtype

+ Code Snippet

// Screen settings
sync on : sync rate 60

// Initialize LOGO variables
LOGO_Initialize()


// TREE VALUES - THESE VALUES SPECIFY THE LOOK OF THE TREES
#constant TOTAL_TREE_TYPES 5
global dim treeShape(TOTAL_TREE_TYPES) as treeShapeType
type treeShapeType
   branchFactor as float
   branchAngleLeft as float
   branchAngleRight as float
endtype

// TREE TYPE 1: STANDARD
treeShape(1).branchFactor = 0.6
treeShape(1).branchAngleLeft = 45
treeShape(1).branchAngleRight = 45

// TREE TYPE 2: BONZAI
treeShape(2).branchFactor = 0.7
treeShape(2).branchAngleLeft = 15
treeShape(2).branchAngleRight = 25

// TREE TYPE 3: WILLOW
treeShape(3).branchFactor = 0.7
treeShape(3).branchAngleLeft = 70
treeShape(3).branchAngleRight = 70

// TREE TYPE 4: PALM
treeShape(4).branchFactor = 0.6
treeShape(4).branchAngleLeft = 15
treeShape(4).branchAngleRight = 70

// TREE TYPE 5: PINE
treeShape(5).branchFactor = 0.7
treeShape(5).branchAngleLeft = 120
treeShape(5).branchAngleRight = 0


// Defaults for animated tree
treeType = 1         // Default tree type
size# = 100.0        // Tree size
branch# = 0.0        // Branch sway oscillation

// Main loop
do
   // Clear screen and show info
   cls
   set cursor 0, 0
   print "SCREEN FPS: "+str$(screen fps())
   print "ANIMATED FRACTAL TREE"
   print "L-Click to grow, R-Click to shrink"
   print "SPACE to change tree type"
   print "Hold CTRL for more branches (MAY CAUSE FPS DROP)"
   
   // Change type of tree with space
   space = spacekey()
   if space = 1 and spacePress = 0
      // Toggle tree types
      inc treeType
      if treeType > TOTAL_TREE_TYPES then dec treeType, TOTAL_TREE_TYPES
   endif
   spacePress = space

   // Sway branches
   branch# = wrapvalue(branch# + 0.5)

   // Grow / Shrink tree
   if mouseclick() = 1 then inc size#, 0.5
   if mouseclick() = 2 then dec size#, 0.5

   // Draw tree
   FractalTree(mousex(), mousey(), 0, int(size#), treeShape(treeType).branchFactor+(controlkey()*0.1), treeShape(treeType).branchAngleLeft+sin(branch#), treeShape(treeType).branchAngleRight-sin(branch#))
   
   sync
loop


// Draw a fractal tree to the current bitmap
function FractalTree(x#, y#, ang#, size, branchFactor#, angLeft#, angRight#)

   // If branchFactor# is not less than 1.0, then the branches cannot get any
   // smaller and the tree will never end, so don't allow that to happen
   if branchFactor# >= 1.0 then exitfunction
   
   // Set initial drawing position
   LOGO_Position(x#, y#, ang#)
   LOGO_PenDown()
   
   // Draw the first branch
   FractalTree_Branch(size, size, branchFactor#, angLeft#, angRight#)

endfunction


// Draw a branch of the fractal tree
function FractalTree_Branch(size, mainSize, branchFactor#, angLeft#, angRight#)

   // End the branch if the size is too small
   if size <= 0 then exitfunction
   
   // Determine color of branch
   // (Fade from brown [bottom] to green [top])
   greenVal# = (mainSize*1.0 - size*3.0) / (mainSize*1.0)
   if greenVal# < 0.0 then greenVal# = 0.0
   ink rgb(128-128*greenVal#, 64+64*greenVal#, 0), 0
   
   // Move the turtle forward
   LOGO_Forward(size)
   
   // Draw the left branches
   LOGO_Left(angLeft#)
   FractalTree_Branch(size * branchFactor#, mainSize, branchFactor#, angLeft#, angRight#)
   
   // Draw the right branches
   LOGO_Right(angLeft#+angRight#)
   FractalTree_Branch(size * branchFactor#, mainSize, branchFactor#, angLeft#, angRight#)
   
   // Return to original position
   LOGO_PenUp()
   LOGO_Left(angRight#)
   LOGO_Back(size)
   LOGO_PenDown()

endfunction


// Setup global variables used by LOGO drawing system
function LOGO_Initialize()

   // Variable set
   global LOGO as LOGOType
   
   // Default variables
   LOGO.x = 0
   LOGO.y = 0
   LOGO.angle = 0
   LOGO.penDown = 1

endfunction


// Put the pen down (draw lines as the turtle moves)
function LOGO_PenDown()

   // Draw lines
   LOGO.penDown = 1

endfunction


// Put the pen up (don't draw lines as the turtle moves)
function LOGO_PenUp()

   // Don't draw lines
   LOGO.penDown = 0

endfunction


// Absolutely position the turtle
function LOGO_Position(x#, y#, ang#)

   // Position the turtle
   LOGO.x = x#
   LOGO.y = y#
   LOGO.angle = ang#
   
endfunction


// Move the turtle forward
function LOGO_Forward(dist#)

   // Determine the angle (assume angle 0 = North)
   ang# = wrapvalue(LOGO.angle - 90)

   // Determine destination offset
   dx# = dist# * cos(ang#)
   dy# = dist# * sin(ang#)
   
   // Draw the line
   if LOGO.penDown = 1 then line LOGO.x, LOGO.y, LOGO.x+dx#, LOGO.y+dy#
   
   // Move the turtle
   inc LOGO.x, dx#
   inc LOGO.y, dy#

endfunction


// Move the turtle backwards
function LOGO_Back(dist#)

   LOGO_Forward(-dist#)

endfunction


// Spin left
function LOGO_Left(ang#)

   LOGO_Right(-ang#)
   
endfunction


// Spin right
function LOGO_Right(ang#)

   LOGO.angle = wrapvalue(LOGO.angle + ang#)
   
endfunction


// UDT for LOGO system
type LOGOType
   x as float
   y as float
   angle as float
   penDown as boolean
endtype

It draws the trees in realtime each frame, allowing them to be animated or changed live. You can move the tree with the mouse, grow/shrink it with clicks, see how the tree "sways in the wind", grow extra branches with CTRL, and view 5 different possible types of trees with SPACE.

And here's the "Lite" version of the code, just generates a basic tree and doesn't have anything fancy like color changing or animation, but it's easier to see just what's going on.

// Screen settings
sync on : sync rate 60

// Initialize LOGO variables
LOGO_Initialize()

// Create a bitmap for tree
create bitmap 1, 512, 512
ink rgb(0, 128, 0), 0
FractalTree(256, 512, 0, 200, 0.6, 45, 45)
get image 1, 0, 0, 512, 512, 1
delete bitmap 1

// Main loop
do
   // Clear screen and show info
   cls
   set cursor 0, 0
   print "SCREEN FPS: "+str$(screen fps())
   print "STATIC FRACTAL TREE"
   
   // Show tree
   paste image 1, 0, 0
   
   sync
loop

// Draw a fractal tree to the current bitmap
function FractalTree(x#, y#, ang#, size, branchFactor#, angLeft#, angRight#)

// If branchFactor# is not less than 1.0, then the branches cannot get any
   // smaller and the tree will never end, so don't allow that to happen
   if branchFactor# >= 1.0 then exitfunction
   
   // Set initial drawing position
   LOGO_Position(x#, y#, ang#)
   LOGO_PenDown()
   
   // Draw the first branch
   FractalTree_Branch(size, branchFactor#, angLeft#, angRight#)

endfunction

// Draw a branch of the fractal tree
function FractalTree_Branch(size, branchFactor#, angLeft#, angRight#)

// End the branch if the size is too small
   if size <= 0 then exitfunction
   
   // Move the turtle forward
   LOGO_Forward(size)
   
   // Draw the left branches
   LOGO_Left(angLeft#)
   FractalTree_Branch(size * branchFactor#, branchFactor#, angLeft#, angRight#)
   
   // Draw the right branches
   LOGO_Right(angLeft#+angRight#)
   FractalTree_Branch(size * branchFactor#, branchFactor#, angLeft#, angRight#)
   
   // Return to original position
   LOGO_PenUp()
   LOGO_Left(angRight#)
   LOGO_Back(size)
   LOGO_PenDown()

endfunction

// Setup global variables used by LOGO drawing system
function LOGO_Initialize()

// Variable set
   global LOGO as LOGOType
   
   // Default variables
   LOGO.x = 0
   LOGO.y = 0
   LOGO.angle = 0
   LOGO.penDown = 1

endfunction

// Put the pen down (draw lines as the turtle moves)
function LOGO_PenDown()

// Draw lines
   LOGO.penDown = 1

endfunction

// Put the pen up (don't draw lines as the turtle moves)
function LOGO_PenUp()

// Don't draw lines
   LOGO.penDown = 0

endfunction

// Absolutely position the turtle
function LOGO_Position(x#, y#, ang#)

// Position the turtle
   LOGO.x = x#
   LOGO.y = y#
   LOGO.angle = ang#
   
endfunction

// Move the turtle forward
function LOGO_Forward(dist#)

// Determine the angle (assume angle 0 = North)
   ang# = wrapvalue(LOGO.angle - 90)

// Determine destination offset
   dx# = dist# * cos(ang#)
   dy# = dist# * sin(ang#)
   
   // Draw the line
   if LOGO.penDown = 1 then line LOGO.x, LOGO.y, LOGO.x+dx#, LOGO.y+dy#
   
   // Move the turtle
   inc LOGO.x, dx#
   inc LOGO.y, dy#

endfunction

// Move the turtle backwards
function LOGO_Back(dist#)

LOGO_Forward(-dist#)

endfunction

// Spin left
function LOGO_Left(ang#)

LOGO_Right(-ang#)
   
endfunction

// Spin right
function LOGO_Right(ang#)

LOGO.angle = wrapvalue(LOGO.angle + ang#)
   
endfunction

// UDT for LOGO system
type LOGOType
   x as float
   y as float
   angle as float
   penDown as boolean
endtype

+ Code Snippet

// Screen settings
sync on : sync rate 60

// Initialize LOGO variables
LOGO_Initialize()


// Create a bitmap for tree
create bitmap 1, 512, 512
ink rgb(0, 128, 0), 0
FractalTree(256, 512, 0, 200, 0.6, 45, 45)
get image 1, 0, 0, 512, 512, 1
delete bitmap 1


// Main loop
do
   // Clear screen and show info
   cls
   set cursor 0, 0
   print "SCREEN FPS: "+str$(screen fps())
   print "STATIC FRACTAL TREE"
   
   // Show tree
   paste image 1, 0, 0
   
   sync
loop


// Draw a fractal tree to the current bitmap
function FractalTree(x#, y#, ang#, size, branchFactor#, angLeft#, angRight#)

   // If branchFactor# is not less than 1.0, then the branches cannot get any
   // smaller and the tree will never end, so don't allow that to happen
   if branchFactor# >= 1.0 then exitfunction
   
   // Set initial drawing position
   LOGO_Position(x#, y#, ang#)
   LOGO_PenDown()
   
   // Draw the first branch
   FractalTree_Branch(size, branchFactor#, angLeft#, angRight#)

endfunction


// Draw a branch of the fractal tree
function FractalTree_Branch(size, branchFactor#, angLeft#, angRight#)

   // End the branch if the size is too small
   if size <= 0 then exitfunction
   
   // Move the turtle forward
   LOGO_Forward(size)
   
   // Draw the left branches
   LOGO_Left(angLeft#)
   FractalTree_Branch(size * branchFactor#, branchFactor#, angLeft#, angRight#)
   
   // Draw the right branches
   LOGO_Right(angLeft#+angRight#)
   FractalTree_Branch(size * branchFactor#, branchFactor#, angLeft#, angRight#)
   
   // Return to original position
   LOGO_PenUp()
   LOGO_Left(angRight#)
   LOGO_Back(size)
   LOGO_PenDown()

endfunction


// Setup global variables used by LOGO drawing system
function LOGO_Initialize()

   // Variable set
   global LOGO as LOGOType
   
   // Default variables
   LOGO.x = 0
   LOGO.y = 0
   LOGO.angle = 0
   LOGO.penDown = 1

endfunction


// Put the pen down (draw lines as the turtle moves)
function LOGO_PenDown()

   // Draw lines
   LOGO.penDown = 1

endfunction


// Put the pen up (don't draw lines as the turtle moves)
function LOGO_PenUp()

   // Don't draw lines
   LOGO.penDown = 0

endfunction


// Absolutely position the turtle
function LOGO_Position(x#, y#, ang#)

   // Position the turtle
   LOGO.x = x#
   LOGO.y = y#
   LOGO.angle = ang#
   
endfunction


// Move the turtle forward
function LOGO_Forward(dist#)

   // Determine the angle (assume angle 0 = North)
   ang# = wrapvalue(LOGO.angle - 90)

   // Determine destination offset
   dx# = dist# * cos(ang#)
   dy# = dist# * sin(ang#)
   
   // Draw the line
   if LOGO.penDown = 1 then line LOGO.x, LOGO.y, LOGO.x+dx#, LOGO.y+dy#
   
   // Move the turtle
   inc LOGO.x, dx#
   inc LOGO.y, dy#

endfunction


// Move the turtle backwards
function LOGO_Back(dist#)

   LOGO_Forward(-dist#)

endfunction


// Spin left
function LOGO_Left(ang#)

   LOGO_Right(-ang#)
   
endfunction


// Spin right
function LOGO_Right(ang#)

   LOGO.angle = wrapvalue(LOGO.angle + ang#)
   
endfunction


// UDT for LOGO system
type LOGOType
   x as float
   y as float
   angle as float
   penDown as boolean
endtype

Screenshot attached of a possible tree that can be generated (using the first snippet). Using the LOGO functions it's also pretty simple to program any sort of line-based fractals, like snowflakes, for example.

Just thought it was interesting.

Attachments

Login to view attachments

Back to top

Profile PM

Latch

18

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 1st May 2009 09:46

Link

Wow, you must be ancient!

The next thing you know, we will be seeing Karel the Robot moving around a grid picking up beepers!

Cool tree by the way!

Enjoy your day.

Back to top

Profile PM

gbark

19

Years of Service

User Offline

Joined: 14th Oct 2005

Location: US - Virginia

Posted: 1st May 2009 09:57 Edited at: 1st May 2009 09:58

Link

Quote: "Wow, you must be ancient! The next thing you know, we will be seeing Karel the Robot moving around a grid picking up beepers!"

Harhar, funny.

I'm actually toying with the idea of a game completely based on fractals and vector graphics. Not just using fractals for skies or terrain like other games, but every piece of scenery (trees, bushes, grass, items, etc) being composed of fractal generated images, with characters or more advanced stuff being vector-based stick-figure characters.

I dunno, probably not a very realistic approach, that's just what I had in mind anyway.

Back to top

Profile PM

Latch

18

Years of Service

User Offline

Joined: 23rd Jul 2006

Location:

Posted: 1st May 2009 11:29

Link

Do it!

I've got a LOGO book somewhere around here. I remember there were some fractal examples... I may try and dig it up.

I wonder if you could adapt your code to 3 dimensions. The move object, and turn object left, right, pitch, (maybe roll but probably not) are sort of a 3d adaptation of turtle graphics. The pen up and pen down could be used to draw, scale and link plains/triangles. Might be quite interesting.

Enjoy your day.

Back to top

Profile PM

gbark

19

Years of Service

User Offline

Joined: 14th Oct 2005

Location: US - Virginia

Posted: 2nd May 2009 04:24 Edited at: 2nd May 2009 04:25

Link

Hey thanks, yeah fractals have always fascinated me, I just never got around to actually trying some out until now.

I think 3D fractals would be incredibly interesting, and with a little work could easily be done in a code snippet. I would need to be able to pitch the turtle, then modify the current turn move command to take multiple angles into account when calculating direction (I already have a 360 degree free-moving mouse-controlled flying camera system, so the math is already done

), and just add in iterations for branching forward/back in Z space in addition to the left/right branching in X space, and it should be good. I'll look into that some more and will post back.

In the meantime, I made a couple more examples.

Your classic Koch Snowflake fractal example,

// Screen settings
sync on : sync rate 60

// Initialize LOGO variables
LOGO_Initialize()

// Create a bitmap for fractal
create bitmap 1, 512, 512
ink rgb(255, 255, 255), 0
FractalSnowFlake(256, 400, 400, 3, 3)
get image 1, 0, 0, 512, 512, 1
delete bitmap 1

// Main loop
do
   // Clear screen and show info
   cls
   set cursor 0, 0
   print "SCREEN FPS: "+str$(screen fps())

// Show fractal
   paste image 1, 0, 0

sync
loop

// Draw a fractal snowflake to the current bitmap
function FractalSnowFlake(x#, y#, size#, sides, minSize#)

// Set the initial drawing position
   LOGO_Position(x#, y#, 0)
   LOGO_PenDown()
   
   // Determine angle of turn needed to complete shape
   ang = 360/sides

// Draw the sides of the snowflake
   for i = 1 to sides
      // Move forward
      FractalSnowFlake_Koch(size#, minSize#)
      // Turn right
      LOGO_Right(ang)
   next i

endfunction

// Draw an iteration of the snowflake
function FractalSnowFlake_Koch(size#, minSize#)

// If the size is less than the requested minimum detail,
   // move forward and stop recursing
   if size# < minSize#
      LOGO_Forward(size#)
      exitfunction
   endif
   
   // Calculate new size
   size# = size# * 0.3
   
   // Draw the first iteration of the flake
   FractalSnowFlake_Koch(size#, minSize#)
   
   // Draw the left iteration of the flake
   LOGO_Left(60)
   FractalSnowFlake_Koch(size#, minSize#)
   
   // Draw the right iteration of the flake
   LOGO_Right(120)
   FractalSnowFlake_Koch(size#, minSize#)
   
   // Return to original position and draw final iteration
   LOGO_Left(60)
   FractalSnowFlake_Koch(size#, minSize#)

endfunction

// Setup global variables used by LOGO drawing system
function LOGO_Initialize()

// Variable set
   global LOGO as LOGOType

// Default variables
   LOGO.x = 0
   LOGO.y = 0
   LOGO.angle = 0
   LOGO.penDown = 1

endfunction

// Put the pen down (draw lines as the turtle moves)
function LOGO_PenDown()

// Draw lines
   LOGO.penDown = 1

endfunction

// Put the pen up (don't draw lines as the turtle moves)
function LOGO_PenUp()

// Don't draw lines
   LOGO.penDown = 0

endfunction

// Absolutely position the turtle
function LOGO_Position(x#, y#, ang#)

// Position the turtle
   LOGO.x = x#
   LOGO.y = y#
   LOGO.angle = ang#

endfunction

// Move the turtle forward
function LOGO_Forward(dist#)

// Determine the angle (assume angle 0 = North)
   ang# = wrapvalue(LOGO.angle - 90)

// Determine destination offset
   dx# = dist# * cos(ang#)
   dy# = dist# * sin(ang#)

// Draw the line
   if LOGO.penDown = 1 then line LOGO.x, LOGO.y, LOGO.x+dx#, LOGO.y+dy#

// Move the turtle
   inc LOGO.x, dx#
   inc LOGO.y, dy#

endfunction

// Move the turtle backwards
function LOGO_Back(dist#)

LOGO_Forward(-dist#)

endfunction

// Spin left
function LOGO_Left(ang#)

LOGO_Right(-ang#)

endfunction

// Spin right
function LOGO_Right(ang#)

LOGO.angle = wrapvalue(LOGO.angle + ang#)

endfunction

// UDT for LOGO system
type LOGOType
   x as float
   y as float
   angle as float
   penDown as boolean
endtype

+ Code Snippet

// Screen settings
sync on : sync rate 60

// Initialize LOGO variables
LOGO_Initialize()


// Create a bitmap for fractal
create bitmap 1, 512, 512
ink rgb(255, 255, 255), 0
FractalSnowFlake(256, 400, 400, 3, 3)
get image 1, 0, 0, 512, 512, 1
delete bitmap 1


// Main loop
do
   // Clear screen and show info
   cls
   set cursor 0, 0
   print "SCREEN FPS: "+str$(screen fps())

   // Show fractal
   paste image 1, 0, 0

   sync
loop


// Draw a fractal snowflake to the current bitmap
function FractalSnowFlake(x#, y#, size#, sides, minSize#)

   // Set the initial drawing position
   LOGO_Position(x#, y#, 0)
   LOGO_PenDown()
   
   // Determine angle of turn needed to complete shape
   ang = 360/sides

   // Draw the sides of the snowflake
   for i = 1 to sides
      // Move forward
      FractalSnowFlake_Koch(size#, minSize#)
      // Turn right
      LOGO_Right(ang)
   next i

endfunction


// Draw an iteration of the snowflake
function FractalSnowFlake_Koch(size#, minSize#)

   // If the size is less than the requested minimum detail,
   // move forward and stop recursing
   if size# < minSize#
      LOGO_Forward(size#)
      exitfunction
   endif
   
   // Calculate new size
   size# = size# * 0.3
   
   // Draw the first iteration of the flake
   FractalSnowFlake_Koch(size#, minSize#)
   
   // Draw the left iteration of the flake
   LOGO_Left(60)
   FractalSnowFlake_Koch(size#, minSize#)
   
   // Draw the right iteration of the flake
   LOGO_Right(120)
   FractalSnowFlake_Koch(size#, minSize#)
   
   // Return to original position and draw final iteration
   LOGO_Left(60)
   FractalSnowFlake_Koch(size#, minSize#)

endfunction


// Setup global variables used by LOGO drawing system
function LOGO_Initialize()

   // Variable set
   global LOGO as LOGOType

   // Default variables
   LOGO.x = 0
   LOGO.y = 0
   LOGO.angle = 0
   LOGO.penDown = 1

endfunction


// Put the pen down (draw lines as the turtle moves)
function LOGO_PenDown()

   // Draw lines
   LOGO.penDown = 1

endfunction


// Put the pen up (don't draw lines as the turtle moves)
function LOGO_PenUp()

   // Don't draw lines
   LOGO.penDown = 0

endfunction


// Absolutely position the turtle
function LOGO_Position(x#, y#, ang#)

   // Position the turtle
   LOGO.x = x#
   LOGO.y = y#
   LOGO.angle = ang#

endfunction


// Move the turtle forward
function LOGO_Forward(dist#)

   // Determine the angle (assume angle 0 = North)
   ang# = wrapvalue(LOGO.angle - 90)

   // Determine destination offset
   dx# = dist# * cos(ang#)
   dy# = dist# * sin(ang#)

   // Draw the line
   if LOGO.penDown = 1 then line LOGO.x, LOGO.y, LOGO.x+dx#, LOGO.y+dy#

   // Move the turtle
   inc LOGO.x, dx#
   inc LOGO.y, dy#

endfunction


// Move the turtle backwards
function LOGO_Back(dist#)

   LOGO_Forward(-dist#)

endfunction


// Spin left
function LOGO_Left(ang#)

   LOGO_Right(-ang#)

endfunction


// Spin right
function LOGO_Right(ang#)

   LOGO.angle = wrapvalue(LOGO.angle + ang#)

endfunction


// UDT for LOGO system
type LOGOType
   x as float
   y as float
   angle as float
   penDown as boolean
endtype

Parameters include the position, size, sides (3 is the "standard", add more for more complex outlines), and minimum length of each line (lower values = more detail in the edges).

And, a splitting spiral fractal.

// Screen settings
sync on : sync rate 60

// Initialize LOGO variables
LOGO_Initialize()

// Create a bitmap for fractal
create bitmap 1, 512, 512
ink rgb(255, 255, 255), 0
FractalSpiral(180, 480, 20)
get image 1, 0, 0, 512, 512, 1
delete bitmap 1

// Main loop
do
   // Clear screen and show info
   cls
   set cursor 0, 0
   print "SCREEN FPS: "+str$(screen fps())

// Show fractal
   paste image 1, 0, 0

sync
loop

// Draw a fractal spiral to the current bitmap
function FractalSpiral(x#, y#, size#)

// Set the initial drawing position
   LOGO_Position(x#, y#, 0)
   LOGO_PenDown()

// Draw the spiral
   FractalSpiral_Segment(size#)

endfunction

// Draw a segment of a fractal spiral
function FractalSpiral_Segment(size#)

// If the size is too small, stop drawing
   if size# < 0.5 then exitfunction

// Loop for 360 degrees
   for i = 1 to 360

// Spin off a new fractal every 5 degrees for every angle 30 and under
      if i MOD 5 = 0 and i <= 30
         // Spin off new spiral
         LOGO_Left(90)
         FractalSpiral_Segment(size# * 0.5 - (0.3 * ((i*1.0-1)/5.0)))
         LOGO_Right(90)
      endif

// Move forward and curve inward
      LOGO_Forward(size#)
      LOGO_Right(i)

next i

// Turn around
   LOGO_Right(180)

endfunction

// Setup global variables used by LOGO drawing system
function LOGO_Initialize()

// Variable set
   global LOGO as LOGOType

// Default variables
   LOGO.x = 0
   LOGO.y = 0
   LOGO.angle = 0
   LOGO.penDown = 1

endfunction

// Put the pen down (draw lines as the turtle moves)
function LOGO_PenDown()

// Draw lines
   LOGO.penDown = 1

endfunction

// Put the pen up (don't draw lines as the turtle moves)
function LOGO_PenUp()

// Don't draw lines
   LOGO.penDown = 0

endfunction

// Absolutely position the turtle
function LOGO_Position(x#, y#, ang#)

// Position the turtle
   LOGO.x = x#
   LOGO.y = y#
   LOGO.angle = ang#

endfunction

// Move the turtle forward
function LOGO_Forward(dist#)

// Determine the angle (assume angle 0 = North)
   ang# = wrapvalue(LOGO.angle - 90)

// Determine destination offset
   dx# = dist# * cos(ang#)
   dy# = dist# * sin(ang#)

// Draw the line
   if LOGO.penDown = 1 then line LOGO.x, LOGO.y, LOGO.x+dx#, LOGO.y+dy#

// Move the turtle
   inc LOGO.x, dx#
   inc LOGO.y, dy#

endfunction

// Move the turtle backwards
function LOGO_Back(dist#)

LOGO_Forward(-dist#)

endfunction

// Spin left
function LOGO_Left(ang#)

LOGO_Right(-ang#)

endfunction

// Spin right
function LOGO_Right(ang#)

LOGO.angle = wrapvalue(LOGO.angle + ang#)

endfunction

// UDT for LOGO system
type LOGOType
   x as float
   y as float
   angle as float
   penDown as boolean
endtype

+ Code Snippet

// Screen settings
sync on : sync rate 60

// Initialize LOGO variables
LOGO_Initialize()


// Create a bitmap for fractal
create bitmap 1, 512, 512
ink rgb(255, 255, 255), 0
FractalSpiral(180, 480, 20)
get image 1, 0, 0, 512, 512, 1
delete bitmap 1


// Main loop
do
   // Clear screen and show info
   cls
   set cursor 0, 0
   print "SCREEN FPS: "+str$(screen fps())

   // Show fractal
   paste image 1, 0, 0

   sync
loop


// Draw a fractal spiral to the current bitmap
function FractalSpiral(x#, y#, size#)

   // Set the initial drawing position
   LOGO_Position(x#, y#, 0)
   LOGO_PenDown()

   // Draw the spiral
   FractalSpiral_Segment(size#)

endfunction


// Draw a segment of a fractal spiral
function FractalSpiral_Segment(size#)

   // If the size is too small, stop drawing
   if size# < 0.5 then exitfunction

   // Loop for 360 degrees
   for i = 1 to 360

      // Spin off a new fractal every 5 degrees for every angle 30 and under
      if i MOD 5 = 0 and i <= 30
         // Spin off new spiral
         LOGO_Left(90)
         FractalSpiral_Segment(size# * 0.5 - (0.3 * ((i*1.0-1)/5.0)))
         LOGO_Right(90)
      endif

      // Move forward and curve inward
      LOGO_Forward(size#)
      LOGO_Right(i)

   next i

   // Turn around
   LOGO_Right(180)

endfunction


// Setup global variables used by LOGO drawing system
function LOGO_Initialize()

   // Variable set
   global LOGO as LOGOType

   // Default variables
   LOGO.x = 0
   LOGO.y = 0
   LOGO.angle = 0
   LOGO.penDown = 1

endfunction


// Put the pen down (draw lines as the turtle moves)
function LOGO_PenDown()

   // Draw lines
   LOGO.penDown = 1

endfunction


// Put the pen up (don't draw lines as the turtle moves)
function LOGO_PenUp()

   // Don't draw lines
   LOGO.penDown = 0

endfunction


// Absolutely position the turtle
function LOGO_Position(x#, y#, ang#)

   // Position the turtle
   LOGO.x = x#
   LOGO.y = y#
   LOGO.angle = ang#

endfunction


// Move the turtle forward
function LOGO_Forward(dist#)

   // Determine the angle (assume angle 0 = North)
   ang# = wrapvalue(LOGO.angle - 90)

   // Determine destination offset
   dx# = dist# * cos(ang#)
   dy# = dist# * sin(ang#)

   // Draw the line
   if LOGO.penDown = 1 then line LOGO.x, LOGO.y, LOGO.x+dx#, LOGO.y+dy#

   // Move the turtle
   inc LOGO.x, dx#
   inc LOGO.y, dy#

endfunction


// Move the turtle backwards
function LOGO_Back(dist#)

   LOGO_Forward(-dist#)

endfunction


// Spin left
function LOGO_Left(ang#)

   LOGO_Right(-ang#)

endfunction


// Spin right
function LOGO_Right(ang#)

   LOGO.angle = wrapvalue(LOGO.angle + ang#)

endfunction


// UDT for LOGO system
type LOGOType
   x as float
   y as float
   angle as float
   penDown as boolean
endtype

Back to top

Profile PM

Neuro Fuzzy

17

Years of Service

User Offline

Joined: 11th Jun 2007

Location:

Posted: 5th May 2009 04:46

Link

cool!

laggy but cool!

Back to top

Profile PM Email

bobbel

15

Years of Service

User Offline

Joined: 5th Jan 2009

Location: In my DBPro case xD

Posted: 15th May 2009 09:37

Link

yeha, i like the first one, it is on a poster in the classroom where we have maths too!

(\__/)
(O.o )
(> < ) This is Bunny. Copy Bunny into your signature to help him on his way to world domination!

Back to top

Profile PM Website

Sorry your browser is not supported!

Code Snippets / [DBP] Turtle Based Fractal Trees

Attachments