2D Sprite Collision Not Working - GameCreators Forum

Author

Message

Sli3her

15

Years of Service

User Offline

Joined: 20th Feb 2011

Location: Deep in code...

Posted: 21st Feb 2011 06:10

Link

Hey all, new here at the forums. I just started programming with DBPro not so long ago and I decided to work on a frogger-like game. Anyways I've got it almost working except for collisions between the frog and cars. I have two cars that move across the screen in opposite directions, the frog of course can only be moved forward or backward. I thought I would try using the SPRITE HIT() command, but cannot get it to execute properly. Here's an example of what I'm attempting to do:

IF SPRITE HIT(FrogSprite, 0)
PLAY SOUND 1
DEC LivesVar
Reset the frog
ENDIF

If you need the full source code just let me know. Thanks for your time!

Back to top

Profile PM

Grog Grueslayer

Valued Member

21

Years of Service

User Offline

Joined: 30th May 2005

Playing: Green Hell

Posted: 21st Feb 2011 09:15

Link

Try using SPRITE COLLISION() instead. SPRITE HIT() only registers a hit around the edge of the sprite while SPRITE COLLISION() registers a hit within the sprite.

The following code snip creates two sprites and checks for SPRITE HIT() and SPRITE COLLISION(). Move the mouse to the center box.

+ Code Snippet

` Create some boxes
ink rgb(255,0,0),0
box 0,0,50,50
get image 1,0,0,50,50,1
ink rgb(0,255,0),0
box 0,0,50,50
get image 2,0,0,50,50,1

` Create two sprites
sprite 1,screen width()/2-25,screen height()/2-25,1
sprite 2,0,0,2
offset sprite 2,25,25

hide mouse

do

 ` Show the sprite on the mouse coordinates
 sprite 2,mousex(),mousey(),2

 ` Check for sprite hit
 if sprite hit(2,0)
  text 0,0,"SPRITE HIT!"
  inc SpHit
 endif
 
 ` Check for sprite collision
 if sprite collision(2,0)
  text 0,20,"SPRITE COLLISION!"
  inc SCol
 endif

 ` Show number of hits and collisions
 text 0,40,"Hits: "+str$(SpHit)
 text 0,60,"Collisions: "+str$(SCol)

loop

Back to top

Profile PM Email

Sli3her

15

Years of Service

User Offline

Joined: 20th Feb 2011

Location: Deep in code...

Posted: 21st Feb 2011 17:33

Link

Grog, I failed to mention that I've also tried using that command with no luck. Maybe I will try checking for X, Y, coordinates if I can't get either of these commands to work. Below is the source code.

`********** LOAD PROGRAM VARIABLES & IMAGES**********
GLOBAL GameState$ = "play"  `use this to keep track of game state
GLOBAL LivesLeft = 5

GLOBAL WinSound = 1
GLOBAL WinSound2 = 2

GLOBAL FrogX = 0              `dummy number for now
GLOBAL FrogY = 0              `dummy number for now

GLOBAL CarOneX = 840
GLOBAL CarOneY = 250
GLOBAL CarOneSpeed = 0

GLOBAL CarTwoX = -110
GLOBAL CarTwoY = 300
GLOBAL CarTwoSpeed = 0

GLOBAL BGImage = 1          `background ref. number

GLOBAL FrogImage = 2        `frog image ref. number
GLOBAL FrogSprite = 2        `frog sprite ref. number

GLOBAL CarOneImage = 3    `car facing left
GLOBAL CarOneSprite = 3    `car facing left

GLOBAL CarTwoImage = 4
GLOBAL CarTwoSprite = 4

HIDE MOUSE

`********** PROGRAM LOOP **********
DisplaySplash()
LoadImages()
SetupDisplay()

DO

CheckForInput()
    UpdateScreen()
    CheckForCollide()
    CheckForWin()
    `DebugOnly()
    
    SYNC
    
    IF GameState$ = "win" 
        SLEEP 5000
        EXIT
    ENDIF
    
LOOP

ThanksForPlaying()

END

`********** PROGRAM FUNCTIONS **********
FUNCTION DisplaySplash()
    
    SET TEXT SIZE 45
    INK RGB(0,255,0), 0
    CENTER TEXT 320, 200, "DarkFrogger"
    
    SET TEXT SIZE 25
    INK RGB(128,128,255), 0
    CENTER TEXT 320, 300, "Press any key to start..."
    
    WAIT KEY
    
    CLS
    
ENDFUNCTION

FUNCTION LoadImages()
    
    SET IMAGE COLORKEY 255, 255, 255
    
    LOAD SOUND "media\Bleep03.wav", WinSound
    LOAD SOUND "media\AlienSquidge01.wav", WinSound2
    
    LOAD IMAGE "media\SmallFroggerBG.bmp", BGImage      `load bg into memory

LOAD BITMAP "media\frog.png", FrogImage                  `load frog image into memory
    GET IMAGE FrogImage, 0, 0, 32, 32                           `grab entire frog image
    
    LOAD BITMAP "media\Car1.bmp", CarOneImage             `load car1 into memory
    GET IMAGE CarOneImage, 0, 0, 108, 81                      `grab entire car1 image   
        
    LOAD BITMAP "media\Car2.bmp", CarTwoImage             `load car2 into memory
    GET IMAGE CarTwoImage, 0, 0, 104, 80                     `grab entire car2 image

SET CURRENT BITMAP 0                                          `draw to the screen

SPRITE FrogSprite, 999, 999, FrogImage                     `make sprite from frog image
    SPRITE CarOneSprite, 999, 999, CarOneImage
    SPRITE CarTwoSprite, 999, 999, CarTwoImage
    
ENDFUNCTION

FUNCTION SetupDisplay()
    
    SYNC ON
    SYNC RATE 10
    
    RANDOMIZE TIMER()
    
    GetNewCarSpeed()
    
    FrogX = (SCREEN WIDTH() / 2) - (SPRITE WIDTH(FrogSprite) / 2)       `set frog to middle of screen
    FrogY = SCREEN HEIGHT() - 35                                                     `set frog in sidewalk
    
ENDFUNCTION

FUNCTION CheckForInput()
    
    IF UPKEY() THEN FrogY = FrogY - 3
    
    IF DOWNKEY() THEN FrogY = FrogY + 3
    
ENDFUNCTION

FUNCTION UpdateScreen()
    
    PASTE IMAGE BGImage, 0, 0
    
    PASTE SPRITE FrogSprite, FrogX, FrogY
    PASTE SPRITE CarOneSprite, CarOneX, CarOneY
    PASTE SPRITE CarTwoSprite, CarTwoX, CarTwoY
    
    MoveCars()
    
    INK 0, 0
    SET TEXT SIZE 20
    SET TEXT TO NORMAL
    TEXT 20, 20, "Lives: " + STR$(LivesLeft)
    
ENDFUNCTION

FUNCTION MoveCars()
    
    DEC CarOneX, CarOneSpeed
    INC CarTwoX, CarTwoSpeed
    
    IF CarOneX < (SCREEN WIDTH() - 840)
        CarOneX = (SCREEN WIDTH() + 200)
        GetNewCarSpeed()
    ENDIF
    
    
    IF CarTwoX > (SCREEN WIDTH() + 200)
        CarTwoX = (SCREEN WIDTH() - 840)
        GetNewCarSpeed()
    ENDIF
    
ENDFUNCTION

FUNCTION CheckForCollide()
    
    FrogLocationX = (FrogX + 16)
    FrogLocationY = (FrogY + 16)
    
   
    
        
        PLAY SOUND WinSound2
            
        SLEEP 2000
        
        FrogX = (SCREEN WIDTH() / 2) - (SPRITE WIDTH(FrogSprite) / 2)
        FrogY = SCREEN HEIGHT() - 35
         
        DEC LivesLeft
    
ENDFUNCTION

FUNCTION CheckForWin()
    
    IF LivesLeft = 0
        
        SET TEXT SIZE 30
        SET TEXT TO BOLD
        
        INK 0, 0
        TEXT 275, 100, "YOU'RE DEAD!"
        
        GameState$ = "win"
        
    ENDIF
    
    
    IF FrogY <= 215

SET TEXT SIZE 30
        SET TEXT TO BOLD

INK 0, 0
        TEXT 275, 100, "YOU MADE IT!"

PLAY SOUND WinSound
        
        GameState$ = "win"

ENDIF
    
ENDFUNCTION

FUNCTION ThanksForPlaying()
    
    CLS
    
    INK RGB(0,255,0), 0
    SET TEXT SIZE 45
    CENTER TEXT 320, 200, "Thanks for playing!"
    
    INK RGB(128,128,255), 0
    SET TEXT SIZE 20
    CENTER TEXT 320, 280, "Developed By: Sli3her"
    CENTER TEXT 320, 300, "Brain Fog Studios"
    CENTER TEXT 320, 350, "Press any key to quit..."
    
    SYNC
    
    WAIT KEY
    
    SYNC OFF
    
ENDFUNCTION

FUNCTION GetNewCarSpeed()
    
    CarOneSpeed = RND(20)
    CarTwoSpeed = RND(20)
    
    IF CarOneSpeed < 10 THEN CarOneSpeed = 10
    IF CarTwoSpeed < 10 THEN CarTwoSpeed = 10
    
ENDFUNCTION

FUNCTION DebugOnly()
    
    SET TEXT SIZE 20
    INK 0,0
    
    TEXT 50, 50, "FrogX = " + STR$(FrogX)
    TEXT 50, 70, "FrogY = " + STR$(FrogY)
    TEXT 50, 90, "CarOneSpeed: " + STR$(CarOneSpeed)
    TEXT 50, 110, "CarTwoSpeed: " + STR$(CarTwoSpeed)
    
ENDFUNCTION

+ Code Snippet

`********** LOAD PROGRAM VARIABLES & IMAGES**********
GLOBAL GameState$ = "play"  `use this to keep track of game state
GLOBAL LivesLeft = 5

GLOBAL WinSound = 1
GLOBAL WinSound2 = 2

GLOBAL FrogX = 0              `dummy number for now
GLOBAL FrogY = 0              `dummy number for now

GLOBAL CarOneX = 840
GLOBAL CarOneY = 250
GLOBAL CarOneSpeed = 0

GLOBAL CarTwoX = -110
GLOBAL CarTwoY = 300
GLOBAL CarTwoSpeed = 0

GLOBAL BGImage = 1          `background ref. number

GLOBAL FrogImage = 2        `frog image ref. number
GLOBAL FrogSprite = 2        `frog sprite ref. number

GLOBAL CarOneImage = 3    `car facing left
GLOBAL CarOneSprite = 3    `car facing left

GLOBAL CarTwoImage = 4
GLOBAL CarTwoSprite = 4

HIDE MOUSE


`********** PROGRAM LOOP **********
DisplaySplash()
LoadImages()
SetupDisplay()

DO

    CheckForInput()
    UpdateScreen()
    CheckForCollide()
    CheckForWin()
    `DebugOnly()
    
    SYNC
    
    IF GameState$ = "win" 
        SLEEP 5000
        EXIT
    ENDIF
    
LOOP


ThanksForPlaying()

END


`********** PROGRAM FUNCTIONS **********
FUNCTION DisplaySplash()
    
    SET TEXT SIZE 45
    INK RGB(0,255,0), 0
    CENTER TEXT 320, 200, "DarkFrogger"
    
    SET TEXT SIZE 25
    INK RGB(128,128,255), 0
    CENTER TEXT 320, 300, "Press any key to start..."
    
    WAIT KEY
    
    CLS
    
ENDFUNCTION


FUNCTION LoadImages()
    
    SET IMAGE COLORKEY 255, 255, 255
    
    LOAD SOUND "media\Bleep03.wav", WinSound
    LOAD SOUND "media\AlienSquidge01.wav", WinSound2
    
    LOAD IMAGE "media\SmallFroggerBG.bmp", BGImage      `load bg into memory

    LOAD BITMAP "media\frog.png", FrogImage                  `load frog image into memory
    GET IMAGE FrogImage, 0, 0, 32, 32                           `grab entire frog image
    
    LOAD BITMAP "media\Car1.bmp", CarOneImage             `load car1 into memory
    GET IMAGE CarOneImage, 0, 0, 108, 81                      `grab entire car1 image   
        
    LOAD BITMAP "media\Car2.bmp", CarTwoImage             `load car2 into memory
    GET IMAGE CarTwoImage, 0, 0, 104, 80                     `grab entire car2 image    

    SET CURRENT BITMAP 0                                          `draw to the screen

    SPRITE FrogSprite, 999, 999, FrogImage                     `make sprite from frog image
    SPRITE CarOneSprite, 999, 999, CarOneImage
    SPRITE CarTwoSprite, 999, 999, CarTwoImage
    
ENDFUNCTION


FUNCTION SetupDisplay()
    
    SYNC ON
    SYNC RATE 10
    
    RANDOMIZE TIMER()
    
    GetNewCarSpeed()
    
    FrogX = (SCREEN WIDTH() / 2) - (SPRITE WIDTH(FrogSprite) / 2)       `set frog to middle of screen
    FrogY = SCREEN HEIGHT() - 35                                                     `set frog in sidewalk
    
ENDFUNCTION


FUNCTION CheckForInput()
    
    IF UPKEY() THEN FrogY = FrogY - 3
    
    IF DOWNKEY() THEN FrogY = FrogY + 3
    
ENDFUNCTION


FUNCTION UpdateScreen()
    
    PASTE IMAGE BGImage, 0, 0
    
    PASTE SPRITE FrogSprite, FrogX, FrogY
    PASTE SPRITE CarOneSprite, CarOneX, CarOneY
    PASTE SPRITE CarTwoSprite, CarTwoX, CarTwoY
    
    MoveCars()
    
    INK 0, 0
    SET TEXT SIZE 20
    SET TEXT TO NORMAL
    TEXT 20, 20, "Lives: " + STR$(LivesLeft)
    
ENDFUNCTION


FUNCTION MoveCars()
    
    DEC CarOneX, CarOneSpeed
    INC CarTwoX, CarTwoSpeed
    
    IF CarOneX < (SCREEN WIDTH() - 840)
        CarOneX = (SCREEN WIDTH() + 200)
        GetNewCarSpeed()
    ENDIF
    
    
    IF CarTwoX > (SCREEN WIDTH() + 200)
        CarTwoX = (SCREEN WIDTH() - 840)
        GetNewCarSpeed()
    ENDIF
    
ENDFUNCTION


FUNCTION CheckForCollide()
    
    FrogLocationX = (FrogX + 16)
    FrogLocationY = (FrogY + 16)
    
   
    
        
        PLAY SOUND WinSound2
            
        SLEEP 2000
        
        FrogX = (SCREEN WIDTH() / 2) - (SPRITE WIDTH(FrogSprite) / 2)
        FrogY = SCREEN HEIGHT() - 35
         
        DEC LivesLeft
    
ENDFUNCTION


FUNCTION CheckForWin()
    
    IF LivesLeft = 0
        
        SET TEXT SIZE 30
        SET TEXT TO BOLD
        
        INK 0, 0
        TEXT 275, 100, "YOU'RE DEAD!"
        
        GameState$ = "win"
        
    ENDIF
    
    
    IF FrogY <= 215

        SET TEXT SIZE 30
        SET TEXT TO BOLD

        INK 0, 0
        TEXT 275, 100, "YOU MADE IT!"

        PLAY SOUND WinSound
        
        GameState$ = "win"

    ENDIF
    
ENDFUNCTION


FUNCTION ThanksForPlaying()
    
    CLS
    
    INK RGB(0,255,0), 0
    SET TEXT SIZE 45
    CENTER TEXT 320, 200, "Thanks for playing!"
    
    INK RGB(128,128,255), 0
    SET TEXT SIZE 20
    CENTER TEXT 320, 280, "Developed By: Sli3her"
    CENTER TEXT 320, 300, "Brain Fog Studios"
    CENTER TEXT 320, 350, "Press any key to quit..."
    
    SYNC
    
    WAIT KEY
    
    SYNC OFF
    
ENDFUNCTION


FUNCTION GetNewCarSpeed()
    
    CarOneSpeed = RND(20)
    CarTwoSpeed = RND(20)
    
    IF CarOneSpeed < 10 THEN CarOneSpeed = 10
    IF CarTwoSpeed < 10 THEN CarTwoSpeed = 10
    
ENDFUNCTION


FUNCTION DebugOnly()
    
    SET TEXT SIZE 20
    INK 0,0
    
    TEXT 50, 50, "FrogX = " + STR$(FrogX)
    TEXT 50, 70, "FrogY = " + STR$(FrogY)
    TEXT 50, 90, "CarOneSpeed: " + STR$(CarOneSpeed)
    TEXT 50, 110, "CarTwoSpeed: " + STR$(CarTwoSpeed)
    
ENDFUNCTION

Back to top

Profile PM

Grog Grueslayer

Valued Member

21

Years of Service

User Offline

Joined: 30th May 2005

Playing: Green Hell

Posted: 21st Feb 2011 18:22

Link

It's because of this:

+ Code Snippet

    SPRITE FrogSprite, 999, 999, FrogImage                     `make sprite from frog image
    SPRITE CarOneSprite, 999, 999, CarOneImage
    SPRITE CarTwoSprite, 999, 999, CarTwoImage

And this:

+ Code Snippet

FUNCTION UpdateScreen()
    
    PASTE IMAGE BGImage, 0, 0
    
    PASTE SPRITE FrogSprite, FrogX, FrogY
    PASTE SPRITE CarOneSprite, CarOneX, CarOneY
    PASTE SPRITE CarTwoSprite, CarTwoX, CarTwoY
    
    MoveCars()
    
    INK 0, 0
    SET TEXT SIZE 20
    SET TEXT TO NORMAL
    TEXT 20, 20, "Lives: " + STR$(LivesLeft)
    
ENDFUNCTION

In the first code snip you place all sprites at 999,999. But because you use PASTE SPRITE all the sprites are still on top of each other and thus colliding all the time. Change PASTE SPRITE to SPRITE and any collision code you add should work fine.

Back to top

Profile PM Email

Sli3her

15

Years of Service

User Offline

Joined: 20th Feb 2011

Location: Deep in code...

Posted: 22nd Feb 2011 00:12

Link

Thanks Grog, works like it should, except that I was under the impression the SPRITE HIT command detects actual impact where as SPRITE COLLISION detects a bounded rectangle collision. For some reason they both seem to do the same thing for me. I ended up cropping the images as close as I could to each object. That seems to help. I've included the final .exe if anyone cares to comment on it or my code. I used to code a lot in VBScript and Python years ago and I wanted to get back with it. So far, I like DBPro a lot. Thanks again Grog!

Back to top

Profile PM

Grog Grueslayer

Valued Member

21

Years of Service

User Offline

Joined: 30th May 2005

Playing: Green Hell

Posted: 22nd Feb 2011 05:25

Link

Np.

SPRITE HIT() looks for the outer edge being hit while SPRITE COLLISION() looks for sprites overlapping each other. Generally it's better to use SPRITE COLLISION() for more accuracy. Yeah, the image size of the sprite determines the area that is detected as colliding. If the actual graphic was only 25x25 but the actual image was 200x200 even if it's a transparency it'll detect collision anywhere within that 200x200 area. There are several pixel perfect routines that people use. Just use the search box at the bottom of this screen and type "pixel perfect".

Your game looks good. Was this for a school project?

Back to top

Profile PM Email

Sli3her

15

Years of Service

User Offline

Joined: 20th Feb 2011

Location: Deep in code...

Posted: 22nd Feb 2011 05:48

Link

Thanks for clearing up the difference between those two commands. I'm reading through DarkBasic Programming by Jerry Ford. I'm just about through the entire book and wanted to make a game from scratch, just to reinforce all the concepts in my own mind. As you can see I'm not much of an artist,lol. Here's the entire code if anyone cares to look through it.

`********** LOAD PROGRAM VARIABLES & IMAGES**********
GLOBAL GameState$ = "play"  `use this to keep track of game state
GLOBAL LivesLeft = 5

GLOBAL WinSound = 1
GLOBAL WinSound2 = 2

GLOBAL FrogX = 0              `dummy number for now
GLOBAL FrogY = 0              `dummy number for now

GLOBAL CarOneX = 840
GLOBAL CarOneY = 260
GLOBAL CarOneSpeed = 0

GLOBAL CarTwoX = -110
GLOBAL CarTwoY = 320
GLOBAL CarTwoSpeed = 0

GLOBAL BGImage = 1          `background ref. number

GLOBAL FrogImage = 2        `frog image ref. number
GLOBAL FrogSprite = 2        `frog sprite ref. number

GLOBAL CarOneImage = 3    `car facing left
GLOBAL CarOneSprite = 3    `car facing left

GLOBAL CarTwoImage = 4
GLOBAL CarTwoSprite = 4

HIDE MOUSE

`********** PROGRAM LOOP **********
DisplaySplash()
LoadImages()
SetupDisplay()

DO

CheckForInput()
    UpdateScreen()
    CheckForCollide()
    CheckForWin()
    `DebugOnly()
    
    SYNC
    
    IF GameState$ = "win" 
        SLEEP 5000
        HIDE SPRITE FrogSprite
        HIDE SPRITE CarOneSprite
        HIDE SPRITE CarTwoSprite
        EXIT
    ENDIF
    
LOOP

ThanksForPlaying()

END

`********** PROGRAM FUNCTIONS **********
FUNCTION DisplaySplash()
    
    SET TEXT SIZE 45
    INK RGB(0,255,0), 0
    CENTER TEXT 320, 200, "DarkFrogger"
    
    SET TEXT SIZE 25
    INK RGB(128,128,255), 0
    CENTER TEXT 320, 300, "Press any key to start..."
    
    WAIT KEY
    
    CLS
    
ENDFUNCTION

FUNCTION LoadImages()
    
    SET IMAGE COLORKEY 255, 255, 255
    
    LOAD SOUND "media\Bleep03.wav", WinSound
    LOAD SOUND "media\AlienSquidge01.wav", WinSound2
    
    LOAD IMAGE "media\SmallFroggerBG.bmp", BGImage      `load bg into memory

LOAD BITMAP "media\frog.png", FrogImage                  `load frog image into memory
    GET IMAGE FrogImage, 0, 0, 32, 32                           `grab entire frog image
    
    LOAD BITMAP "media\Car1.bmp", CarOneImage             `load car1 into memory
    GET IMAGE CarOneImage, 0, 0, 68, 31                      `grab entire car1 image   
        
    LOAD BITMAP "media\Car2.bmp", CarTwoImage             `load car2 into memory
    GET IMAGE CarTwoImage, 0, 0, 68, 30                     `grab entire car2 image

SET CURRENT BITMAP 0                                          `draw to the screen

SPRITE FrogSprite, 999, 999, FrogImage                     `make sprite from frog image
    SPRITE CarOneSprite, 999, 999, CarOneImage
    SPRITE CarTwoSprite, 999, 999, CarTwoImage
    
ENDFUNCTION

FUNCTION SetupDisplay()
    
    SYNC ON
    SYNC RATE 10
    
    RANDOMIZE TIMER()
    
    GetNewCarSpeed()
    
    FrogX = (SCREEN WIDTH() / 2) - (SPRITE WIDTH(FrogSprite) / 2)       `set frog to middle of screen
    FrogY = SCREEN HEIGHT() - 35                                                     `set frog in sidewalk
    
ENDFUNCTION

FUNCTION CheckForInput()
    
    IF UPKEY() THEN FrogY = FrogY - 3
    
    IF DOWNKEY() THEN FrogY = FrogY + 3
    
ENDFUNCTION

FUNCTION UpdateScreen()
    
    PASTE IMAGE BGImage, 0, 0
    
    SPRITE FrogSprite, FrogX, FrogY, FrogImage
    SPRITE CarOneSprite, CarOneX, CarOneY, CarOneImage
    SPRITE CarTwoSprite, CarTwoX, CarTwoY, CarTwoImage
    
    MoveCars()
    
    INK 0, 0
    SET TEXT SIZE 20
    SET TEXT TO NORMAL
    TEXT 20, 20, "Lives: " + STR$(LivesLeft)
    
ENDFUNCTION

FUNCTION MoveCars()
    
    DEC CarOneX, CarOneSpeed
    INC CarTwoX, CarTwoSpeed
    
    IF CarOneX < (SCREEN WIDTH() - 840)
        CarOneX = (SCREEN WIDTH() + 200)
        GetNewCarSpeed()
    ENDIF
    
    
    IF CarTwoX > (SCREEN WIDTH() + 200)
        CarTwoX = (SCREEN WIDTH() - 840)
        GetNewCarSpeed()
    ENDIF
    
ENDFUNCTION

FUNCTION CheckForCollide()
    
   IF SPRITE HIT(FrogSprite, 0)
    
        PLAY SOUND WinSound2
            
        SLEEP 2000
        
        FrogX = (SCREEN WIDTH() / 2) - (SPRITE WIDTH(FrogSprite) / 2)
        FrogY = SCREEN HEIGHT() - 35
         
        DEC LivesLeft
        
    ENDIF
    
ENDFUNCTION

FUNCTION CheckForWin()
    
    IF LivesLeft = 0
        
        SET TEXT SIZE 30
        SET TEXT TO BOLD
        
        INK 0, 0
        TEXT 275, 100, "YOU'RE DEAD!"
        
        GameState$ = "win"
        
    ENDIF
    
    
    IF FrogY <= 215

SET TEXT SIZE 30
        SET TEXT TO BOLD

INK 0, 0
        TEXT 275, 100, "YOU MADE IT!"

PLAY SOUND WinSound
        
        GameState$ = "win"
        
    ENDIF
    
ENDFUNCTION

FUNCTION ThanksForPlaying()
    
    CLS
    
    INK RGB(0,255,0), 0
    SET TEXT SIZE 45
    CENTER TEXT 320, 200, "Thanks for playing!"
    
    INK RGB(128,128,255), 0
    SET TEXT SIZE 20
    CENTER TEXT 320, 280, "Developed By: Sli3her"
    CENTER TEXT 320, 300, "Brain Fog Studios"
    CENTER TEXT 320, 350, "Press any key to quit..."
    
    SYNC
    
    WAIT KEY
    
    SYNC OFF
    
ENDFUNCTION

FUNCTION GetNewCarSpeed()
    
    CarOneSpeed = RND(20)
    CarTwoSpeed = RND(20)
    
    IF CarOneSpeed < 10 THEN CarOneSpeed = 10
    IF CarTwoSpeed < 10 THEN CarTwoSpeed = 10
    
ENDFUNCTION

FUNCTION DebugOnly()
    
    SET TEXT SIZE 20
    INK 0,0
    
    TEXT 50, 50, "FrogX = " + STR$(FrogX)
    TEXT 50, 70, "FrogY = " + STR$(FrogY)
    TEXT 50, 90, "CarOneSpeed: " + STR$(CarOneSpeed)
    TEXT 50, 110, "CarTwoSpeed: " + STR$(CarTwoSpeed)
    
ENDFUNCTION

+ Code Snippet

`********** LOAD PROGRAM VARIABLES & IMAGES**********
GLOBAL GameState$ = "play"  `use this to keep track of game state
GLOBAL LivesLeft = 5

GLOBAL WinSound = 1
GLOBAL WinSound2 = 2

GLOBAL FrogX = 0              `dummy number for now
GLOBAL FrogY = 0              `dummy number for now

GLOBAL CarOneX = 840
GLOBAL CarOneY = 260
GLOBAL CarOneSpeed = 0

GLOBAL CarTwoX = -110
GLOBAL CarTwoY = 320
GLOBAL CarTwoSpeed = 0

GLOBAL BGImage = 1          `background ref. number

GLOBAL FrogImage = 2        `frog image ref. number
GLOBAL FrogSprite = 2        `frog sprite ref. number

GLOBAL CarOneImage = 3    `car facing left
GLOBAL CarOneSprite = 3    `car facing left

GLOBAL CarTwoImage = 4
GLOBAL CarTwoSprite = 4

HIDE MOUSE


`********** PROGRAM LOOP **********
DisplaySplash()
LoadImages()
SetupDisplay()

DO

    CheckForInput()
    UpdateScreen()
    CheckForCollide()
    CheckForWin()
    `DebugOnly()
    
    SYNC
    
    IF GameState$ = "win" 
        SLEEP 5000
        HIDE SPRITE FrogSprite
        HIDE SPRITE CarOneSprite
        HIDE SPRITE CarTwoSprite
        EXIT
    ENDIF
    
LOOP


ThanksForPlaying()

END


`********** PROGRAM FUNCTIONS **********
FUNCTION DisplaySplash()
    
    SET TEXT SIZE 45
    INK RGB(0,255,0), 0
    CENTER TEXT 320, 200, "DarkFrogger"
    
    SET TEXT SIZE 25
    INK RGB(128,128,255), 0
    CENTER TEXT 320, 300, "Press any key to start..."
    
    WAIT KEY
    
    CLS
    
ENDFUNCTION


FUNCTION LoadImages()
    
    SET IMAGE COLORKEY 255, 255, 255
    
    LOAD SOUND "media\Bleep03.wav", WinSound
    LOAD SOUND "media\AlienSquidge01.wav", WinSound2
    
    LOAD IMAGE "media\SmallFroggerBG.bmp", BGImage      `load bg into memory

    LOAD BITMAP "media\frog.png", FrogImage                  `load frog image into memory
    GET IMAGE FrogImage, 0, 0, 32, 32                           `grab entire frog image
    
    LOAD BITMAP "media\Car1.bmp", CarOneImage             `load car1 into memory
    GET IMAGE CarOneImage, 0, 0, 68, 31                      `grab entire car1 image   
        
    LOAD BITMAP "media\Car2.bmp", CarTwoImage             `load car2 into memory
    GET IMAGE CarTwoImage, 0, 0, 68, 30                     `grab entire car2 image    

    SET CURRENT BITMAP 0                                          `draw to the screen

    SPRITE FrogSprite, 999, 999, FrogImage                     `make sprite from frog image
    SPRITE CarOneSprite, 999, 999, CarOneImage
    SPRITE CarTwoSprite, 999, 999, CarTwoImage
    
ENDFUNCTION


FUNCTION SetupDisplay()
    
    SYNC ON
    SYNC RATE 10
    
    RANDOMIZE TIMER()
    
    GetNewCarSpeed()
    
    FrogX = (SCREEN WIDTH() / 2) - (SPRITE WIDTH(FrogSprite) / 2)       `set frog to middle of screen
    FrogY = SCREEN HEIGHT() - 35                                                     `set frog in sidewalk
    
ENDFUNCTION


FUNCTION CheckForInput()
    
    IF UPKEY() THEN FrogY = FrogY - 3
    
    IF DOWNKEY() THEN FrogY = FrogY + 3
    
ENDFUNCTION


FUNCTION UpdateScreen()
    
    PASTE IMAGE BGImage, 0, 0
    
    SPRITE FrogSprite, FrogX, FrogY, FrogImage
    SPRITE CarOneSprite, CarOneX, CarOneY, CarOneImage
    SPRITE CarTwoSprite, CarTwoX, CarTwoY, CarTwoImage
    
    MoveCars()
    
    INK 0, 0
    SET TEXT SIZE 20
    SET TEXT TO NORMAL
    TEXT 20, 20, "Lives: " + STR$(LivesLeft)
    
ENDFUNCTION


FUNCTION MoveCars()
    
    DEC CarOneX, CarOneSpeed
    INC CarTwoX, CarTwoSpeed
    
    IF CarOneX < (SCREEN WIDTH() - 840)
        CarOneX = (SCREEN WIDTH() + 200)
        GetNewCarSpeed()
    ENDIF
    
    
    IF CarTwoX > (SCREEN WIDTH() + 200)
        CarTwoX = (SCREEN WIDTH() - 840)
        GetNewCarSpeed()
    ENDIF
    
ENDFUNCTION


FUNCTION CheckForCollide()
    
   IF SPRITE HIT(FrogSprite, 0)
    
        PLAY SOUND WinSound2
            
        SLEEP 2000
        
        FrogX = (SCREEN WIDTH() / 2) - (SPRITE WIDTH(FrogSprite) / 2)
        FrogY = SCREEN HEIGHT() - 35
         
        DEC LivesLeft
        
    ENDIF
    
ENDFUNCTION


FUNCTION CheckForWin()
    
    IF LivesLeft = 0
        
        SET TEXT SIZE 30
        SET TEXT TO BOLD
        
        INK 0, 0
        TEXT 275, 100, "YOU'RE DEAD!"
        
        GameState$ = "win"
        
    ENDIF
    
    
    IF FrogY <= 215

        SET TEXT SIZE 30
        SET TEXT TO BOLD

        INK 0, 0
        TEXT 275, 100, "YOU MADE IT!"

        PLAY SOUND WinSound
        
        GameState$ = "win"
        
    ENDIF
    
ENDFUNCTION


FUNCTION ThanksForPlaying()
    
    CLS
    
    INK RGB(0,255,0), 0
    SET TEXT SIZE 45
    CENTER TEXT 320, 200, "Thanks for playing!"
    
    INK RGB(128,128,255), 0
    SET TEXT SIZE 20
    CENTER TEXT 320, 280, "Developed By: Sli3her"
    CENTER TEXT 320, 300, "Brain Fog Studios"
    CENTER TEXT 320, 350, "Press any key to quit..."
    
    SYNC
    
    WAIT KEY
    
    SYNC OFF
    
ENDFUNCTION


FUNCTION GetNewCarSpeed()
    
    CarOneSpeed = RND(20)
    CarTwoSpeed = RND(20)
    
    IF CarOneSpeed < 10 THEN CarOneSpeed = 10
    IF CarTwoSpeed < 10 THEN CarTwoSpeed = 10
    
ENDFUNCTION


FUNCTION DebugOnly()
    
    SET TEXT SIZE 20
    INK 0,0
    
    TEXT 50, 50, "FrogX = " + STR$(FrogX)
    TEXT 50, 70, "FrogY = " + STR$(FrogY)
    TEXT 50, 90, "CarOneSpeed: " + STR$(CarOneSpeed)
    TEXT 50, 110, "CarTwoSpeed: " + STR$(CarTwoSpeed)
    
ENDFUNCTION

Back to top

Profile PM

Sorry your browser is not supported!

DarkBASIC Professional Discussion / 2D Sprite Collision Not Working