Sorry your browser is not supported!

///////////////////////////////////////
//       PS 1.4 Normal mapping       //
//    by Carlos(Darkcoder)Wilkes     //
//      http://darkcoder.co.uk       //
//     [email protected]       //
///////////////////////////////////////

float4x4 worldViewProjection : WorldViewProjection;
float4x4 world               : World;

float3 lightDirection;
float3 lightColour;
float3 ambientColour;

// Textures
texture Texture0 <string resourceName = "";>;
texture Texture1 <string resourceName = "";>;

// Samplers
sampler2D diffuseSampler = sampler_state
{
	texture = <Texture0>;
};
sampler2D normalSampler = sampler_state
{
	texture = <Texture1>;
};

// Vertex shader
void vsMain0(
	  in    float4 iPosition : POSITION
	, in    float3 iT        : TANGENT
	, in    float3 iB        : BINORMAL
	, in    float3 iN        : NORMAL
	, out   float4 oPosition : POSITION
	, out   float3 oLight    : TEXCOORD1
	, inout float2 ioUv0     : TEXCOORD0 )
{
	// Create matrix to transform between world and tangent space
	float3x3 tbn = { iT, iB, iN };
	         tbn = mul( tbn, world );
	
	// Calculate outputs
	oPosition = mul( iPosition, worldViewProjection );
	oLight    = mul( tbn, lightDirection );
}

// Pixel shader
void psMain0(
	  in    float2 iUv0    : TEXCOORD0
	, in    float3 iLight  : TEXCOORD1
	, out   float4 oColour : COLOR0 )
{
	// Read textures
	float4 diffuse = tex2D( diffuseSampler, iUv0 );
	float3 normal  = tex2D( normalSampler, iUv0 ).rgb * 2.0 - 1.0;
	
	// Calculate illumination from light
	float illumination = max( dot( normal, iLight ), 0.0 );
	
	// Calculate outputs
	oColour.rgb = diffuse.rgb * ambientColour // Ambient contribution
	            + diffuse.rgb * lightColour * illumination; // Light contribution
	oColour.a   = diffuse.a;
}

// Technique
technique normalMapping
{
	pass p0
	{
		vertexShader = compile vs_1_1 vsMain0();
		pixelShader  = compile ps_1_4 psMain0();
	}
}

vectorID as integer = 1
null = make vector4(vectorID)


set vector4 vectorID, x, y, z, 0.0
normalize vector4 vectorID, vectorID
set effect constant vector 1, "lightDirection", vectorID

set vector4 vectorID, red, green, blue, 0.0
set effect constant vector 1, "lightColour", vectorID

set vector4 vectorID, red, green, blue, 0.0
set effect constant vector 1, "ambientColour", vectorID