Screen image vs texture mapped image.

Author

Message

Rich Dersheimer

AGK Developer

17

Years of Service

User Offline

Joined: 1st Jul 2009

Location: Inside the box

Posted: 6th Apr 2011 23:10

Link

Here's the premise...

A large plane textured with a background image. Since SCROLL BACKDROP no longer works, I'll scroll the texture on the plane.

Is there a formula to size the plane so that the camera image (looking at the plane) is exactly the same as if I had pasted the image on the screen in 2D?

For instance, it seems that using an 800x600 window, an 800x600 plane, and a camera distance of -500z gives a very close match with the pasted full screen image, as illustrated in the snippet below. Hit "s" or "c" to change the display.

+ Code Snippet

set display mode 800,600,32
autocam off

ink 0xFFFFFFFF,0
box 0,0,800,600
ink 0xFFFF0000,0
box 1,1,799,599
ink 0xFFFFFFFF,0
line 400,0,400,600
line 0,300,800,300
text 100,100,"CAMERA"
get image 1,0,0,800,600,3
ink 0xFFFF0000,0
text 100,100,"CAMERA"
ink 0xFFFFFFFF,0
text 100,100,"SCREEN"
get image 2,0,0,800,600,3

make object plane 1,800,600
texture object 1,1
set object emissive 1,0xFFFFFFFF
set object filter 1,0
position camera 0,0,-500
point camera 0,0,0

do
    if inkey$()="s" 
        set camera view 0,0,0,0
        paste image 2,0,0
    endif
    
    if inkey$()="c" then set camera view 0,0,800,600
loop

But it's not exact.

Back to top

Profile PM Email

Quel

17

Years of Service

User Offline

Joined: 13th Mar 2009

Location:

Posted: 6th Apr 2011 23:22

Link

Sorry i don't have time to look more into it, but as i can remember sprites have UV scrolling too. Maybe that could be easier for you, look it up in the help.

Back to top

Profile PM

Rich Dersheimer

AGK Developer

17

Years of Service

User Offline

Joined: 1st Jul 2009

Location: Inside the box

Posted: 6th Apr 2011 23:37

Link

Yah, I've done that with sprites, but what I have in mind is for the 3D environment. I forget the term for it, but when I work with Lightwave 3D, you can assign an object to show a background image that exactly matches the bitmap of the image. So, the user wouldn't realize a 3D screen was even there until, SWOOSH!, the whole screen rotates away as a spinning cube.

I'm probably not explaining it very well. Just looking for an exact method of matching a textured plane with a 2D image, but it might not even be possible.

Back to top

Profile PM Email

Green Gandalf

VIP Member

21

Years of Service

User Offline

Joined: 3rd Jan 2005

Playing: Malevolence:Sword of Ahkranox, Skyrim, Civ6.

Posted: 7th Apr 2011 00:12

Link

I think you need to offset the plain by half a pixel as in this snippet:

+ Code Snippet

set display mode 800, 600, 32
sync on : sync rate 60 : sync

autocam off
color backdrop rgb(255,255,255)
position camera 0, 0, -500
point camera 0, 0, 0

make object plain 1, 800, 600
position object 1, -0.5, 0.5, 0 ` offset the plain by half a pixel in X and Y directions
load image "test.png", 1
texture object 1, 1

repeat
  scroll object texture 1, 0.0, 0.0005
  sync
until spacekey()

end

I guess the correct Z value should be computed from the camera's FOV and the screen's height but I'm not sure. That method gives a Z value very close to your 500 which is perhaps not a coincidence.

Back to top

Profile PM Email

Rich Dersheimer

AGK Developer

17

Years of Service

User Offline

Joined: 1st Jul 2009

Location: Inside the box

Posted: 7th Apr 2011 00:45 Edited at: 7th Apr 2011 00:55

Link

Okay, I'll try that. And I'll look into the FOV, I hadn't thought of messing with that. Thankee!

EDIT:Well, that half "pixel" did the trick, the camera image and the pasted image are identical. On to sizes besides 800x600!

Umm, FOV is 61.9621391296 and screen height is 600. What calculation gives 500 from that?

Back to top

Profile PM Email

Matty H

17

Years of Service

User Offline

Joined: 7th Oct 2008

Location: England

Posted: 7th Apr 2011 01:12

Link

I've just been working on something similar to this, here is the code, its in GDK but you get the point

+ Code Snippet

	//FOV
    float a = dbATAN((viewWidth / 2.0) / distance) * 2.0;
	float aspect = viewWidth / viewHeight;
	dbSetCameraAspect(1, aspect);
	dbSetCameraFOV(1, a / aspect);

I was using camera 1, the distance is the camera distance from the plane, I think this may help.

fulcrum physics - free collision/physics plug-in for DarkGDK

Back to top

Profile PM Email

Green Gandalf

VIP Member

21

Years of Service

User Offline

Joined: 3rd Jan 2005

Playing: Malevolence:Sword of Ahkranox, Skyrim, Civ6.

Posted: 7th Apr 2011 01:32

Link

Quote: "Umm, FOV is 61.9621391296 and screen height is 600. What calculation gives 500 from that?"

Basic trigonometry. The following calculation uses the right-angled triangle with side screenheight/2 and angle FOV/2. The second side is the camera depth and is about 499.6577 according to DBPro. The formula is:

+ Code Snippet

(600.0/tan(61.9621391296/2.0)/2.0)

Back to top

Profile PM Email

Rich Dersheimer

AGK Developer

17

Years of Service

User Offline

Joined: 1st Jul 2009

Location: Inside the box

Posted: 7th Apr 2011 18:57

Link

Thanks guys, between the two examples, I'm sure I can figure out how to get what I want!

Back to top

Profile PM Email

BatVink

Moderator

23

Years of Service

User Offline

Joined: 4th Apr 2003

Location: Gods own County, UK

Posted: 8th Apr 2011 00:02

Link

I use this in all my projects. I didn't write it, and I've never tried to understand it, I just know it has worked for all screen sizes...

+ Code Snippet

` *************************************************************************************
` Function: positionOnScreen()
` Converts X/Y screen coordinates to a 3D-based position for HUD plains
` Z# allows for priority adjustment.  The higher the Z# value, the closer to the front.
` *************************************************************************************
function positionOnScreen(id,X#,Y#,Z#)     

    
 X#=(X#-screen width()/2)+Object Size x(id)/2         `Adjust position relative to screen pixels
 Y#=((Y#*-1)+screen height()/2) - Object Size y(id)/2

 Position Object id, X#,Y#,gDist - Z#
     
endfunction

Back to top

Profile PM Email

pictionaryjr

17

Years of Service

User Offline

Joined: 12th Mar 2009

Location:

Posted: 8th Apr 2011 01:24

Link

i almost got a function working for you. i'll post it in a second. it even rotates the object and repositions it for the camera. you'll have to take off the lighting effects on the object tho

Experimental Games Blog
Experimental Games YouTube Channel

Back to top

Profile PM Email

pictionaryjr

17

Years of Service

User Offline

Joined: 12th Mar 2009

Location:

Posted: 8th Apr 2011 01:54

Link

Done

The threedrm functions have to come with it because those are my functions so i don't have to rewrite my 3d rotation matrix maths all over again every time.

All you have to do is create a plane thats 1,1 in size and texture it with your background, take the setting off for it so its not effected by any light. and then just run this function in your main loop.

rem planebackground(object number,distance from camera)
function planebackground(obj,distance#)
    cax#=camera angle x()
    cay#=camera angle y()
    cx#=camera position x()
    cy#=camera position y()
    cz#=camera position z()
    width#=screen width()
    height#=screen height()
    fov#=(3.14/2.905)*57.2957795
    screeny#=tan(fov#/2)
    screenx#=screeny#*(width#/height#)
    px#=(((distance#*screenx#)+screenx#)*2)/width#
    py#=(((distance#*screeny#)+screeny#)*2)/height#
    leftxoffset#=0-((distance#*screenx#)+screenx#)
    rightxoffset#=(width#*px#)-((distance#*screenx#)+screenx#)
    leftyoffset#=(distance#*screeny#)+screeny#
    rightyoffset#=((distance#*screeny#)+screeny#)-(height#*py#)
    planesizex#=(rightxoffset#-leftxoffset#)*100
    planesizey#=(rightyoffset#-leftyoffset#)*100
    scale object obj,planesizex#,planesizey#,100
    zpos#=threedrmz(0,0,distance#,cax#,cay#)+cz#
    ypos#=threedrmy(0,0,distance#,cax#,cay#)+cy#
    xpos#=threedrmx(0,0,distance#,cax#,cay#)+cx#
    position object obj,xpos#,ypos#,zpos#
    rotate object obj,360-wrapvalue(cax#+180),wrapvalue(cay#+180),0
endfunction

function threedrmx(x#,y#,z#,ax#,ay#)
   zpos#=(y#*sin(ax#))+(z#*cos(ax#))
   xpos#=(x#*cos(ay#))+(zpos#*sin(ay#))
endfunction xpos#

function threedrmy(x#,y#,z#,ax#,ay#)
   ypos#=(y#*cos(ax#))+(z#*(-1*sin(ax#)))
endfunction ypos#

function threedrmz(x#,y#,z#,ax#,ay#)
   zpos#=(y#*sin(ax#))+(z#*cos(ax#))
   zpos#=(x#*(-1*sin(ay#)))+(zpos#*cos(ay#))
endfunction zpos#

+ Code Snippet

rem planebackground(object number,distance from camera)
function planebackground(obj,distance#)
    cax#=camera angle x()
    cay#=camera angle y()
    cx#=camera position x()
    cy#=camera position y()
    cz#=camera position z()
    width#=screen width()
    height#=screen height()
    fov#=(3.14/2.905)*57.2957795
    screeny#=tan(fov#/2)
    screenx#=screeny#*(width#/height#)
    px#=(((distance#*screenx#)+screenx#)*2)/width#
    py#=(((distance#*screeny#)+screeny#)*2)/height#
    leftxoffset#=0-((distance#*screenx#)+screenx#)
    rightxoffset#=(width#*px#)-((distance#*screenx#)+screenx#)
    leftyoffset#=(distance#*screeny#)+screeny#
    rightyoffset#=((distance#*screeny#)+screeny#)-(height#*py#)
    planesizex#=(rightxoffset#-leftxoffset#)*100
    planesizey#=(rightyoffset#-leftyoffset#)*100
    scale object obj,planesizex#,planesizey#,100
    zpos#=threedrmz(0,0,distance#,cax#,cay#)+cz#
    ypos#=threedrmy(0,0,distance#,cax#,cay#)+cy#
    xpos#=threedrmx(0,0,distance#,cax#,cay#)+cx#
    position object obj,xpos#,ypos#,zpos#
    rotate object obj,360-wrapvalue(cax#+180),wrapvalue(cay#+180),0
endfunction

function threedrmx(x#,y#,z#,ax#,ay#)
   zpos#=(y#*sin(ax#))+(z#*cos(ax#))
   xpos#=(x#*cos(ay#))+(zpos#*sin(ay#))
endfunction xpos#

function threedrmy(x#,y#,z#,ax#,ay#)
   ypos#=(y#*cos(ax#))+(z#*(-1*sin(ax#)))
endfunction ypos#

function threedrmz(x#,y#,z#,ax#,ay#)
   zpos#=(y#*sin(ax#))+(z#*cos(ax#))
   zpos#=(x#*(-1*sin(ay#)))+(zpos#*cos(ay#))
endfunction zpos#

Experimental Games Blog
Experimental Games YouTube Channel

Back to top

Profile PM Email

Green Gandalf

VIP Member

21

Years of Service

User Offline

Joined: 3rd Jan 2005

Playing: Malevolence:Sword of Ahkranox, Skyrim, Civ6.

Posted: 8th Apr 2011 23:12

Link

@BatVink

Quote: "I use this in all my projects. I didn't write it, and I've never tried to understand it, I just know it has worked for all screen sizes..."

How can that work? Don't you need to know what gdist is and where the camera is?

Perhaps there's something you're not telling us - or something simple I've missed?

Back to top

Profile PM Email

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Screen image vs texture mapped image.