Sorry your browser is not supported!

Rem Project: UberTerrain
Rem Created: Saturday, March 14, 2009

Rem ***** Main Source File *****

sync on : sync rate 0 : sync: Autocam Off
hide mouse
global objects
phy start

center text screen width()/2,screen height()/2,"Loading"
sync

heightmap=1
texture=2
detail=3

load image "Heightmap.bmp",heightmap
load image "texture.jpg",texture
load image "detail.tga",detail

`Make a Terrain
terrain = UT MakeTerrain()
UT SetTerrainHeightmap terrain, heightmap
UT SetTerrainTexture terrain,texture
UT SetTerrainDetail terrain,detail
UT SetTerrainLOD terrain,4
UT SetTerrainScale terrain,12
UT SetTerrainYScale terrain,2
UT SetTerrainSplit terrain,8
UT SetTerrainDetailTile terrain,2
UT SetTerrainLODDistances terrain,1000,2000,3000,4000,5000,6000
UT SetAdvancedPhysics terrain,1
UT BuildTerrain terrain


`Build
    Building=1
    while Building

    `The visual object
        object=FreeObject()

    `The Physics Object
        phyobject=FreeObject()

    `Generate a sector
        progress=UT ContinueBuild(object,PhyObject,0) `Generates a sector, phyobject can be ignored in normal physics mode

        Phy Make Rigid Body Static Mesh PhyObject
        

    `Example showing that you can set it to any physics/collision system you want
        `SC_SetupObject phyobject,0,0

        if progress=-1 then Building=0
    endwhile

viewrange#=15000.0
maincam=0


fog on
fog distance viewrange#
set camera range maincam,1,viewrange#
fog color 128,170,255
color backdrop maincam,rgb(128,170,255)

`phy make material 1,"hardsmooth"
`phy set material dynamic friction 1,0.2
`phy set material static friction 1,0.2
`phy set material restitution 1,0.2
`phy build material 1


position camera maincam, 0, 300, 0

start=timer()
do
   position mouse screen width()/2, screen height()/2

   elapsedtime#=(timer()-start)/1000.0: start=timer()

   xrot#=camera angle x(maincam)
   if upkey()
       inc speed#,1000*elapsedtime#
       if speed#>500.0 then speed#=500.0
   endif
   if downkey()
       inc speed#,-1000*elapsedtime#
       if speed#<-500.0 then speed#=-500.0
   endif

   if upkey()=0 and downkey()=0
       if speed#>0
           inc speed#,-1000*elapsedtime#
           if speed#<0.0 then speed#=0.0
       else
           inc speed#,1000*elapsedtime#
           if speed#>0.0 then speed#=0.0
       endif
   endif

   move camera maincam, speed# * elapsedtime#

   if camera position x(maincam) > UT GetTerrainSize(terrain) Then position camera maincam, UT GetTerrainSize(terrain), camera position y(maincam), camera position z(maincam)
   if camera position x(maincam) < 0.0 Then position camera maincam, 0.0, camera position y(maincam), camera position z(maincam)
   if camera position z(maincam) > UT GetTerrainSize(terrain) then position camera maincam, camera position x(maincam), camera position y(maincam), UT GetTerrainSize(terrain)
   if camera position z(maincam) < 0.0 Then position camera maincam, camera position x(maincam), camera position y(maincam), 0.0

   gheight#=UT GetGroundHeight(terrain,camera position x(maincam),camera position z(maincam))+10.0
   position camera maincam,camera position x(maincam),gheight# + 20.0,camera position z(maincam)

   rotate camera maincam,xrot#+mousemovey()/6.0,camera angle y()+mousemovex()/3.0,0

   if camera angle x(maincam)>70 then xrotate camera maincam,70
   if camera angle x(maincam)<-70 then xrotate camera maincam,-70


   If MouseClick() = 1
      Obj = FreeObject()
      Make Object Sphere Obj, 5.0
      Position Object Obj, Camera Position X(), Camera Position Y() + 100, Camera Position Z()
      Rotate Object Obj, Camera Angle X(), Camera Angle Y(), 0.0
      
      Phy Make Rigid Body Dynamic Sphere Obj, 1
      
      Phy Set Rigid Body Linear Velocity Obj, 10.0, 0.0, 0.0
   EndIf

   Phy Update
   UT Update maincam
sync
Loop
End

function FreeObject()
inc objects
endfunction objects