[DBP] Move/Scale/Rotate with Vertexdata Commands

Author

Message

BMacZero

18

Years of Service

User Offline

Joined: 30th Dec 2005

Location: E:/ NA / USA

Posted: 27th Aug 2010 21:31 Edited at: 28th Aug 2010 03:26

Link

In case you should ever need such a thing, these functions will let you offset, scale, or rotate an object within its vertexdata. This will, for example, allow you to clone the object and have it keep all these settings.

I'm using it in an editor program where I want to be able to adjust an object and then save it, having it retain the adjustments.

I should note that unlike the DBP command, the vert functions act cumulatively, so if you tell it to rotate the object 40 degrees and then tell it to do 50 degrees, overall the object will be rotated 90 degrees, whereas with ROTATE OBJECT the object would end at 50 degrees.

function vertsoff(object,offx as float,offy as float,offz as float)
lock vertexdata for limb object,0,2
for c=0 to get vertexdata vertex count()-1
    set vertexdata position c,get vertexdata position x(c)+offx,get vertexdata position y(c)+offy,get vertexdata position z(c)+offz
next c
unlock vertexdata
endfunction

function vertscale(object,scale)
lock vertexdata for limb object,0,2
local temp as float
temp=scale/100.0
for c=0 to get vertexdata vertex count()-1
    set vertexdata position c,get vertexdata position x(c)*temp,get vertexdata position y(c)*temp,get vertexdata position z(c)*temp
next c
unlock vertexdata
endfunction

function vertrotate(object,xangle as float,yangle as float,zangle as float)
lock vertexdata for limb object,0,2
local posx as float
local posy as float
local posz as float
for c=0 to get vertexdata vertex count()-1
    posx=get vertexdata position x(c)
    posy=get vertexdata position y(c)
    posz=get vertexdata position z(c)
    `xrotate
    if xangle<>0
        ang#=atanfull(posz,-posy)-90
        dist#=SQRT(posz*posz+posy*posy)
        posz=dist#*cos(ang#+xangle)
        posy=dist#*sin(ang#+xangle)
    endif
    `yrotate
    if yangle<>0
        ang#=atanfull(posx,-posz)-90
        dist#=SQRT(posz*posz+posx*posx)
        posx=dist#*cos(ang#+yangle)
        posz=dist#*sin(ang#+yangle)
    endif
    `zrotate
    if zangle<>0
        ang#=atanfull(posx,-posy)-90
        dist#=SQRT(posx*posx+posy*posy)
        posx=dist#*cos(ang#+zangle)
        posy=dist#*sin(ang#+zangle)
    endif
    set vertexdata position c,posx,posy,posz
next c
unlock vertexdata
endfunction

+ Code Snippet

function vertsoff(object,offx as float,offy as float,offz as float)
lock vertexdata for limb object,0,2
for c=0 to get vertexdata vertex count()-1
    set vertexdata position c,get vertexdata position x(c)+offx,get vertexdata position y(c)+offy,get vertexdata position z(c)+offz
next c
unlock vertexdata
endfunction


function vertscale(object,scale)
lock vertexdata for limb object,0,2
local temp as float
temp=scale/100.0
for c=0 to get vertexdata vertex count()-1
    set vertexdata position c,get vertexdata position x(c)*temp,get vertexdata position y(c)*temp,get vertexdata position z(c)*temp
next c
unlock vertexdata
endfunction


function vertrotate(object,xangle as float,yangle as float,zangle as float)
lock vertexdata for limb object,0,2
local posx as float
local posy as float
local posz as float
for c=0 to get vertexdata vertex count()-1
    posx=get vertexdata position x(c)
    posy=get vertexdata position y(c)
    posz=get vertexdata position z(c)
    `xrotate
    if xangle<>0
        ang#=atanfull(posz,-posy)-90
        dist#=SQRT(posz*posz+posy*posy)
        posz=dist#*cos(ang#+xangle)
        posy=dist#*sin(ang#+xangle)
    endif
    `yrotate
    if yangle<>0
        ang#=atanfull(posx,-posz)-90
        dist#=SQRT(posz*posz+posx*posx)
        posx=dist#*cos(ang#+yangle)
        posz=dist#*sin(ang#+yangle)
    endif
    `zrotate
    if zangle<>0
        ang#=atanfull(posx,-posy)-90
        dist#=SQRT(posx*posx+posy*posy)
        posx=dist#*cos(ang#+zangle)
        posy=dist#*sin(ang#+zangle)
    endif
    set vertexdata position c,posx,posy,posz
next c
unlock vertexdata
endfunction

EDIT: Added Lock flags of 2 to make sure changes stick.

Latest progress: Fog of War implemented

Back to top

Profile PM Email Website

=PRoF=

21

Years of Service

User Offline

Joined: 17th Mar 2003

Location: Milton Keynes, UK

Posted: 31st Aug 2010 21:15 Edited at: 31st Aug 2010 21:26

Link

I've been working on exactly the same thing! The vertex rescaling bit I based mine on was by Cash Curtis II, it looks very similar to yours but seems to have issues rescaling models with Limbs. Not sure why tho.

I'm gonna try your one and see if it makes any difference or not.

>Edit<

I see the difference now when comparing them, CCII's version cycles through the limbs, where as yours just does limb 0.

Neither seem to work with the models I'm trying to convert (Made with 3DWS).

Here is my implementation of Cash Curtis II's rescaling snippet, in case anyone wants to see it.

+ Code Snippet

//**********************************************************************
//	This function rescales an object permanently (don't forget to save! lol)
//**********************************************************************

function fixObjectScale(obj, scaleX#, scaleY#, scaleZ#)

	//	Kudos - Cash Curtis II

	scaleX#=scaleX#/100.0
	scaleY#=scaleY#/100.0
	scaleZ#=scaleZ#/100.0
	
	`get number of limbs in object
	perform checklist for object limbs obj
	numlimbs = checklist quantity()
	empty checklist
	
	for A = 0 to numlimbs-1
	
		LOCK VERTEXDATA FOR LIMB obj, A, 2
		
		for V=0 to GET VERTEXDATA VERTEX COUNT()-1
			`get the positions and multiply by 2 for double scale
			X#=GET VERTEXDATA POSITION X(V)*scaleX#
			Y#=GET VERTEXDATA POSITION Y(V)*scaleY#
			Z#=GET VERTEXDATA POSITION Z(V)*scaleZ#
			`set changes
			SET VERTEXDATA POSITION V, X#, Y#, Z#
		
		next V
		
		UNLOCK VERTEXDATA
			
	next A
		
	calculate object bounds obj
	
endfunction

Back to top

Profile PM Email Website

Sorry your browser is not supported!

Code Snippets / [DBP] Move/Scale/Rotate with Vertexdata Commands