Move Object to Player (from any position)

Author

Message

Crabbages

13

Years of Service

User Offline

Joined: 12th Aug 2010

Location:

Posted: 22nd Mar 2011 23:46

Link

Hello everyone.
Soooo the player would be in the centre of the screen and the object (which could spawn anywhere) will travel to the player and allways at a certain speed nomatter the distance.

I feel like I keep coming close but slipping up along the way...is there an answer? I bet it's staring me in the face.
(atm im looking into trigonometry with sin and cos but good grief my brain hurts.)

Thanks for loooking.

Back to top

Profile PM

Hodgey

14

Years of Service

User Offline

Joined: 10th Oct 2009

Location: Australia

Posted: 23rd Mar 2011 12:19

Link

Hi, here is a 2D example, hope it is what you're looking for. If you're looking for a 3d version, I don't have time to write one up right now but maybe on the weekend.

Rem Project: Dark Basic Pro Project
Rem Created: Wednesday, March 23, 2011

Rem ***** Main Source File *****
sync on : sync rate 60

// create type
type object
    x as float
    y as float
    xspeed as float
    yspeed as float
endtype

// create objects
player as object
com as object

// set player values
player.x = 100.00
player.y = 240.00
player.xspeed = 2.00
player.yspeed = 2.00

// set computer's values
com.x = 400.00
com.y = 240.00
com.xspeed = 1.00
com.yspeed = 1.00

// distance
distance as float

do
    cls
    // move player
    if upkey()=1 then dec player.y, player.yspeed
    if downkey()=1 then inc player.y, player.yspeed
    if leftkey()=1 then dec player.x, player.xspeed
    if rightkey()=1 then inc player.x, player.xspeed
    
    // get distance
    distance = get_distance(player.x, com.x, player.y, com.y)
    
    // move computer towards player
    if distance > 10.00
        com.xspeed = sin(asin(((player.x - com.x)/distance)))
        com.yspeed = cos(acos(((player.y - com.y)/distance)))
    else 
        com.xspeed = 1.00
        com.yspeed = 1.00
    endif
    
    inc com.x, com.xspeed
    inc com.y, com.yspeed
    
    text 0, 0, "You are red, use arrowkeys to move around"
    
    ink rgb(255,0,0), 0
    circle int(player.x), int(player.y), 10
    
    ink rgb(0, 255, 0), 0
    circle int(com.x), int(com.y), 10
    
    sync
loop

function get_distance( x1 as float , x2 as float , y1 as float , y2 as float )
// distance formula
    distance as float
    distance = sqrt(((x1 - x2)^2) + ((y1 - y2)^2))
endfunction distance

+ Code Snippet

Rem Project: Dark Basic Pro Project
Rem Created: Wednesday, March 23, 2011

Rem ***** Main Source File *****
sync on : sync rate 60

// create type
type object
    x as float
    y as float
    xspeed as float
    yspeed as float
endtype

// create objects
player as object
com as object

// set player values
player.x = 100.00
player.y = 240.00
player.xspeed = 2.00
player.yspeed = 2.00

// set computer's values
com.x = 400.00
com.y = 240.00
com.xspeed = 1.00
com.yspeed = 1.00

// distance
distance as float

do
    cls
    // move player
    if upkey()=1 then dec player.y, player.yspeed
    if downkey()=1 then inc player.y, player.yspeed
    if leftkey()=1 then dec player.x, player.xspeed
    if rightkey()=1 then inc player.x, player.xspeed
    
    // get distance
    distance = get_distance(player.x, com.x, player.y, com.y)
    
    // move computer towards player
    if distance > 10.00
        com.xspeed = sin(asin(((player.x - com.x)/distance)))
        com.yspeed = cos(acos(((player.y - com.y)/distance)))
    else 
        com.xspeed = 1.00
        com.yspeed = 1.00
    endif
    
    inc com.x, com.xspeed
    inc com.y, com.yspeed
    
    text 0, 0, "You are red, use arrowkeys to move around"
    
    ink rgb(255,0,0), 0
    circle int(player.x), int(player.y), 10
    
    ink rgb(0, 255, 0), 0
    circle int(com.x), int(com.y), 10
    
    sync
loop

function get_distance( x1 as float , x2 as float , y1 as float , y2 as float )
// distance formula
    distance as float
    distance = sqrt(((x1 - x2)^2) + ((y1 - y2)^2))
endfunction distance

A clever person solves a problem, a wise person avoids it - Albert Einstein

Back to top

Profile PM Email

Crabbages

13

Years of Service

User Offline

Joined: 12th Aug 2010

Location:

Posted: 23rd Mar 2011 18:26

Link

Brilliant! Thankyou very much.
You could do a 3D version to help other people and the future me, I had done alot of searching and don't remember a 3d version I just remember a mountain of 404 pages but this alone was wonderful.
I always feel terrible that I only ever ask for help and can't give any...someday.. I should sit down with this and conquer my old enemy trigonometry.

Thank you again

Back to top

Profile PM

kamac

13

Years of Service

User Offline

Joined: 30th Nov 2010

Location: Poland

Posted: 23rd Mar 2011 21:32

Link

( By the way, wrong thread

, next time post it here or here )

Back to top

Profile PM Email

Hodgey

14

Years of Service

User Offline

Joined: 10th Oct 2009

Location: Australia

Posted: 23rd Mar 2011 22:25

Link

Glad it helped. Just realized that the sin and cos functions aren't necessary so to save you a bit of grief here is the same example without the sin and cos which works just as well.

Rem ***** Main Source File *****
sync on : sync rate 60

// create type
type object
    x as float
    y as float
    xspeed as float
    yspeed as float
endtype

// create objects
player as object
com as object

// set player values
player.x = 100.00
player.y = 240.00
player.xspeed = 2.00
player.yspeed = 2.00

// set computer's values
com.x = 400.00
com.y = 240.00
com.xspeed = 1.00
com.yspeed = 1.00

// distance
distance as float

do
    cls
    // move player
    if upkey()=1 then dec player.y, player.yspeed
    if downkey()=1 then inc player.y, player.yspeed
    if leftkey()=1 then dec player.x, player.xspeed
    if rightkey()=1 then inc player.x, player.xspeed
    
    // get distance
    distance = get_distance(player.x, com.x, player.y, com.y)
    
    // move computer towards player
    if distance > 10.00
        com.xspeed = ((player.x - com.x)/distance)
        com.yspeed = ((player.y - com.y)/distance)
    else 
        com.xspeed = 1.00
        com.yspeed = 1.00
    endif
    
    inc com.x, com.xspeed
    inc com.y, com.yspeed
    
    text 0, 0, "You are red, use arrowkeys to move around"
    
    ink rgb(255,0,0), 0
    circle int(player.x), int(player.y), 10
    
    ink rgb(0, 255, 0), 0
    circle int(com.x), int(com.y), 10
    
    sync
loop

function get_distance( x1 as float , x2 as float , y1 as float , y2 as float )
// distance formula
    distance as float
    distance = sqrt(((x1 - x2)^2) + ((y1 - y2)^2))
endfunction distance

+ Code Snippet

Rem ***** Main Source File *****
sync on : sync rate 60

// create type
type object
    x as float
    y as float
    xspeed as float
    yspeed as float
endtype

// create objects
player as object
com as object

// set player values
player.x = 100.00
player.y = 240.00
player.xspeed = 2.00
player.yspeed = 2.00

// set computer's values
com.x = 400.00
com.y = 240.00
com.xspeed = 1.00
com.yspeed = 1.00

// distance
distance as float

do
    cls
    // move player
    if upkey()=1 then dec player.y, player.yspeed
    if downkey()=1 then inc player.y, player.yspeed
    if leftkey()=1 then dec player.x, player.xspeed
    if rightkey()=1 then inc player.x, player.xspeed
    
    // get distance
    distance = get_distance(player.x, com.x, player.y, com.y)
    
    // move computer towards player
    if distance > 10.00
        com.xspeed = ((player.x - com.x)/distance)
        com.yspeed = ((player.y - com.y)/distance)
    else 
        com.xspeed = 1.00
        com.yspeed = 1.00
    endif
    
    inc com.x, com.xspeed
    inc com.y, com.yspeed
    
    text 0, 0, "You are red, use arrowkeys to move around"
    
    ink rgb(255,0,0), 0
    circle int(player.x), int(player.y), 10
    
    ink rgb(0, 255, 0), 0
    circle int(com.x), int(com.y), 10
    
    sync
loop

function get_distance( x1 as float , x2 as float , y1 as float , y2 as float )
// distance formula
    distance as float
    distance = sqrt(((x1 - x2)^2) + ((y1 - y2)^2))
endfunction distance

A clever person solves a problem, a wise person avoids it - Albert Einstein

Back to top

Profile PM Email

Sorry your browser is not supported!

2D All the way! / Move Object to Player (from any position)