Hello sberk,
I have a development where I display a map when the player picks it up. For example, in one of my levels, the player picks up a map and can cycle through the map by pressing the M key.
The script I use for this particular map is as follows:
;Artifical Inteligence Script::::::::::::::::::::::::::
desc = Shows Map Text HUD (When M Key Is Pressed)
;Triggers
:state=0:hudreset,hudx=50,hudy=50,hudimagefine=RPG_Mod\huds\ww2_bf\ww2_bf_l04objhud01b.tga,hudname=map,hudhide=1,hudmake=display
:state=0:hudreset,hudx=50,hudy=50,hudimagefine=RPG_Mod\huds\ww2_bf\ww2_bf_l04objhud01c.tga,hudname=map1,hudhide=1,hudmake=display
:state=0:hudreset,hudx=50,hudy=50,hudimagefine=RPG_Mod\huds\ww2_bf\ww2_bf_l04objhud01d.tga,hudname=map2,hudhide=1,hudmake=display,state=10
;M Key Pressed
:state=10,plrwithinzone=1
:state=10,rpg_itemreadytouse=$Maps,scancodekeypressed=50:hudshow=map,timerstart,state=15
:state=15,timergreater=500,scancodekeypressed=50:hudunshow=map,state=20
:state=20,scancodekeypressed=50:hudshow=map1,timerstart,state=25
:state=25,timergreater=500,scancodekeypressed=50:hudunshow=map1,state=30
:state=30,scancodekeypressed=50:hudshow=map2,timerstart,state=35
:state=35,timergreater=500,scancodekeypressed=50:hudunshow=map2,state=40
:state=40,scancodekeypressed=50:timerstart,state=45
:state=45,timergreater=500:state=10
;End of Script
As you can see from the script, I use three huds for this script. Map, Map1, and Map2 shows three different maps when the player presses the M key. An example of what my image looks like can be found
here. You will notice the first hud shows the player the first map and also indicates to the player to press M to view the next map.
You can do this with anything. Another example I have for you is this same level, but instead of a map, I have a book the player can view. The script I use for the book is as follows:
;Artifical Inteligence Script::::::::::::::::::::::::::
desc = Shows Book Text HUD (When V Key Is Pressed)
;Triggers
:state=0:hudreset,hudx=50,hudy=50,hudimagefine=RPG_Mod\huds\ww2_bf\ww2_bf_l04objhud07b.tga,hudname=book1,hudhide=1,hudmake=display
:state=0:hudreset,hudx=50,hudy=50,hudimagefine=RPG_Mod\huds\ww2_bf\ww2_bf_l04objhud07c.tga,hudname=book2,hudhide=1,hudmake=display,state=10
;V Key Pressed
:state=10,plrwithinzone=1
:state=10,rpg_itemreadytouse=$Books,scancodekeypressed=47:hudshow=book1,timerstart,state=15
:state=15,timergreater=500,scancodekeypressed=47:hudunshow=book1,state=20
:state=20,scancodekeypressed=47:hudshow=book2,timerstart,state=25
:state=25,timergreater=500,scancodekeypressed=47:hudunshow=book2,state=30
:state=30,scancodekeypressed=47:timerstart,state=35
:state=35,timergreater=500:state=10
;End of Script
As you can see, I have the V key bound to viewing the book. I also have two hud pictures for the two different views (book1, book2). You can see an example image of this
here.
As far as game play, my method does not slow the game down at all. All it is is a script that uses the specified key to display a hud or multiple huds. It's all up to how you want to do it.
As far as how to create a hud with a map, I did a screen capture with my capture utility, then copied it over the template hud I use all the time. I use a specific size for my map huds, but you can make it any size you want (ex: make it fill the entire screen for more detail).
Hopefully this answers your question.
- BlackFox
