Displayed the typed input - GameCreators Forum

Author

Message

czzplnm

15

Years of Service

User Offline

Joined: 10th Aug 2010

Location:

Posted: 23rd Aug 2010 09:23 Edited at: 23rd Aug 2010 09:23

Link

When my program asks for the user input, it does not show them what they are typing. Would like to do that and don't know what to search on forum. Nothing comes up.

+ Code Snippet

Rem Project: vagga
Rem Created: Sunday, August 22, 2010

Rem ***** Main Source File *****
sync on
sync rate 30
set window on
set display mode 400, 100, 32
disable escapekey
Set Text Opaque
LOAD MUSIC "E:\programming\vagabonds\ccc.wav", 1
T=Timer()
input "Please enter your destination time";endTime$
sync

DO
Elapsed=(Timer()-T)/1000

cls
text 0, 0, "Your destination time is "+endTime$
  text 0,15,"Current Time = " + GET TIME$()
  Elapsed=(Timer()-T)/1000
  Text 0,30,"Time Elapsed = "+Str$(Elapsed)
  sync
cTime$ = GET TIME$()
  if cTime$ = endTime$
  PLAY MUSIC 1
  sync
  endif
sync
LOOP
end

Edit: Topic name should have been "Display"

"The eternal mystery of the world is its comprehensibility."
-Albert Einstein
Join this vent for Dark Programming - lead.typefrag.com:16020

Back to top

Profile PM Email

Grog Grueslayer

Valued Member

21

Years of Service

User Offline

Joined: 30th May 2005

Playing: Green Hell

Posted: 23rd Aug 2010 09:31

Link

Don't turn on SYNCing till after the INPUT. The reason it doesn't work is because you can't SYNC during the INPUT. You can create your own input routine so you can SYNC.

sync rate 0
sync on

` Make all text overwrite previous text (for backspace)
set text opaque

` Make Answer$ equal the output of the function GetInput()
Answer$=GetInput()

` Show the answer
text 0,40,"Answer = "+Answer$
sync
wait key
end

` Get the users input
function GetInput()

` Clear the buffer (so no previous keys are added to the string)
 clear entry buffer
 ` Create a timer for backspace
 tim=timer()

do

` Show the prompt and user input
   text 0,0,"User Input: " + Com$+"| "
   ` Get the keys typed by the user and clear the buffer again
   a$=entry$(1):clear entry buffer

` Check for backspace (the timer is so the text doesn't delete too quickly)
   if keystate(14) and timer()>tim+100
    ` Remove last character from the input string
    Com$ = left$(Com$,len(Com$)-1)
    ` Clear a$ and reset timer
    a$="":tim=timer()
   endif

` Check for enter key and leave the DO/LOOP
   if keystate(28) then exit

` Check if a$ is more than nothing and Com$ is no more than 30 characters
   if a$<>"" and len(Com$)<30
    ` Add a$ to Com$
    Com$ = Com$ + a$
   endif

sync
 
 loop

` End the function with whatever the user entered
endfunction Com$

+ Code Snippet

sync rate 0
sync on

` Make all text overwrite previous text (for backspace)
set text opaque

` Make Answer$ equal the output of the function GetInput()
Answer$=GetInput()

` Show the answer
text 0,40,"Answer = "+Answer$
sync
wait key
end


` Get the users input
function GetInput()

 ` Clear the buffer (so no previous keys are added to the string)
 clear entry buffer
 ` Create a timer for backspace
 tim=timer()

 do

   ` Show the prompt and user input
   text 0,0,"User Input: " + Com$+"| "
   ` Get the keys typed by the user and clear the buffer again
   a$=entry$(1):clear entry buffer

   ` Check for backspace (the timer is so the text doesn't delete too quickly)
   if keystate(14) and timer()>tim+100
    ` Remove last character from the input string
    Com$ = left$(Com$,len(Com$)-1)
    ` Clear a$ and reset timer
    a$="":tim=timer()
   endif

   ` Check for enter key and leave the DO/LOOP
   if keystate(28) then exit

   ` Check if a$ is more than nothing and Com$ is no more than 30 characters
   if a$<>"" and len(Com$)<30
    ` Add a$ to Com$
    Com$ = Com$ + a$
   endif

  sync
 
 loop

` End the function with whatever the user entered
endfunction Com$

Back to top

Profile PM Email

czzplnm

15

Years of Service

User Offline

Joined: 10th Aug 2010

Location:

Posted: 23rd Aug 2010 10:43

Link

Beautiful mate. Modified it a tad with my other stuff. Thanks

Rem Project: vagga
Rem Created: Sunday, August 22, 2010

Rem ***** Main Source File *****
set window on
set display mode 400, 100, 32
sync rate 0
sync on

` Make all text overwrite previous text (for backspace)
set text opaque

` Make Answer$ equal the output of the function GetInput()
Answer$=GetInput()

` Show the answer

LOAD MUSIC "E:\programming\vagabonds\sound.wav", 1
T=Timer()
DO
Elapsed=(Timer()-T)/1000
cls
text 0,0,"Destination = "+Answer$
  Elapsed=(Timer()-T)/1000
  Text 0,15,"Time Elapsed = "+Str$(Elapsed)
  Text 0,30,"Current Time = " + GET TIME$()
  sync
  theTime$ = GET TIME$()
  if theTime$ = Answer$
  PLAY MUSIC 1 
  endif

LOOP
end

` Get the users input
function GetInput()

` Clear the buffer (so no previous keys are added to the string)
 clear entry buffer
 ` Create a timer for backspace
 tim=timer()

do

` Show the prompt and user input
   text 0,0,"HH:MM:SS " + Com$+"| "
   ` Get the keys typed by the user and clear the buffer again
   a$=entry$(1):clear entry buffer

` Check for backspace (the timer is so the text doesn't delete too quickly)
   if keystate(14) and timer()>tim+100
    ` Remove last character from the input string
    Com$ = left$(Com$,len(Com$)-1)
    ` Clear a$ and reset timer
    a$="":tim=timer()
   endif

` Check for enter key and leave the DO/LOOP
   if keystate(28) then exit

` Check if a$ is more than nothing and Com$ is no more than 30 characters
   if a$<>"" and len(Com$)<30
    ` Add a$ to Com$
    Com$ = Com$ + a$
   endif
  sync
 
 loop

` End the function with whatever the user entered
endfunction Com$

+ Code Snippet

Rem Project: vagga
Rem Created: Sunday, August 22, 2010

Rem ***** Main Source File *****
set window on
set display mode 400, 100, 32
sync rate 0
sync on

` Make all text overwrite previous text (for backspace)
set text opaque

` Make Answer$ equal the output of the function GetInput()
Answer$=GetInput()

` Show the answer




LOAD MUSIC "E:\programming\vagabonds\sound.wav", 1
T=Timer()
DO
Elapsed=(Timer()-T)/1000
cls
text 0,0,"Destination = "+Answer$
  Elapsed=(Timer()-T)/1000
  Text 0,15,"Time Elapsed = "+Str$(Elapsed)
  Text 0,30,"Current Time = " + GET TIME$()
  sync
  theTime$ = GET TIME$()
  if theTime$ = Answer$
  PLAY MUSIC 1 
  endif

LOOP
end


` Get the users input
function GetInput()

 ` Clear the buffer (so no previous keys are added to the string)
 clear entry buffer
 ` Create a timer for backspace
 tim=timer()

 do

   ` Show the prompt and user input
   text 0,0,"HH:MM:SS " + Com$+"| "
   ` Get the keys typed by the user and clear the buffer again
   a$=entry$(1):clear entry buffer

   ` Check for backspace (the timer is so the text doesn't delete too quickly)
   if keystate(14) and timer()>tim+100
    ` Remove last character from the input string
    Com$ = left$(Com$,len(Com$)-1)
    ` Clear a$ and reset timer
    a$="":tim=timer()
   endif

   ` Check for enter key and leave the DO/LOOP
   if keystate(28) then exit

   ` Check if a$ is more than nothing and Com$ is no more than 30 characters
   if a$<>"" and len(Com$)<30
    ` Add a$ to Com$
    Com$ = Com$ + a$
   endif
  sync
 
 loop

` End the function with whatever the user entered
endfunction Com$

"The eternal mystery of the world is its comprehensibility."
-Albert Einstein
Join this vent for Dark Programming - lead.typefrag.com:16020

Back to top

Profile PM Email

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Displayed the typed input