Lander / Zarch / Virus Style Landscape Generation and Movement

Author

Message

StevetS

21

Years of Service

User Offline

Joined: 19th May 2004

Location:

Posted: 15th Oct 2010 01:21

Link

I've been searching round the forums for a while and wondering whether anyone has attempted a Zarch/Virus style game in DBPro?

It was pretty much cutting edge in 1987 when David Braben wrote the 'Lander' demo for the Archimedes and it looks like the sort of thing DBP should be able to handle without problem though I don't think I've seen any remakes. Does anyone know any different?

The meat of the game has to be in the landscape generation and manipulation code where the extents of the screen consist of a 12x12 grid of squares at varying height making up the ground. The game map is square (about 20x20 screens = about 240x240 landscape squares wide and deep) but the game 'wraps around', so the player leaving one side of the screen appears seamlessly on the opposite side without interruption to the 3D view.

Link the game in motion:
http://www.youtube.com/watch?v=ZiixfIXMNGA

As the player is always in the centre of the screen I'm guessing the player object is stationary in x and z co-ords and the landscape 'scrolls' around it lifting data from a height map of sorts (so there is no flipping effect which would otherwise be apparent should the player position jump to opposite sides of a 3D map). i.e the player would never encounter a map 'edge'.

Setting up the landscape array for 256x256 squares would be a simple case of

+ Code Snippet

for z=0 to 255
    for x=0 to 255
        col=point (x,z)
        if col=???? then landscape_height(x,z)=????
     next x
next z

Lifting the data from the array for the local squares is also straightforward and fast but generating the actual 12x12 landscape I'm guessing would present several options:

1. A matrix (everyone seems to hate them!)
2. Object/s (would possibly need 4 of them flick/flacking around to keep the landscape seamless but removes the need to generate the landscape - predesigned as objects)
3. A terrain (a bit like a matrix object?)
4. Manually defining polygons to create the 12x12 grid (doubling up triangle objects)

I think I like the idea of '4' as each polygon as an object can be recoloured and interacted with (respond individually to a collision command - e.g. when a virus particle hits it then change its colour to red) whereas as the others are individual items also requiring a separate texture to colour them (or am I wrong?) which then needs to be repasted everytime a landscape square needs to change colour.

Using polygons we'd be moving the 12x12 landscape grid until it reached a boundary edge then generating the next row or column of 12 squares (24 polygons) while deleting the opposite edge of squares. Sounds quite simple but there'd be big performance hit with running through two 24 cycle loops every couple of game loops (when an edge was reached) and having to delete 24 objects then create a replacement 24 objects at the opposite side.

Does anyone have any thoughts on what the most efficient method of doing all of the above would be?

Back to top

Profile PM

Van B

Moderator

22

Years of Service

User Offline

Joined: 8th Oct 2002

Location: Sunnyvale

Posted: 15th Oct 2010 12:48

Link

I think the best method for a Virus game would be a matrix - because you would have a tile sheet, and updating the tile on the matrix, or indeed updating the terrain would be very easy with a matrix. Plus, you can scroll and update as well, so having just a small 32x32 matrix for instance means you could update it with the camera scrolling, matrices should be perfect for such a task.

For actually generating the landscape, well it can be very simple too, it depends on your approach. I mean, you could make a random terrain just using random values then smoothing several times, with a small terrain it should be quick to generate too.

I always liked Virus, but not necesserily the plot - I just liked to fly about the place trying not to crash. You should check out Hunter too, on the Amiga and Atari-ST, was an awesome game that used a similar terrain system to Virus, but was more about combat and vehicles and searching.

Health, Ammo, and bacon and eggs!

Back to top

Profile PM Email

StevetS

21

Years of Service

User Offline

Joined: 19th May 2004

Location:

Posted: 15th Oct 2010 22:06 Edited at: 16th Oct 2010 19:26

Link

Thanks for the reply Van!

I loved Virus - I think I've still got the original Virus, and Hunter (belive it or don't) for the ST in a big sealed plastic box (along with my ST1040) in my parents loft - if my dad's not dumped it yet!

I'm thinking I might just dig it out and fire it up!

I wasn't thinking of remaking the game, just thinking of how easy to code in DBPro. Tho, then again, when I finish Quazatron I might just look at a Virus/Hunter crossover. People in Virus, a Defender style 'protect the innocent' option as a side mission to stopping the virus spread. Could be a goer!

A matrix you say??!!

I've put a little bit of code together (using notepad, at lunchtime, at work

though I've checked in compiles and complies tonight!):

`Basic landscape using triangles
`Programmed in Windows Notepad!

color backdrop rgb(0,0,0)

dim tileheight(12,12)

`Active tile data. 12x12 grid taken from a full level in final game
for z=0 to 11
    for x=0 to 11
        ht=0
	read ydata
        tileheight(x,z)=ydata
next x
next z

ydata:
data 10,10,20,20,20,20,20,20,20,20,20,20
data 20,20,20,20,20,20,20,20,20,30,40,40
data 10,20,20,20,20,20,20,20,20,20,20,30
data 10,20,20,20,20,20,20,20,20,20,20,30
data 10,20,20,20,20,20,20,20,20,20,20,30
data 10,20,20,20,20,20,20,40,40,40,20,20
data 10,20,20,20,20,20,20,40,40,40,20,20
data 10,20,20,20,20,20,20,40,40,40,20,20
data 10,20,20,20,20,20,20,20,20,20,20,20
data 10,20,20,20,20,20,20,20,20,20,20,20
data 10,20,20,20,20,20,20,20,20,20,20,20
data 30,30,30,30,30,30,30,30,30,40,30,40

`Generate the level - will be done 'on-the-fly' in the proper code
obj=1
for z=0 to 11
    for x=0 to 11
        make object triangle obj,x*40,tileheight(x,z),z*40,x*40,tileheight(x,z+1),z*40+40,x*40+40,tileheight(x+1,z),z*40
        inc obj
        make object triangle obj,x*40,tileheight(x,z+1),z*40+40,x*40+40,tileheight(x+1,z+1),z*40+40,x*40+40,tileheight(x+1,z),z*40
        colr=rnd(255):colg=rnd(255)
        color object obj,rgb(colr,colg,0)
        color object obj-1,rgb(colr,colg,0)
        inc obj
    next x
next z

camx=240:camy=200:camz=-400
xang=0:yang=0:zang=0

tmr=timer()
repeat
    `simply move the camera around
    position camera camx,camy,camz
    point camera camx,camy-100,camz+200
    rotate camera xang,yang,zang

if upkey() then inc camz
    if downkey() then dec camz
    if leftkey() then dec camx
    if rightkey() then inc camx
    if inkey$()="q" then inc camy
    if inkey$()="a" then dec camy
    if inkey$()="z" then dec yang
    if inkey$()="x" then inc yang

set cursor 0,0:print "USING TRIANGLES: PRESS '1' TO REDO WITH A MATRIX. CURSORS/Q/A/Z/X TO MOVE/LOOK"
set cursor 50,50:print "fps:";screen fps()

until inkey$()="1"

`Delete the polygons
for z=0 to 288
    delete object z
next z

`Create using a matrix instead of polygons
make matrix 1,480,480,12,12

`Place the matrix in the 3d world
position matrix 1,0,0,0

`Create some basic tiles

for z=0 to 11
    for x=0 to 11
        tilecol=rgb(rnd(255),rnd(255),0)
        ink tilecol,0
        box x*10,z*10,x*10+10,z*10+10
        
    next x
next z

ink rgb(255,255,255),0

get image 1,0,0,120,120,0
prepare matrix texture 1,1,12,12

`Generate the matrix
t=1
for z=1 to 12
    for x=1 to 12
        set matrix tile 1,rnd(10)+1,rnd(10)+1,t
        set matrix height 1,x,z,tileheight(x,z)
        inc t
    next x
next t

repeat
    `Again, moving the camera around apologies for the repeative coding!
    if upkey() then inc camz
    if downkey() then dec camz
    if leftkey() then dec camx
    if rightkey() then inc camx
    if inkey$()="q" then inc camy
    if inkey$()="a" then dec camy
    if inkey$()="z" then dec yang
    if inkey$()="x" then inc yang

position camera camx,camy,camz
    point camera camx,camy-100,camz+200
    rotate camera xang,yang,zang
    
    update matrix 1
    
    set cursor 0,0:print "USING A MATRIX: PRESS '2' TO EXIT. CURSORS/Q/A/Z/X TO MOVE/LOOK"
    set cursor 50,50:print "fps:";screen fps()
    
until inkey$()="2"

END

+ Code Snippet

`Basic landscape using triangles
`Programmed in Windows Notepad!

color backdrop rgb(0,0,0)

dim tileheight(12,12)

`Active tile data. 12x12 grid taken from a full level in final game
for z=0 to 11
    for x=0 to 11
        ht=0
	read ydata
        tileheight(x,z)=ydata
next x
next z

ydata:
data 10,10,20,20,20,20,20,20,20,20,20,20
data 20,20,20,20,20,20,20,20,20,30,40,40
data 10,20,20,20,20,20,20,20,20,20,20,30
data 10,20,20,20,20,20,20,20,20,20,20,30
data 10,20,20,20,20,20,20,20,20,20,20,30
data 10,20,20,20,20,20,20,40,40,40,20,20
data 10,20,20,20,20,20,20,40,40,40,20,20
data 10,20,20,20,20,20,20,40,40,40,20,20
data 10,20,20,20,20,20,20,20,20,20,20,20
data 10,20,20,20,20,20,20,20,20,20,20,20
data 10,20,20,20,20,20,20,20,20,20,20,20
data 30,30,30,30,30,30,30,30,30,40,30,40

`Generate the level - will be done 'on-the-fly' in the proper code
obj=1
for z=0 to 11
    for x=0 to 11
        make object triangle obj,x*40,tileheight(x,z),z*40,x*40,tileheight(x,z+1),z*40+40,x*40+40,tileheight(x+1,z),z*40
        inc obj
        make object triangle obj,x*40,tileheight(x,z+1),z*40+40,x*40+40,tileheight(x+1,z+1),z*40+40,x*40+40,tileheight(x+1,z),z*40
        colr=rnd(255):colg=rnd(255)
        color object obj,rgb(colr,colg,0)
        color object obj-1,rgb(colr,colg,0)
        inc obj
    next x
next z

camx=240:camy=200:camz=-400
xang=0:yang=0:zang=0

tmr=timer()
repeat
    `simply move the camera around
    position camera camx,camy,camz
    point camera camx,camy-100,camz+200
    rotate camera xang,yang,zang

    if upkey() then inc camz
    if downkey() then dec camz
    if leftkey() then dec camx
    if rightkey() then inc camx
    if inkey$()="q" then inc camy
    if inkey$()="a" then dec camy
    if inkey$()="z" then dec yang
    if inkey$()="x" then inc yang

set cursor 0,0:print "USING TRIANGLES: PRESS '1' TO REDO WITH A MATRIX. CURSORS/Q/A/Z/X TO MOVE/LOOK"
set cursor 50,50:print "fps:";screen fps()

until inkey$()="1"

`Delete the polygons
for z=0 to 288
    delete object z
next z

`Create using a matrix instead of polygons
make matrix 1,480,480,12,12

`Place the matrix in the 3d world
position matrix 1,0,0,0

`Create some basic tiles

for z=0 to 11
    for x=0 to 11
        tilecol=rgb(rnd(255),rnd(255),0)
        ink tilecol,0
        box x*10,z*10,x*10+10,z*10+10
        
    next x
next z

ink rgb(255,255,255),0

get image 1,0,0,120,120,0
prepare matrix texture 1,1,12,12

`Generate the matrix
t=1
for z=1 to 12
    for x=1 to 12
        set matrix tile 1,rnd(10)+1,rnd(10)+1,t
        set matrix height 1,x,z,tileheight(x,z)
        inc t
    next x
next t

repeat
    `Again, moving the camera around apologies for the repeative coding!
    if upkey() then inc camz
    if downkey() then dec camz
    if leftkey() then dec camx
    if rightkey() then inc camx
    if inkey$()="q" then inc camy
    if inkey$()="a" then dec camy
    if inkey$()="z" then dec yang
    if inkey$()="x" then inc yang

    position camera camx,camy,camz
    point camera camx,camy-100,camz+200
    rotate camera xang,yang,zang
    
    update matrix 1
    
    set cursor 0,0:print "USING A MATRIX: PRESS '2' TO EXIT. CURSORS/Q/A/Z/X TO MOVE/LOOK"
    set cursor 50,50:print "fps:";screen fps()
    
until inkey$()="2"

END

Just moving a very basic visible landscape around the screen.

I'm getting around 530fps shifting my 288 polygon round (without regenerating or replacing them), compared to 1770 with an identical textured matrix.

Looks like the matrix is a lot faster, though I'm not yet so sure about the interactivity of the matrix, nor does it look at the constant regeneration of the landscape required. (Mind modification of vertices has to be quicker than deletion and regeneraton of objects in each affected row and column).

You need to be able to register changes to the colours of the individual squares to show the virus spreading. So basically the texture (or at least part of it) has to be re-applied every game cycle to reflect any virus spread. Will have to have a look at that!

Edit:

As an edit (not wanting to double-post)!

I've been thinking about the ingame objects - enemies and such - I guess there's no real need to run through the drawing commands if they're not physically within the 12x12 visible screen.

Could just bypass the draw commands in each cycle and only update their co-ordinate positions in the game world (as opposed to using the hide object command or simply letting them exist outside a 12x12 skybox. If they then fall within a 6/7 square radius around the player they could be added back in as physical objects.

Not sure whether this would save some processing time?

Back to top

Profile PM

Dr Tank

16

Years of Service

User Offline

Joined: 1st Apr 2009

Location: Southampton, UK

Posted: 11th Nov 2010 20:29 Edited at: 12th Nov 2010 17:29

Link

Virus is a cool game. I had v2000 for playstation and it was very impressive and attractive, but the controls and gameplay were a bit too hard and unforgiving. Zeewolf on the Amiga used the same kind of engine. That was an awesome game!

Your demo looks nice. If you want speed you would be better off using memblocks, but a matrix will do OK.

To get wrapping mechanics, i recommend using dwords for object positions. This way, to get the position of anything relative to the player, you subtract the player's dword co-ordinates from those of the other thing.

To get the landscape working fast, a matrix isn't ideal because when you update a line it can slow down, but I think for something like 12x12 it won't really be a problem. You don't want to be repositioning the matrix each frame though. Centre the matrix about the origin and don't move it. Let the player model stray from the origin horizontally (it can move up or down), within a grid square. Once it goes out of the grid square, you move it by a grid square back into the square around the origin, and shift the matrix, updating the new edge from the map.

You could get the sharp cutoff and hide the jerky matrix update by making an inverted black box centred on the player.

I should really be doing other things but I might make an example of this!

Back to top

Profile PM

Dr Tank

16

Years of Service

User Offline

Joined: 1st Apr 2009

Location: Southampton, UK

Posted: 12th Nov 2010 04:08 Edited at: 12th Nov 2010 17:23

Link

SKIP TO NEXT POST. SORRY.

Back to top

Profile PM

Dr Tank

16

Years of Service

User Offline

Joined: 1st Apr 2009

Location: Southampton, UK

Posted: 12th Nov 2010 17:04 Edited at: 12th Nov 2010 17:28

Link

Check this out. No media required. Mouse to tilt, mouseclick to thrust. Next up: tank and map, but I should leave that for a bit later.

`PRESS SPACE TO:
`on LHS of screen, draw objects in dword space.
`on RHS, draw them with positions relative to "player" position
`check that player position loops around right.

sync on

sync rate 60:skipsyncmode=0:set display mode desktop width(),desktop height(),32,1  `STANDARD MODE
`sync rate 30:skipsyncmode=1:set display mode 848,480,32,1   `FOR YOUTUBE VID CAPTURE

autocam off
hide mouse
backdrop on:color backdrop 0
set camera aspect 1.66667

dim thing_posx(100) as dword
dim thing_posz(100) as dword
dim thing_color(100) as dword

for t=1 to 100
   thing_posx(t)=rnd(255)<<24 `256=2^8 , 8+24=32
   thing_posz(t)=rnd(255)<<24
   `thing_color(t)=0xFF000000 OR rgb(rnd(255),rnd(255),rnd(255))
   thing_color(t)=rgb(rnd(255),rnd(255),rnd(255))
next t
thing_color(0)=0xFFFFFF00  `make sure "player" is visible!

`now add terrain array (ground heights)
dim map_height(1023,1023)  `whole map is 1024 square
dim map_tile(1023,1023) as byte  `only need 4 values
for a=0 to 1023
for b=0 to 1023
   `map_height(a,b)=rnd(255)   `used rnd(255) so can easily get colour out if want to draw heightmap
   map_height(a,b)=0.3* (rnd(50) +100*cos(50*a) +50*cos(40*a +50*b))
   map_tile(a,b)=1+rnd(3)  `tiles are numbered from 1-4

map_tile(a,b)=1+rnd(2)  `no red
next b
next a

`make a square "launchpad", virus style.
for a=0 to 7:for b=0 to 7:    map_tile(a,b)=2:        next b:next a
for a=1 to 7:for b=1 to 7:    map_height(a,b)=100.0:  next b:next a

mat_divs=13 `13 squares - means that after cropping with box, 12x12 will be visible
mat_square_size=1<<22      `2^32 / 2^10, since whole world is dword (2^32) and divided into 1024x1024 squares.

subtract_factor=6*mat_square_size    `(matrix size - mat square size)/2  =`6*mat square size
   `subtract factor is taken from player position in order to find where from map array to take beginning corner of matrix from.

mat_view_size#=1000.0
conversion_factor#=mat_view_size#/(mat_square_size*12)   `to convert from dword positions to float for positioning in DBP
                                                         `"real world" and rendering

mat_actual_size#=mat_view_size#*(13.0/12.0)
make matrix 1,mat_actual_size#,mat_actual_size#,13,13
`position matrix centrally.
position matrix 1,-0.5*mat_actual_size#,0.0,-0.5*mat_actual_size#

`load image "test2.bmp",1:prepare matrix texture 1,1,1,1

draw_mat_tex() `for no media
`load image "test3a.bmp",1
prepare matrix texture 1,1,2,2  `2 by 2 mat tex.
`set matrix trim 1,0.01,0.01   `prevent tex bleeding due to filtering
set matrix texture 1,2,0   `no mipmap. stops adjacent matrix tiles (on tile map) bleeding into eachother
                           `downside is that lines look ugly
set matrix 1,0,1,0,0,0,0,0

`position camera above it so can see it. will be repositioning camera every frame anyway.
`position camera 0,1000,0:point camera 0,0,0
`fill mat with info to check it's viewable
for a=0 to 13
for b=0 to 13
   set matrix height 1,a,b,map_height(a,b)
next b
next a
update matrix 1

`box object to disguise edges moving
make object box 100,mat_view_size#,-10.0*mat_view_size#,mat_view_size#
`single_pixel_image(100,50,0,0,200)
single_pixel_image(100,0,0,0,255)
texture object 100,100
set object 100,1,3,1,0,0,0,0

`player (red ball on ground)
make object sphere 1,20
single_pixel_image(2,255,0,0,255)
texture object 1,2

`make some other objects positioned near to the player.
single_pixel_image(101,100,100,100,255)
for t=1 to 20
   thing_posx(t)=rnd(10*mat_square_size) + 10*mat_square_size
   thing_posz(t)=rnd(10*mat_square_size)
   `make object box 50+t,10,100,10
   make object sphere 50+t,100
   offset limb 50+t,0,0,50,0
   texture object 50+t,101
next t

`make a skyscraper
t=20
thing_posx(t)=15*mat_square_size
thing_posz(t)=12*mat_square_size
delete object 50+t
wide#=4.0*mat_square_size*conversion_factor#
make object box 50+t,wide#,500,wide#
offset limb 50+t,0,0,200,0
texture object 50+t,101

`make a "virus" style ship object!
make object box 200,50,20,80

`ADD HELICOPTER BLADES AS A LIMB!
make object box 201,10,2,150
make mesh from object 201,201
add limb 201,1,201
delete mesh 201
rotate limb 201,1,0,90,0
make mesh from object 201,201
delete object 201

add limb 200,1,201
delete mesh 201
offset limb 200,1,0,25,0

speedx#=0.0
speedz#=0.0
speedy#=0.0
hi#=0.0

do

if keystate(35):helimode=1:totalthr#=thr# * defaultthrust#:endif `h for heli
                                          `added line to set thrust is not really necessary.
                                          `stops heli crashing when switch to heli mode.
if keystate(31):helimode=0:endif `s for ship
if helimode
turnsmooth#=50.0
defaultthrust#=0.35  `should make this vary - increase when get close to ground => auto terrain following
clickthrust#=0.5
thrustsmooth#=50.0
pointsmooth#=10.0
show limb 200,1      `show helicopter blades
text 0,100,"HELICOPTER MODE (press S for spaceship)"
else
turnsmooth#=10.0
defaultthrust#=0.0
clickthrust#=1.0
thrustsmooth#=1.0
pointsmooth#=1.0
hide limb 200,1
text 0,100,"SPACESHIP MODE (press H for helicopter)"
endif
`text 0,100,str$(helimode)
text 0,120,"THRUST="+str$(totalthr#)

`MOUSE TO TILT SHIP  `t denotes target (am adding smoothing to get mx,mz from these)
tmx#=tmx#+mousemovex()
tmz#=tmz#-mousemovey()

msq#=tmx#*tmx#+tmz#*tmz#
m#=sqrt(msq#)
if m#>100.0
   tmx#=(tmx#/m#)*100.0
   tmz#=(tmz#/m#)*100.0
endif

mx#=curvevalue(tmx#,mx#,pointsmooth#)
mz#=curvevalue(tmz#,mz#,pointsmooth#)
`get length of this vector
msq#=mx#*mx#+mz#*mz#
m#=sqrt(msq#)

`draw circle with cursor in
circle 50,50,48
dot 50+(50.0/100.0)*mx#, 50-(50.0/100.0)*mz#
dot 50+(50.0/100.0)*tmx#, 50-(50.0/100.0)*tmz# ,0xFFFF0000  `red dot for target

ya#=atanfull(mx#,mz#)
rotate object 200,m#,ya#,0.0

`want to 1st rotate to get "spin"
                                          `then rotate to tilt to thrust angle (from horizontal)
                                          `then rotate to "point" in thrust direction (viewed from above)

`for obj on ground this is
                                          `1st "spin"
                                          `then ground slope elevation
                                          `then slope direction.

`this works!!
tu#=curveangle(ya#,tu#,turnsmooth#)
rotate limb 200,0,0,wrapvalue(tu#-ya#),0

`helicopter blades
br#=wrapvalue(br#+10.0) `blade rotation
rotate limb 200,1,0,wrapvalue(br#-ya#),0

`movespeed=1<<23      `bitshift<< makes bigger! (this number can be anything)
movespeed=1<<18
inc thing_posx(0), -movespeed*(leftkey()-rightkey())
inc thing_posz(0), movespeed*(upkey()-downkey())

mc=mouseclick()
thr#=2000.0
`speedx#=0.95*speedx#+thr#*mx#*mc `small angle approximation!
`speedz#=0.95*speedz#+thr#*mz#*mc

targetthrust#=thr# * ( clickthrust#*mc + defaultthrust#)
totalthr#=curvevalue( targetthrust# , totalthr# , thrustsmooth# )
speedx#=0.95*speedx#+ totalthr# *mx#*(sin(m#)/m#)*(180.0/3.14) `NOTE THAT CAN INCORPORATE (180/PI) INTO THRUST CONSTANT
speedz#=0.95*speedz#+ totalthr# *mz#*(sin(m#)/m#)*(180.0/3.14) `FOR FEWER CALCULATIONS. ALSO SIN NEED ONLY CALC ONCE.
inc thing_posx(0),speedx#
inc thing_posz(0),speedz#

`speedy#=0.95*speedy# + conversion_factor#*thr#*mc*(180.0/3.14) - 1.0  `should use proper trig! last part is gravity
speedy#=0.95*speedy# + conversion_factor#*totalthr# *cos(m#)*(180.0/3.14) - 1.0
inc hi#,speedy#

pgridx=thing_posx(0)>>22
pgridz=thing_posz(0)>>22
`gridx=(thing_posx(0)-subtract_factor)>>22 `not player grid, but grid where want to start reading landscape info to matrix
`gridz=(thing_posz(0)-subtract_factor)>>22
   `can also achieve this by using (playergrid-6) &&1023
gridx=(pgridx-6)&&1023
gridz=(pgridz-6)&&1023

`using bitshift to right 22, grid goes from 0-1023.
                        `1024=2^10     22+10=32 (bits in a dword!)

`should only update when grid square changes.
`after that maybe use shifting- maybe faster.
if last_gridx<>gridx or last_gridz<>gridz
for a=0 to 13
for b=0 to 13
   set matrix height 1,a,b,map_height((a+gridx)&&1023,(b+gridz)&&1023)
next b
next a

for a=0 to 12
for b=0 to 12
   set matrix tile 1,a,b,map_tile((a+gridx)&&1023,(b+gridz)&&1023)
next b
next a

update matrix 1
last_gridx=gridx
last_gridz=gridz
endif
`POSITION CAMERA USING "REMAINDER"
`cx=-2097152+ ( (thing_posx(0)-subtract_factor) && 4194303 )       `2^22 -1 . =0x4FFFFF ?!
`cz=-2097152+ ( (thing_posz(0)-subtract_factor) && 4194303 )
cx=-2097152+ ( thing_posx(0) && 4194303 )       `dur! subtract factor && ... =0
cz=-2097152+ ( thing_posz(0) && 4194303 )

camx#=conversion_factor#*cx           `bit lame that are getting +ve and -ve values. perhaps should have mat corner at origin.
camz#=conversion_factor#*cz
`position camera camx#,1000,camz#-400:point camera camx#,0,camz#  `down looking. with this no need for clip plane
position object 100,camx#,0,camz#

position object 1, camx#,ground_height(thing_posx(0),thing_posz(0) ),camz#
`position object 200, camx#,100,camz#
gh#=50.0+ground_height(thing_posx(0),thing_posz(0) )
if hi#<gh#:hi#=gh#:speedy#=0.0:endif   `really should be some other speed if moving horizontally..
position object 200, camx#,hi#,camz#

position camera camx#,hi#,camz#-995:point camera camx#,hi#,camz#  `horiz looking. AT PLAYER

set camera clip 0,1,0,0,camz#-0.5*mat_view_size#,0,0,1

`POSITION OTHER OBJECTS! should decide whether to show (are on visible matrix)
`do that later.
for t=1 to 20
dx=thing_posx(t)-thing_posx(0)
dz=thing_posz(t)-thing_posz(0)
`tx#=(conversion_factor#*dx) +camx#
`tz#=(conversion_factor#*dz) +camz#
tx#=conversion_factor#*(dx+cx) `equivalent to above
tz#=conversion_factor#*(dz+cz)
position object 50+t,tx#,ground_height(thing_posx(t),thing_posz(t) ),tz#
next t

text 0,140,"DWORD CO-ORDS="+str$(thing_posx(0))+","+str$(thing_posz(0))
text 0,150,"GRID CO-ORDS="+str$(gridx)+","+str$(gridz)

text 0,170,str$(screen fps())+" FPS"
`text 100,20,str$(conversion_factor#)

`OLD TEST THING ===========================================
IF SPACEKEY()
`DRAW DOTS TO SCREEN
box 0,50,256,50+256,0xFF000080,0xFF000080,0xFF000080,0xFF000080
for t=0 to 10
   spx=thing_posx(t)>>24   `gets 0-255 (2^8)
   spz=50+(thing_posz(t)>>24)
   dot spx,spz,thing_color(t)
next y

`NOW DRAW WITH POSITIONS RELATIVE TO PLAYER!
box 300,50,300+256,50+256,0xFF000080,0xFF000080,0xFF000080,0xFF000080
for t=0 to 10
   REMSTART
   spx=300+((thing_posx(t)-thing_posx(0))>>24)   `gets 0-255 (2^8)
   spz=50+((thing_posz(t)-thing_posz(0))>>24)
   REMEND
   `put player in middle
   spx=300+((thing_posx(t)-thing_posx(0)-(1<<31))>>24)   `gets 0-255 (2^8)
   spz=50+((thing_posz(t)-thing_posz(0)-(1<<31))>>24)
   dot spx,spz,thing_color(t)
next y
ENDIF
`============================================================

if skipsyncmode
   skipsync=1-skipsync
   if skipsync then sync
else
   sync
endif

loop

end

function ground_height(x as dword, z as dword)
xg=x>>22
zg=z>>22
xgp=(xg+1)&&1023
zgp=(zg+1)&&1023
rx=x && 4194303
rz=z && 4194303
fx#=rx / (1.0*4194304)
fz#=rz / (1.0*4194304)

`text 100,100,str$(fx#)+","+str$(fz#)

height#=(map_height(xg,zg)*(1.0-fx#)*(1.0-fz#) + map_height(xgp,zg)*fx#*(1.0-fz#) +map_height(xg,zgp)*(1.0-fx#)*fz# +map_height(xgp,zgp)*fx#*fz#)
`^^ simplified version : mat square is treated as surface formed by straight lines in x, and z direction when viewed from above,
`connecting the square polygon grid. that there are actually 2 flat triangles is ignored.

endfunction height#

function single_pixel_image(imagenum,red,green,blue,alpha)
#constant temp_memblocknum 1
   make memblock temp_memblocknum,16
   write memblock dword temp_memblocknum,0,1
   write memblock dword temp_memblocknum,4,1
   write memblock dword temp_memblocknum,8,32
   write memblock dword temp_memblocknum,12,rgba(red,green,blue,alpha)
   make image from memblock imagenum,temp_memblocknum
   delete memblock temp_memblocknum
endfunction

`RGBA function by Aaron Miller
function rgba(r,g,b,a)
   c = (a and 0xff) << 24 or ((r and 0xff) << 16) or ((g and 0xff) << 8) or (b and 0xff)
endfunction c

`FOR NO MEDIA
function draw_mat_tex()
   create bitmap 1,256,256
   box 0,0,128,128,0xFFDFDFDF,0xFFFFFFFF,0xFFFFFFFF,0xFFEFEFEF
   box 0,128,128,256,0xFF808080,0xFF808080,0xFF707070,0xFF808080
   box 128,0,256,128,0xFF484848,0xFF606060,0xFF505050,0xFF606060
   box 128,128,256,256,0xFFFF4040,0xFFFF4040,0xFFFF4040,0xFFFF4040   `red tile. not currently used.
      `graduated boxes. means can see seam between tiles even if same type
      `should play with graduations for best effect. should i have opposite corners same colour?
      `should all corners be different?

`lines
   ink 0xFF606060,0
   w=0   `width   `CURRENTLY LINES SWITCHED OFF
   box 0,0,w,256
   box 0,0,256,w
   box 0,128-w,256,128+w
   box 128-w,0,128+w,256
   box 0,256-w,256,256
   box 256-w,0,256,256
   ink 0xFFFFFFFF,0

get image 1,0,0,256,256
   `save image "testx.bmp",1
   delete bitmap 1
endfunction

+ Code Snippet


`PRESS SPACE TO:
`on LHS of screen, draw objects in dword space.
`on RHS, draw them with positions relative to "player" position
`check that player position loops around right.


sync on

sync rate 60:skipsyncmode=0:set display mode desktop width(),desktop height(),32,1  `STANDARD MODE
`sync rate 30:skipsyncmode=1:set display mode 848,480,32,1   `FOR YOUTUBE VID CAPTURE

autocam off
hide mouse
backdrop on:color backdrop 0
set camera aspect 1.66667

dim thing_posx(100) as dword
dim thing_posz(100) as dword
dim thing_color(100) as dword

for t=1 to 100
   thing_posx(t)=rnd(255)<<24 `256=2^8 , 8+24=32
   thing_posz(t)=rnd(255)<<24
   `thing_color(t)=0xFF000000 OR rgb(rnd(255),rnd(255),rnd(255))
   thing_color(t)=rgb(rnd(255),rnd(255),rnd(255))
next t
thing_color(0)=0xFFFFFF00  `make sure "player" is visible!

`now add terrain array (ground heights)
dim map_height(1023,1023)  `whole map is 1024 square
dim map_tile(1023,1023) as byte  `only need 4 values
for a=0 to 1023
for b=0 to 1023
   `map_height(a,b)=rnd(255)   `used rnd(255) so can easily get colour out if want to draw heightmap
   map_height(a,b)=0.3* (rnd(50) +100*cos(50*a) +50*cos(40*a +50*b))
   map_tile(a,b)=1+rnd(3)  `tiles are numbered from 1-4

   map_tile(a,b)=1+rnd(2)  `no red
next b
next a

`make a square "launchpad", virus style.
for a=0 to 7:for b=0 to 7:    map_tile(a,b)=2:        next b:next a
for a=1 to 7:for b=1 to 7:    map_height(a,b)=100.0:  next b:next a

mat_divs=13 `13 squares - means that after cropping with box, 12x12 will be visible
mat_square_size=1<<22      `2^32 / 2^10, since whole world is dword (2^32) and divided into 1024x1024 squares.

subtract_factor=6*mat_square_size    `(matrix size - mat square size)/2  =`6*mat square size
   `subtract factor is taken from player position in order to find where from map array to take beginning corner of matrix from.

mat_view_size#=1000.0
conversion_factor#=mat_view_size#/(mat_square_size*12)   `to convert from dword positions to float for positioning in DBP
                                                         `"real world" and rendering

mat_actual_size#=mat_view_size#*(13.0/12.0)
make matrix 1,mat_actual_size#,mat_actual_size#,13,13
`position matrix centrally.
position matrix 1,-0.5*mat_actual_size#,0.0,-0.5*mat_actual_size#

`load image "test2.bmp",1:prepare matrix texture 1,1,1,1

draw_mat_tex() `for no media
`load image "test3a.bmp",1
prepare matrix texture 1,1,2,2  `2 by 2 mat tex.
`set matrix trim 1,0.01,0.01   `prevent tex bleeding due to filtering
set matrix texture 1,2,0   `no mipmap. stops adjacent matrix tiles (on tile map) bleeding into eachother
                           `downside is that lines look ugly
set matrix 1,0,1,0,0,0,0,0

`position camera above it so can see it. will be repositioning camera every frame anyway.
`position camera 0,1000,0:point camera 0,0,0
`fill mat with info to check it's viewable
for a=0 to 13
for b=0 to 13
   set matrix height 1,a,b,map_height(a,b)
next b
next a
update matrix 1

`box object to disguise edges moving
make object box 100,mat_view_size#,-10.0*mat_view_size#,mat_view_size#
`single_pixel_image(100,50,0,0,200)
single_pixel_image(100,0,0,0,255)
texture object 100,100
set object 100,1,3,1,0,0,0,0


`player (red ball on ground)
make object sphere 1,20
single_pixel_image(2,255,0,0,255)
texture object 1,2

`make some other objects positioned near to the player.
single_pixel_image(101,100,100,100,255)
for t=1 to 20
   thing_posx(t)=rnd(10*mat_square_size) + 10*mat_square_size
   thing_posz(t)=rnd(10*mat_square_size)
   `make object box 50+t,10,100,10
   make object sphere 50+t,100
   offset limb 50+t,0,0,50,0
   texture object 50+t,101
next t

`make a skyscraper
t=20
thing_posx(t)=15*mat_square_size
thing_posz(t)=12*mat_square_size
delete object 50+t
wide#=4.0*mat_square_size*conversion_factor#
make object box 50+t,wide#,500,wide#
offset limb 50+t,0,0,200,0
texture object 50+t,101


`make a "virus" style ship object!
make object box 200,50,20,80


`ADD HELICOPTER BLADES AS A LIMB!
make object box 201,10,2,150
make mesh from object 201,201
add limb 201,1,201
delete mesh 201
rotate limb 201,1,0,90,0
make mesh from object 201,201
delete object 201

add limb 200,1,201
delete mesh 201
offset limb 200,1,0,25,0


speedx#=0.0
speedz#=0.0
speedy#=0.0
hi#=0.0

do

if keystate(35):helimode=1:totalthr#=thr# * defaultthrust#:endif `h for heli
                                          `added line to set thrust is not really necessary.
                                          `stops heli crashing when switch to heli mode.
if keystate(31):helimode=0:endif `s for ship
if helimode
turnsmooth#=50.0
defaultthrust#=0.35  `should make this vary - increase when get close to ground => auto terrain following
clickthrust#=0.5
thrustsmooth#=50.0
pointsmooth#=10.0
show limb 200,1      `show helicopter blades
text 0,100,"HELICOPTER MODE (press S for spaceship)"
else
turnsmooth#=10.0
defaultthrust#=0.0
clickthrust#=1.0
thrustsmooth#=1.0
pointsmooth#=1.0
hide limb 200,1
text 0,100,"SPACESHIP MODE (press H for helicopter)"
endif
`text 0,100,str$(helimode)
text 0,120,"THRUST="+str$(totalthr#)


`MOUSE TO TILT SHIP  `t denotes target (am adding smoothing to get mx,mz from these)
tmx#=tmx#+mousemovex()
tmz#=tmz#-mousemovey()

msq#=tmx#*tmx#+tmz#*tmz#
m#=sqrt(msq#)
if m#>100.0
   tmx#=(tmx#/m#)*100.0
   tmz#=(tmz#/m#)*100.0
endif

mx#=curvevalue(tmx#,mx#,pointsmooth#)
mz#=curvevalue(tmz#,mz#,pointsmooth#)
`get length of this vector
msq#=mx#*mx#+mz#*mz#
m#=sqrt(msq#)


`draw circle with cursor in
circle 50,50,48
dot 50+(50.0/100.0)*mx#, 50-(50.0/100.0)*mz#
dot 50+(50.0/100.0)*tmx#, 50-(50.0/100.0)*tmz# ,0xFFFF0000  `red dot for target


ya#=atanfull(mx#,mz#)
rotate object 200,m#,ya#,0.0

                                          `want to 1st rotate to get "spin"
                                          `then rotate to tilt to thrust angle (from horizontal)
                                          `then rotate to "point" in thrust direction (viewed from above)

                                          `for obj on ground this is
                                          `1st "spin"
                                          `then ground slope elevation
                                          `then slope direction.


`this works!!
tu#=curveangle(ya#,tu#,turnsmooth#)
rotate limb 200,0,0,wrapvalue(tu#-ya#),0

`helicopter blades
br#=wrapvalue(br#+10.0) `blade rotation
rotate limb 200,1,0,wrapvalue(br#-ya#),0

`movespeed=1<<23      `bitshift<< makes bigger! (this number can be anything)
movespeed=1<<18
inc thing_posx(0), -movespeed*(leftkey()-rightkey())
inc thing_posz(0), movespeed*(upkey()-downkey())

mc=mouseclick()
thr#=2000.0
`speedx#=0.95*speedx#+thr#*mx#*mc `small angle approximation!
`speedz#=0.95*speedz#+thr#*mz#*mc

targetthrust#=thr# * ( clickthrust#*mc + defaultthrust#)
totalthr#=curvevalue( targetthrust# , totalthr# , thrustsmooth# )
speedx#=0.95*speedx#+ totalthr# *mx#*(sin(m#)/m#)*(180.0/3.14) `NOTE THAT CAN INCORPORATE (180/PI) INTO THRUST CONSTANT
speedz#=0.95*speedz#+ totalthr# *mz#*(sin(m#)/m#)*(180.0/3.14) `FOR FEWER CALCULATIONS. ALSO SIN NEED ONLY CALC ONCE.
inc thing_posx(0),speedx#
inc thing_posz(0),speedz#

`speedy#=0.95*speedy# + conversion_factor#*thr#*mc*(180.0/3.14) - 1.0  `should use proper trig! last part is gravity
speedy#=0.95*speedy# + conversion_factor#*totalthr# *cos(m#)*(180.0/3.14) - 1.0
inc hi#,speedy#


pgridx=thing_posx(0)>>22
pgridz=thing_posz(0)>>22
`gridx=(thing_posx(0)-subtract_factor)>>22 `not player grid, but grid where want to start reading landscape info to matrix
`gridz=(thing_posz(0)-subtract_factor)>>22
   `can also achieve this by using (playergrid-6) &&1023
gridx=(pgridx-6)&&1023
gridz=(pgridz-6)&&1023

                        `using bitshift to right 22, grid goes from 0-1023.
                        `1024=2^10     22+10=32 (bits in a dword!)


`should only update when grid square changes.
`after that maybe use shifting- maybe faster.
if last_gridx<>gridx or last_gridz<>gridz
for a=0 to 13
for b=0 to 13
   set matrix height 1,a,b,map_height((a+gridx)&&1023,(b+gridz)&&1023)
next b
next a

for a=0 to 12
for b=0 to 12
   set matrix tile 1,a,b,map_tile((a+gridx)&&1023,(b+gridz)&&1023)
next b
next a

update matrix 1
last_gridx=gridx
last_gridz=gridz
endif
`POSITION CAMERA USING "REMAINDER"
`cx=-2097152+ ( (thing_posx(0)-subtract_factor) && 4194303 )       `2^22 -1 . =0x4FFFFF ?!
`cz=-2097152+ ( (thing_posz(0)-subtract_factor) && 4194303 )
cx=-2097152+ ( thing_posx(0) && 4194303 )       `dur! subtract factor && ... =0
cz=-2097152+ ( thing_posz(0) && 4194303 )

camx#=conversion_factor#*cx           `bit lame that are getting +ve and -ve values. perhaps should have mat corner at origin.
camz#=conversion_factor#*cz
`position camera camx#,1000,camz#-400:point camera camx#,0,camz#  `down looking. with this no need for clip plane
position object 100,camx#,0,camz#

position object 1, camx#,ground_height(thing_posx(0),thing_posz(0) ),camz#
`position object 200, camx#,100,camz#
gh#=50.0+ground_height(thing_posx(0),thing_posz(0) )
if hi#<gh#:hi#=gh#:speedy#=0.0:endif   `really should be some other speed if moving horizontally..
position object 200, camx#,hi#,camz#

position camera camx#,hi#,camz#-995:point camera camx#,hi#,camz#  `horiz looking. AT PLAYER

set camera clip 0,1,0,0,camz#-0.5*mat_view_size#,0,0,1

`POSITION OTHER OBJECTS! should decide whether to show (are on visible matrix)
`do that later.
for t=1 to 20
dx=thing_posx(t)-thing_posx(0)
dz=thing_posz(t)-thing_posz(0)
`tx#=(conversion_factor#*dx) +camx#
`tz#=(conversion_factor#*dz) +camz#
tx#=conversion_factor#*(dx+cx) `equivalent to above
tz#=conversion_factor#*(dz+cz)
position object 50+t,tx#,ground_height(thing_posx(t),thing_posz(t) ),tz#
next t

text 0,140,"DWORD CO-ORDS="+str$(thing_posx(0))+","+str$(thing_posz(0))
text 0,150,"GRID CO-ORDS="+str$(gridx)+","+str$(gridz)

text 0,170,str$(screen fps())+" FPS"
`text 100,20,str$(conversion_factor#)

`OLD TEST THING ===========================================
IF SPACEKEY()
`DRAW DOTS TO SCREEN
box 0,50,256,50+256,0xFF000080,0xFF000080,0xFF000080,0xFF000080
for t=0 to 10
   spx=thing_posx(t)>>24   `gets 0-255 (2^8)
   spz=50+(thing_posz(t)>>24)
   dot spx,spz,thing_color(t)
next y

`NOW DRAW WITH POSITIONS RELATIVE TO PLAYER!
box 300,50,300+256,50+256,0xFF000080,0xFF000080,0xFF000080,0xFF000080
for t=0 to 10
   REMSTART
   spx=300+((thing_posx(t)-thing_posx(0))>>24)   `gets 0-255 (2^8)
   spz=50+((thing_posz(t)-thing_posz(0))>>24)
   REMEND
   `put player in middle
   spx=300+((thing_posx(t)-thing_posx(0)-(1<<31))>>24)   `gets 0-255 (2^8)
   spz=50+((thing_posz(t)-thing_posz(0)-(1<<31))>>24)
   dot spx,spz,thing_color(t)
next y
ENDIF
`============================================================


if skipsyncmode
   skipsync=1-skipsync
   if skipsync then sync
else
   sync
endif

loop


end




function ground_height(x as dword, z as dword)
xg=x>>22
zg=z>>22
xgp=(xg+1)&&1023
zgp=(zg+1)&&1023
rx=x && 4194303
rz=z && 4194303
fx#=rx / (1.0*4194304)
fz#=rz / (1.0*4194304)

`text 100,100,str$(fx#)+","+str$(fz#)

height#=(map_height(xg,zg)*(1.0-fx#)*(1.0-fz#) + map_height(xgp,zg)*fx#*(1.0-fz#) +map_height(xg,zgp)*(1.0-fx#)*fz# +map_height(xgp,zgp)*fx#*fz#)
`^^ simplified version : mat square is treated as surface formed by straight lines in x, and z direction when viewed from above,
`connecting the square polygon grid. that there are actually 2 flat triangles is ignored.

endfunction height#


function single_pixel_image(imagenum,red,green,blue,alpha)
#constant temp_memblocknum 1
   make memblock temp_memblocknum,16
   write memblock dword temp_memblocknum,0,1
   write memblock dword temp_memblocknum,4,1
   write memblock dword temp_memblocknum,8,32
   write memblock dword temp_memblocknum,12,rgba(red,green,blue,alpha)
   make image from memblock imagenum,temp_memblocknum
   delete memblock temp_memblocknum
endfunction

`RGBA function by Aaron Miller
function rgba(r,g,b,a)
   c = (a and 0xff) << 24 or ((r and 0xff) << 16) or ((g and 0xff) << 8) or (b and 0xff)
endfunction c

`FOR NO MEDIA
function draw_mat_tex()
   create bitmap 1,256,256
   box 0,0,128,128,0xFFDFDFDF,0xFFFFFFFF,0xFFFFFFFF,0xFFEFEFEF
   box 0,128,128,256,0xFF808080,0xFF808080,0xFF707070,0xFF808080
   box 128,0,256,128,0xFF484848,0xFF606060,0xFF505050,0xFF606060
   box 128,128,256,256,0xFFFF4040,0xFFFF4040,0xFFFF4040,0xFFFF4040   `red tile. not currently used.
      `graduated boxes. means can see seam between tiles even if same type
      `should play with graduations for best effect. should i have opposite corners same colour?
      `should all corners be different?

   `lines
   ink 0xFF606060,0
   w=0   `width   `CURRENTLY LINES SWITCHED OFF
   box 0,0,w,256
   box 0,0,256,w
   box 0,128-w,256,128+w
   box 128-w,0,128+w,256
   box 0,256-w,256,256
   box 256-w,0,256,256
   ink 0xFFFFFFFF,0

   get image 1,0,0,256,256
   `save image "testx.bmp",1
   delete bitmap 1
endfunction

Quote: "You need to be able to register changes to the colours of the individual squares to show the virus spreading. So basically the texture (or at least part of it) has to be re-applied every game cycle to reflect any virus spread. Will have to have a look at that!"

That's very doable. You just change the matrix tiles and update the matrix. You wouldn't need to do it every frame. You could update every 10 frames or so, or when virus "bombs" or whatever are dropped.

Back to top

Profile PM

Dr Tank

16

Years of Service

User Offline

Joined: 1st Apr 2009

Location: Southampton, UK

Posted: 14th Nov 2010 02:19 Edited at: 14th Nov 2010 02:21

Link

I've been playing a bit more with this. Here's a vid showing the camera in action. More info in the vid description.

Here's a retro remake of Virus made in Blitz Basic. It's pretty awesome. Check it out.

One thing that I forgot about Virus was that the controls were horrible for a non expert, with the mouse moving left/right to turn the ship, and up/down to pitch. My thing uses a system like in Zeewolf which I find more intuitive, but limits the pitch of your vehicle.

Do you guys actually like the original control system from Zarch?

Back to top

Profile PM

Sorry your browser is not supported!

Game Design Theory / Lander / Zarch / Virus Style Landscape Generation and Movement