Sorry your browser is not supported!

d ^ 2 = (X1-X3)^2 + (Y1-Y3)^2

d ^ 2 - (X1 - X3) ^ 2 = (Y1 - Y3) ^ 2
then
sqrt[(d ^ 2 - (X1 - X3) ^ 2] = sqrt[(Y1 - Y3) ^ 2]
then
d - (X1 - X3) = (Y1 - Y3)
then ?

d ^ 2 = (X1-X)^2 + (Y1-Y)^2

d ^ 2 - (X1 - X) ^ 2 = (Y1 - Y) ^ 2
then
sqrt[(d ^ 2 - (X1 - X) ^ 2] = sqrt[(Y1 - Y) ^ 2]
then
d - (X1 - X) = (Y1 - Y)
then 
d - (X1 - X) - Y1 = (Y1 - Y) - Y1
then
d - (X1 - X) - Y1 = - Y
then
-1*(d - (X1 - X) - Y1) = Y

`App setup
set display mode 1024,512,32
set window on

`Variables used
`In the points variable; the first index is the number of the point, the second index holds x or y.
dim Points(4,1) as integer
dim Distances(3) as float
dim Max(1) as integer
dim Min(3) as integer
`Set variables
Max(0)=0 : Max(1)=0 : Min(0)=512 : Min(1)=512 : xspread=2 : yspread=3

do
   REM PROBLEM SET-UP
   `Make triangle with a minimum spread of points
   REMSTART
      As I don't know how to check whether or not a point is within the bounds of a triangle
      what I do here is make it so that the 3 points defining the triangle have a minimum
      seperation on the x and y axes (xspread and yspread respectively this gives a greater
      chance of a randomly selected point 4 being within the bounds of the triangle.
   REMEND
   repeat
      `Reset the spread values
      Min(xspread)=512 : Min(yspread)=512
      `Plot points
      for Pnt = 1 to 3
         for coord = 0 to 1
            Points(Pnt,0) = rnd(512)
            Points(Pnt,1) = rnd(512)
            if Max(coord) < Points(Pnt,coord) then Max(coord) = Points(Pnt,coord)
            if Min(coord) > Points(Pnt,coord) then Min(coord) = Points(Pnt,coord)
         next coord
      next Pnt
      `Check the point's spread
      for Pnt1 = 1 to 3
         for Pnt2 = 1 to 3
            if Pnt1<>Pnt2
               x1 = Points(Pnt1,0)
               x2 = Points(Pnt2,0)
               if Min(xspread)>abs(x2-x1) then Min(xspread) = abs(x2-x1)

               y1 = Points(Pnt1,1)
               y2 = Points(Pnt2,1)
               if Min(yspread)>abs(y2-y1) then Min(yspread) = abs(y2-y1)
            endif
         next Pnt2
      next Pnt1
   until Min(xspread)>128 and Min(yspread)>128

   `Clear the screen and draw the points
   cls
   ink RGB(240,240,240),0
   for Pnt=1 to 3
      circle Points(Pnt,0),Points(Pnt,1),2
      text Points(Pnt,0)+10,Points(Pnt,1)-10,"Point " + STR$(Pnt)
   next Pnt

   REMSTART
      The max and min variables used here hold the value of the maximum and
      minimum x and y values of any of the 3 points defining the triangle,
      again this helps to get point 4 within the bounds of the triangle
   REMEND
   `Find and draw point 4
   dec Max(0),10 : dec Max(1),10 : inc Min(0),10 : inc Min(1),10
   ink RGB(240,50,50),0
   repeat
      Points(4,0) = rnd(512)
      Points(4,1) = rnd(512)
   until Points(4,0)<Max(0) and Points(4,1)<Max(1) and Points(4,0)>Min(0) and Points(4,1)>Min(1)
   circle Points(4,0),Points(4,1),2

   `Draw lines between all the points
   ink RGB(50,50,240),0
   line points(1,0),points(1,1),points(2,0),points(2,1)
   line points(2,0),points(2,1),points(3,0),points(3,1)
   line points(3,0),points(3,1),points(1,0),points(1,1)
   ink RGB(240,50,50),0
   for Pnt=1 to 3
      line Points(Pnt,0),Points(Pnt,1),Points(4,0),Points(4,1)
   next Pnt

   REMSTART
      These angles and distances were given in the problem:
         gamma (for each point)
         distance from each point to every other point
      to find gamma in this example we must use the position of point 4,
      which may sound like cheating but is the only way to find the angle
      given in the problem, before solving it.
   REMEND
   `Find known angles and distances:
   ink RGB(240,240,50),1
   for Pnt = 1 to 3
      dx# = Points(4,0) - Points(Pnt,0)
      dy# = Points(4,1) - Points(Pnt,1)
      Distances(Pnt) = sqrt(dx#^2 + dy#^2)
      circle Points(Pnt,0),Points(Pnt,1),Distances(Pnt)
   next Pnt

   `Sin(Beta) = y/h for points 1 and 4
   h# = sqrt( (Points(4,0) - Points(1,0))^2 + (Points(4,1) - Points(1,1))^2 )
   x# = Points(4,0)-Points(1,0)
   y# = Points(4,1)-Points(1,1)

   if x#>0
      if y#>0
         beta# =  wrapvalue( 360 - asin( y#/h#) )
      else
         beta# =  wrapvalue( asin( y#/h#) )
      endif
   else
      if y#>0
         beta# =  wrapvalue( 180 + asin( y#/h#) )
      else
         beta# =  wrapvalue( 180 - asin( y#/h#) )
      endif
   endif

   REM SOLUTION
   `Sin(Alpha) = y/h for points 1 and 2
   h# = sqrt( (Points(2,0) - Points(1,0))^2 + (Points(2,1) - Points(1,1))^2 )
   x# = Points(2,0)-Points(1,0)
   y# = Points(2,1)-Points(1,1)

   if x#>0
      if y#>0
         alpha#  = wrapvalue( 360 -asin( y#/h#))
      else
         alpha# = wrapvalue( asin( y#/h#))
      endif
   else
      if y#>0
         alpha#  = wrapvalue( 180 +  asin( y#/h#) )
      else
         alpha# = wrapvalue(  180 - asin( y#/h#)) `was 180 +
      endif
   endif

   ink RGB(50,240,50),0
   for ang = 1 to alpha#
      x = points(1,0) + 5*cos(ang)
      y = points(1,1) + 5*sin(ang)
      dot x,y
   next ang

   for ang = 1 to beta#
      x = points(1,0) + 25*cos(ang)
      y = points(1,1) + 25*sin(ang)
      dot x,y
   next ang

   gamma# = wrapvalue( alpha# - beta# )

   REMSTART
      Gamma is the given angle in the problem, however both beta and alpha
      are needed to find it in the first place. If the angle gamma is given
      only alpha needs to be calculated (using the coordinates of the 3 points
      given) then added to gamma to give beta:
      beta = alpha + gamma
      Beta is then plugged into the circle equations:
      x = a + r * cos( beta )
      y = b + r * sin( beta )
      where a and b are the x,y cordinates of point 1 (as this is the point
      from which the angle beta has been calculated) and r is the distance
      from point 1 to point 4 given in the problem.
   REMEND

   `Calculate the values of point 4
   Point4X# = Points(1,0)+Distances(1)*cos(beta#)
   Point4Y# = Points(1,1)+Distances(1)*sin(beta#)

   `Print the results to the screen
   ink RGB(255,255,255),0
   print "Known values:"
   for Pnt=1 to 3
      print "Point ",Pnt," is at (",Points(Pnt,0),",",Points(Pnt,1),")"
   next Pnt
   print ""
   print "The angle between the line of the points 1 & 2 and the horizontal: ", alpha#
   print ""
   print "The angle between the line of the points 1 & 4 and the horizontal is: ", beta#
   print "This is the angle nessasary to find the coordinates of point 4 using circle equations."
   print ""
   print "The true x value of point 4 is: ",Points(4,0)
   print "The true y value of point 4 is: ",Points(4,1)
   print "The calculated x value of point 4 is: ",Point4X#
   print "The calculated y value of point 4 is: ",Point4Y#

   wait key
loop

Original: 
d^2 = (x1^2 - x^2) + (y1^2 - y^2)
f^2 = (x3^2 - x^2) + (y3^2 - y^2)

To Find (X, Y):
` Point 1 to Point (X, Y)  - Use Length d
-1 * sqrt(d^2 - (x1^2 - x^2) - y1^2) = dy
-1 * sqrt(d^2 - (y1^2 - y^2) - x1^2) = dx

` Point 3 to Point (X, Y) - Use Length f
-1 * sqrt(f^2 - (x3^2 - x^2) - y3^2) = fy
-1 * sqrt(f^2 - (y3^2 - y^2) - x3^2) = fx

Need to clean this up....

Dist = ([(x1^2 - x^2) + (y1^2 - y^2)] - [(x3^2 - x^2) + (y3^2 - y^2)])

then:

Dist = [x1^2 + y1^2] - [x3^2 + y3^2]

c^2 = (x1^2 - x3^2) + (y1^2 - y3^2)

c^2 = (x1^2 - x3^2) + (y1^2 - y3^2)
[x1^2 + y1^2] - [x3^2 + y3^2]

[x1^2 + y1^2] - [x3^2 + y3^2]

d^2 = (x1 - x)^2 + (y1 - y)^2

(a - b)^2 = a^2 - 2*a*b + b^2

//Fun with triangles, by Mike Shihrer, aka Visigoth
//If you find this code useful, you may use it with no restrictions, but a small credit would be nice :)

set display mode 1024,768,32
//for ui
global side_inc#
global rotation_inc#
global hide_flag
hide_flag = 1

//adjust these if your keypress draw lines too fast or slow
//and if rotating triangle is too fast or slow

side_inc# = .05
rotation_inc# = .15

//variables for the internal triangle solution
global angA#
global angB#
global angC#
global sideA#
global sideB#
global sideC#
global xA#
global yA#
global xB#
global yB#
global xC#
global yC#
global r_ang#
//init internal side lengths
sideA# = 160.0
sideB# = 240.0
sideC# = 360.0

//variables for external triangle
global e_angA#
global e_angB#
global e_angC#
global e_sideA#
global e_sideB#
global e_sideC#
global e_xA#
global e_yA#
global e_xB#
global e_yB#
global e_xC#
global e_yC#

//init external side lengths
//assume fixed, except side c, since same as internal side c
e_sideA# = 240.0
e_sideB# = 480.0
e_sideC# = sideC#


//variables for offsetting the triangle on the display
global oX#
global oY#

oX# = 100.0
oY# = 100.0

//since we know all the sides, this is all we need
solve_triangle_sss(sideA#,sideB#,sideC#,e_sideA#,e_sideB#,e_sideC#)
get_coordinates(angA#,angB#,angC#,sideA#,sideB#,sideC#,e_angA#,e_angB#,e_angC#,e_sideA#,e_sideB#,e_sideC#)


//////////////////////////////////
do
	cls
	ink rgb(255,255,255)
	plot_triangles(sideA#,sideB#,sideC#)
	print_data()
	key_toggles()
loop
/////////////////////////////////
end


//these 2 functions are all you need to solve a triangle when all three sides are known
//first, you solve and get the angles.
//that is the first function
//second function determines coordinates, based on point A at 0,0
//THE MEAT AND BONES////////////////////////////////////////////////////
function solve_triangle_sss(a#,b#,c#,ea#,eb#,ec#)
	//where c# is the longest side
	//find largest angle first
	//internal triangle
	angC# = acos((a#^2 + b#^2 - c#^2) / (2*a#*b#))
	//find next angle
	angA# = asin((a# * sin(angC#)) / c#)
	//find last angle
	angB# =  180.00 - (angA# + angC#)
	
	//external triangle
	e_angC# = acos((ea#^2 + eb#^2 - ec#^2) / (2*ea#*eb#))
	//find next angle
	e_angA# = asin((ea# * sin(e_angC#)) / ec#)
	//find last angle
	e_angB# =  180.00 - (e_angA# + e_angC#)

endfunction


function get_coordinates(aA#,aB#,aC#,sa#,sb#,sc#,eaA#,eaB#,eaC#,esa#,esb#,esc#)
//where aA#, aB#,aC# are the angles
//where sa#,sb#,sc# are the sides
//angs are opposite sides
//largest side on bottom
//xA,yA, etc are the coordinates
//this diagram will be upside down on the display, but the data is correct
//                       xC,yC
//                        aC#
//                        /\
//                       /  \                                                y0
//                      /    \                                               | 
//                  sb#/      \ sa#                                          |
//                    /        \                                             |
//                   /          \                                            | 
//				aA# /____________\ aB#                                    x0 |---------- x screen width()
//	            xA,yA	  sc#	 xB,yB                                       y screen height
//                                                                           			
//                                                                           
//                                                                           
// xA,yA at 0,0
//
//internal tri
	xA# = 0.0
	yA# = 0.0
	//this would be the "random" point in the middle of the problem
	xC# = sb# * (cos(aA#))
	yC# = sb# * (sin(aA#))

	xB# = sc#
	yB# = 0.0
//external
	e_xA# = 0.0
	e_yA# = 0.0
	
	e_xC# = esb# * (cos(eaA#))
	e_yC# = esb# * (sin(eaA#))

	e_xB# = esc#
	e_yB# = 0.0

//now you can reposition points by offsetting ,rotating, or scaling them 
//see next few functions				
endfunction
/////////////////////////////end MEAT AND BONES///////////////////////////////////////////////
//the rest of these functions show how the data can be used
function plot_triangles(l1#,l2#,l3#)

//if you can solve for 1 triangle, the other two are automatically solved, because the external triangle is known
//keep in mind, 2D screen coordinates are: x positive is to the right, y positive is down, so triangle will be upside down

if hide_flag = 0
//original results
	//external tris
	ink rgb(255,255,255)
	line e_xA#,e_yA#,e_xB#,e_yB#
	line e_xB#,e_yB#,e_xC#,e_yC#
	line e_xC#,e_yC#,e_xA#,e_yA#
	//internal tris
	ink rgb(0,0,255)
	line xA#,yA#,xB#,yB#
	line xB#,yB#,xC#,yC#
	line xC#,yC#,xA#,yA#
	line xc#,yc#,e_xC#,e_yC#
endif

//offset
	//internal
	ink rgb(0,0,255)
	line xA# + oX#,yA# + oY#,xB# + oX#,yB# + oY#
	line xB# + oX#,yB# + oY#,xC# + oX#,yC# + oY#
	line xC# + oX#,yC# + oY#,xA# + oX#,yA# + oY#
	line xC#+ ox#,yC# + oY#,e_xC# + oX#,e_yC# + oY#
	ink rgb(255,0,0)
	
	//external
	ink rgb(255,255,255)
	line e_xA# + oX#,e_yA# + oY#,e_xB# + oX#,e_yB# + oY#
	line e_xB# + oX#,e_yB# + oY#,e_xC# + oX#,e_yC# + oY#
	line e_xC# + oX#,e_yC# + oY#,e_xA# + oX#,e_yA# + oY#
	
	//display
	set cursor xC#+ ox#,yC# + oY#
	print "random point :" , xC#+ ox#,",",yC# + oY#
	
	
//rotate internal triangle around point A
//just for show
if hide_flag = 0
	ink rgb(0,0,255)
	newx1# = cos(r_ang#)
	newy1# = sin(r_ang#)
	newx2# = cos((360.0 + angA#) + r_ang#)
	newy2# = sin((360.0 + angA#) + r_ang#)
	
	line xA# + oX#, yA# + oY#, oX# + (newx1# * l3#), oY#  + (newy1# * l3#)	
	line oX# + (newx1# * l3#), oY#  + (newy1# * l3#),oX# + (newx2# * l2#), oY#  + (newy2# * l2#)
	line oX# + (newx2# * l2#), oY#  + (newy2# * l2#),xA# + oX#,yA# + oY#
	
	set cursor xA# + oX#, yA# + oY#
	ink rgb(255,255,255)
	print "angle :" , r_ang#
	set cursor oX# + (newx1# * l3#),oY#  + (newy1# * l3#)
	print "Point B X :",oX# + (newx1# * l3#),", Point B Y :",oY#  + (newy1# * l3#)
	set cursor oX# + (newx2# * l2#), oY#  + (newy2# * l2#)
	print "Point C X :",oX# + (newx2# * l2#),",Point C Y :", oY#  + (newy2# * l2#)
	
 	inc r_ang#,rotation_inc#
 	if r_ang# > 360.0
 		r_ang# = 0
 	endif
	set cursor 0,0
endif
	
endfunction

function print_data()
	x = screen width() / 2
	y = 0
	set cursor x,y
	ink rgb(0,255,0)
	print "Controls" : inc y,10 : set cursor x,y
	print "keyboard 1,2,3 increase internal sides" : inc y,10 : set cursor x,y
	print "keyboard 4,5,6 decrease internal sides" : inc y,10 : set cursor x,y
	print "keyboard 7,8 increase external sides" : inc y,10 : set cursor x,y
	print "keyboard 9,0 decrease external sides" : inc y,10 : set cursor x,y
	print "h,s hide/show rotating triangle, origin triangle" : inc y,10 : set cursor x,y
	print "q,w inc/dec origin offset X, e,r inc/dec origin offset Y"
	//print "angles : " ,angA#,",",angB#,",",angC# : inc y,10 : set cursor x,y
	//print "point A :" ,xA#,",",yA# : inc y,10 : set cursor x,y
	//print "point B :" ,xB#,",",yB# : inc y,10 : set cursor x,y
	//print "point C :" ,xC#,",",yC# : inc y,10 : set cursor x,y
	//print "side A :" , sideA# : inc y,10 : set cursor x,y
	//print "side B :" , sideB# : inc y,10 : set cursor x,y
	//print "side C :" , sideC# : inc y,10 : set cursor x,y
	//print "r_ang :" , r_ang# : inc y,10 : set cursor x,y
	print scancode()
	set cursor mousex() + 20,mousey() + 20
	print mousex(),",",mousey()
endfunction

function key_toggles()
//keys 1,2,3 make sides A,B,C longer
//keys 4,5,6 make sided A,B,C shorter
//it is possible to have lengths of sides that will not make a triangle, which won't crash anything, you just won't get a triangle
	if keystate(2) = 1
		inc sideA#,side_inc#
		solve_triangle_sss(sideA#,sideB#,sideC#,e_sideA#,e_sideB#,e_sideC#)
		get_coordinates(angA#,angB#,angC#,sideA#,sideB#,sideC#,e_angA#,e_angB#,e_angC#,e_sideA#,e_sideB#,e_sideC#)
	endif
	
	if keystate(3) = 1
		inc sideB#,side_inc#
		solve_triangle_sss(sideA#,sideB#,sideC#,e_sideA#,e_sideB#,e_sideC#)
		get_coordinates(angA#,angB#,angC#,sideA#,sideB#,sideC#,e_angA#,e_angB#,e_angC#,e_sideA#,e_sideB#,e_sideC#)	
	endif 
	
	if keystate(4) = 1
		inc sideC#,side_inc#
		e_sideC# = sideC#
		solve_triangle_sss(sideA#,sideB#,sideC#,e_sideA#,e_sideB#,e_sideC#)
		get_coordinates(angA#,angB#,angC#,sideA#,sideB#,sideC#,e_angA#,e_angB#,e_angC#,e_sideA#,e_sideB#,e_sideC#)
	endif
	
	if keystate(5) = 1
		dec sideA#, side_inc#
		solve_triangle_sss(sideA#,sideB#,sideC#,e_sideA#,e_sideB#,e_sideC#)
		get_coordinates(angA#,angB#,angC#,sideA#,sideB#,sideC#,e_angA#,e_angB#,e_angC#,e_sideA#,e_sideB#,e_sideC#)	
	endif 
	
	if keystate(6) = 1
		dec sideB#, side_inc#
		solve_triangle_sss(sideA#,sideB#,sideC#,e_sideA#,e_sideB#,e_sideC#)
		get_coordinates(angA#,angB#,angC#,sideA#,sideB#,sideC#,e_angA#,e_angB#,e_angC#,e_sideA#,e_sideB#,e_sideC#)
	endif
	
	if keystate(7) = 1
		dec sideC#,side_inc#
		e_sideC# = sideC#
		solve_triangle_sss(sideA#,sideB#,sideC#,e_sideA#,e_sideB#,e_sideC#)
		get_coordinates(angA#,angB#,angC#,sideA#,sideB#,sideC#,e_angA#,e_angB#,e_angC#,e_sideA#,e_sideB#,e_sideC#)	
	endif 
	
	if keystate(8) = 1
		inc e_sideA#, side_inc#
		solve_triangle_sss(sideA#,sideB#,sideC#,e_sideA#,e_sideB#,e_sideC#)
		get_coordinates(angA#,angB#,angC#,sideA#,sideB#,sideC#,e_angA#,e_angB#,e_angC#,e_sideA#,e_sideB#,e_sideC#)
	endif
	
	if keystate(9) = 1
		inc e_sideB#,side_inc#
		solve_triangle_sss(sideA#,sideB#,sideC#,e_sideA#,e_sideB#,e_sideC#)
		get_coordinates(angA#,angB#,angC#,sideA#,sideB#,sideC#,e_angA#,e_angB#,e_angC#,e_sideA#,e_sideB#,e_sideC#)	
	endif 
	
	if keystate(10) = 1
		dec e_sideA#, side_inc#
		solve_triangle_sss(sideA#,sideB#,sideC#,e_sideA#,e_sideB#,e_sideC#)
		get_coordinates(angA#,angB#,angC#,sideA#,sideB#,sideC#,e_angA#,e_angB#,e_angC#,e_sideA#,e_sideB#,e_sideC#)
	endif
	
	if keystate(11) = 1
		dec e_sideB#,side_inc#
		solve_triangle_sss(sideA#,sideB#,sideC#,e_sideA#,e_sideB#,e_sideC#)
		get_coordinates(angA#,angB#,angC#,sideA#,sideB#,sideC#,e_angA#,e_angB#,e_angC#,e_sideA#,e_sideB#,e_sideC#)	
	endif 
	
	if keystate(16) = 1
		inc oX#,1.0
	endif
	
	if keystate(17) = 1
		dec oX#,1.0
	endif
	
	if keystate(18) = 1
		inc oY#,1.0
	endif
	
	if keystate(19) = 1
		dec oY#,1.0
	endif
	
	
	//hide or show static triangles
	if keystate(35) = 1
		hide_flag = 1
	endif
	if keystate(31) = 1 
		hide_flag = 0
	endif

endfunction

d^2 = (x1 - x)^2 + (y1 - y)^2
f^2 = (x3 - x)^2 + (y3 - y)^2

- (x1 - x)^2 = (y1 - y)^2 - d^2
 (x1 - x)^2 = -(y1 - y)^2 + d^2
Sqrt[(x1 - x)^2] = Sqrt[-(y1 - y)^2] + Sqrt[d^2]
(x1 - x) = -(y1 - y) + d
- x = -(y1 - y) + d - x1 
x = (y1 - y) - d + x1 

-(y1 - y)^2 = (x1 - x)^2 - d^2
(y1 - y)^2 = -(x1 - x)^2 + d^2
Sqrt[(y1 - y)^2] = Sqrt[-(x1 - x)^2] + Sqrt[d^2]
(y1 - y) = -(x1 - x) + d
- y = -(x1 - x) + d - y1
y = (x1 - x) - d + y1

- (x3 - x)^2 = (y3 - y)^2 - f^2
 (x3 - x)^2 = -(y3 - y)^2 + f^2
Sqrt[(x3 - x)^2] = Sqrt[-(y3 - y)^2] + Sqrt[f^2]
(x3 - x) = -(y3 - y) + f
- x = -(y3 - y) + f - x1 
x = (y3 - y) - f + x3

-(y3 - y)^2 = (x3 - x)^2 - f^2
(y3 - y)^2 = -(x3 - x)^2 + f^2
Sqrt[(y3 - y)^2] = Sqrt[-(x3 - x)^2] + Sqrt[d^2]
(y3 - y) = -(x3 - x) + f
- y = -(x3 - x) + f - y3
y = (x3 - x) - f + y3

Dist = [(x1 - x)^2 + (y1 - y)^2] - [(x3 - x)^2 + (y3 - y)^2]

Dist = [(x1^2 - 2*x1*x + x^2) + (y1^2 - 2*y1*y + y^2)] - [(x3^2 - 2*x3*x + x^2) + (y3^2 - 2*y3*y + y^2)]

[(x1 - x)^2 + (y1 - y)^2] + [(x3 - x)^2 + (y3 - y)^2]

d^2 - f^2 = [(x1 - x)^2 + (y1 - y)^2] - [(x3 - x)^2 + (y3 - y)^2]

- (x1 - x)^2 = (y1 - y)^2 - d^2
 (x1 - x)^2 = -(y1 - y)^2 + d^2
Sqrt[(x1 - x)^2] = Sqrt[-(y1 - y)^2] + Sqrt[d^2]
(x1 - x) = -(y1 - y) + d
- x = -(y1 - y) + d - x1 
x = (y1 - y) - d + x1 

d^2 - f^2 = [(x1 - x)^2 + (y1 - y)^2] - [(x3 - x)^2 + (y3 - y)^2]

d^2 + f^2 = [(x1 - x)^2 + (y1 - y)^2] + [(x3 - x)^2 + (y3 - y)^2]

function solve_triangle_sss(a#,b#,c#,ea#,eb#,ec#)
//declare angA@,angB#, etc as globals
	angC# = acos((a#^2 + b#^2 - c#^2) / (2*a#*b#))
	angA# = asin((a# * sin(angC#)) / c#)
	angB# =  180.00 - (angA# + angC#)
	
	//external triangle, only needed fot the example
	e_angC# = acos((ea#^2 + eb#^2 - ec#^2) / (2*ea#*eb#))
	e_angA# = asin((ea# * sin(e_angC#)) / ec#)
	e_angB# =  180.00 - (e_angA# + e_angC#)
endfunction


function get_coordinates(aA#,aB#,aC#,sa#,sb#,sc#,eaA#,eaB#,eaC#,esa#,esb#,esc#)
	xA# = 0.0
	yA# = 0.0
	//this would be the "random" point in the middle of the problem
	xC# = sb# * (cos(aA#))
	yC# = sb# * (sin(aA#))

	xB# = sc#
	yB# = 0.0
//external
	e_xA# = 0.0
	e_yA# = 0.0
	
	e_xC# = esb# * (cos(eaA#))
	e_yC# = esb# * (sin(eaA#))

	e_xB# = esc#
	e_yB# = 0.0				
endfunction

 (x1 - x)^2 = -(y1 - y)^2 + d^2
Sqrt[(x1 - x)^2] = Sqrt[-(y1 - y)^2] + Sqrt[d^2]

(x1 - x)^2 = x1^2 - 2*x1*x + x^2