Perlin Noise Problem - GameCreators Forum

Author

Message

DigitalFury

15

Years of Service

User Offline

Joined: 30th Jul 2010

Location: United States

Posted: 11th Oct 2010 02:07 Edited at: 16th Oct 2010 23:52

Link

I found this site: http://freespace.virgin.net/hugo.elias/models/m_perlin.htm

For those who don't know what Perlin Noise is:
http://en.wikipedia.org/wiki/Perlin_noise

Can't seem to figure out what is wrong with it. Image is attached.

Code:

Global Persistence# : Persistence# = 0.25
Global Octaves : Octaves = 4

Global Width : Width = 256
Global Height : Height = 256

Global Dim Noise(Width, Height) As Float

Randomize 7893463

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = GetRND() `RND(255)
	Next Y
Next X

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = SmoothNoise(X, Y)
	Next Y
Next X

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = PerlinNoise_2D(X, Y)
	Next Y
Next X

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		H = Noise(X, Y) * 255.0
		Dot X, Y, RGB(H, H, H)
	Next Y
Next X

Do

Loop

Function GetRND()
    RND# = RND(100) * 0.01 * 100.0
    If RND(1) = 1 Then RND# = -RND#
EndFunction RND#

Function PerlinNoise_2D(X, Y)
   	If Octaves <= 0 then Octaves = 0
   	If Octaves => 15 then Octaves = 15
	
	For Octave = 0 To Octaves	
		Frequency = 2 ^ Octave
		Amplitude# = Persistence# ^ Octave
	
		Total# = Total# + InterpolateNoise(X , Y, Frequency) * Amplitude#
	Next Octave
EndFunction Total#

Function InterpolateNoise(X, Y, Frequency)	
	V1# = Noise(X, Y)
	V2# = Noise(X + 1, Y)
	V3# = Noise(X, Y + 1)
	V4# = Noise(X + 1, Y + 1)
	
	HeightX# = Linear_Interpolate(V1#, V2#, Frequency)	
	HeightY# = Linear_Interpolate(V3#, V4#, Frequency)	
	Height#  = Linear_Interpolate(HeightX#, HeightY#, Frequency)
EndFunction Height#

Function Linear_Interpolate( a as float, b as float, x as float )
   returnValue# =  a * (1.0 - x) + b * x
Endfunction returnValue#

Function SmoothNoise(X, Y)
	Corners# = (Noise(X - 1, Y - 1) + Noise(X + 1, Y - 1) + Noise(X - 1, Y + 1) + Noise(X + 1, Y + 1)) / 16.0
	Sides# = (Noise(X - 1, Y) + Noise(X + 1, Y) + Noise(X, Y - 1) + Noise(X, Y + 1)) / 8.0
    Center# = Noise(X, Y) / 4.0
    Value# = Corners# + Sides# + Center#
EndFunction Value#

+ Code Snippet

Global Persistence# : Persistence# = 0.25
Global Octaves : Octaves = 4

Global Width : Width = 256
Global Height : Height = 256

Global Dim Noise(Width, Height) As Float

Randomize 7893463

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = GetRND() `RND(255)
	Next Y
Next X

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = SmoothNoise(X, Y)
	Next Y
Next X

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = PerlinNoise_2D(X, Y)
	Next Y
Next X

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		H = Noise(X, Y) * 255.0
		Dot X, Y, RGB(H, H, H)
	Next Y
Next X

Do

Loop

Function GetRND()
    RND# = RND(100) * 0.01 * 100.0
    If RND(1) = 1 Then RND# = -RND#
EndFunction RND#

Function PerlinNoise_2D(X, Y)
   	If Octaves <= 0 then Octaves = 0
   	If Octaves => 15 then Octaves = 15
	
	For Octave = 0 To Octaves	
		Frequency = 2 ^ Octave
		Amplitude# = Persistence# ^ Octave
	
		Total# = Total# + InterpolateNoise(X , Y, Frequency) * Amplitude#
	Next Octave
EndFunction Total#

Function InterpolateNoise(X, Y, Frequency)	
	V1# = Noise(X, Y)
	V2# = Noise(X + 1, Y)
	V3# = Noise(X, Y + 1)
	V4# = Noise(X + 1, Y + 1)
	
	HeightX# = Linear_Interpolate(V1#, V2#, Frequency)	
	HeightY# = Linear_Interpolate(V3#, V4#, Frequency)	
	Height#  = Linear_Interpolate(HeightX#, HeightY#, Frequency)
EndFunction Height#

Function Linear_Interpolate( a as float, b as float, x as float )
   returnValue# =  a * (1.0 - x) + b * x
Endfunction returnValue#

Function SmoothNoise(X, Y)
	Corners# = (Noise(X - 1, Y - 1) + Noise(X + 1, Y - 1) + Noise(X - 1, Y + 1) + Noise(X + 1, Y + 1)) / 16.0
	Sides# = (Noise(X - 1, Y) + Noise(X + 1, Y) + Noise(X, Y - 1) + Noise(X, Y + 1)) / 8.0
    Center# = Noise(X, Y) / 4.0
    Value# = Corners# + Sides# + Center#
EndFunction Value#

Code Snippet 2:

Global Width : Width = 256
Global Height : Height = 256

Global Dim Noise(Width, Height) As Float

Randomize 7893463

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = GetRND()
	Next Y
Next X

remstart
For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = SmoothNoise(X, Y)
	Next Y
Next X
remend

Octaves = 16
`Amplitude# = 1.0
Persistance# = 0.5
`Frequency# = 0.0625
MaxHeight# = 255.0

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = PerlinNoise(X, Y, MaxHeight#, Octaves, Persistance#)
	Next Y
Next X

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		H# = Noise(X, Y)
		Dot X, Y, RGB(H#, H#, H#)
	Next Y
Next X

Do

Loop

Function PerlinNoise(X, Y, MaxHeight#, Octaves, Persistance#)
	For Octave = 0 To Octaves		
		`Frequency# = Frequency# * 2.0
		`Amplitude# = Amplitude# * Persistance#
		Frequency# = 2.0 ^ Octave
		Amplitude# = Persistence# ^ Octave
		Value# = Value# + Interpolate(X * Frequency#, Y * Frequency#) * Amplitude#
					
		Value# = Value# * MaxHeight#
	Next Index	
	
	If Value# < -1.0 Then Value# = -1.0
	If Value# > 1.0 Then Value# = 1.0
EndFunction Value#

Function SmoothNoise(X, Y)
	Corners# = (Noise(X - 1, Y - 1) + Noise(X + 1, Y - 1) + Noise(X - 1, Y + 1) + Noise(X + 1, Y + 1)) / 16.0
	Sides# = (Noise(X - 1, Y) + Noise(X + 1, Y) + Noise(X, Y - 1) + Noise(X, Y + 1)) / 8.0
    Center# = Noise(X, Y) / 4.0
    Value# = Corners# + Sides# + Center#
EndFunction Value#

Function GetRND()
    RND# = RND(100) * 0.01 * 100.0
    If RND(1) = 1 Then RND# = -RND#
EndFunction RND#

` This is exactly the same function from the website
` but it says: Array Out Of Bounds. Maybe +1 or -1 from allowed bounds
Function Interpolate(X#, Y#)
	X = Int(X#)
    FX# = X# - X
	
	Y = Int(Y#)
	FY# = Y# - Y
	
	V1# = SmoothNoise(X, Y)
	V2# = SmoothNoise(X + 1, Y)
	V3# = SmoothNoise(X, Y + 1)
	V4# = SmoothNoise(X + 1, Y + 1)

HeightX# = Linear_Interpolate(V1#, V2#, FX#)
	HeightY# = Linear_Interpolate(V3#, V4#, FX#)	
	Height# = Linear_Interpolate(HeightX#, HeightY#, FY#)
EndFunction Height#

Function Linear_Interpolate(A#, B#, X#)
	Value# =  A# * (1 - X#) + B# * X#
Endfunction Value#

Function Cosine_Interpolate(A#, B#, X#)	
	F# = (1.0 - Cos(X# * Pi())) * 0.5
	Value# = A# * (1.0 - F#) + B# * F#
EndFunction Value#

+ Code Snippet

Global Width : Width = 256
Global Height : Height = 256

Global Dim Noise(Width, Height) As Float

Randomize 7893463

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = GetRND()
	Next Y
Next X

remstart
For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = SmoothNoise(X, Y)
	Next Y
Next X
remend

Octaves = 16
`Amplitude# = 1.0
Persistance# = 0.5
`Frequency# = 0.0625
MaxHeight# = 255.0

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		Noise(X, Y) = PerlinNoise(X, Y, MaxHeight#, Octaves, Persistance#)
	Next Y
Next X

For X = 1 To Width - 1
	For Y = 1 To Height - 1
		H# = Noise(X, Y)
		Dot X, Y, RGB(H#, H#, H#)
	Next Y
Next X

Do

Loop

Function PerlinNoise(X, Y, MaxHeight#, Octaves, Persistance#)
	For Octave = 0 To Octaves		
		`Frequency# = Frequency# * 2.0
		`Amplitude# = Amplitude# * Persistance#
		Frequency# = 2.0 ^ Octave
		Amplitude# = Persistence# ^ Octave
		Value# = Value# + Interpolate(X * Frequency#, Y * Frequency#) * Amplitude#
					
		Value# = Value# * MaxHeight#
	Next Index	
	
	If Value# < -1.0 Then Value# = -1.0
	If Value# > 1.0 Then Value# = 1.0
EndFunction Value#

Function SmoothNoise(X, Y)
	Corners# = (Noise(X - 1, Y - 1) + Noise(X + 1, Y - 1) + Noise(X - 1, Y + 1) + Noise(X + 1, Y + 1)) / 16.0
	Sides# = (Noise(X - 1, Y) + Noise(X + 1, Y) + Noise(X, Y - 1) + Noise(X, Y + 1)) / 8.0
    Center# = Noise(X, Y) / 4.0
    Value# = Corners# + Sides# + Center#
EndFunction Value#

Function GetRND()
    RND# = RND(100) * 0.01 * 100.0
    If RND(1) = 1 Then RND# = -RND#
EndFunction RND#

` This is exactly the same function from the website
` but it says: Array Out Of Bounds. Maybe +1 or -1 from allowed bounds
Function Interpolate(X#, Y#)
	X = Int(X#)
    FX# = X# - X
	
	Y = Int(Y#)
	FY# = Y# - Y
	
	V1# = SmoothNoise(X, Y)
	V2# = SmoothNoise(X + 1, Y)
	V3# = SmoothNoise(X, Y + 1)
	V4# = SmoothNoise(X + 1, Y + 1)	

	HeightX# = Linear_Interpolate(V1#, V2#, FX#)
	HeightY# = Linear_Interpolate(V3#, V4#, FX#)	
	Height# = Linear_Interpolate(HeightX#, HeightY#, FY#)
EndFunction Height#

Function Linear_Interpolate(A#, B#, X#)
	Value# =  A# * (1 - X#) + B# * X#
Endfunction Value#

Function Cosine_Interpolate(A#, B#, X#)	
	F# = (1.0 - Cos(X# * Pi())) * 0.5
	Value# = A# * (1.0 - F#) + B# * F#
EndFunction Value#

Found from another website:

+ Code Snippet

Frequency# = Frequency# * 2.0
Amplitude# = Amplitude# * Persistance#

Tried almost everything I could think of.

Any help would be appreciated.

Thanks

Edit:

Added pictures of finished algorithms as I finish them. Check the posts below.

Back to top

Profile PM Email

old_School

16

Years of Service

User Offline

Joined: 29th Aug 2009

Location:

Posted: 11th Oct 2010 02:10 Edited at: 11th Oct 2010 02:12

Link

Might try testing the code by setting it to a specfic sound then go for random

Edit:
Not sound I mean image.

Edit:
Scratch that I did mean sound but I also dont see were it has a path or anything to detect sound files. Looks like its missing alot of construts. Maybe its just me.

Back to top

Profile PM

DigitalFury

15

Years of Service

User Offline

Joined: 30th Jul 2010

Location: United States

Posted: 11th Oct 2010 02:11 Edited at: 12th Oct 2010 02:17

Link

@old_School - What exactly do you mean?

Edit:
@old_School - Perlin Noise is for Images. It generates noise, smooths it, and the perlin noise algorithm would output something like this:

The input image is generated random noise. It is generated to output different results everytime.

Posted Wiki.

Back to top

Profile PM Email

DigitalFury

15

Years of Service

User Offline

Joined: 30th Jul 2010

Location: United States

Posted: 12th Oct 2010 21:59

Link

No one? Hmm thought someone might know something about perlin noise. There are a lot of examples out there...mine is just one of those that isn't working. lol

Back to top

Profile PM Email

Neuro Fuzzy

19

Years of Service

User Offline

Joined: 11th Jun 2007

Location:

Posted: 12th Oct 2010 22:41

Link

DarkCoder once wrote an awesome perlin noise function:

paste image GenerateNoise(timer(),512,6,1),0,0
wait key
end

`Perlin Noise Courtesy of Dark Coder ;) ()
Function GenerateNoise( Seed, startingRes, totalOctaves, Sampling )
   Randomize Seed
   If startingRes > 512 Then startingRes = 512
   If totalOctaves > 8 Then totalOctaves = 8

// Generate noise for all octaves
   for octaveID = 1 to totalOctaves
       memblockID  = octaveID
       octaveRes   = startingRes / 2 ^ (octaveID - 1)
       Make Memblock memblockID, octaveRes * octaveRes * 4 // A single float
       for x = 0 to octaveRes - 1
           for y = 0 to octaveRes - 1
               Write Memblock Float memblockID, ( x + y * octaveRes ) * 4, ( Rnd(2000) - 1000 ) * 0.001
           next
       next
   next

// add all layers together
   memblockID  = totalOctaves + 1

Make Memblock memblockID, 12 + startingRes * startingRes * 4
   Write Memblock DWord memblockID, 0, startingRes
   Write Memblock DWord memblockID, 4, startingRes
   Write Memblock DWord memblockID, 8, 32

minHeight#      = -1.9
   maxHeight#      =  1.9
   minInv#         = -minHeight#
   heightRange#    =  maxHeight# - minHeight#
   _255DivRange#   =  255.0 / heightRange#
   sResReciprocal# =    1.0 / (startingRes)

for x = 0 to startingRes - 1
       for y = 0 to startingRes - 1
           x#          = x * sResReciprocal#
           y#          = y * sResReciprocal#
           height#     = 0.0
           Strength#   = 1.0
           `height# = Memblock Float( 1, ( x + y * startingRes ) * 4 )

for OctaveID = totalOctaves to 1 step -1
           `for OctaveID = 7 to 7 step -1
               octaveRes = startingRes / 2 ^ (octaveID - 1)
               // Store the float pixel we are over on the current octave
               memblockX# = x# * octaveRes
               memblockY# = y# * octaveRes
               // Store the int version for pixel sampling
               memblockX  = memblockX#
               memblockY  = memblockY#
               // Get the local offset
               memblockX# = memblockX# mod 1.0
               memblockY# = memblockY# mod 1.0

If Sampling = 1
                 `BiCubic Sampling
                  sample1#  = Sample( OctaveID, memblockX - 1, memblockY - 1, octaveRes )
                  sample2#  = Sample( OctaveID, memblockX    , memblockY - 1, octaveRes )
                  sample3#  = Sample( OctaveID, memblockX + 1, memblockY - 1, octaveRes )
                  sample4#  = Sample( OctaveID, memblockX + 2, memblockY - 1, octaveRes )
                  mHeight1# = CubicInterpolate( sample1#, sample2#, sample3#, sample4#, memblockX# )
                  sample1#  = Sample( OctaveID, memblockX - 1, memblockY    , octaveRes )
                  sample2#  = Sample( OctaveID, memblockX    , memblockY    , octaveRes )
                  sample3#  = Sample( OctaveID, memblockX + 1, memblockY    , octaveRes )
                  sample4#  = Sample( OctaveID, memblockX + 2, memblockY    , octaveRes )
                  mHeight2# = CubicInterpolate( sample1#, sample2#, sample3#, sample4#, memblockX# )
                  sample1#  = Sample( OctaveID, memblockX - 1, memblockY + 1, octaveRes )
                  sample2#  = Sample( OctaveID, memblockX    , memblockY + 1, octaveRes )
                  sample3#  = Sample( OctaveID, memblockX + 1, memblockY + 1, octaveRes )
                  sample4#  = Sample( OctaveID, memblockX + 2, memblockY + 1, octaveRes )
                  mHeight3# = CubicInterpolate( sample1#, sample2#, sample3#, sample4#, memblockX# )
                  sample1#  = Sample( OctaveID, memblockX - 1, memblockY + 2, octaveRes )
                  sample2#  = Sample( OctaveID, memblockX    , memblockY + 2, octaveRes )
                  sample3#  = Sample( OctaveID, memblockX + 1, memblockY + 2, octaveRes )
                  sample4#  = Sample( OctaveID, memblockX + 2, memblockY + 2, octaveRes )
                  mHeight4# = CubicInterpolate( sample1#, sample2#, sample3#, sample4#, memblockX# )
                  mHeight#  = CubicInterpolate( mHeight1#, mHeight2#, mHeight3#, mHeight4#, memblockY# )
               Else
                 `BiLinear Sampling
                  sample1#  = Sample( OctaveID, memblockX    , memblockY, octaveRes )
                  sample2#  = Sample( OctaveID, memblockX + 1, memblockY, octaveRes )
                  mHeightX# = Linear_Interpolate( sample1#, sample2#, memblockX# )
                  sample1#  = Sample( OctaveID, memblockX    , memblockY + 1, octaveRes)
                  sample2#  = Sample( OctaveID, memblockX + 1, memblockY + 1, octaveRes)
                  mHeightY# = Linear_Interpolate( sample1#, sample2#, memblockX# )
                  mHeight#  = Linear_Interpolate( mHeightX#, mHeightY#, memblockY# )
               EndIf

height# = height# + mHeight# * Strength#
               Strength# = Strength# * 0.5
           next

height  = (height# + minInv#) * _255DivRange#
           if height > 255 then height = 255
           if height <   0 then height = 0
           Write Memblock Byte memblockID, 12 + ( x + y * startingRes ) * 4    , height // B
           Write Memblock Byte memblockID, 12 + ( x + y * startingRes ) * 4 + 1, height // G
           Write Memblock Byte memblockID, 12 + ( x + y * startingRes ) * 4 + 2, height // R
           Write Memblock Byte memblockID, 12 + ( x + y * startingRes ) * 4 + 3, 255    // A
       next
   next

// Create image
   Img = GetBlankImgNo()
   Make Image From Memblock Img, memblockID

For octaveID = 1 to totalOctaves
      Delete Memblock octaveID
   Next octaveID
   Delete Memblock totalOctaves + 1
   Cls
EndFunction Img

Function Sample( memblockID, x, y, memblockRes )
   if x < 0 then x = x + memblockRes
   if y < 0 then y = y + memblockRes
   if x > memblockRes-1 then x = x - memblockRes
   if y > memblockRes-1 then y = y - memblockRes
   returnValue# = Memblock Float( memblockID, ( x + y * memblockRes ) * 4 )
Endfunction returnValue#

Function Linear_Interpolate( a as float, b as float, x as float )
   returnValue# =  a * (1.0 - x) + b * x
Endfunction returnValue#

Function CubicInterpolate( aMinOne as float, a as float, b as float, bAddOne as float, acrossAB as float )
   P as float
   Q as float
   R as float
   S as float
   P = (bAddOne - b) - (aMinOne - a)
   Q = (aMinOne - a) - P
   R = b - aMinOne
   S = a
   returnValue# =  P * acrossAB ^ 3 + Q * acrossAB ^ 2 + R * acrossAB + S
EndFunction returnValue#
Function GetBlankImgNo()
   For Num = 1 To 65500
      If Image Exist( Num ) = 0
         ExitFunction Num
      EndIf
   Next Num
EndFunction 0

+ Code Snippet

paste image GenerateNoise(timer(),512,6,1),0,0
wait key
end


`Perlin Noise Courtesy of Dark Coder ;) ()
Function GenerateNoise( Seed, startingRes, totalOctaves, Sampling )
   Randomize Seed
   If startingRes > 512 Then startingRes = 512
   If totalOctaves > 8 Then totalOctaves = 8

   // Generate noise for all octaves
   for octaveID = 1 to totalOctaves
       memblockID  = octaveID
       octaveRes   = startingRes / 2 ^ (octaveID - 1)
       Make Memblock memblockID, octaveRes * octaveRes * 4 // A single float
       for x = 0 to octaveRes - 1
           for y = 0 to octaveRes - 1
               Write Memblock Float memblockID, ( x + y * octaveRes ) * 4, ( Rnd(2000) - 1000 ) * 0.001
           next
       next
   next

   // add all layers together
   memblockID  = totalOctaves + 1

   Make Memblock memblockID, 12 + startingRes * startingRes * 4
   Write Memblock DWord memblockID, 0, startingRes
   Write Memblock DWord memblockID, 4, startingRes
   Write Memblock DWord memblockID, 8, 32

   minHeight#      = -1.9
   maxHeight#      =  1.9
   minInv#         = -minHeight#
   heightRange#    =  maxHeight# - minHeight#
   _255DivRange#   =  255.0 / heightRange#
   sResReciprocal# =    1.0 / (startingRes)

   for x = 0 to startingRes - 1
       for y = 0 to startingRes - 1
           x#          = x * sResReciprocal#
           y#          = y * sResReciprocal#
           height#     = 0.0
           Strength#   = 1.0
           `height# = Memblock Float( 1, ( x + y * startingRes ) * 4 )

           for OctaveID = totalOctaves to 1 step -1
           `for OctaveID = 7 to 7 step -1
               octaveRes = startingRes / 2 ^ (octaveID - 1)
               // Store the float pixel we are over on the current octave
               memblockX# = x# * octaveRes
               memblockY# = y# * octaveRes
               // Store the int version for pixel sampling
               memblockX  = memblockX#
               memblockY  = memblockY#
               // Get the local offset
               memblockX# = memblockX# mod 1.0
               memblockY# = memblockY# mod 1.0

               If Sampling = 1
                 `BiCubic Sampling
                  sample1#  = Sample( OctaveID, memblockX - 1, memblockY - 1, octaveRes )
                  sample2#  = Sample( OctaveID, memblockX    , memblockY - 1, octaveRes )
                  sample3#  = Sample( OctaveID, memblockX + 1, memblockY - 1, octaveRes )
                  sample4#  = Sample( OctaveID, memblockX + 2, memblockY - 1, octaveRes )
                  mHeight1# = CubicInterpolate( sample1#, sample2#, sample3#, sample4#, memblockX# )
                  sample1#  = Sample( OctaveID, memblockX - 1, memblockY    , octaveRes )
                  sample2#  = Sample( OctaveID, memblockX    , memblockY    , octaveRes )
                  sample3#  = Sample( OctaveID, memblockX + 1, memblockY    , octaveRes )
                  sample4#  = Sample( OctaveID, memblockX + 2, memblockY    , octaveRes )
                  mHeight2# = CubicInterpolate( sample1#, sample2#, sample3#, sample4#, memblockX# )
                  sample1#  = Sample( OctaveID, memblockX - 1, memblockY + 1, octaveRes )
                  sample2#  = Sample( OctaveID, memblockX    , memblockY + 1, octaveRes )
                  sample3#  = Sample( OctaveID, memblockX + 1, memblockY + 1, octaveRes )
                  sample4#  = Sample( OctaveID, memblockX + 2, memblockY + 1, octaveRes )
                  mHeight3# = CubicInterpolate( sample1#, sample2#, sample3#, sample4#, memblockX# )
                  sample1#  = Sample( OctaveID, memblockX - 1, memblockY + 2, octaveRes )
                  sample2#  = Sample( OctaveID, memblockX    , memblockY + 2, octaveRes )
                  sample3#  = Sample( OctaveID, memblockX + 1, memblockY + 2, octaveRes )
                  sample4#  = Sample( OctaveID, memblockX + 2, memblockY + 2, octaveRes )
                  mHeight4# = CubicInterpolate( sample1#, sample2#, sample3#, sample4#, memblockX# )
                  mHeight#  = CubicInterpolate( mHeight1#, mHeight2#, mHeight3#, mHeight4#, memblockY# )
               Else
                 `BiLinear Sampling
                  sample1#  = Sample( OctaveID, memblockX    , memblockY, octaveRes )
                  sample2#  = Sample( OctaveID, memblockX + 1, memblockY, octaveRes )
                  mHeightX# = Linear_Interpolate( sample1#, sample2#, memblockX# )
                  sample1#  = Sample( OctaveID, memblockX    , memblockY + 1, octaveRes)
                  sample2#  = Sample( OctaveID, memblockX + 1, memblockY + 1, octaveRes)
                  mHeightY# = Linear_Interpolate( sample1#, sample2#, memblockX# )
                  mHeight#  = Linear_Interpolate( mHeightX#, mHeightY#, memblockY# )
               EndIf

               height# = height# + mHeight# * Strength#
               Strength# = Strength# * 0.5
           next

           height  = (height# + minInv#) * _255DivRange#
           if height > 255 then height = 255
           if height <   0 then height = 0
           Write Memblock Byte memblockID, 12 + ( x + y * startingRes ) * 4    , height // B
           Write Memblock Byte memblockID, 12 + ( x + y * startingRes ) * 4 + 1, height // G
           Write Memblock Byte memblockID, 12 + ( x + y * startingRes ) * 4 + 2, height // R
           Write Memblock Byte memblockID, 12 + ( x + y * startingRes ) * 4 + 3, 255    // A
       next
   next

   // Create image
   Img = GetBlankImgNo()
   Make Image From Memblock Img, memblockID

   For octaveID = 1 to totalOctaves
      Delete Memblock octaveID
   Next octaveID
   Delete Memblock totalOctaves + 1
   Cls
EndFunction Img


Function Sample( memblockID, x, y, memblockRes )
   if x < 0 then x = x + memblockRes
   if y < 0 then y = y + memblockRes
   if x > memblockRes-1 then x = x - memblockRes
   if y > memblockRes-1 then y = y - memblockRes
   returnValue# = Memblock Float( memblockID, ( x + y * memblockRes ) * 4 )
Endfunction returnValue#

Function Linear_Interpolate( a as float, b as float, x as float )
   returnValue# =  a * (1.0 - x) + b * x
Endfunction returnValue#

Function CubicInterpolate( aMinOne as float, a as float, b as float, bAddOne as float, acrossAB as float )
   P as float
   Q as float
   R as float
   S as float
   P = (bAddOne - b) - (aMinOne - a)
   Q = (aMinOne - a) - P
   R = b - aMinOne
   S = a
   returnValue# =  P * acrossAB ^ 3 + Q * acrossAB ^ 2 + R * acrossAB + S
EndFunction returnValue#
Function GetBlankImgNo()
   For Num = 1 To 65500
      If Image Exist( Num ) = 0
         ExitFunction Num
      EndIf
   Next Num
EndFunction 0

What that function does, is first create a bunch of random memblocks, representing a grid of a certain resolution. For example, if startingres=512, and octaves=8, that would create grids with random numbers in each spot, of resolution: 512x512, 256x256, 128x128, 64x64, 32x32, 16x16, 8x8, and 4x4. Then, the program adds all of those together. Thats where the interpolation comes in - for example, the 4x4 grid has to be interpolated up to 512x512. Then, you add all the interpolated values together, to get the final result.

What you're doing... doesn't look like its that. Not that i thoroughly read through it (and I can't compile it :\)

Back to top

Profile PM Email

DigitalFury

15

Years of Service

User Offline

Joined: 30th Jul 2010

Location: United States

Posted: 12th Oct 2010 22:55 Edited at: 16th Oct 2010 02:23

Link

@Neuro Fuzzy - I only found like two examples on the forums after searching for quite a bit. I haven't found this one though. My latest example should compile. Thanks 4 trying..might need matrix01util. Fixed my example. Try it now.

This noise seems a lot more controlled.

I did want to get my demo working though. I couldn't figure out most of the demos I did find.

Thanks for the snippet. ^^

Edit:

This is interesting. It seems he generates noise first. I didn't know that. Hmm each octave (sample) is stored in a memblock.

Ahhh I don't know what mod is. What is that? I looked it up and it is confusing.

DarkCoder made one hell perlin noise example. It is going to take a very long time to figure it out. I don't know if I can. I'm trying to make mine as simple as possible.

Back to top

Profile PM Email

sladeiw

17

Years of Service

User Offline

Joined: 16th May 2009

Location: UK

Posted: 13th Oct 2010 02:50

Link

Increase the value of Persistence#, then you'll keep trying until you suss it out

Back to top

Profile PM

DigitalFury

15

Years of Service

User Offline

Joined: 30th Jul 2010

Location: United States

Posted: 13th Oct 2010 03:02 Edited at: 13th Oct 2010 03:05

Link

@sladeiw - Tried different values. There are acceptable values on the website I posted.

I did manage to get Diamond Square to work. Now I just have to get Perlin Noise to work. Perlin Noise is more flexible and has more variation then Diamond Square so I will use Perlin Noise.

Here is Diamond Square:

I am going to rework diamond square to work for different algorithms.

Back to top

Profile PM Email

Neuro Fuzzy

19

Years of Service

User Offline

Joined: 11th Jun 2007

Location:

Posted: 16th Oct 2010 00:26

Link

Ah! I'll try to explain the snippet to you. I have a need to create 3d perlin noise and evaluate it at certain points, so I took a look back at this post and realized I didn't really understand the interpolation. I do now, and let me explain it to you

O rite, 1st, "mod" is the modulo function. Basically... Remember in elementary school, when you would write 3/2=1R1. mod returns the remainder. Basically:
a=b*k+c. Given a and b, find the largest k and smallest c, where k is a whole number. C is the remainder, and C is a mod b (this definition takes into accounts floats, so 3.1 mod 1.5=.1)

Cubic interpolation takes in four values, and interpolates between the second and third value, given a value *inbetween 0 and 1*. Any float modulo 1.0 will be inbetween 0 and 1. That number represents the distance from the last whole point (which would be considered an index on the memblock grid).

All "memblockX#" and "memblockY#" are is the distance from the last whole grid area, for which noise data exists, and this is the value used to interpolate.

So, the function gets interpolants of four rows, like this:
--*--
--*--
--*--
--*--
where a * represents the last -, + a number less than 1. The interpolated information is calculated for each *.

Then, the last line of the "bicubic sampling" section:
mHeight# = CubicInterpolate( mHeight1#, mHeight2#, mHeight3#, mHeight4#, memblockY# )
takes the information from those four *s, and interpolates between the second and third.

Then, that value is added to a "total". Strength# represents how much of that value gets added, and it decreases exponentially with "OctaveID".

height# = height# + mHeight# * Strength#
Strength# = Strength# * .5

After adding up all the interpolated interpolants, with weighting, all it does is save that data to the memblock and move on to the next thing.

I was gonna draw a diagram but I g2g like right now, i might later

Back to top

Profile PM Email

DigitalFury

15

Years of Service

User Offline

Joined: 30th Jul 2010

Location: United States

Posted: 16th Oct 2010 02:14

Link

@Neuro Fuzzy -

I understand what mod means now. Thanks.

I don't really know why Dark Coder would use memblocks. He could use an array with another dimension for the octave. I guess it is a good way to store the information.

In every example I have noticed Perlin Noise has taken each sample this way:

+ Code Snippet

V1# = Noise(X, Y)
V2# = Noise(X + 1, Y)
V3# = Noise(X, Y + 1)
V4# = Noise(X + 1, Y + 1)

Here he is using a different way to sample for interpolation.

+ Code Snippet

sample1#  = Sample( OctaveID, memblockX - 1, memblockY + 1, octaveRes )
            sample2#  = Sample( OctaveID, memblockX    , memblockY + 1, octaveRes )
            sample3#  = Sample( OctaveID, memblockX + 1, memblockY + 1, octaveRes )
            sample4#  = Sample( OctaveID, memblockX + 2, memblockY + 1, octaveRes )
            mHeight3# = CubicInterpolate( sample1#, sample2#, sample3#, sample4#, memblockX# )

Attached Image Showing Diagrams For Both Snippets.

I looked at the Diamond Square example and tried to figure it out, but that algorithm is even more difficult to understand. It seems it is limited to two octaves and a preset algorithm for sampling.

I am trying to make the Perlin Noise Algorithm as simple as possible. I have tried several variations of the algorithm because not everything was explained here:

http://freespace.virgin.net/hugo.elias/models/m_perlin.htm

I just posted every variation of my perlin noise. What could I possibly be doing wrong?

A diagram would definitely be helpful!

Thanks your the greatest!

DigitalFury

Back to top

Profile PM Email

DigitalFury

15

Years of Service

User Offline

Joined: 30th Jul 2010

Location: United States

Posted: 16th Oct 2010 02:24

Link

Updates:

Played around with the Diamond Square function to output different results:

Back to top

Profile PM Email

dark coder

23

Years of Service

User Offline

Joined: 6th Oct 2002

Location: Japan

Posted: 16th Oct 2010 06:14 Edited at: 16th Oct 2010 06:18

Link

Quote: "I don't really know why Dark Coder would use memblocks. He could use an array with another dimension for the octave. I guess it is a good way to store the information."

Because if I used a 2D array then I'd have a lot of unused indices, I could have used a single 1D array and calculated the offsets myself, but I guess I found this method to be clearer.

Quote: "Here he is using a different way to sample for interpolation."

My code supports both bilinear and bicubic sampling, linear interpolation only requires 2 values and a weight, but cubic requires 4 values and a weight, and that's only for one axis. Because it's bicubic I have to do this across both axis which requires 16 samples(4*4), whereas bilinear is 4 samples(2*2), the result is that bicubic is far smoother. Notice that you only quoted the code from the first set of samples, that calculates the weight across the X axis for a Y offset of -1, I do the same 3 more times for a Y offset of 0, 1 and 2. This gives me 4 cubically interpolated heights across the X axis, I then use those heights to do a final cubic interpolation thus giving me bicubic. Similarly, if I were to do tricubic interpolation I'd need to do a total of 64 samples(4*4*4), or 8(2*2*2) for trilinear.

Back to top

Profile PM Email

DigitalFury

15

Years of Service

User Offline

Joined: 30th Jul 2010

Location: United States

Posted: 16th Oct 2010 07:02 Edited at: 16th Oct 2010 23:49

Link

@dark coder - So in order to bicubically interpolate you need to apply a Cubic Interpolation to those four samples.

I think I only did one linear interpolation to one sample. I guess I can adapt my code to sample the same way you do. Hopefully it works.

@ Everyone:

Updates: Fault Formation Algorithm

Finally Figured it out.

The first algorithm is the Fault Formation Algorithm.

I need to do some more work to it.

It is different from the results of other people's examples. I may need to look into why.

Here is a screenie!:

The number is the amount of interpolations.

Digital Fury

Back to top

Profile PM Email

DigitalFury

15

Years of Service

User Offline

Joined: 30th Jul 2010

Location: United States

Posted: 16th Oct 2010 23:32 Edited at: 16th Oct 2010 23:39

Link

Finished Voronoi Diagrams. I didn't like how it turned out so I am going to write my own.

Next algorithm is going to be the circles algorithm.

Back to top

Profile PM Email

Neuro Fuzzy

19

Years of Service

User Offline

Joined: 11th Jun 2007

Location:

Posted: 17th Oct 2010 01:08

Link

Cool. All the images look a bit grainy though... You might want to try "set display mode" to get a higher resolution. On a related note, you might want to check out anti-aliased lines (Phalaex had an implementation of xiaolin-wu anti-aliasing).

Also, you might wanna consider putting these in the "code snippets" section. It'd be pretty cool.

Back to top

Profile PM Email

DigitalFury

15

Years of Service

User Offline

Joined: 30th Jul 2010

Location: United States

Posted: 17th Oct 2010 01:11

Link

@Neuro Fuzzy - Blew up the images two times. That would be why. ^^ Oooo anti-aliasing sounds awesome. Will look into it. I am making a lib for an event bigger project. I might not post them. Might after the project.

Digital Fury

Back to top

Profile PM Email

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Perlin Noise Problem