Timer Using BASIC2D - GameCreators Forum

Author

Message

ArcherSam

15

Years of Service

User Offline

Joined: 13th Mar 2011

Location: Florida, US

Posted: 27th Apr 2011 06:48 Edited at: 27th Apr 2011 06:54

Link

I need help building a basic timer that progresses over four minutes. Also I need the timer to show progress without stopping runtime(or without using the WAIT command)!

+ Code Snippet

REM Project: Timer

REM ***** Main Source File *****

GOTO Timer_Loop

Timer_Loop:
    GOSUB Timer_Data
    DO
        GOSUB Timer_Behavior
        GOSUB Timer_Graphics
    LOOP

Timer_Data:
    time = 0
    limit = 2400000 `4 minutes = 240 seconds = 240000 milliseconds
    segment = limit / 100
    x1Pos = 20
    x2Pos = x1Pos + 100
    x3Pos = 0
    y1Pos = 20
    y2Pos = 40
    RETURN
    
Timer_Graphics:
    BOX x1Pos, y1Pos, x2Pos, y2Pos
    BOX x1Pos, y1Pos, x3Pos, y2Pos
    RETURN
    
Timer_Behavior:
    x3Pos = x1Pos + (segment * time)
    time = time + 1
    RETURN

Sam

Back to top

Profile PM

enderleit

19

Years of Service

User Offline

Joined: 30th May 2007

Location: Denmark

Posted: 27th Apr 2011 12:24

Link

I made some castbars using timers a long time ago... could probably be used for that...

http://forum.thegamecreators.com/?m=forum_view&t=146651&b=5

- Martin Enderleit
http://sites.google.com/site/menderleit

Back to top

Profile PM Email Website

ArcherSam

15

Years of Service

User Offline

Joined: 13th Mar 2011

Location: Florida, US

Posted: 27th Apr 2011 15:21

Link

Thanks enderleit. Amazing and simple timers!

Back to top

Profile PM

baxslash

Valued Member

Bronze Codemaster

19

Years of Service

User Offline

Joined: 26th Dec 2006

Location: Duffield

Posted: 27th Apr 2011 15:43

Link

Try something a little simpler using the "timer" command like this:

+ Code Snippet

Rem Project: Dark Basic Pro Project
Rem Created: Wednesday, April 27, 2011

Rem ***** Main Source File *****
REM Project: Timer

REM ***** Main Source File *****
sync on : sync rate 0

totaltime = 240000
endtime = timer()+totaltime

do
    cls
    time = timer()
    if time<endtime
        show_countdown_box(time, endtime, totaltime)
        text 5,25,get_time(endtime - time)
        sync
    else
        end
    endif
loop

function get_time(ms)
    secs = ms/1000
    mins = secs/60
    hrs = mins/60
    if mins>0
        secs = secs - mins*60
        s$ = str$(secs)
        if secs<10
            s$ = "0"+s$
        endif
        m$ = str$(mins)
    endif
    if hrs>0
        mins = mins - hrs*60
        if mins<10
            m$ = "0"+m$
        endif
    endif
    tim$ = str$(hrs)+":"+m$+":"+s$
endfunction tim$

function show_countdown_box(t#, et#, totaltime)
    perc# = (et# - t#)/totaltime
    x2 = 5 + (screen width()-10)*perc#
    box 5,5,x2,15
endfunction

Back to top

Profile PM Email

ArcherSam

15

Years of Service

User Offline

Joined: 13th Mar 2011

Location: Florida, US

Posted: 27th Apr 2011 15:59

Link

Thanks baxslash. Before posting this issue, I had tried using timer and failed. The conversion done in get_time(ms) are really helpful and allowed me to see how to use TIMER().

Back to top

Profile PM

ArcherSam

15

Years of Service

User Offline

Joined: 13th Mar 2011

Location: Florida, US

Posted: 27th Apr 2011 16:54 Edited at: 27th Apr 2011 16:55

Link

With the solution provided by baxslash I was able to achieve my goal. Also the reason I have to use function, and subroutines in this format is because of the game structure of my game. When I have issues, I extract the necessary coding to solve the issue and then I make sure it is the follows the game structure in order for easy application of the solution.

REM Project: Timer

REM ***** Main Source File *****

Timer_Loop:
    GOSUB Timer_Data
    DO
        GOSUB Timer_Behavior
        GOSUB Timer_Graphics
    LOOP

Timer_Data: 
    simpleTimer AS Timer_Design   
    simpleTimer.totalTime = 240000
    simpleTimer.endTime   = TIMER() + simpleTimer.totalTime
    
    TYPE Timer_Design
         totalTime  AS Integer
         endTime    AS Integer
         time       AS Integer
         clock      AS String
    ENDTYPE
    
    RETURN
    
Timer_Graphics:
    CLS
    
    drawTimer(simpleTimer.time, simpleTimer.endTime, simpleTimer.totalTime)
    `PRINT simpleTimer.clock
    
    SYNC
    RETURN
    
Timer_Behavior:
    simpleTimer.time = TIMER()
    IF simpleTimer.time < simpleTimer.endTime
       simpleTimer.clock = getTime(simpleTimer.endTime - simpleTimer.time)
    ENDIF
    RETURN
    
FUNCTION getTime(ms)
    secs = ms / 1000
    mins = secs / 60
    hrs  = mins / 60
    
    IF mins > 0
        secs = secs - mins * 60
        s$ = str$(secs)
        IF secs < 10
            s$ = "0" + s$
        ENDIF
        m$ = str$(mins)
    ENDIF
    
    IF hrs > 0
        mins = mins - hrs * 60
        IF mins < 10
            m$ = "0" + m$
        ENDIF
    ENDIF
    
    tim$ = m$ + ":" + s$
ENDFUNCTION tim$

FUNCTION drawTimer(time#, endTime#, totaltime)
    percent# = (endTime# - time#) / totaltime
    x2Pos = ((SCREEN WIDTH() / 2) - 50) + (100-10) * percent# `x1 + (length - ?) * percent
    BOX ((SCREEN WIDTH() / 2) - 50), 5, x2Pos ,15
ENDFUNCTION

+ Code Snippet

REM Project: Timer

REM ***** Main Source File *****


Timer_Loop:
    GOSUB Timer_Data
    DO
        GOSUB Timer_Behavior
        GOSUB Timer_Graphics
    LOOP

Timer_Data: 
    simpleTimer AS Timer_Design   
    simpleTimer.totalTime = 240000
    simpleTimer.endTime   = TIMER() + simpleTimer.totalTime
    
    TYPE Timer_Design
         totalTime  AS Integer
         endTime    AS Integer
         time       AS Integer
         clock      AS String
    ENDTYPE
    
    RETURN
    
Timer_Graphics:
    CLS
    
    drawTimer(simpleTimer.time, simpleTimer.endTime, simpleTimer.totalTime)
    `PRINT simpleTimer.clock
    
    SYNC
    RETURN
    
Timer_Behavior:
    simpleTimer.time = TIMER()
    IF simpleTimer.time < simpleTimer.endTime
       simpleTimer.clock = getTime(simpleTimer.endTime - simpleTimer.time)
    ENDIF
    RETURN
    
FUNCTION getTime(ms)
    secs = ms / 1000
    mins = secs / 60
    hrs  = mins / 60
    
    IF mins > 0
        secs = secs - mins * 60
        s$ = str$(secs)
        IF secs < 10
            s$ = "0" + s$
        ENDIF
        m$ = str$(mins)
    ENDIF
    
    IF hrs > 0
        mins = mins - hrs * 60
        IF mins < 10
            m$ = "0" + m$
        ENDIF
    ENDIF
    
    tim$ = m$ + ":" + s$
ENDFUNCTION tim$

FUNCTION drawTimer(time#, endTime#, totaltime)
    percent# = (endTime# - time#) / totaltime
    x2Pos = ((SCREEN WIDTH() / 2) - 50) + (100-10) * percent# `x1 + (length - ?) * percent
    BOX ((SCREEN WIDTH() / 2) - 50), 5, x2Pos ,15
ENDFUNCTION

Back to top

Profile PM

baxslash

Valued Member

Bronze Codemaster

19

Years of Service

User Offline

Joined: 26th Dec 2006

Location: Duffield

Posted: 27th Apr 2011 17:04

Link

Great! Glad to help

You could also optimise my function a little by removing the "hrs" part since you aren't using it.

Back to top

Profile PM Email

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Timer Using BASIC2D