Sprite fade in/out based on timer?

Author

Message

Mugen Wizardry

User Banned

Posted: 6th Jan 2011 03:41

Hi all. I'm having a bit of a problem. You see, what I want to do, is fade out a sprite after a timer reaches 0 after a specified amount of time.

What I need is after the timer reaches 0, for the sprite to fade out.

I also need to fade in the sprite as well.

Here is the code I made:

+ Code Snippet

Rem Simple 30 Second Countdown Timer

sync on

    create image 1,128,128

    sprite 1,0,0,1

global fadeval

    fadeval = 255

    delete image 1

    Set Text Opaque

    Ink RGB(255,255,255),0

    Seconds=3: Rem change this value to alter the length of the timer

    T=HiTimer()

    global fadestart

make object cube 1,10

do
    
Call_Timer(1,fadeval,Seconds)

if fadestart

    if fadeval<0 then fadeval=0

  repeat

        dec fadeval,1

      if fadeval>0

        set sprite alpha 1,fadeval

      endif

  until fadeval=0

endif

    sync
loop

Function Call_Timer(s,fadeval,secs)

  Elapsed=(HiTimer()-T)/1000
  TimeLeft=secs-Elapsed
  
  if TimeLeft>0

      Center Text screen width()/2,screen height()/2+20,Str$(TimeLeft)+"   "

  else

      Seconds=3

  endif
  
      if TimeLeft=0

          if fadeval>0
              fadestart=1
          endif

      endif

endfunction

Thanks for the help! ^^

CHECK OUT SOME MUSIC FROM MY NEW TECHNO CD! TECHNOKINESIS
http://www.youtube.com/watch?v=4a8KedfgVv0
ALSO, CHECK OUT MY NEW TECHNO CD AT Amazon.com!

Back to top

Profile

BillR

23

Years of Service

User Offline

Joined: 19th Mar 2003

Location: United States

Posted: 6th Jan 2011 07:26 Edited at: 6th Jan 2011 07:42

Link

Good to see some code from you, always the best way to get help.

Whenever something isn't working in your program like you think it should, adding print statements as debug code is the best way to track it down.
Here is your program, slightly modified to compile, you example wouldn't even compile because of this command

+ Code Snippet

create image 1,128,128

So I added some print statements to debug your code

+ Code Snippet

Rem Simple 30 Second Countdown Timer

sync on
sync rate 60
`create image 1,128,128
print "SPRITE"
get image 1,0,0,100,50,1
cls

sprite 1,0,0,1
global fadeval
fadeval = 255
`delete image 1

Set Text Opaque
Ink RGB(255,255,255),0
Seconds=3: Rem change this value to alter the length of the timer
T=HiTimer()
global fadestart
    
make object cube 1,10

do    
   Call_Timer(1,fadeval,Seconds)
   if fadestart
      if fadeval<0 then fadeval=0
      repeat
         dec fadeval,1
         if fadeval>0
            set sprite alpha 1,fadeval
         endif
      until fadeval=0
   endif
   
set cursor 0,100
print "fadestart=";fadestart
print "fadeval=";fadeval

   sync
loop


Function Call_Timer(s,fadeval,secs)
Elapsed=(HiTimer()-T)/1000
TimeLeft=secs-Elapsed

if TimeLeft>0
   Center Text screen width()/2,screen height()/2+20,Str$(TimeLeft)+"   "
else
   Seconds=3
endif
if TimeLeft=0
   if fadeval>0
      fadestart=1
   endif
endif
endfunction

The fadeval=0 with no fading happening
So time to check the code...
Seems you are in your repeat loop for fading with no sync command
that will redraw the screen to see the fading
So adding a sync command in your repeat loop will fade the sprite

+ Code Snippet

Rem Simple 30 Second Countdown Timer

sync on
sync rate 60
`create image 1,128,128
print "SPRITE"
get image 1,0,0,100,50,1
cls

sprite 1,0,0,1
global fadeval
fadeval = 255
`delete image 1

Set Text Opaque
Ink RGB(255,255,255),0
Seconds=3: Rem change this value to alter the length of the timer
T=HiTimer()
global fadestart
    
make object cube 1,10

do    
   Call_Timer(1,fadeval,Seconds)
   if fadestart
      if fadeval<0 then fadeval=0
      repeat
         dec fadeval,1
         if fadeval>0
            set sprite alpha 1,fadeval
            sync
         endif
      until fadeval=0
   endif
   
set cursor 0,100
print "fadestart=";fadestart
print "fadeval=";fadeval

   sync
loop


Function Call_Timer(s,fadeval,secs)
Elapsed=(HiTimer()-T)/1000
TimeLeft=secs-Elapsed

if TimeLeft>0
   Center Text screen width()/2,screen height()/2+20,Str$(TimeLeft)+"   "
else
   Seconds=3
endif
if TimeLeft=0
   if fadeval>0
      fadestart=1
   endif
endif
endfunction

While this works, it is really NOT what you want to do...
You really only want one sync command in your main loop unless you are getting user input or doing something special

You don't really want to fade an object in a repeat loop causing everything on the screen to halt until the fading is completed,
so fading it out or in a little bit each time through your main loop is the best way to do this.
Try it yourself, and if you get stuck, ask for help with your new code.

Back to top

Profile PM Email

BillR

23

Years of Service

User Offline

Joined: 19th Mar 2003

Location: United States

Posted: 6th Jan 2011 07:37 Edited at: 6th Jan 2011 07:39

Link

A few constructive comments...
1) Don't skip a line between each command
2) Change your tab spacing to 3, more common and easier for use to edit your code when asking for help
3) Always copy your code from your forum post into a newly loaded DBPro and see if it compiles,
that will tell you if you forgot to copy all the code or if there is a problem with your post code, your code wouldn't compile the way you posted it.

Hey, great to see you posting code when asking for help!
Good Luck to your programming efforts!

Back to top

Profile PM Email

BillR

23

Years of Service

User Offline

Joined: 19th Mar 2003

Location: United States

Posted: 6th Jan 2011 08:00 Edited at: 6th Jan 2011 08:06

Link

After writing my constructive comments, which I hope you will take in the
helpful manner that they were intended to be, I didn't want to seem to harsh, and to help a little more.

So here is some improved code that fades the sprite over and over
with only one sync command in the main loop

Rem Simple 30 Second Countdown Timer

sync on
sync rate 60
`create image 1,128,128
print "SPRITE"
get image 1,0,0,100,50,1
cls

sprite 1,0,0,1

global fadeval
global fadestart
global T
global seconds
fadeval = 255
Seconds=3: Rem change this value to alter the length of the timer
T=HiTimer()

`delete image 1
Set Text Opaque
Ink RGB(255,255,255),0

make object cube 1,10

do    
   if fadestart
      if fadeval>0
         dec fadeval,1
         if fadeval>0
            set sprite alpha 1,fadeval
         endif
      else
         fadeval=255
         fadestart=0
         seconds=3
         T=HiTimer()
         set sprite alpha 1,fadeval
      endif
   else
      Call_Timer(1,fadeval,Seconds)
   endif
   
   
set cursor 0,100
print "fadestart=";fadestart
print "fadeval=";fadeval

sync
loop

Function Call_Timer(s,fadeval,secs)
Elapsed=(HiTimer()-T)/1000
TimeLeft=secs-Elapsed

if TimeLeft>0
   Center Text screen width()/2,screen height()/2+20,Str$(TimeLeft)+"   "
else
   Seconds=3
endif
if TimeLeft=0
   if fadeval>0
      fadestart=1
   endif
endif
endfunction

+ Code Snippet

Rem Simple 30 Second Countdown Timer

sync on
sync rate 60
`create image 1,128,128
print "SPRITE"
get image 1,0,0,100,50,1
cls

sprite 1,0,0,1

global fadeval
global fadestart
global T
global seconds
fadeval = 255
Seconds=3: Rem change this value to alter the length of the timer
T=HiTimer()

`delete image 1
Set Text Opaque
Ink RGB(255,255,255),0

make object cube 1,10

do    
   if fadestart
      if fadeval>0
         dec fadeval,1
         if fadeval>0
            set sprite alpha 1,fadeval
         endif
      else
         fadeval=255
         fadestart=0
         seconds=3
         T=HiTimer()
         set sprite alpha 1,fadeval
      endif
   else
      Call_Timer(1,fadeval,Seconds)
   endif
   
   
set cursor 0,100
print "fadestart=";fadestart
print "fadeval=";fadeval

   sync
loop


Function Call_Timer(s,fadeval,secs)
Elapsed=(HiTimer()-T)/1000
TimeLeft=secs-Elapsed

if TimeLeft>0
   Center Text screen width()/2,screen height()/2+20,Str$(TimeLeft)+"   "
else
   Seconds=3
endif
if TimeLeft=0
   if fadeval>0
      fadestart=1
   endif
endif
endfunction

Hope this helps.

Work on your fade in sprite routine, if you get stuck, post your new code here for help.

Back to top

Profile PM Email

Sasuke

20

Years of Service

User Offline

Joined: 2nd Dec 2005

Location: Milton Keynes UK

Posted: 6th Jan 2011 13:53 Edited at: 6th Jan 2011 13:54

Link

Just thought I'd add to this. Analyse your code cause there's a ton you don't need and this can be optimized quite a bit. Efficiency is key in programming.

A dream is a fantasy, if you achieve that fantasy it was never a dream to begin with.

Back to top

Profile PM Email

Mugen Wizardry

User Banned

Posted: 6th Jan 2011 14:53

Link

thanks guys.

How would i make it fade in after the timer?
here's the code:

Rem Simple 30 Second Countdown Timer

sync on
sync rate 60
`create image 1,128,128
print "SPRITE"
get image 1,0,0,100,50,1
cls

sprite 1,0,0,1

global fadeval
global fadestart
global T
global seconds
fadeval = 0
Seconds=3: Rem change this value to alter the length of the timer
T=HiTimer()

`delete image 1
Set Text Opaque
Ink RGB(255,255,255),0

make object cube 1,10

do

gosub fadein
   
   
set cursor 0,100
print "fadestart=";fadestart
print "fadeval=";fadeval

sync
loop

Function Call_Timer(s,fadeval,secs)
Elapsed=(HiTimer()-T)/1000
TimeLeft=secs-Elapsed

if TimeLeft>0
   Center Text screen width()/2,screen height()/2+20,Str$(TimeLeft)+"   "
else
   Seconds=3
endif
if TimeLeft=0
   if fadeval>0
      fadestart=1
   endif
endif
endfunction

fadeout:
   if fadestart
      if fadeval>0
         dec fadeval,1
         if fadeval>0
            set sprite alpha 1,fadeval
         endif
      else
         fadeval=255
         fadestart=0
         seconds=3
         T=HiTimer()
         set sprite alpha 1,fadeval
      endif
   else
      Call_Timer(1,fadeval,Seconds)
   endif
return

fadein:
   if fadestart
      if fadeval=0
         inc fadeval,1
         if fadeval>0
            set sprite alpha 1,fadeval
         endif
      else
         fadeval=0
         fadestart=0
         seconds=3
         T=HiTimer()
         set sprite alpha 1,fadeval
      endif
   else
      Call_Timer(1,fadeval,Seconds)
   endif
return

+ Code Snippet

Rem Simple 30 Second Countdown Timer

sync on
sync rate 60
`create image 1,128,128
print "SPRITE"
get image 1,0,0,100,50,1
cls

sprite 1,0,0,1

global fadeval
global fadestart
global T
global seconds
fadeval = 0
Seconds=3: Rem change this value to alter the length of the timer
T=HiTimer()

`delete image 1
Set Text Opaque
Ink RGB(255,255,255),0

make object cube 1,10

do    

gosub fadein
   
   
set cursor 0,100
print "fadestart=";fadestart
print "fadeval=";fadeval

   sync
loop


Function Call_Timer(s,fadeval,secs)
Elapsed=(HiTimer()-T)/1000
TimeLeft=secs-Elapsed

if TimeLeft>0
   Center Text screen width()/2,screen height()/2+20,Str$(TimeLeft)+"   "
else
   Seconds=3
endif
if TimeLeft=0
   if fadeval>0
      fadestart=1
   endif
endif
endfunction

fadeout:
   if fadestart
      if fadeval>0
         dec fadeval,1
         if fadeval>0
            set sprite alpha 1,fadeval
         endif
      else
         fadeval=255
         fadestart=0
         seconds=3
         T=HiTimer()
         set sprite alpha 1,fadeval
      endif
   else
      Call_Timer(1,fadeval,Seconds)
   endif
return

fadein:
   if fadestart
      if fadeval=0
         inc fadeval,1
         if fadeval>0
            set sprite alpha 1,fadeval
         endif
      else
         fadeval=0
         fadestart=0
         seconds=3
         T=HiTimer()
         set sprite alpha 1,fadeval
      endif
   else
      Call_Timer(1,fadeval,Seconds)
   endif
return

Thanks!

CHECK OUT SOME MUSIC FROM MY NEW TECHNO CD! TECHNOKINESIS
http://www.youtube.com/watch?v=4a8KedfgVv0
ALSO, CHECK OUT MY NEW TECHNO CD AT Amazon.com!

Back to top

Profile

Mugen Wizardry

User Banned

Posted: 6th Jan 2011 20:34

Link

anyone? :/

CHECK OUT SOME MUSIC FROM MY NEW TECHNO CD! TECHNOKINESIS
http://www.youtube.com/watch?v=4a8KedfgVv0
ALSO, CHECK OUT MY NEW TECHNO CD AT Amazon.com!

Back to top

Profile

BillR

23

Years of Service

User Offline

Joined: 19th Mar 2003

Location: United States

Posted: 6th Jan 2011 20:58 Edited at: 6th Jan 2011 22:44

Link

Yep, I'm working on it...back in a few minutes.

OK, here it is.....I added a few things...

Rem Simple 30 Second Countdown Timer

set display mode desktop width(),desktop height(),32
sync on
sync rate 60
color backdrop 0

`set up constants for easy setting of fading types
#CONSTANT FADEIN 1
#CONSTANT FADEOUT 2
#CONSTANT FADEINOUT 3

`setup typed array for sprite fading
type spinfo
   x as integer
   y as integer
   fadetype as integer
   fadespeed as integer
   fadestart as integer
   fadeend as integer
   fadedir as integer
   fadeval as integer
endtype

`OK, let's dimension our type array
dim spriteinfo(100) as spinfo

`create sprite images
for i=1 to 4
print "SPRITE #";i
get image i,0,0,100,20,1
sprite i,0,i*30,i
set sprite alpha i,0
cls
next i

`globals set for timed fading
global T1
global seconds

Set Text Opaque
Ink RGB(255,255,255),0

make object cube 1,10

`set up 2 fading sprite from the start, using no timer
fadesprite(3,FADEINOUT,5,0,255,1)     :`set sprite for Fading In & Out
fadesprite(4,FADEINOUT,2,150,255,1)     :`set sprite for Fading In & Out from 150-255 range

Seconds=3: Rem change this value to alter the length of the timer
T1=HiTimer()

do    
   TimeLeft=Call_Timer2(T1,Seconds)
   if TimeLeft=0 and spriteinfo(1).fadetype=0
      `params= spritenum,fadetype,fadeinc,fadestart,fadeend,fadedir(only used for fadeinout)5
      fadesprite(1,FADEIN,1,0,255,1)     :`set sprite for Fading In
      fadesprite(2,FADEOUT,1,255,0,-1)     :`set sprite for Fading Out
      T1=HiTimer()
   endif
      
   fadeallsprites()           :`fades any sprites with fadetype set>0

`----------------------
`debug code to be removed later - usually don't indent debug code, easier to find & remove later   
set cursor 0,0
print "Sprite #1 Fades IN, #2 Fades OUT, #3 Fades IN & Out, #4 Fades Partial In & Out"
`remstart
set cursor 0,200
for i=1 to 4
print "Sprite #";i
print "fadetype=";spriteinfo(i).fadetype
print "fadeval=";spriteinfo(i).fadeval
print "fadedir=";spriteinfo(i).fadedir
print "  "
next i
`remend
`-----------------------

sync
loop

`sets values in sprite array
function fadesprite(spnum, ftype, fspeed, fstart, fend, fdir)
spriteinfo(spnum).fadetype=ftype
spriteinfo(spnum).fadestart=fstart
spriteinfo(spnum).fadeend=fend
spriteinfo(spnum).fadespeed=fspeed
spriteinfo(spnum).fadedir=fdir
endfunction

`fade all sprites(numbered 1 to 100) with fadetype>0
function fadeallsprites()
for i=1 to 100
if spriteinfo(i).fadetype>0
   select spriteinfo(i).fadetype
      case 1      :`fade in
         set sprite alpha i,spriteinfo(i).fadeval
         inc spriteinfo(i).fadeval,spriteinfo(i).fadespeed
         if spriteinfo(i).fadeval >= spriteinfo(i).fadeend
            spriteinfo(i).fadetype = 0
         endif
      endcase
      
      case 2      :`fade out
         set sprite alpha i,spriteinfo(i).fadeval
         dec spriteinfo(i).fadeval,spriteinfo(i).fadespeed
         if spriteinfo(i).fadeval <= spriteinfo(i).fadeend
            spriteinfo(i).fadetype = 0
         endif
      endcase
      case 3      :`fade in & out continuously
         if spriteinfo(i).fadedir>0
            inc spriteinfo(i).fadeval,spriteinfo(i).fadespeed
            if spriteinfo(i).fadeval >= spriteinfo(i).fadeend
               spriteinfo(i).fadeval=spriteinfo(i).fadeend
               spriteinfo(i).fadedir=spriteinfo(i).fadedir*-1
            endif
         else
            dec spriteinfo(i).fadeval,spriteinfo(i).fadespeed
            if spriteinfo(i).fadeval <= spriteinfo(i).fadestart
               spriteinfo(i).fadeval=spriteinfo(i).fadestart
               spriteinfo(i).fadedir=spriteinfo(i).fadedir*-1
            endif
         endif
         set sprite alpha i,spriteinfo(i).fadeval         
      endcase
   endselect
endif
next i
endfunction

Function Call_Timer2(starttime,secs)
Elapsed=(HiTimer()-starttime)/1000
TimeLeft=secs-Elapsed

if TimeLeft>0
   Center Text screen width()/2,screen height()/2+20,Str$(TimeLeft)+"   "
endif
endfunction TimeLeft

+ Code Snippet

Rem Simple 30 Second Countdown Timer

set display mode desktop width(),desktop height(),32
sync on
sync rate 60
color backdrop 0

`set up constants for easy setting of fading types
#CONSTANT FADEIN 1
#CONSTANT FADEOUT 2
#CONSTANT FADEINOUT 3

`setup typed array for sprite fading
type spinfo
   x as integer
   y as integer
   fadetype as integer
   fadespeed as integer
   fadestart as integer
   fadeend as integer
   fadedir as integer
   fadeval as integer
endtype

`OK, let's dimension our type array
dim spriteinfo(100) as spinfo

`create sprite images
for i=1 to 4
print "SPRITE #";i
get image i,0,0,100,20,1
sprite i,0,i*30,i
set sprite alpha i,0
cls
next i

`globals set for timed fading
global T1
global seconds

Set Text Opaque
Ink RGB(255,255,255),0

make object cube 1,10

`set up 2 fading sprite from the start, using no timer
fadesprite(3,FADEINOUT,5,0,255,1)     :`set sprite for Fading In & Out
fadesprite(4,FADEINOUT,2,150,255,1)     :`set sprite for Fading In & Out from 150-255 range

Seconds=3: Rem change this value to alter the length of the timer
T1=HiTimer()

do    
   TimeLeft=Call_Timer2(T1,Seconds)
   if TimeLeft=0 and spriteinfo(1).fadetype=0
      `params= spritenum,fadetype,fadeinc,fadestart,fadeend,fadedir(only used for fadeinout)5
      fadesprite(1,FADEIN,1,0,255,1)     :`set sprite for Fading In
      fadesprite(2,FADEOUT,1,255,0,-1)     :`set sprite for Fading Out
      T1=HiTimer()
   endif
      
   fadeallsprites()           :`fades any sprites with fadetype set>0

`----------------------
`debug code to be removed later - usually don't indent debug code, easier to find & remove later   
set cursor 0,0
print "Sprite #1 Fades IN, #2 Fades OUT, #3 Fades IN & Out, #4 Fades Partial In & Out"
`remstart
set cursor 0,200
for i=1 to 4
print "Sprite #";i
print "fadetype=";spriteinfo(i).fadetype
print "fadeval=";spriteinfo(i).fadeval
print "fadedir=";spriteinfo(i).fadedir
print "  "
next i
`remend
`-----------------------

   sync
loop

`sets values in sprite array
function fadesprite(spnum, ftype, fspeed, fstart, fend, fdir)
spriteinfo(spnum).fadetype=ftype
spriteinfo(spnum).fadestart=fstart
spriteinfo(spnum).fadeend=fend
spriteinfo(spnum).fadespeed=fspeed
spriteinfo(spnum).fadedir=fdir
endfunction


`fade all sprites(numbered 1 to 100) with fadetype>0
function fadeallsprites()
for i=1 to 100
if spriteinfo(i).fadetype>0
   select spriteinfo(i).fadetype
      case 1      :`fade in
         set sprite alpha i,spriteinfo(i).fadeval
         inc spriteinfo(i).fadeval,spriteinfo(i).fadespeed
         if spriteinfo(i).fadeval >= spriteinfo(i).fadeend
            spriteinfo(i).fadetype = 0
         endif
      endcase
      
      case 2      :`fade out
         set sprite alpha i,spriteinfo(i).fadeval
         dec spriteinfo(i).fadeval,spriteinfo(i).fadespeed
         if spriteinfo(i).fadeval <= spriteinfo(i).fadeend
            spriteinfo(i).fadetype = 0
         endif
      endcase
      case 3      :`fade in & out continuously
         if spriteinfo(i).fadedir>0
            inc spriteinfo(i).fadeval,spriteinfo(i).fadespeed
            if spriteinfo(i).fadeval >= spriteinfo(i).fadeend
               spriteinfo(i).fadeval=spriteinfo(i).fadeend
               spriteinfo(i).fadedir=spriteinfo(i).fadedir*-1
            endif
         else
            dec spriteinfo(i).fadeval,spriteinfo(i).fadespeed
            if spriteinfo(i).fadeval <= spriteinfo(i).fadestart
               spriteinfo(i).fadeval=spriteinfo(i).fadestart
               spriteinfo(i).fadedir=spriteinfo(i).fadedir*-1
            endif
         endif
         set sprite alpha i,spriteinfo(i).fadeval         
      endcase
   endselect
endif
next i
endfunction


Function Call_Timer2(starttime,secs)
Elapsed=(HiTimer()-starttime)/1000
TimeLeft=secs-Elapsed

if TimeLeft>0
   Center Text screen width()/2,screen height()/2+20,Str$(TimeLeft)+"   "
endif
endfunction TimeLeft

I built a typed array for sprite fading, as well as a little fading engine...you can:
Fade In
Fade Out
Fade In & Out

I will add comments to the code, just wanted to get it out here for now....Enjoy!
I think I will post a tutorial on this

Back to top

Profile PM Email

Mugen Wizardry

User Banned

Posted: 7th Jan 2011 00:19

Link

its PERFECT. thank u

Except 1 thing. how do i control how many times i can call a fade in or fade out or both?

CHECK OUT SOME MUSIC FROM MY NEW TECHNO CD! TECHNOKINESIS
http://www.youtube.com/watch?v=4a8KedfgVv0
ALSO, CHECK OUT MY NEW TECHNO CD AT Amazon.com!

Back to top

Profile

BillR

23

Years of Service

User Offline

Joined: 19th Mar 2003

Location: United States

Posted: 7th Jan 2011 00:58 Edited at: 7th Jan 2011 02:17

Link

Not sure exactly what you mean...
But you can call the fadesprite routine as many times as you want to.
You can change it if you want to, but this version expects your sprites to be numbered
from 1 to 100, and updates the correct slot in the sprite array every time you call the fadesprite routine.

Try using it, you can fade sprites, blink sprites by fading in & out faster, etc.
Here is 100 sprites fading in & out

Rem Simple 30 Second Countdown Timer

set display mode desktop width(),desktop height(),32
sync on
sync rate 60
color backdrop 0

`set up constants for easy setting of fading types
#CONSTANT FADEIN 1
#CONSTANT FADEOUT 2
#CONSTANT FADEINOUT 3

global maxsprites=100
global numin=0
global numout=0
global numinout=0

`setup typed array for sprite fading
type spinfo
   x as integer
   y as integer
   fadetype as integer
   fadespeed as integer
   fadestart as integer
   fadeend as integer
   fadedir as integer
   fadeval as integer
endtype

`OK, let's dimension our type array
dim spriteinfo(maxsprites) as spinfo

`create sprite images
for i=1 to 100
print "SPRITE #";i
get image i,0,0,100,20,1
sprite i,rnd(desktop width()-100),rnd(desktop height()-60)+50,i
set sprite alpha i,0
cls
next i

Set Text Opaque
Ink RGB(255,255,255),0

spriteptr=0
do    
   inc spriteptr
   if spriteptr>maxsprites then spriteptr=1

if spriteinfo(spriteptr).fadetype=0       :`either no fade is set, or fade is done-ready for another fade
      ftype=rnd(2)+1                         :`three posible fade types
      `params= spritenum,fadetype,fadeinc,fadestart,fadeend,fadedir(only used for fadeinout)5                                 
      if ftype=1 then fadesprite(spriteptr,1,rnd(10)+1,0,255,1):inc numin     :`set sprite for Fading In
      if ftype=2 then fadesprite(spriteptr,2,rnd(10)+1,255,0,1):inc numout     :`set sprite for Fading Out
      if ftype=3 then fadesprite(spriteptr,3,rnd(10)+1,0,255,1):inc numinout     :`set sprite for Fading In & Out
      `eventually all sprites get set to fadetype=3, since this code never resets fadetype=3 like it does for type 1 & 2
   endif
      
   fadeallsprites()           :`Main Fade Routine - fades any sprites with fadetype set>0

`----------------------
`debug code to be removed later - usually don't indent debug code, easier to find & remove later   
set cursor 0,0
print "Sprites Fading"
print "IN = ";numin
print "OUT = ";numout
print "IN&OUT = ";numinout
`----------------------

sync
loop

`sets values in sprite array
function fadesprite(spnum, ftype, fspeed, fstart, fend, fdir)
spriteinfo(spnum).fadetype=ftype
spriteinfo(spnum).fadestart=fstart
spriteinfo(spnum).fadeend=fend
spriteinfo(spnum).fadespeed=fspeed
spriteinfo(spnum).fadedir=fdir
spriteinfo(spnum).fadeval=fstart
endfunction

`fade all sprites(numbered 1 to 100) with fadetype>0
function fadeallsprites()
for i=1 to 100
if spriteinfo(i).fadetype>0
   select spriteinfo(i).fadetype
      case 1      :`fade in
         set sprite alpha i,spriteinfo(i).fadeval
         inc spriteinfo(i).fadeval,spriteinfo(i).fadespeed
         if spriteinfo(i).fadeval >= spriteinfo(i).fadeend
            spriteinfo(i).fadetype = 0
            dec numin
         endif
      endcase
      
      case 2      :`fade out
         set sprite alpha i,spriteinfo(i).fadeval
         dec spriteinfo(i).fadeval,spriteinfo(i).fadespeed
         if spriteinfo(i).fadeval <= spriteinfo(i).fadeend
            spriteinfo(i).fadetype = 0
            dec numout
         endif
      endcase
      case 3      :`fade in & out continuously
         if spriteinfo(i).fadedir>0
            inc spriteinfo(i).fadeval,spriteinfo(i).fadespeed
            if spriteinfo(i).fadeval >= spriteinfo(i).fadeend
               spriteinfo(i).fadeval=spriteinfo(i).fadeend
               spriteinfo(i).fadedir=spriteinfo(i).fadedir*-1
            endif
         else
            dec spriteinfo(i).fadeval,spriteinfo(i).fadespeed
            if spriteinfo(i).fadeval <= spriteinfo(i).fadestart
               spriteinfo(i).fadeval=spriteinfo(i).fadestart
               spriteinfo(i).fadedir=spriteinfo(i).fadedir*-1
            endif
         endif
         set sprite alpha i,spriteinfo(i).fadeval         
      endcase
   endselect
endif
next i
endfunction

+ Code Snippet

Rem Simple 30 Second Countdown Timer

set display mode desktop width(),desktop height(),32
sync on
sync rate 60
color backdrop 0

`set up constants for easy setting of fading types
#CONSTANT FADEIN 1
#CONSTANT FADEOUT 2
#CONSTANT FADEINOUT 3

global maxsprites=100
global numin=0
global numout=0
global numinout=0

`setup typed array for sprite fading
type spinfo
   x as integer
   y as integer
   fadetype as integer
   fadespeed as integer
   fadestart as integer
   fadeend as integer
   fadedir as integer
   fadeval as integer
endtype

`OK, let's dimension our type array
dim spriteinfo(maxsprites) as spinfo

`create sprite images
for i=1 to 100
print "SPRITE #";i
get image i,0,0,100,20,1
sprite i,rnd(desktop width()-100),rnd(desktop height()-60)+50,i
set sprite alpha i,0
cls
next i

Set Text Opaque
Ink RGB(255,255,255),0

spriteptr=0
do    
   inc spriteptr
   if spriteptr>maxsprites then spriteptr=1

   if spriteinfo(spriteptr).fadetype=0       :`either no fade is set, or fade is done-ready for another fade
      ftype=rnd(2)+1                         :`three posible fade types
      `params= spritenum,fadetype,fadeinc,fadestart,fadeend,fadedir(only used for fadeinout)5                                 
      if ftype=1 then fadesprite(spriteptr,1,rnd(10)+1,0,255,1):inc numin     :`set sprite for Fading In
      if ftype=2 then fadesprite(spriteptr,2,rnd(10)+1,255,0,1):inc numout     :`set sprite for Fading Out
      if ftype=3 then fadesprite(spriteptr,3,rnd(10)+1,0,255,1):inc numinout     :`set sprite for Fading In & Out
      `eventually all sprites get set to fadetype=3, since this code never resets fadetype=3 like it does for type 1 & 2
   endif
      
   fadeallsprites()           :`Main Fade Routine - fades any sprites with fadetype set>0

`----------------------
`debug code to be removed later - usually don't indent debug code, easier to find & remove later   
set cursor 0,0
print "Sprites Fading"
print "IN = ";numin
print "OUT = ";numout
print "IN&OUT = ";numinout
`----------------------

   sync
loop

`sets values in sprite array
function fadesprite(spnum, ftype, fspeed, fstart, fend, fdir)
spriteinfo(spnum).fadetype=ftype
spriteinfo(spnum).fadestart=fstart
spriteinfo(spnum).fadeend=fend
spriteinfo(spnum).fadespeed=fspeed
spriteinfo(spnum).fadedir=fdir
spriteinfo(spnum).fadeval=fstart
endfunction


`fade all sprites(numbered 1 to 100) with fadetype>0
function fadeallsprites()
for i=1 to 100
if spriteinfo(i).fadetype>0
   select spriteinfo(i).fadetype
      case 1      :`fade in
         set sprite alpha i,spriteinfo(i).fadeval
         inc spriteinfo(i).fadeval,spriteinfo(i).fadespeed
         if spriteinfo(i).fadeval >= spriteinfo(i).fadeend
            spriteinfo(i).fadetype = 0
            dec numin
         endif
      endcase
      
      case 2      :`fade out
         set sprite alpha i,spriteinfo(i).fadeval
         dec spriteinfo(i).fadeval,spriteinfo(i).fadespeed
         if spriteinfo(i).fadeval <= spriteinfo(i).fadeend
            spriteinfo(i).fadetype = 0
            dec numout
         endif
      endcase
      case 3      :`fade in & out continuously
         if spriteinfo(i).fadedir>0
            inc spriteinfo(i).fadeval,spriteinfo(i).fadespeed
            if spriteinfo(i).fadeval >= spriteinfo(i).fadeend
               spriteinfo(i).fadeval=spriteinfo(i).fadeend
               spriteinfo(i).fadedir=spriteinfo(i).fadedir*-1
            endif
         else
            dec spriteinfo(i).fadeval,spriteinfo(i).fadespeed
            if spriteinfo(i).fadeval <= spriteinfo(i).fadestart
               spriteinfo(i).fadeval=spriteinfo(i).fadestart
               spriteinfo(i).fadedir=spriteinfo(i).fadedir*-1
            endif
         endif
         set sprite alpha i,spriteinfo(i).fadeval         
      endcase
   endselect
endif
next i
endfunction

Back to top

Profile PM Email

Sasuke

20

Years of Service

User Offline

Joined: 2nd Dec 2005

Location: Milton Keynes UK

Posted: 7th Jan 2011 16:48

Link

Nice, though it might be best to implement timer based fading so if the frame rate changes it runs a constant speed. So sort of like 2 key frames using linear interpolation.

A dream is a fantasy, if you achieve that fantasy it was never a dream to begin with.

Back to top

Profile PM Email

Mugen Wizardry

User Banned

Posted: 7th Jan 2011 16:51

Link

how exactly would i do that?

CHECK OUT SOME MUSIC FROM MY NEW TECHNO CD! TECHNOKINESIS
http://www.youtube.com/watch?v=4a8KedfgVv0
ALSO, CHECK OUT MY NEW TECHNO CD AT Amazon.com!

Back to top

Profile

Sasuke

20

Years of Service

User Offline

Joined: 2nd Dec 2005

Location: Milton Keynes UK

Posted: 7th Jan 2011 17:09

Link

I'll post an example later when I get back from work, but for now look up timer based movement.

A dream is a fantasy, if you achieve that fantasy it was never a dream to begin with.

Back to top

Profile PM Email

Sasuke

20

Years of Service

User Offline

Joined: 2nd Dec 2005

Location: Milton Keynes UK

Posted: 7th Jan 2011 18:49 Edited at: 7th Jan 2011 18:54

Link

I guess no work today.

Ok, linear interpolation basically is a straight line between two points. I've seen you've been doing a bit with 3d bezier's, this can be known as bezier interpolation or B-Spline interpolation, so basically these are method from getting to one point and to another.

What we want to do is work out where a value would be between a specific time. To do this we need what we'd call a 'Key', which is a point with in a frame time. The 'Key' holds the time or frame of the point and holds a value. So if we wanted to move an object forward 100 units with in 3 seconds, we'd make two keys, one with a time of 0.0 and a value of 0, and the other with a time of 3 and a value of 100, then work out the value based on the elasped.

Now when we program something, we need to work out what is 'Specific' and what is 'Generic' (common). So for instance, I want to fade a sprite over certain amount of time. Now looking at that, you need to think what else could need to be faded over a certain amount of time or what needs a value changing over time. This would be classed as 'Generic' because the main feature, which is work out a value at a certain time, can be used for many things. If it was something that could only be applied to Sprites then it's 'Specific'.

So with this let's get in to this:

More info on: Linear Interpolation

I came up with a neat function to do this between two points, it can also deal with inc and dec between points. The only issue is I don't have a lot of time to explain the math. I will edit in how the math works in a bit when I get back to the comp.

The function:

+ Code Snippet

// single point to point linear interpolation
function LinearInterpolation( time as float, startTime as float, endTime as float, fromVal as float, toVal as float )
    
    local out as float

    // check if time is outside bounds and fire out resulting values
    if (time < startTime) || (time > endTime)
        if (time < startTime)
            exitfunction fromVal
        else
            exitfunction toVal
        endif
    else
        // work out the value at the specific time
        out = (((time-startTime) * (toVal-fromVal)) / (endTime-startTime)) + fromVal
    endif
    
endfunction out

And using it:

global _oldTick as dword
global _newTick as dword        : _newTick = hitimer()
global _delta as float

startTime# = 0
endTime# = 3.5
startValue = 255
endValue = 0

randomize timer()
sync on : sync rate 60

cls rgb(255,144,23)
center text 32,8,"SPRITE"
get image 1,0,0,64,32,1
cls

sprite 1,0,0,1

do

_oldTick = _newTick
    _newTick = hitimer()
    _delta   = (_newTick-_oldTick)
    
    spriteElasped# = spriteElasped# + (_delta*0.001)
    if spriteElasped# > (endTime#)
        spriteElasped# = 0.0
        endTime# = rnd(3)+0.5
        // this just flips the values to fade in and out
        startValue = 255-startValue
        endValue = 255-endValue
    endif
    
    spriteAlpha = int(LinearInterpolation( spriteElasped#, startTime#, endTime#, startValue, endValue ))
    set sprite alpha 1, spriteAlpha

text 0,64,"Time: "+str$(spriteElasped#,2)
    text 0,76,"Alpha: "+str$(spriteAlpha)

sync
loop

// single point to point linear interpolation
function LinearInterpolation( time as float, startTime as float, endTime as float, fromVal as float, toVal as float )
    
    local out as float

// check if time is outside bounds and fire out resulting values
    if (time < startTime) || (time > endTime)
        if (time < startTime)
            exitfunction fromVal
        else
            exitfunction toVal
        endif
    else
        out = (((time-startTime) * (toVal-fromVal)) / (endTime-startTime)) + fromVal
    endif
    
endfunction out

+ Code Snippet

global _oldTick as dword
global _newTick as dword        : _newTick = hitimer()
global _delta as float

startTime# = 0
endTime# = 3.5
startValue = 255
endValue = 0

randomize timer()
sync on : sync rate 60

cls rgb(255,144,23)
center text 32,8,"SPRITE"
get image 1,0,0,64,32,1
cls

sprite 1,0,0,1

do

    _oldTick = _newTick
    _newTick = hitimer()
    _delta   = (_newTick-_oldTick)
    
    spriteElasped# = spriteElasped# + (_delta*0.001)
    if spriteElasped# > (endTime#)
        spriteElasped# = 0.0
        endTime# = rnd(3)+0.5
        // this just flips the values to fade in and out
        startValue = 255-startValue
        endValue = 255-endValue
    endif
    
    spriteAlpha = int(LinearInterpolation( spriteElasped#, startTime#, endTime#, startValue, endValue ))
    set sprite alpha 1, spriteAlpha

    text 0,64,"Time: "+str$(spriteElasped#,2)
    text 0,76,"Alpha: "+str$(spriteAlpha)    

    sync
loop

// single point to point linear interpolation
function LinearInterpolation( time as float, startTime as float, endTime as float, fromVal as float, toVal as float )
    
    local out as float

    // check if time is outside bounds and fire out resulting values
    if (time < startTime) || (time > endTime)
        if (time < startTime)
            exitfunction fromVal
        else
            exitfunction toVal
        endif
    else
        out = (((time-startTime) * (toVal-fromVal)) / (endTime-startTime)) + fromVal
    endif
    
endfunction out

A dream is a fantasy, if you achieve that fantasy it was never a dream to begin with.

Back to top

Profile PM Email

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Sprite fade in/out based on timer?