Well, I was thinking about creating my own images using Photoshop using the skills I'm going to college for. I have tried to use some of my past 2D images from past courses in a Skysphere. But all of them look blown-up and pixelated. I don't mind the pixies I just wish everything didn't look so close up.
@Van-B I like what you've done. And I played with it a little by changing the mouse control to a keyboard control. I also tried to move the camera as if a player was "flying" in space and eventually lost the stars. For some reason, after adding a little camera movement I lost the planet object. I was using your code as a way to learn the 3D aspects of a space environment. Code is below.
`Starry sky example by Van-B
sync on
sync rate 0
set display mode desktop width(),desktop height(),32
set camera range 1,10000
color backdrop 0
fog color 0
fog on
fog distance 1000,5000
`Make sky texture
set image colorkey 255,0,255
cls rgb(255,0,255)
for a=0 to 512
c=rnd(250)+5
ink rgb(c,c,c),0
`Make 1 in 10 stars a colour
if rnd(9)=1 then ink rgb((c/2)+rnd(127),(c/2)+rnd(127),(c/2)+rnd(127)),rgb(0,0,0)
dot rnd(512),rnd(512)
next a
get image 20,0,0,512,512,1
`Make star plain mesh - adjust plain size to suit
make object plain 19,150,150 : rotate object 19,0,0,90 : fix object pivot 19
make object cube 20,10000 : hide limb 20,0
make mesh from object 19,19
`Add 50 star plains as limbs, randomly
for l=1 to 51
position object 19,rnd(14000)-7000,rnd(14000)-7000,rnd(14000)-7000
point object 19,0,0,0
position object 19,0,0,0
move object 19,8000+rnd(1000)
add limb 20,l,19
offset limb 20,l,object position x(19),object position y(19),object position z(19)
rotate limb 20,l,object angle x(19),object angle y(19),object angle z(19)
next l
`Make mesh 20, and object 20, the sky object
make mesh from object 20,20
delete object 19
delete object 20
make object 20,20,20
texture object 20,20
set object fog 20,0
set object light 20,0
set object cull 20,0
set object texture 20,0,0
ghost object on 20
`Add an object to test
make object sphere 100,1000.0
cx=-2000
move camera cx
`Main loop
do
if upkey()=1 then pitch camera up 0,0.1
if downkey()=1 then pitch camera down 0,0.1
if leftkey()=1 then turn camera left 0,0.1
if rightkey()=1 then turn camera right 0,0.1
if inkey$()="a"
spd=spd+1
if spd>5 then spd=5
cx=cx+spd
endif
if inkey$()="z"
spd=spd-1
if spd<-5 then spd=-5
cx=cx-spd
endif
position object 20,camera position x(),camera position y(),camera position z()
move camera 0,cx
`text 0,0,str$(screen fps())
sync
loop
What I was attempting to do was find a way to see if a player could set a traveling speed by pressing a single key. I also tried to allow the player to shut off "engines" to bring them to a halt. Guess I still have some learning to do LOL.
