I was going to help you further after knowing if you've at least tried but seems you are ahead of me.
There are many ways to get this done and I'll show you 2 ways that I use.
1) Simply Load up a bitmap and just grab the images from that. You an have up to 32 different bitmaps, bitmaps can be at any size you desire as long as your machine can handle it but bitmap 0 is the screen and you cannot modify it because it is restricted to your display settings.
sync on
sync rate 60
gosub LoadingBitmap
do
if leftkey() and Image > 0 then dec Image
if rightkey() and image < 170 then inc Image
paste image PointerTile+Image,100,100
sync
loop
LoadingBitmap:
`This variable is used to point to the start of the set of tiles that are be to be loaded.
PointerTile = 100
`Load the image onto the bitmap 1. When doing so the current bitmap changes to 1 also.
`The bitmap size is the same as the image and thus alowing you to grab image greater
`that the extent of the screen.
load bitmap "test.png",1
`Grab the images.
count = -1
for lpy = 0 to 19-1
for lpx = 0 to 9-1
x = lpx*32
y = lpy*32
inc count
get image PointerTile+count,x,y,x+32,y+32,1
next lpx
next lpy
`Bitmap 0 is the display screen, if we dont switch back every graphical output we do
`will only apply to bitmap 1 and we will not see anything.
set current bitmap 0
return
2) The second way I'll show you is to load the Tileset as an image and create a bitmap at the size of 32,32. The Tileset is offset and pasted onto the bitmap then grabbed into different tiles.
sync on
sync rate 60
gosub LoadingBitmap2
do
if leftkey() and Image > 0 then dec Image
if rightkey() and image < 170 then inc Image
paste image PointerTile+Image,100,100
sync
loop
LoadingBitmap2:
TileSet = 10
PointerTile = 100
load image "test.png",TileSet,1
create bitmap 1,32,32
count = -1
for lpy = 0 to 19-1
for lpx = 0 to 9-1
x = lpx*-32
y = lpy*-32
inc count
paste image TileSet,x,y
get image PointerTile+count,0,0,32,32,1
next lpx
next lpy
set current bitmap 0
return
I've attached the image used for the example, remember to download that first before running the codes.
[edit]
I apologize I misunderstood you but the way to get it to work is also in the examples too.