This isn't a game, but it shows the concept of using DBC code to texture limbs with separate images. It may not help you until you understand the concept of a limb. There are several examples and discussions on these forums if you search:
set display mode 800,600,32
sync on
sync rate 0
_main:
rem build textures
gosub _create_textures
rem make body
gosub _build_body
position camera 0,10,-50
do
turn object left 1,.1
sync
loop
end
_create_textures:
rem make textures
set text font "arial",1
set text size 40
sync
rem read data strings to texture body parts with
ink rgb(255,255,255),0
restore _body_parts
for img=1 to 6
rem read the names and create an image to use as a texture
read a$
cls
text 0,0,a$
get image img,0,0,text width(a$),text size()
sync
next img
_body_parts:
data "head"
data "left arm"
data "right arm"
data "body"
data "left leg"
data "right leg"
return
_build_body:
rem make body as the root object
make object cylinder 1,20
rem texture the cylinder with the body texture
texture object 1,4
rem make the head - sphere to limb attached to object 1 (body)
make object sphere 2,8
make mesh from object 2,2
delete object 2
add limb 1,1,2
rem texture the head
texture limb 1,1,1
rem position the head
offset limb 1,1,0,14,0
rem cleanup non longer needed mesh
delete mesh 2
rem add arms - box to limb attached to object 1
make object box 2,20,4,4
make mesh from object 2,2
rem left arm
add limb 1,2,2
offset limb 1,2,-20,8,0
rem texture left arm
texture limb 1,2,2
rem right arm
add limb 1,3,2
offset limb 1,3,20,8,0
rem texture rght arm
texture limb 1,3,3
rem clean up
delete object 2
delete mesh 2
rem add legs
make object box 2,4,20,4
make mesh from object 2,2
rem left leg
add limb 1,4,2
offset limb 1,4,-6,-20,0
rem texture left leg
texture limb 1,4,5
rem right leg
add limb 1,5,2
offset limb 1,5,6,-20,0
rem texture right leg
texture limb 1,5,6
rem clean up
delete object 2
delete mesh 2
returnEnjoy your day.
