Without seeing what your function calls do and what your values are it's a bit like guesswork.
Why not post a simple demo example? I'll hunt my code out for "The Waystation" and post it here if I have it handy...
EDIT: Here it is...
function movePlayer()
g#=gravity#*FrameX#
spd#=2*FrameX#
if keystate(42) then spd#=4*FrameX#
rem rotate player with mouse
mx#=mousemovex()
my#=mousemovey()
mx#=mx#/6
my#=my#/6
crX=crX+my#
crY=crY+mx#
if crX>40 then crX=40
if crX<-40 then crX=-40
rotate object 1,crX,crY,0
oldx# = object position x(1)
oldy# = object position y(1)
oldz# = object position z(1)
rem apply gravity, and user changes to movement
angy# = object angle y(1)
vx# = 0
vz# = 0
rem if player is jumping or falling then apply 'normal' gravity
rem if not attempt to keep the player stuck to the floor
if vy#=0 and jumptimer=0 then vy# = vy# + 8*g# else vy# = vy# + g#
if keystate(32)=1 then vx# = vx# + spd#*cos(angy#) : vz# = vz# - spd#*sin(angy#):Moving=1
if keystate(30)=1 then vx# = vx# - spd#*cos(angy#) : vz# = vz# + spd#*sin(angy#):Moving=1
if keystate(31)=1 then vx# = vx# - spd#*sin(angy#) : vz# = vz# - spd#*cos(angy#):Moving=1
if keystate(17)=1 then vx# = vx# + spd#*sin(angy#) : vz# = vz# + spd#*cos(angy#):Moving=1
rem only jump if on ground, and a certain time after last jump
if ground=1
if spacekey()=1 and jumptimer=0 then vy# = vy# + 4.0 : jumptimer = 20
endif
rem this would be the player's final position without collision
x# = oldx#+vx#
y# = oldy#+vy#
z# = oldz#+vz#
rem first handle gravity - seperated from horizontal movement
rem to achieve a more realistic effect
rem Method: simple - cast a sphere vertically down, if it hits the level then
rem position the object there (sticky collision) then move
rem on to horizontal movement
rem more complex - if we were to only use the simple method the player would be
rem allowed to climb almost vertical slopes. Alternative is to
rem get the normalY direction to work out how flat the gorund
rem below the player is, 0-slope# is flatter, slope#-1 is steeper.
rem if it's flat, use sticky collision, if it's steep slide the
rem player down the slope. Changing slope# determines how steep the
rem player can climb. NOTE: this also effects stairs.
collide = sc_SphereCastGroup(1,oldx#,oldy#,oldz#,oldx#,oldy#+vy#,oldz#,radius#,0)
if collide>0
rem how flat is this ground
ny# = sc_getCollisionNormalY()
if abs(ny#)>slope#
rem FLAT, stick
oldy# = sc_getStaticCollisionY()
else
rem STEEP, slide
x# = x# - oldx# : z# = z# - oldz#
oldx# = sc_getCollisionSlideX()
oldy# = sc_getCollisionSlideY()
oldz# = sc_getCollisionSlideZ()
x# = x# + oldx# : z# = z# + oldz#
endif
rem ny#<0 means the player has hit a ceiling rather than a floor
if ny#>slope#
rem only on ground if standing on flat ground
ground = 1
vy# = 0
else
ground = 0
rem if player has hit a flat ceiling then stop vy# movement
if ny#<-slope# then vy# = gravity#
endif
else
rem nothing below player, not on ground, add vertical speed to player
oldy# = oldy# + vy#
ground = 0
endif
rem jumptimer will decrease only when player is back on ground
rem creates a pause between two successive jumps
if ground = 1 and jumptimer>0 then dec jumptimer
rem handle horizontal movement as sliding
rem player only collides with group 1 (level) objs and moves freely through others
collide = sc_SphereSlideGroup(1,oldx#,oldy#,oldz#,x#,oldy#,z#,radius#,0)
if collide>0
rem if hit, reposition player, halt movement vector
x# = sc_getCollisionSlideX()
oldy# = sc_getCollisionSlideY()
z# = sc_getCollisionSlideZ()
vx# = 0
vz# = 0
rem code for giving the player a jumping help up stairs
rem if slope# is set very high but stairs are still required
dy# = oldy#-sc_getStaticCollisionY()
if dy#<slope# and dy#>0 and ground=1 then vy# = 0.5
endif
`Edit camera height while crouching/moving
height#=140
if keystate(46) then height#=85 `crouch key is 'C'
mheight=0
if Moving=1
t#=timer()
if prevMove=0
movetimer=t#
endif
if keystate(42)=0
mheight=sin((1000-(t#-movetimer))/2.77777777777)*3
if t#>movetimer+1000
movetimer=t#
if ground=1 then play_feet()
endif
`if mheight/3>85 and ground=1 then play_feet()
else
mheight=sin((500-(t#-movetimer))/2.77777777777)*3
if t#>movetimer+500
movetimer=t#
if ground=1 then play_feet()
endif
`if mheight/3>80 and ground=1 then play_feet()
endif
prevMove=1
else
prevMove=0
endif
height#=height#+mheight
rem check for bumping head
collide = sc_SphereSlideGroup(1,oldx#,oldy#+height#,oldz#,x#,oldy#+height#,z#,radius#,0)
if collide>0
rem if hit, reposition player, halt movement vector
x# = sc_getCollisionSlideX()
oldy# = sc_getCollisionSlideY()-height#
z# = sc_getCollisionSlideZ()
vx# = 0
vz# = 0
endif
rem position the player
position object 1,x#,oldy#,z#
sc_updateObject 1
prevground=ground
endfunction
