Sorry your browser is not supported!

rem
rem First Person Game TUTORIAL
rem
rem How to create an FPS Creator Level for loading into DBPro:
rem 1. Run FPSCREATOR.EXE and scroll to the TOP/LEFT/BOTTOM corner of the editing area
rem 2. Use PREFAB to make a room in this corner
rem 3. Click the BUILD GAME button to build the level as an executable
rem 4. Exit FPSCREATOR.EXE and navigate to MyGames\yourexe\
rem 5. Copy the FILES folder to this source code folder
rem 6. Delete all folders within FILES folder except 'levelbank' and 'texturebank'
rem 7. Navigate to FILES\LEVELBANK and unzip the level1.zip using 'mypassword'
rem 8. Create a new folder called TESTLEVEL
rem 9. Copy the files you have extracted to this folder, then navigate to the files
rem 10. Delete all except UNIVERSE.DBO, UNIVERSE.DBU and the LIGHTMAPS folder
rem 11. Ensure the 'Files' folder sits alongside this application and run

rem Use desktop resolution, vsync on
sync on : sync rate 0
desktopwidth=desktop width()
desktopheight=desktop height()
set display mode desktopwidth,desktopheight,32,1
`backdrop on
rem Set font
set text font "Copperplate Gothic Bold"
ink rgb(255,255,200),0
set text size 24
center text desktopwidth/2,desktopheight/2,"Loading please wait...."
sync

`sync rate 30
rem Initialise application and hide mouse pointer
autocam off : hide mouse : disable escapekey

rem Load level (load static objects read a DBO and DBU file pair)
gdividetexturesize=0 : universefile$="levelbank\testlevel\universe.dbo"
set dir "Files" : load static objects universefile$,gdividetexturesize

rem Place camera (the topmost/leftmost/lowest tile of the FPSC level universe)
rem Remember that these coordinates will change with each new FPSC level used
position camera 50,560,-50
point camera 400,560,-100
set ambient light 50
load music "media\music misty room.mp3",1
loop music 1
rem Main loop
while escapekey()=0
 `
 rem Control camera
 gosub _camera
 `
 rem Show on-screen displays
 `center text screen width()/2,screen height()-50,"FPS CREATOR LEVEL LOADED INTO DARK BASIC PROFESSIONAL"
  center text screen width()/2,screen height()-50,"FPS "+str$(screen fps())
 `
 rem Keep light with camera
 set point light 0,camera position x(),camera position y()+50,camera position z()
 `
 rem Update
 sync
 `
endwhile

rem Delete level
delete static objects

rem End program
end

_camera:

rem Read W,A,S,D keys for movement
tkeystate17=keystate(17)
tkeystate31=keystate(31)
tkeystate30=keystate(30)
tkeystate32=keystate(32)

tkeystate57=keystate(57)

rem Store CURRENT camera position
cox#=camera position x()
coy#=camera position y()
coz#=camera position z()

rem Determine camera direction
movement=0
if tkeystate17=1
 if tkeystate30=1
  y#=315 : movement=1
 else
  if tkeystate32=1
   y#=45 : movement=1
  else
   y#=0 : movement=1
  endif
 endif
else
 if tkeystate31=1
  if tkeystate30=1
   y#=225 : movement=1
  else
   if tkeystate32=1
    y#=135 : movement=1
   else
    y#=180 : movement=1
   endif
  endif
 else
  if tkeystate30=1
   y#=270 : movement=1
  else
   if tkeystate32=1
    y#=90 : movement=1
   endif
  endif
 endif
endif

if tkeystate57=1 and rep=0 and jump=0
    jump=1
    rep=1
    dec gravity#,5
ENDIF

if tkeystate57=0 
    rep=0
ENDIF

rem Store camera angles
sx#=camera angle x()
sy#=camera angle y()
sz#=camera angle z()

rem Move camera in direction and restore camera angles
rotate camera 0,camera angle y()+y#,0
if movement=1 then move camera 3.0
rotate camera sx#,sy#,sz#

rem Store NEW camera position (and apply gravity)
cmx#=camera position x()
cmy#=camera position y()-gravity#
cmz#=camera position z()

rem Check volume collision between CURRENT and NEW camera positions
if static volume(cox#,coy#-25,coz#,cmx#,cmy#-25,cmz#,1.0)=1
 `
 rem If collision detected, determine material touching
 materialtype=get static collision value()
 `
 rem If collision, calculate new ADJUSTED NEW camera position to avoid this collision
 cmx#=cox#+get static collision x()
 cmy#=coy#+get static collision y()
 cmz#=coz#+get static collision z()
 `
 rem Reset gravity
 gravity#=0.5
 jump=0
 `
else
 `
 rem If no collision, must be in freefall so increase gravity
 inc gravity#,0.5
 `
endif

rem Update camera with ADJUSTED NEW position
position camera cmx#,cmy#,cmz#

rem Mouselook control
position mouse 400,300
cammovex#=mousemovex()*2
cammovey#=mousemovey()*2
camangx#=camera angle x()+cammovey#
camangy#=camera angle y()+cammovex#
if wrapvalue(camangx#)>85 and wrapvalue(camangx#)<180 then camangx#=85.0
if wrapvalue(camangx#)>180 and wrapvalue(camangx#)<275 then camangx#=275.0
rotate camera curveangle(camangx#,camera angle x(),15.0),curveangle(camangy#,camera angle y(),15.0),camera angle z()

return