it doesnt for me....heres the new code
Rem Project: Sniper Showdown
Rem Created: Monday, March 08, 2010
Rem ***** Main Source File *****
TYPE WEAPON
name AS STRING
range AS INTEGER
mesh AS INTEGER
clipsize AS INTEGER
recoil AS INTEGER
autoflag AS BOOLEAN
damage AS INTEGER
ENDTYPE
TYPE PLAYER
ammo AS INTEGER
clipammo AS INTEGER
primaryweapon AS WEAPON
sidearm AS WEAPON
currentweapon AS WEAPON
X# AS FLOAT
Y# AS FLOAT
Z# AS FLOAT
ENDTYPE
SYNC ON : SYNC RATE 60 : HIDE MOUSE : SET DISPLAY MODE 800,600,32 : MAXIMIZE WINDOW
SET TEXT FONT "Times New Roman" : SET TEXT SIZE 30
GOSUB Define_Variables
GOSUB Load_Media
GOSUB Load_Entities
GOSUB Create_Level
DO
REM INPUT
IF UPKEY() = 1
oldangle = OBJECT ANGLE X(1)
XROTATE OBJECT 1,0
MOVE OBJECT 1,2
XROTATE OBJECT 1,oldangle
ENDIF
IF DOWNKEY()=1
oldangle = OBJECT ANGLE X(1)
XROTATE OBJECT 1,0
MOVE OBJECT 1,-2
XROTATE OBJECT 1,oldangle
ENDIF
IF RIGHTKEY()=1
oldangle = OBJECT ANGLE X(1)
XROTATE OBJECT 1,0
MOVE OBJECT RIGHT 1,2
XROTATE OBJECT 1,oldangle
ENDIF
IF LEFTKEY()=1
oldangle = OBJECT ANGLE X(1)
XROTATE OBJECT 1,0
MOVE OBJECT LEFT 1,2
XROTATE OBJECT 1,oldangle
ENDIF
IF MOUSECLICK() = 1 AND player(1).clipammo > 0
IF clicked = 0
clicked = 1
DEC player(1).clipammo,1
DEC player(1).ammo,1
IF INTERSECT OBJECT(2,player(1).X#,player(1).Y#,player(1).Z#, LIMB POSITION X(1,1), LIMB POSITION Y(1,1), LIMB POSITION Z(1,1))
DEC enemyhealth, player(1).currentweapon.damage
ENDIF
ENDIF
ELSE
clicked = 0
ENDIF
IF KEYSTATE(19) = 1 AND RELOADING =0
REM RELOAD
RELOADING = 1
ENDIF
IF RELOADING = 1
INC RELOADTIMER
CENTER TEXT 400,250,"RELOADING..."
IF RELOADTIMER >= 200
player(1).clipammo = player(1).primaryweapon.clipsize
RELOADING = 0
RELOADTIMER = 0
ENDIF
ENDIF
IF keystate(31) = 1
if swap = 0
swap = 1
IF player(1).currentweapon = player(1).primaryweapon
player(1).currentweapon = player(1).sidearm
ELSE
player(1).currentweapon = player(1).primaryweapon
ENDIF
change mesh 1,2,player(1).currentweapon.mesh
endif
ELSE
swap = 0
ENDIF
CAMY#=CAMY#+MOUSEMOVEX()*.1
CAMX#=CAMX#+MOUSEMOVEY()*.1
IF CAMX#>90 AND CAMX#<135 THEN CAMX#=90
IF CAMX#>270 AND CAMX#<225 THEN CAMX#=90
YROTATE CAMERA CAMY#
XROTATE CAMERA CAMX#
YROTATE OBJECT 1,CAMY#
XROTATE OBJECT 1,CAMX#
REM UPDATE VARIABLES
player(1).x# = OBJECT POSITION X(1)
player(1).y# = OBJECT POSITION Y(1)
player(1).z# = OBJECT POSITION Z(1)
REM ADJUST CAMERA
POSITION CAMERA player(1).x#,player(1).y#,player(1).z#
REM UPDATE HUD
SPRITE 1,383,283,1
SCALE SPRITE 1,10
IF player(1).ammo > 0
SPRITE 2,0,0,2
ELSE
SPRITE 2,0,0,3
ENDIF
SCALE SPRITE 2,20
TEXT 16,30,"x" + str$(player(1).ammo)
SPRITE 3,0,80,4
SCALE SPRITE 3,20
TEXT 40,90,"x" + STR$(player(1).clipammo)
IF OBJECT EXIST(2)
IF OBJECT IN SCREEN(2)
IF enemyhealth > 0
CENTER TEXT OBJECT SCREEN X(2),OBJECT SCREEN Y(2)-60,STR$(enemyhealth) + "%"
ELSE
DELETE OBJECT 2
ENDIF
ENDIF
ENDIF
SYNC
LOOP
`----------------------------------------------------------------------------------------------------------------
`SUBROUTINES
`----------------------------------------------------------------------------------------------------------------
Define_Variables:
REM CREATE THE SNIPER RIFLE OF THE WEAPON TYPE
sniper AS WEAPON
sniper.name = "Sniper"
sniper.range = 1000
sniper.clipsize = 5
sniper.recoil = 10
sniper.autoflag = 0
sniper.damage = 20
sniper.mesh = 2
REM CREAT EA PISTOL OBJECT
pistol AS WEAPON
pistol.name = "Pistol"
pistol.range = 200
pistol.clipsize = 10
pistol.recoil = 2
pistol.autoflag = 0
pistol.damage = 3
pistol.mesh = 3
REM CREATE PLAYERS
dim player(1) AS PLAYER
player(1).ammo = 30
player(1).primaryweapon = sniper
player(1).sidearm = pistol
player(1).currentweapon = player(1).primaryweapon
player(1).clipammo = player(1).primaryweapon.clipsize
player(1).X# = 0
player(1).Y# = 0
player(1).Z# = 0
enemyhealth = 100
RETURN
`----------------------------------------------------------------------------------------------------------------
Load_Media:
LOAD IMAGE "media\Crosshair.jpg",1
LOAD IMAGE "media\bullet.jpg",2
LOAD IMAGE "media\bullet0.jpg",3
LOAD IMAGE "media\clip.jpg",4
RETURN
`----------------------------------------------------------------------------------------------------------------
Load_Entities:
REM LOAD PLAYER
MAKE OBJECT SPHERE 1,10
COLOR OBJECT 1,RGB(150,255,0)
MOVE OBJECT UP 1,5
HIDE LIMB 1,0
REM CREATE A LIMB FOR SHOOTING
MAKE OBJECT PLAIN 9999,1,1
target_limb_mesh = 1
MAKE MESH FROM OBJECT target_limb_mesh,9999
DELETE OBJECT 9999
ADD LIMB 1,1,1
OFFSET LIMB 1,1,0,0,1000
`HIDE LIMB 1,1
REM LOAD SNIPER
LOAD OBJECT "sniper.X",999
MAKE MESH FROM OBJECT 2,999
DELETE OBJECT 999
ADD LIMB 1,2,2
OFFSET LIMB 1,2,10.5,-3,5
ROTATE LIMB 1,2,0,0,0
COLOR LIMB 1,2,RGB(0,150,150)
REM MAKE PISTOL MESH
MAKE OBJECT BOX 999,1,2,4
MAKE MESH FROM OBJECT 3,999
DELETE OBJECT 999
REM CREATE ENEMY
CLONE OBJECT 2,1
COLOR OBJECT 2,RGB(255,0,0)
SHOW LIMB 2,0
REM CREATE GROUND
MAKE OBJECT PLAIN 3,10000,10000
COLOR OBJECT 3,RGB(0,255,0)
XROTATE OBJECT 3,270
RETURN
`----------------------------------------------------------------------------------------------------------------
Create_Level:
RETURN
`----------------------------------------------------------------------------------------------------------------
`------------------------------------------------------------------------------------------------------------------
`FUNCTIONS
`---------------------------------------------------------------------------------------------------------------
right now im trying to get the sidearm functionality to work
