TopGUI - Open source immediate mode GUI

Author

Message

Chris Tate

DBPro Master

15

Years of Service

User Offline

Joined: 29th Aug 2008

Location: London, England

Posted: 4th Jan 2012 01:24 Edited at: 4th Jan 2012 01:26

Link

Ok, I'm starting to work on some projects and wanted to share the extra controls as I create them. The controls I make will reside in seperate source files that can be added to any up-to-date TopGUI project.

To start with I have added a button with rounded edge and a button that is bevelled.

If Diggsey or anyone good with graphics programming knowledge can give some tips on the rounded edge buttons, please do so, because they do not look perfect; and they look worse when you use a large radius.

Button Source File

Button Snippet (v0.1) - (Excuse my browser for adding double tabs)

` TopGUI Extras - Buttons 0.1 - 04/01/12
` By Chris Tate - christate@binarymodular.com
` for Diggsey's TopGUI
`======================

function guiExtRoundedButton(id as guiId, x, y, w, h, cornerRadius, caption$)
    guiLayout(id, x, y, w, h)

guiBeginControl(x, y, w, h, 1)
    
    clicked = guiButtonLogic(id, w, h)
    guiExtButtonDrawRounded(id, w, h, cornerRadius, caption$)
    
    guiEndControl()
endfunction clicked

function guiExtBevelButton(id as guiId, x, y, w, h, bevelThickness, caption$)
    guiLayout(id, x, y, w, h)

guiBeginControl(x, y, w, h, 1)
    
    clicked = guiButtonLogic(id, w, h)
    guiExtButtonDrawBevelled(id, w, h, bevelThickness, caption$)
    
    guiEndControl()
endfunction clicked

function guiExtButtonDrawRounded(id as guiId, w, h, cornerRadius, caption$)
    x = guiAdjustX(0)
    y = guiAdjustY(0)
    
    focused = guiGetFocus() = id
    pressed = focused and spacekey()
	cornerRadius = max(cornerRadius,1)
    dblCornerRadius = cornerRadius * 2
	step# = 90.0 / max(1,cornerRadius-1)
	
    if guiGetHot() = id or pressed
        if guiGetActive() = id or pressed
            ` Active (pressed) box area
            a2FillBox x, y+cornerRadius, x+w, y+h-CornerRadius, THEME_ACTIVE_DARK, THEME_ACTIVE_DARK, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT
			
			
			` Top edge
			curve# = 0.0
	
			for i = y to y+cornerRadius
				offset = cos( curve# ) * cornerRadius
				a2Line x + offset, i, x + w - offset, i, THEME_ACTIVE_LIGHT
				a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK
				inc curve#, step#
			next i

` Bottom edge
			curve# = 0.0
			
			bottom1 = y + h - cornerRadius : bottom2 = y + h
			for i = bottom1 to bottom2
				offset = sin( curve# ) * cornerRadius
				a2Line x + offset, i, x + w - offset, i, THEME_ACTIVE_DARK
				a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK
				inc curve#, step#
			next i
				
			
        else
            ` Hot
            a2FillBox x, y+cornerRadius, x+w, y+h-CornerRadius, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT, THEME_ACTIVE_DARK, THEME_ACTIVE_DARK
			
			` Top edge
			curve# = 0.0
	
			for i = y to y+cornerRadius-1
				offset = cos( curve# ) * cornerRadius
				a2Line x + offset, i, x + w - offset, i, THEME_ACTIVE_LIGHT
				a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK
				inc curve#, step#
			next i

` Bottom edge
			curve# = 0.0
			
			bottom1 = y + h - cornerRadius : bottom2 = y + h - 1
			for i = bottom1 to bottom2
				offset = sin( curve# ) * cornerRadius
				a2Line x + offset, i, x + w - offset, i, THEME_ACTIVE_DARK
				a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK	
				inc curve#, step#
			next i		
			
        endif
    else
        ` Normal
        a2FillBox x, y+cornerRadius, x+w, y+h-CornerRadius, THEME_INACTIVE_LIGHT, THEME_INACTIVE_LIGHT, THEME_INACTIVE_DARK, THEME_INACTIVE_DARK
		
		` Top edge
		curve# = 0.0

for i = y to y+cornerRadius			
			offset = cos( curve# ) * cornerRadius
			a2Line x + offset, i, x + w - offset, i, THEME_INACTIVE_LIGHT
			a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK
			inc curve#, step#
		next i

` Bottom edge
		curve# = 0.0
		bottom1 = y + h - cornerRadius : bottom2 = y + h
		for i = bottom1 to bottom2
			offset = sin( curve# ) * cornerRadius
			a2Line x + offset, i, x + w - offset, i, THEME_INACTIVE_DARK
			a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK
			inc curve#, step#
		next i
			
    endif
    
    a2SetLineAA 0
	` Left Line
	a2Line x, y+cornerRadius, x, y+h-cornerRadius, THEME_OUTLINE_DARK
	` Right Line
	a2Line x+w-1, y+cornerRadius, x+w-1, y+h-cornerRadius, THEME_OUTLINE_DARK
	` Top Line
	a2Line x+cornerRadius, y, x+w-cornerRadius, y, THEME_OUTLINE_DARK
	` Bottom Line
	a2Line x+cornerRadius, y+h-1, x+w-cornerRadius, y+h-1, THEME_OUTLINE_DARK	
    a2SetLineAA 1
    
    `a2BoxText gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW
    `a2BoxText gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK
    guiFastBoxText(gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW)
    guiFastBoxText(gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK)
    
    if focused
        guiDrawFocusRect(x+3, y+3, x+w-4, y+h-4, THEME_FOCUS_DARK)
    endif
    
endfunction

function guiExtButtonDrawBevelled(id as guiId, w, h, bevelThickness, caption$)
    x = guiAdjustX(0)
    y = guiAdjustY(0)
    
    focused = guiGetFocus() = id
    pressed = focused and spacekey()
    halfContrast = max( 1, contrast ) / 2

if guiGetHot() = id or pressed
		
        if guiGetActive() = id or pressed
            ` Active (pressed)
            a2FillBox x, y, x+w, y+h, THEME_ACTIVE_DARK, THEME_ACTIVE_DARK, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT
			` Pressed Darkness
			a2FillBox x+bevelThickness, y, x+w-bevelThickness, y+bevelThickness, THEME_SHADOW_START, THEME_SHADOW_START, THEME_SHADOW_END, THEME_SHADOW_END
			a2FillBox x, y, x+bevelThickness, y+h, THEME_SHADOW_END, THEME_SHADOW_END, THEME_SHADOW_START, THEME_SHADOW_START						
			` Pressed Highlight			
			a2FillBox x+bevelThickness, y+h-bevelThickness, x+w-bevelThickness, y+h, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT
			a2FillBox x+w-bevelThickness, y, x+w, y+h, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT	
        else
            ` Hot
            a2FillBox x, y, x+w, y+h, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT, THEME_ACTIVE_DARK, THEME_ACTIVE_DARK
			` Darkness
			a2FillBox x+bevelThickness, y+h-bevelThickness, x+w-bevelThickness, y+h, THEME_SHADOW_START, THEME_SHADOW_START, THEME_SHADOW_END, THEME_SHADOW_END
			a2FillBox x+w-bevelThickness, y, x+w, y+h, THEME_SHADOW_END, THEME_SHADOW_END, THEME_SHADOW_START, THEME_SHADOW_START
			` Highlight
			a2FillBox x+bevelThickness, y, x+w-bevelThickness, y+bevelThickness, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT
			a2FillBox x, y, x+bevelThickness, y+h, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT					
        endif
    else
        ` Normal
        a2FillBox x, y, x+w, y+h, THEME_INACTIVE_LIGHT, THEME_INACTIVE_LIGHT, THEME_INACTIVE_DARK, THEME_INACTIVE_DARK
		` Darkness
		a2FillBox x+bevelThickness, y+h-bevelThickness, x+w-bevelThickness, y+h, THEME_SHADOW_START, THEME_SHADOW_START, THEME_SHADOW_END, THEME_SHADOW_END
		a2FillBox x+w-bevelThickness, y, x+w, y+h, THEME_SHADOW_END, THEME_SHADOW_END, THEME_SHADOW_START, THEME_SHADOW_START
		` Highlight
		a2FillBox x+bevelThickness, y, x+w-bevelThickness, y+bevelThickness, THEME_INACTIVE_LIGHT, THEME_INACTIVE_LIGHT, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT
		a2FillBox x, y, x+bevelThickness, y+h, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT, THEME_INACTIVE_LIGHT, THEME_INACTIVE_LIGHT		
    endif
    
    a2SetLineAA 0
    a2Box x, y, x+w-1, y+h-1, THEME_OUTLINE_DARK
    a2SetLineAA 1
    
    `a2BoxText gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW
    `a2BoxText gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK
    guiFastBoxText(gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW)
    guiFastBoxText(gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK)
    
    if focused
        guiDrawFocusRect(x+3, y+3, x+w-4, y+h-4, THEME_FOCUS_DARK)
    endif
    
endfunction

+ Code Snippet

` TopGUI Extras - Buttons 0.1 - 04/01/12
` By Chris Tate - christate@binarymodular.com
` for Diggsey's TopGUI
`======================

function guiExtRoundedButton(id as guiId, x, y, w, h, cornerRadius, caption$)
    guiLayout(id, x, y, w, h)

    guiBeginControl(x, y, w, h, 1)
    
    clicked = guiButtonLogic(id, w, h)
    guiExtButtonDrawRounded(id, w, h, cornerRadius, caption$)
    
    guiEndControl()
endfunction clicked

function guiExtBevelButton(id as guiId, x, y, w, h, bevelThickness, caption$)
    guiLayout(id, x, y, w, h)

    guiBeginControl(x, y, w, h, 1)
    
    clicked = guiButtonLogic(id, w, h)
    guiExtButtonDrawBevelled(id, w, h, bevelThickness, caption$)
    
    guiEndControl()
endfunction clicked

function guiExtButtonDrawRounded(id as guiId, w, h, cornerRadius, caption$)
    x = guiAdjustX(0)
    y = guiAdjustY(0)
    
    focused = guiGetFocus() = id
    pressed = focused and spacekey()
	cornerRadius = max(cornerRadius,1)
    dblCornerRadius = cornerRadius * 2
	step# = 90.0 / max(1,cornerRadius-1)
	
    if guiGetHot() = id or pressed
        if guiGetActive() = id or pressed
            ` Active (pressed) box area
            a2FillBox x, y+cornerRadius, x+w, y+h-CornerRadius, THEME_ACTIVE_DARK, THEME_ACTIVE_DARK, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT
			
			
			` Top edge
			curve# = 0.0
	
			for i = y to y+cornerRadius
				offset = cos( curve# ) * cornerRadius
				a2Line x + offset, i, x + w - offset, i, THEME_ACTIVE_LIGHT
				a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK
				inc curve#, step#
			next i

			` Bottom edge
			curve# = 0.0
			
			bottom1 = y + h - cornerRadius : bottom2 = y + h
			for i = bottom1 to bottom2
				offset = sin( curve# ) * cornerRadius
				a2Line x + offset, i, x + w - offset, i, THEME_ACTIVE_DARK
				a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK
				inc curve#, step#
			next i
				
			
        else
            ` Hot
            a2FillBox x, y+cornerRadius, x+w, y+h-CornerRadius, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT, THEME_ACTIVE_DARK, THEME_ACTIVE_DARK
			
			` Top edge
			curve# = 0.0
	
			for i = y to y+cornerRadius-1
				offset = cos( curve# ) * cornerRadius
				a2Line x + offset, i, x + w - offset, i, THEME_ACTIVE_LIGHT
				a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK
				inc curve#, step#
			next i

			` Bottom edge
			curve# = 0.0
			
			bottom1 = y + h - cornerRadius : bottom2 = y + h - 1
			for i = bottom1 to bottom2
				offset = sin( curve# ) * cornerRadius
				a2Line x + offset, i, x + w - offset, i, THEME_ACTIVE_DARK
				a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK	
				inc curve#, step#
			next i		
			
        endif
    else
        ` Normal
        a2FillBox x, y+cornerRadius, x+w, y+h-CornerRadius, THEME_INACTIVE_LIGHT, THEME_INACTIVE_LIGHT, THEME_INACTIVE_DARK, THEME_INACTIVE_DARK
		
		` Top edge
		curve# = 0.0

		for i = y to y+cornerRadius			
			offset = cos( curve# ) * cornerRadius
			a2Line x + offset, i, x + w - offset, i, THEME_INACTIVE_LIGHT
			a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK
			inc curve#, step#
		next i

		` Bottom edge
		curve# = 0.0
		bottom1 = y + h - cornerRadius : bottom2 = y + h
		for i = bottom1 to bottom2
			offset = sin( curve# ) * cornerRadius
			a2Line x + offset, i, x + w - offset, i, THEME_INACTIVE_DARK
			a2Dot x + offset, i, THEME_OUTLINE_DARK : a2Dot x + w - offset, i, THEME_OUTLINE_DARK
			inc curve#, step#
		next i
			
    endif
    
    a2SetLineAA 0
	` Left Line
	a2Line x, y+cornerRadius, x, y+h-cornerRadius, THEME_OUTLINE_DARK
	` Right Line
	a2Line x+w-1, y+cornerRadius, x+w-1, y+h-cornerRadius, THEME_OUTLINE_DARK
	` Top Line
	a2Line x+cornerRadius, y, x+w-cornerRadius, y, THEME_OUTLINE_DARK
	` Bottom Line
	a2Line x+cornerRadius, y+h-1, x+w-cornerRadius, y+h-1, THEME_OUTLINE_DARK	
    a2SetLineAA 1
    
    `a2BoxText gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW
    `a2BoxText gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK
    guiFastBoxText(gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW)
    guiFastBoxText(gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK)
    
    if focused
        guiDrawFocusRect(x+3, y+3, x+w-4, y+h-4, THEME_FOCUS_DARK)
    endif
    
endfunction

function guiExtButtonDrawBevelled(id as guiId, w, h, bevelThickness, caption$)
    x = guiAdjustX(0)
    y = guiAdjustY(0)
    
    focused = guiGetFocus() = id
    pressed = focused and spacekey()
    halfContrast = max( 1, contrast ) / 2
		

    if guiGetHot() = id or pressed
		
        if guiGetActive() = id or pressed
            ` Active (pressed)
            a2FillBox x, y, x+w, y+h, THEME_ACTIVE_DARK, THEME_ACTIVE_DARK, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT
			` Pressed Darkness
			a2FillBox x+bevelThickness, y, x+w-bevelThickness, y+bevelThickness, THEME_SHADOW_START, THEME_SHADOW_START, THEME_SHADOW_END, THEME_SHADOW_END
			a2FillBox x, y, x+bevelThickness, y+h, THEME_SHADOW_END, THEME_SHADOW_END, THEME_SHADOW_START, THEME_SHADOW_START						
			` Pressed Highlight			
			a2FillBox x+bevelThickness, y+h-bevelThickness, x+w-bevelThickness, y+h, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT
			a2FillBox x+w-bevelThickness, y, x+w, y+h, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT	
        else
            ` Hot
            a2FillBox x, y, x+w, y+h, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT, THEME_ACTIVE_DARK, THEME_ACTIVE_DARK
			` Darkness
			a2FillBox x+bevelThickness, y+h-bevelThickness, x+w-bevelThickness, y+h, THEME_SHADOW_START, THEME_SHADOW_START, THEME_SHADOW_END, THEME_SHADOW_END
			a2FillBox x+w-bevelThickness, y, x+w, y+h, THEME_SHADOW_END, THEME_SHADOW_END, THEME_SHADOW_START, THEME_SHADOW_START
			` Highlight
			a2FillBox x+bevelThickness, y, x+w-bevelThickness, y+bevelThickness, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT
			a2FillBox x, y, x+bevelThickness, y+h, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT, THEME_ACTIVE_LIGHT, THEME_ACTIVE_LIGHT					
        endif
    else
        ` Normal
        a2FillBox x, y, x+w, y+h, THEME_INACTIVE_LIGHT, THEME_INACTIVE_LIGHT, THEME_INACTIVE_DARK, THEME_INACTIVE_DARK
		` Darkness
		a2FillBox x+bevelThickness, y+h-bevelThickness, x+w-bevelThickness, y+h, THEME_SHADOW_START, THEME_SHADOW_START, THEME_SHADOW_END, THEME_SHADOW_END
		a2FillBox x+w-bevelThickness, y, x+w, y+h, THEME_SHADOW_END, THEME_SHADOW_END, THEME_SHADOW_START, THEME_SHADOW_START
		` Highlight
		a2FillBox x+bevelThickness, y, x+w-bevelThickness, y+bevelThickness, THEME_INACTIVE_LIGHT, THEME_INACTIVE_LIGHT, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT
		a2FillBox x, y, x+bevelThickness, y+h, THEME_FOCUS_LIGHT, THEME_FOCUS_LIGHT, THEME_INACTIVE_LIGHT, THEME_INACTIVE_LIGHT		
    endif
    
    a2SetLineAA 0
    a2Box x, y, x+w-1, y+h-1, THEME_OUTLINE_DARK
    a2SetLineAA 1
    
    `a2BoxText gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW
    `a2BoxText gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK
    guiFastBoxText(gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW)
    guiFastBoxText(gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK)
    
    if focused
        guiDrawFocusRect(x+3, y+3, x+w-4, y+h-4, THEME_FOCUS_DARK)
    endif
    
endfunction

Tester Demo

sync on : sync rate 0
set display mode desktop width(), desktop height(), 32, 0

` Initialise the GUI
guiInit()

global windowX = 750
global windowY = 100
global windowW = 400
global windowH = 400

global windowX2 = 200
global windowY2 = 50
global windowW2 = 500
global windowH2 = 600

global windowX3 = 50
global windowY3 = 300
global windowW3 = 350
global windowH3 = 400

global windowChecked1 = 0
global windowChecked2 = 0
global windowValue3 = 0
global windowText$ = "Edit me!"
global windowScrollX2
global windowScrollY2
global windowItem
global windowScrollX1
global windowScrollY1
global windowTabIndex = 1
global windowIndex3 = 0
global menuChecked = 0
global menuCheckedIndex = 0
global panelScrollX
global panelScrollY
global sliderValue
global spinnerValue as float
global spinnerValue2 as float

` These are names of functions. Each function draws a window. They are put
` in an array so that they can easily be re-ordered when a window is
` brought to the front.
dim windowFuncPtrs(2) as string
windowFuncPtrs(0) = "window2"
windowFuncPtrs(1) = "window1"
windowFuncPtrs(2) = "window3"

make camera 1
set current camera 1
set camera aspect 1, 1
set camera to image 1, 1, 300, 300, 2
color backdrop 1, 0
make object cube 1, 1
set object mask 1, %10
backdrop off 0
set current camera 0

ink 0, 0

initDBProParser()

` Declare a variable to hold the text document
myTextDocument as guiTextDocumentType

` Create a text document
guiCreateTextDocument()

` Put some text in it
guiSetTextDocumentFromString("sync on : sync rate 0" + lf$() + lf$() + "make object cube 1, 10" + lf$() + lf$() + "do" + lf$() + "    myvar = 1" + lf$() + "    print " + quote$("myvar: ") + ", myvar" + lf$() + "    sync `Update the screen" + lf$() + "loop")

` Attach the DBPro syntax parser
guiCurrentTextDocument.parser = get ptr to function("DBProParser")

` Put the result into the text document variable
myTextDocument = guiCurrentTextDocument

dim expanded(7) as boolean

do
    gameFocused = guiGame(GEN_ID, 0, 0, screen width(), screen height())

` Activate the text document
    guiSetCurrentTextDocument(myTextDocument)
    
    ` Draw and update the textarea
    guiTextarea(GEN_ID, 50, 50, 150, 300, scrollx, scrolly, 0)
    
    ` *IMPORTANT* Save changes to text document into variable
    myTextDocument = guiCurrentTextDocument
    
    ` Update scrolling
    scrollx = guiScrollX()
    scrolly = guiScrollY()
    
    guiHProgressbar(GEN_ID, 400, 200, 200, 24, (timer()/5) mod 1000, 1000, 0, 1)
    guiVProgressbar(GEN_ID, 400, 250, 50, 200, (timer()/5) mod 1000, 1000, 1, 1)
    
    guiGroupboxBegin(GEN_ID, 500, 500, 300, 300, THEME_TEXT_LIGHT, "Groupbox")
    guiGroupboxEnd()
    
    guiTreeviewBegin(GEN_ID, 30, 400, 300, 300, treescrollx, treescrolly, 24, treeIndex)
        expanded(0) = guiTreenodeBegin("Root node 1", 0, expanded(0))
            expanded(1) = guiTreenodeBegin("Node 1", 0, expanded(1))
                guiTreenode("Child node 1", 0)
                guiTreenode("Child node 2", 0)
                guiTreenode("Child node 3", 0)
                guiTreenode("Child node 4", 0)
                guiTreenode("Child node 5", 0)
            guiTreenodeEnd()
            expanded(2) = guiTreenodeBegin("Node 2", 0, expanded(2))
                expanded(3) = guiTreenodeBegin("Sub node 1", 0, expanded(3))
                    guiTreenode("Child node 1", 0)
                    guiTreenode("Child node 2", 0)
                    guiTreenode("Child node 3", 0)
                    guiTreenode("Child node 4", 0)
                    guiTreenode("Child node 5", 0)
                guiTreenodeEnd()
            guiTreenodeEnd()
            guiTreenode("Child node 1", 0)
            guiTreenode("Child node 2", 0)
            guiTreenode("Child node 3", 0)
            guiTreenode("Child node 4", 0)
            expanded(4) = guiTreenodeBegin("Node 3", 0, expanded(4))
                expanded(5) = guiTreenodeBegin("Sub node 1", 0, expanded(5))
                    expanded(6) = guiTreenodeBegin("Deep node 1", 0, expanded(6))
                        expanded(7) = guiTreenodeBegin("Deeper node 1", 0, expanded(7))
                            guiTreenode("Child node 1", 0)
                            guiTreenode("Child node 2", 0)
                            guiTreenode("Child node 3", 0)
                        guiTreenodeEnd()
                    guiTreenodeEnd()
                guiTreenodeEnd()
            guiTreenodeEnd()
        guiTreenodeEnd()
    treeIndex = guiTreeviewEnd()
    treescrollx = guiScrollX()
    treescrolly = guiScrollY()
    
    ` Draw the windows making sure they are in the correct order
    guiWindowListNames(get arrayptr(windowFuncPtrs()), guiRootFocused())
    
    ` Open context menu on right click
    if gui.msd = 2
        menux = gui.msx
        menuy = gui.msy
        menuopen = 1
    else
        menuopen = 0
    endif
    
    ` Draw context menu
    if guiContextMenuBegin(GEN_ID, menux, menuy, 150, 180, menuopen)
        doExampleMenu()
        guiContextMenuEnd()
    endif
    
    ` Update cube
    yrotate object 1, hitimer()*0.02
    
    print screen fps()
    
    ` Update GUI
    guiUpdate()
    sync

cls 0xFFC0D0FF
loop

function sayHello(opened)
    if opened
        ` Initial dialog position and size
        guiModal.x = 300
        guiModal.y = 300
        guiModal.width = 220
        guiModal.height = 110
        
        ` Prevent a non-modal control from keeping the focus
        guiSetFocus(0, 0, 0)
    endif
    
    if guiMessageBox(guiModal.id, "Title", "Hello, this is a message box!", guiModal.x, guiModal.y, guiModal.width, guiModal.height, guiModal.focused)
        guiCloseModal()
    endif
    guiModal.x = guiMoveX(guiModal.x, 0, 1000000, guiModal.width, 0, 1000000)
    guiModal.y = guiMoveY(guiModal.y, 0, 1000000, guiModal.height, 0, 1000000)
endfunction

` Automatically find all the DBPro keywords
function initDBProParser()
    ` Get DBPro install path from registry
    path$ = get registry$("SOFTWARE\Dark Basic\Dark Basic Pro", "INSTALL-PATH")
    path$ = path$ + "\Editor\Keywords"
    
    ` If registry key not found, try program files
    if path exist(path$) = 0
        path$ = dir programs() + "\The Game Creators\Dark Basic Professional\Editor\Keywords"
    endif
    
    ` Open the keywords folder
    set dir path$
    
    ` Put all keywords into a lookup table for speed
    make lookup 1
    
    find first
    repeat
        if get file type() = 0
            if fast right$(get file name$(), 4) = ".ini"
                open to read 1, get file name$()
                
                read string 1, line$
                while file end(1) = 0
                    pos = find char(line$, "=")
                    if pos
                        keyword$ = fast lower$(fast left$(line$, pos-1))
                        set lookup 1, keyword$, "keyword"
                    endif
                
                    read string 1, line$
                endwhile
                
                close file 1
            endif
        endif
    
        find next
    until get file type() = -1
endfunction

` Check if the text starts with a keyword and return its length
function findKeyword(text$)
    text$ = fast lower$(text$)
    l = fast len(text$)
    for i = 1 to l
        c = mid ascii(text$, i)
        if guiIsLetterOrDigit(c) = 0 and c <> 32 and c <> 36
            exit
        endif
    next i
    dec i
    
    keyword$ = text$
    while i > 0
        keyword$ = fast left$(keyword$, i)
        if lookup exist(1, keyword$)
            exitfunction i
        endif
        
        i = last instr(keyword$, " ")-1
    endwhile
endfunction 0

` Check if the text starts with a word and return its length
function findWord(text$)
    l = fast len(text$)
    for i = 1 to l
        c = mid ascii(text$, i)
        if guiIsLetterOrDigit(c) = 0
            dec i
            exitfunction i
        endif
    next i
endfunction l

` Check if the text starts with symbols and return its length
function findSymbol(text$)
    l = fast len(text$)
    for i = 1 to l
        c = mid ascii(text$, i)
        if guiIsLetter(c) or c = 34 or c = 96
            dec i
            exitfunction i
        endif
    next i
endfunction l

` Check if the text starts with a quoted string and return its length
function findString(text$)
    c = mid ascii(text$, 1)
    if c = 34
        l = find ascii(text$, 34, 2)
        if l = 0 then l = fast len(text$)
    else
        l = 0
    endif
endfunction l

` DBPro syntax parser, called for each line
function DBProParser(state, text$, colorFuncPtr)
    ` colorFunc must be called at least once even for an empty line
    ` so that the textarea knows what font to use to determine the
    ` line height.
    if text$ = "" and colorFuncPtr <> 0
        call function ptr colorFuncPtr, 0, 0, gui.fontId, ""
    endif

` While the line has text left to parse
    while text$ <> ""
        ` If we are in a multiline comment
        if state
            ` TODO: Handle multiline comments
        else
            ` Get first character code
            c = asc(text$)
            if guiIsLetter(c)
                ` If it's a letter check for keywords and words
                keyword = findKeyword(text$)
                if keyword
                    ` It's a keyword
                    call function ptr colorFuncPtr, 0xFF0000FF, 0, gui.fontId, fast left$(text$, keyword)
                    text$ = mid$(text$, keyword+1, 0)
                else
                    ` It's a word (eg. variable name)
                    wordlen = findWord(text$)
                    call function ptr colorFuncPtr, 0xFF000000, 0, gui.fontId, fast left$(text$, wordlen)
                    text$ = mid$(text$, wordlen+1, 0)
                endif
            else
                ` If it's not a letter check for a symbol, quoted string or single-line comment
                symbol = findSymbol(text$)
                if symbol
                    ` It's a symbol or number
                    call function ptr colorFuncPtr, 0xFFFF0000, 0, gui.fontId, fast left$(text$, symbol)
                    text$ = mid$(text$, symbol+1, 0)
                else
                    str = findString(text$)
                    if str
                        ` It's a quoted string
                        call function ptr colorFuncPtr, 0xFF800080, 0, gui.fontId, fast left$(text$, str)
                        text$ = mid$(text$, str+1, 0)
                    else
                        ` It's a single-line comment, so process the rest of the line
                        call function ptr colorFuncPtr, 0xFF808080, 0, gui.fontId, text$
                        text$ = ""
                    endif
                endif
            endif
        endif
    endwhile
endfunction state

function doExampleMenu()
    guiMenuItem("Item 0", 0, 24, 20, 0)
    menuChecked = guiCheckboxMenuItem("Check me", 0, 24, 20, menuChecked)
    guiSplitterMenuItem(5)
    guiMenuItem("Item 2", 0, 24, 20, 0)
    if guiDropDownMenuItemBegin(GEN_ID, "Set Theme", 24, 20, 0, 150, 98)
        menuCheckedIndex = guiRadioButtonMenuItem("Default", 0, 24, 20, 0, menuCheckedIndex)
        menuCheckedIndex = guiRadioButtonMenuItem("Red", 0, 24, 20, 1, menuCheckedIndex)
        menuCheckedIndex = guiRadioButtonMenuItem("Green", 0, 24, 20, 2, menuCheckedIndex)
        menuCheckedIndex = guiRadioButtonMenuItem("Blue", 0, 24, 20, 3, menuCheckedIndex)
        
        select menuCheckedIndex
            case 0
                guiSetTheme("Default")
            endcase
            
            case 1
                guiSetTheme("Red")
            endcase
            case 2
                guiSetTheme("Green")
            endcase
            case 3
                guiSetTheme("Blue")
            endcase
        endselect
        
        guiDropDownMenuItemEnd()
    endif
    guiMenuItem("Item 3", 0, 24, 20, 0)
    guiMenuItem("Item 4", 0, 24, 20, 0)
    guiSplitterMenuItem(5)
    if guiMenuItem("Dialog", 0, 24, 20, 0)
        guiOpenModalName(RND_ID, 0, "sayHello", 0)
    endif
endfunction

function window1(focused)

clicked = guiWindowBegin(GEN_ID, windowX, windowY, windowW, windowH, "Hello world!", 0, focused)
        
		if guiButton(GEN_ID, 230, 50, 150, 25, "Normal Button")
			guiMessageBox(GEN_ID, "Alert", "Button clicked", Screen Width() / 2, Screen Height() / 2, 300, 150, 1 )
		Endif

if guiExtRoundedButton(GEN_ID, 230, 100, 150, 25, 4, "Round Button")
			guiMessageBox(GEN_ID, "Alert", "Button clicked", Screen Width() / 2, Screen Height() / 2, 300, 150, 1 )
		Endif

if guiExtRoundedButton(GEN_ID, 230, 150, 150, 100, 4, "Big Round Button")
			guiMessageBox(GEN_ID, "Alert", "Button clicked", Screen Width() / 2, Screen Height() / 2, 300, 150, 1 )
		Endif

if guiExtBevelButton(GEN_ID, 230, 300, 150, 25, 4, "Bevel Button")
			guiMessageBox(GEN_ID, "Alert", "Button clicked", Screen Width() / 2, Screen Height() / 2, 300, 150, 1 )
		Endif
		
		
        guiMenuBegin(GEN_ID, 0, 0, windowW-8, 24)
        if guiDropDownMenuItemBegin(GEN_ID, "File", 24, 0, 0, 150, 180)
            doExampleMenu()
            guiDropDownMenuItemEnd()
        endif
        if guiDropDownMenuItemBegin(GEN_ID, "Edit", 24, 0, 0, 150, 180)
            doExampleMenu()
            guiDropDownMenuItemEnd()
        endif
        if guiDropDownMenuItemBegin(GEN_ID, "View", 24, 0, 0, 150, 180)
            doExampleMenu()
            guiDropDownMenuItemEnd()
        endif
        guiMenuEnd()
        
        windowChecked1 = guiCheckbox(GEN_ID, 20, 40, 120, 30, "Check me", windowChecked1)
        
        guiListboxBegin(GEN_ID, 20, 100, 200, 200, windowScrollX1, windowScrollY1, 0, 1)
            for i = 0 to 10
                if guiListboxItem("Item "+str$(i), i mod 3, windowItem = i) then windowItem = i
            next i
        guiListboxEnd()
        windowScrollX1 = guiScrollX()
        windowScrollY1 = guiScrollY()
        
    guiWindowEnd()
    windowX = guiMoveX(windowX, 0, 1000000, windowW, 50, 1000000)
    windowY = guiMoveY(windowY, 0, 1000000, windowH, 50, 1000000)
    windowW = guiResizeW(windowW)
    windowH = guiResizeH(windowH)

endfunction clicked

function window2(focused)

windowId = GEN_ID
    clicked = guiScrollWindowBegin(windowId, windowX2, windowY2, windowW2, windowH2, "Hello World!", windowScrollX2, windowScrollY2, 1000, 1000, 0, focused)
        
        windowChecked2 = guiRadioButton(GEN_ID, 100, 40, 120, 30, "Check me", 0, windowChecked2)
        windowChecked2 = guiRadioButton(GEN_ID, 100, 80, 120, 30, "Check me", 1, windowChecked2)
        windowChecked2 = guiRadioButton(GEN_ID, 100, 120, 120, 30, "Check me", 2, windowChecked2)
        windowChecked2 = guiRadioButton(GEN_ID, 100, 160, 120, 30, "Check me", 3, windowChecked2)

guiTabsBegin(GEN_ID, 100, 200, 308, 332, 25, windowTabIndex)
            if guiTabBegin("Tab 0", 0)
            
                guiBeginGridLayout(0, 0, 29, 29, -2, -2)
            
                if guiButton(GEN_ID, 0, 0, 10, 1, "Click me!")
                    guiOpenModalName(RND_ID, windowId, "sayHello", 0)
                endif
                if guiButton(GEN_ID, 0, 1, 3, 2, "Click me!")
                    guiOpenModalName(RND_ID, windowId, "sayHello", 0)
                endif
                guiButton(GEN_ID, 6, 1, 3, 3, "Hi")
                guiButton(GEN_ID, 5, 4, 5, 2, "Hi")
                guiButton(GEN_ID, 7, 7, 3, 3, "Fill")
                
                guiEndGridLayout()
                
                guiTabEnd()
            endif
            if guiTabBegin("Tab 1", 0)
                a2DrawImage 1, guiAdjustX(0), guiAdjustY(0), 0, 0, 0, 1, 0, 0xFFFFFFFF
                guiTabEnd()
            endif
            if guiTabBegin("Tab 2", 0)
                windowText$ = guiPassbox(GEN_ID, 20, 20, 150, 25, windowText$, chr$(149), 0)
                guiTabEnd()
            endif
        windowTabIndex = guiTabsEnd()
        
        guiScrollPanelBegin(GEN_ID, 500, 100, 300, 300, panelScrollX, panelScrollY, 0, 1, 1)
            if guiButton(GEN_ID, 200, 300, 200, 50, "Click me!")
            endif
        guiScrollPanelEnd(600, 600)
        panelScrollX = guiScrollX()
        panelScrollY = guiScrollY()
        
        sliderValue = guiHSlider(GEN_ID, 500, 500, 300, 30, sliderValue, 15, 1)
        sliderValue = guiVSlider(GEN_ID, 500, 550, 30, 300, sliderValue, 15, 1)
        spinnerValue = guiSpinner(GEN_ID, 600, 600, 100, 25, spinnerValue, -100.0, 100.0, 0.05, 2, 1)
        spinnerValue2 = guiSpinner(GEN_ID, 600, 630, 100, 25, spinnerValue2, -100.0, 100.0, 0.05, 2, 1)

guiScrollWindowEnd()
    windowX2 = guiMoveX(windowX2, 0, 1000000, windowW2, 50, 1000000)
    windowY2 = guiMoveY(windowY2, 0, 1000000, windowH2, 50, 1000000)
    windowW2 = guiResizeW(windowW2)
    windowH2 = guiResizeH(windowH2)
    windowScrollX2 = guiScrollX()
    windowScrollY2 = guiScrollY()

endfunction clicked

function window3(focused)

clicked = guiWindowBegin(GEN_ID, windowX3, windowY3, windowW3, windowH3, "Hello world!", 0, focused)
        
        windowValue3 = guiHScrollbar(GEN_ID, 30, 30, 250, 21, windowValue3, 100, 20, 5)
        windowValue3 = guiVScrollbar(GEN_ID, 30, 60, 21, 250, windowValue3, 100, 20, 5)
        windowText$ = guiTextbox(GEN_ID, 60, 60, 150, 25, windowText$, 0)
        guiLabel(GEN_ID, 60, 100, 100, 50, "Some text on a label.", 1, 1, 0xFFFFFFFF)
        
        guiComboboxBegin(GEN_ID, 60, 200, 150, 21, windowIndex3, 100, 1)
            guiComboboxItem("Hello", 20, 0)
            guiComboboxItem("world!", 20, 1)
            guiComboboxItem("Another item", 20, 1)
            guiComboboxItem("Item 4", 20, 1)
            guiComboboxItem("Item 5", 20, 1)
            guiComboboxItem("Item 6", 20, 1)
            guiComboboxItem("Item 7", 20, 1)
        windowIndex3 = guiComboboxEnd()
        
    guiWindowEnd()
    windowX3 = guiMoveX(windowX3, 0, 1000000, windowW3, 50, 1000000)
    windowY3 = guiMoveY(windowY3, 0, 1000000, windowH3, 50, 1000000)
    windowW3 = guiResizeW(windowW3)
    windowH3 = guiResizeH(windowH3)

endfunction clicked

end

+ Code Snippet

sync on : sync rate 0
set display mode desktop width(), desktop height(), 32, 0

` Initialise the GUI
guiInit()

global windowX = 750
global windowY = 100
global windowW = 400
global windowH = 400

global windowX2 = 200
global windowY2 = 50
global windowW2 = 500
global windowH2 = 600

global windowX3 = 50
global windowY3 = 300
global windowW3 = 350
global windowH3 = 400

global windowChecked1 = 0
global windowChecked2 = 0
global windowValue3 = 0
global windowText$ = "Edit me!"
global windowScrollX2
global windowScrollY2
global windowItem
global windowScrollX1
global windowScrollY1
global windowTabIndex = 1
global windowIndex3 = 0
global menuChecked = 0
global menuCheckedIndex = 0
global panelScrollX
global panelScrollY
global sliderValue
global spinnerValue as float
global spinnerValue2 as float

` These are names of functions. Each function draws a window. They are put
` in an array so that they can easily be re-ordered when a window is
` brought to the front.
dim windowFuncPtrs(2) as string
windowFuncPtrs(0) = "window2"
windowFuncPtrs(1) = "window1"
windowFuncPtrs(2) = "window3"

make camera 1
set current camera 1
set camera aspect 1, 1
set camera to image 1, 1, 300, 300, 2
color backdrop 1, 0
make object cube 1, 1
set object mask 1, %10
backdrop off 0
set current camera 0

ink 0, 0

initDBProParser()

` Declare a variable to hold the text document
myTextDocument as guiTextDocumentType

` Create a text document
guiCreateTextDocument()

` Put some text in it
guiSetTextDocumentFromString("sync on : sync rate 0" + lf$() + lf$() + "make object cube 1, 10" + lf$() + lf$() + "do" + lf$() + "    myvar = 1" + lf$() + "    print " + quote$("myvar: ") + ", myvar" + lf$() + "    sync `Update the screen" + lf$() + "loop")

` Attach the DBPro syntax parser
guiCurrentTextDocument.parser = get ptr to function("DBProParser")

` Put the result into the text document variable
myTextDocument = guiCurrentTextDocument

dim expanded(7) as boolean

do
    gameFocused = guiGame(GEN_ID, 0, 0, screen width(), screen height())

    ` Activate the text document
    guiSetCurrentTextDocument(myTextDocument)
    
    ` Draw and update the textarea
    guiTextarea(GEN_ID, 50, 50, 150, 300, scrollx, scrolly, 0)
    
    ` *IMPORTANT* Save changes to text document into variable
    myTextDocument = guiCurrentTextDocument
    
    ` Update scrolling
    scrollx = guiScrollX()
    scrolly = guiScrollY()
    
    guiHProgressbar(GEN_ID, 400, 200, 200, 24, (timer()/5) mod 1000, 1000, 0, 1)
    guiVProgressbar(GEN_ID, 400, 250, 50, 200, (timer()/5) mod 1000, 1000, 1, 1)
    
    guiGroupboxBegin(GEN_ID, 500, 500, 300, 300, THEME_TEXT_LIGHT, "Groupbox")
    guiGroupboxEnd()
    
    guiTreeviewBegin(GEN_ID, 30, 400, 300, 300, treescrollx, treescrolly, 24, treeIndex)
        expanded(0) = guiTreenodeBegin("Root node 1", 0, expanded(0))
            expanded(1) = guiTreenodeBegin("Node 1", 0, expanded(1))
                guiTreenode("Child node 1", 0)
                guiTreenode("Child node 2", 0)
                guiTreenode("Child node 3", 0)
                guiTreenode("Child node 4", 0)
                guiTreenode("Child node 5", 0)
            guiTreenodeEnd()
            expanded(2) = guiTreenodeBegin("Node 2", 0, expanded(2))
                expanded(3) = guiTreenodeBegin("Sub node 1", 0, expanded(3))
                    guiTreenode("Child node 1", 0)
                    guiTreenode("Child node 2", 0)
                    guiTreenode("Child node 3", 0)
                    guiTreenode("Child node 4", 0)
                    guiTreenode("Child node 5", 0)
                guiTreenodeEnd()
            guiTreenodeEnd()
            guiTreenode("Child node 1", 0)
            guiTreenode("Child node 2", 0)
            guiTreenode("Child node 3", 0)
            guiTreenode("Child node 4", 0)
            expanded(4) = guiTreenodeBegin("Node 3", 0, expanded(4))
                expanded(5) = guiTreenodeBegin("Sub node 1", 0, expanded(5))
                    expanded(6) = guiTreenodeBegin("Deep node 1", 0, expanded(6))
                        expanded(7) = guiTreenodeBegin("Deeper node 1", 0, expanded(7))
                            guiTreenode("Child node 1", 0)
                            guiTreenode("Child node 2", 0)
                            guiTreenode("Child node 3", 0)
                        guiTreenodeEnd()
                    guiTreenodeEnd()
                guiTreenodeEnd()
            guiTreenodeEnd()
        guiTreenodeEnd()
    treeIndex = guiTreeviewEnd()
    treescrollx = guiScrollX()
    treescrolly = guiScrollY()
    
    ` Draw the windows making sure they are in the correct order
    guiWindowListNames(get arrayptr(windowFuncPtrs()), guiRootFocused())
    
    ` Open context menu on right click
    if gui.msd = 2
        menux = gui.msx
        menuy = gui.msy
        menuopen = 1
    else
        menuopen = 0
    endif
    
    ` Draw context menu
    if guiContextMenuBegin(GEN_ID, menux, menuy, 150, 180, menuopen)
        doExampleMenu()
        guiContextMenuEnd()
    endif
    
    ` Update cube
    yrotate object 1, hitimer()*0.02
    
    print screen fps()
    
    ` Update GUI
    guiUpdate()
    sync

    cls 0xFFC0D0FF
loop

function sayHello(opened)
    if opened
        ` Initial dialog position and size
        guiModal.x = 300
        guiModal.y = 300
        guiModal.width = 220
        guiModal.height = 110
        
        ` Prevent a non-modal control from keeping the focus
        guiSetFocus(0, 0, 0)
    endif
    
    if guiMessageBox(guiModal.id, "Title", "Hello, this is a message box!", guiModal.x, guiModal.y, guiModal.width, guiModal.height, guiModal.focused)
        guiCloseModal()
    endif
    guiModal.x = guiMoveX(guiModal.x, 0, 1000000, guiModal.width, 0, 1000000)
    guiModal.y = guiMoveY(guiModal.y, 0, 1000000, guiModal.height, 0, 1000000)
endfunction

` Automatically find all the DBPro keywords
function initDBProParser()
    ` Get DBPro install path from registry
    path$ = get registry$("SOFTWARE\Dark Basic\Dark Basic Pro", "INSTALL-PATH")
    path$ = path$ + "\Editor\Keywords"
    
    ` If registry key not found, try program files
    if path exist(path$) = 0
        path$ = dir programs() + "\The Game Creators\Dark Basic Professional\Editor\Keywords"
    endif
    
    ` Open the keywords folder
    set dir path$
    
    ` Put all keywords into a lookup table for speed
    make lookup 1
    
    find first
    repeat
        if get file type() = 0
            if fast right$(get file name$(), 4) = ".ini"
                open to read 1, get file name$()
                
                read string 1, line$
                while file end(1) = 0
                    pos = find char(line$, "=")
                    if pos
                        keyword$ = fast lower$(fast left$(line$, pos-1))
                        set lookup 1, keyword$, "keyword"
                    endif
                
                    read string 1, line$
                endwhile
                
                close file 1
            endif
        endif
    
        find next
    until get file type() = -1
endfunction

` Check if the text starts with a keyword and return its length
function findKeyword(text$)
    text$ = fast lower$(text$)
    l = fast len(text$)
    for i = 1 to l
        c = mid ascii(text$, i)
        if guiIsLetterOrDigit(c) = 0 and c <> 32 and c <> 36
            exit
        endif
    next i
    dec i
    
    keyword$ = text$
    while i > 0
        keyword$ = fast left$(keyword$, i)
        if lookup exist(1, keyword$)
            exitfunction i
        endif
        
        i = last instr(keyword$, " ")-1
    endwhile
endfunction 0

` Check if the text starts with a word and return its length
function findWord(text$)
    l = fast len(text$)
    for i = 1 to l
        c = mid ascii(text$, i)
        if guiIsLetterOrDigit(c) = 0
            dec i
            exitfunction i
        endif
    next i
endfunction l

` Check if the text starts with symbols and return its length
function findSymbol(text$)
    l = fast len(text$)
    for i = 1 to l
        c = mid ascii(text$, i)
        if guiIsLetter(c) or c = 34 or c = 96
            dec i
            exitfunction i
        endif
    next i
endfunction l

` Check if the text starts with a quoted string and return its length
function findString(text$)
    c = mid ascii(text$, 1)
    if c = 34
        l = find ascii(text$, 34, 2)
        if l = 0 then l = fast len(text$)
    else
        l = 0
    endif
endfunction l

` DBPro syntax parser, called for each line
function DBProParser(state, text$, colorFuncPtr)
    ` colorFunc must be called at least once even for an empty line
    ` so that the textarea knows what font to use to determine the
    ` line height.
    if text$ = "" and colorFuncPtr <> 0
        call function ptr colorFuncPtr, 0, 0, gui.fontId, ""
    endif

    ` While the line has text left to parse
    while text$ <> ""
        ` If we are in a multiline comment
        if state
            ` TODO: Handle multiline comments
        else
            ` Get first character code
            c = asc(text$)
            if guiIsLetter(c)
                ` If it's a letter check for keywords and words
                keyword = findKeyword(text$)
                if keyword
                    ` It's a keyword
                    call function ptr colorFuncPtr, 0xFF0000FF, 0, gui.fontId, fast left$(text$, keyword)
                    text$ = mid$(text$, keyword+1, 0)
                else
                    ` It's a word (eg. variable name)
                    wordlen = findWord(text$)
                    call function ptr colorFuncPtr, 0xFF000000, 0, gui.fontId, fast left$(text$, wordlen)
                    text$ = mid$(text$, wordlen+1, 0)
                endif
            else
                ` If it's not a letter check for a symbol, quoted string or single-line comment
                symbol = findSymbol(text$)
                if symbol
                    ` It's a symbol or number
                    call function ptr colorFuncPtr, 0xFFFF0000, 0, gui.fontId, fast left$(text$, symbol)
                    text$ = mid$(text$, symbol+1, 0)
                else
                    str = findString(text$)
                    if str
                        ` It's a quoted string
                        call function ptr colorFuncPtr, 0xFF800080, 0, gui.fontId, fast left$(text$, str)
                        text$ = mid$(text$, str+1, 0)
                    else
                        ` It's a single-line comment, so process the rest of the line
                        call function ptr colorFuncPtr, 0xFF808080, 0, gui.fontId, text$
                        text$ = ""
                    endif
                endif
            endif
        endif
    endwhile
endfunction state

function doExampleMenu()
    guiMenuItem("Item 0", 0, 24, 20, 0)
    menuChecked = guiCheckboxMenuItem("Check me", 0, 24, 20, menuChecked)
    guiSplitterMenuItem(5)
    guiMenuItem("Item 2", 0, 24, 20, 0)
    if guiDropDownMenuItemBegin(GEN_ID, "Set Theme", 24, 20, 0, 150, 98)
        menuCheckedIndex = guiRadioButtonMenuItem("Default", 0, 24, 20, 0, menuCheckedIndex)
        menuCheckedIndex = guiRadioButtonMenuItem("Red", 0, 24, 20, 1, menuCheckedIndex)
        menuCheckedIndex = guiRadioButtonMenuItem("Green", 0, 24, 20, 2, menuCheckedIndex)
        menuCheckedIndex = guiRadioButtonMenuItem("Blue", 0, 24, 20, 3, menuCheckedIndex)
        
        select menuCheckedIndex
            case 0
                guiSetTheme("Default")
            endcase
            
            case 1
                guiSetTheme("Red")
            endcase
            case 2
                guiSetTheme("Green")
            endcase
            case 3
                guiSetTheme("Blue")
            endcase
        endselect
        
        guiDropDownMenuItemEnd()
    endif
    guiMenuItem("Item 3", 0, 24, 20, 0)
    guiMenuItem("Item 4", 0, 24, 20, 0)
    guiSplitterMenuItem(5)
    if guiMenuItem("Dialog", 0, 24, 20, 0)
        guiOpenModalName(RND_ID, 0, "sayHello", 0)
    endif
endfunction

function window1(focused)

    clicked = guiWindowBegin(GEN_ID, windowX, windowY, windowW, windowH, "Hello world!", 0, focused)
        
		if guiButton(GEN_ID, 230, 50, 150, 25, "Normal Button")
			guiMessageBox(GEN_ID, "Alert", "Button clicked", Screen Width() / 2, Screen Height() / 2, 300, 150, 1 )
		Endif

		if guiExtRoundedButton(GEN_ID, 230, 100, 150, 25, 4, "Round Button")
			guiMessageBox(GEN_ID, "Alert", "Button clicked", Screen Width() / 2, Screen Height() / 2, 300, 150, 1 )
		Endif

		if guiExtRoundedButton(GEN_ID, 230, 150, 150, 100, 4, "Big Round Button")
			guiMessageBox(GEN_ID, "Alert", "Button clicked", Screen Width() / 2, Screen Height() / 2, 300, 150, 1 )
		Endif

		if guiExtBevelButton(GEN_ID, 230, 300, 150, 25, 4, "Bevel Button")
			guiMessageBox(GEN_ID, "Alert", "Button clicked", Screen Width() / 2, Screen Height() / 2, 300, 150, 1 )
		Endif
		
		
        guiMenuBegin(GEN_ID, 0, 0, windowW-8, 24)
        if guiDropDownMenuItemBegin(GEN_ID, "File", 24, 0, 0, 150, 180)
            doExampleMenu()
            guiDropDownMenuItemEnd()
        endif
        if guiDropDownMenuItemBegin(GEN_ID, "Edit", 24, 0, 0, 150, 180)
            doExampleMenu()
            guiDropDownMenuItemEnd()
        endif
        if guiDropDownMenuItemBegin(GEN_ID, "View", 24, 0, 0, 150, 180)
            doExampleMenu()
            guiDropDownMenuItemEnd()
        endif
        guiMenuEnd()
        
        windowChecked1 = guiCheckbox(GEN_ID, 20, 40, 120, 30, "Check me", windowChecked1)
        
        guiListboxBegin(GEN_ID, 20, 100, 200, 200, windowScrollX1, windowScrollY1, 0, 1)
            for i = 0 to 10
                if guiListboxItem("Item "+str$(i), i mod 3, windowItem = i) then windowItem = i
            next i
        guiListboxEnd()
        windowScrollX1 = guiScrollX()
        windowScrollY1 = guiScrollY()
        
    guiWindowEnd()
    windowX = guiMoveX(windowX, 0, 1000000, windowW, 50, 1000000)
    windowY = guiMoveY(windowY, 0, 1000000, windowH, 50, 1000000)
    windowW = guiResizeW(windowW)
    windowH = guiResizeH(windowH)

endfunction clicked

function window2(focused)

    windowId = GEN_ID
    clicked = guiScrollWindowBegin(windowId, windowX2, windowY2, windowW2, windowH2, "Hello World!", windowScrollX2, windowScrollY2, 1000, 1000, 0, focused)
        
        windowChecked2 = guiRadioButton(GEN_ID, 100, 40, 120, 30, "Check me", 0, windowChecked2)
        windowChecked2 = guiRadioButton(GEN_ID, 100, 80, 120, 30, "Check me", 1, windowChecked2)
        windowChecked2 = guiRadioButton(GEN_ID, 100, 120, 120, 30, "Check me", 2, windowChecked2)
        windowChecked2 = guiRadioButton(GEN_ID, 100, 160, 120, 30, "Check me", 3, windowChecked2)

        guiTabsBegin(GEN_ID, 100, 200, 308, 332, 25, windowTabIndex)
            if guiTabBegin("Tab 0", 0)
            
                guiBeginGridLayout(0, 0, 29, 29, -2, -2)
            
                if guiButton(GEN_ID, 0, 0, 10, 1, "Click me!")
                    guiOpenModalName(RND_ID, windowId, "sayHello", 0)
                endif
                if guiButton(GEN_ID, 0, 1, 3, 2, "Click me!")
                    guiOpenModalName(RND_ID, windowId, "sayHello", 0)
                endif
                guiButton(GEN_ID, 6, 1, 3, 3, "Hi")
                guiButton(GEN_ID, 5, 4, 5, 2, "Hi")
                guiButton(GEN_ID, 7, 7, 3, 3, "Fill")
                
                guiEndGridLayout()
                
                guiTabEnd()
            endif
            if guiTabBegin("Tab 1", 0)
                a2DrawImage 1, guiAdjustX(0), guiAdjustY(0), 0, 0, 0, 1, 0, 0xFFFFFFFF
                guiTabEnd()
            endif
            if guiTabBegin("Tab 2", 0)
                windowText$ = guiPassbox(GEN_ID, 20, 20, 150, 25, windowText$, chr$(149), 0)
                guiTabEnd()
            endif
        windowTabIndex = guiTabsEnd()
        
        guiScrollPanelBegin(GEN_ID, 500, 100, 300, 300, panelScrollX, panelScrollY, 0, 1, 1)
            if guiButton(GEN_ID, 200, 300, 200, 50, "Click me!")
            endif
        guiScrollPanelEnd(600, 600)
        panelScrollX = guiScrollX()
        panelScrollY = guiScrollY()
        
        sliderValue = guiHSlider(GEN_ID, 500, 500, 300, 30, sliderValue, 15, 1)
        sliderValue = guiVSlider(GEN_ID, 500, 550, 30, 300, sliderValue, 15, 1)
        spinnerValue = guiSpinner(GEN_ID, 600, 600, 100, 25, spinnerValue, -100.0, 100.0, 0.05, 2, 1)
        spinnerValue2 = guiSpinner(GEN_ID, 600, 630, 100, 25, spinnerValue2, -100.0, 100.0, 0.05, 2, 1)

    guiScrollWindowEnd()
    windowX2 = guiMoveX(windowX2, 0, 1000000, windowW2, 50, 1000000)
    windowY2 = guiMoveY(windowY2, 0, 1000000, windowH2, 50, 1000000)
    windowW2 = guiResizeW(windowW2)
    windowH2 = guiResizeH(windowH2)
    windowScrollX2 = guiScrollX()
    windowScrollY2 = guiScrollY()

endfunction clicked

function window3(focused)

    clicked = guiWindowBegin(GEN_ID, windowX3, windowY3, windowW3, windowH3, "Hello world!", 0, focused)
        
        windowValue3 = guiHScrollbar(GEN_ID, 30, 30, 250, 21, windowValue3, 100, 20, 5)
        windowValue3 = guiVScrollbar(GEN_ID, 30, 60, 21, 250, windowValue3, 100, 20, 5)
        windowText$ = guiTextbox(GEN_ID, 60, 60, 150, 25, windowText$, 0)
        guiLabel(GEN_ID, 60, 100, 100, 50, "Some text on a label.", 1, 1, 0xFFFFFFFF)
        
        guiComboboxBegin(GEN_ID, 60, 200, 150, 21, windowIndex3, 100, 1)
            guiComboboxItem("Hello", 20, 0)
            guiComboboxItem("world!", 20, 1)
            guiComboboxItem("Another item", 20, 1)
            guiComboboxItem("Item 4", 20, 1)
            guiComboboxItem("Item 5", 20, 1)
            guiComboboxItem("Item 6", 20, 1)
            guiComboboxItem("Item 7", 20, 1)
        windowIndex3 = guiComboboxEnd()
        
    guiWindowEnd()
    windowX3 = guiMoveX(windowX3, 0, 1000000, windowW3, 50, 1000000)
    windowY3 = guiMoveY(windowY3, 0, 1000000, windowH3, 50, 1000000)
    windowW3 = guiResizeW(windowW3)
    windowH3 = guiResizeH(windowH3)

endfunction clicked

end

Back to top

Profile PM Email Website

GlenNU

12

Years of Service

User Offline

Joined: 10th Oct 2011

Location:

Posted: 6th Feb 2012 07:55

Link

i am having a problem with sprites and topgui:

with topgui - white sprite:

without topgui:

-

Back to top

Profile PM

GlenNU

12

Years of Service

User Offline

Joined: 10th Oct 2011

Location:

Posted: 13th Feb 2012 04:28

Link

I already fixed the above post..

is it possible to implement an imagebox in topgui?

-

Back to top

Profile PM

Diggsey

17

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 13th Feb 2012 13:06 Edited at: 13th Feb 2012 13:07

Link

Sorry I must have missed your first post, what was the problem in the end?

Also, TopGUI already supports an imagebox. For normal or tiled images you can use a normal panel or a scroll panel (guiPanel(), guiScrollPanel()). For other effects such as scaling, you can just draw the image yourself using "a2DrawImage" when inside the window you want it to appear in.

guiAdjustX(localx) and guiAdjustY(localy) will convert local coordinates inside the current control into screen coordinates for you.

[b]

Back to top

Profile PM Email Website

Gunslinger

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 17th Feb 2012 01:29 Edited at: 17th Feb 2012 01:41

Link

First of all i have to say: Awesome Project! Allready using it in my project(s). Keep on it!

You could add a Text button like i'm doing.

function guiTextButtonDraw(id as guiId, w, h, caption$)
    x = guiAdjustX(0)
    y = guiAdjustY(0)
    
    focused = guiGetFocus() = id
    pressed = focused and spacekey()
    
    if guiGetHot() = id or pressed
        if guiGetActive() = id or pressed
            ` Active (pressed)           
   		guiFastBoxText(gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW_ACTIVE)
    		guiFastBoxText(gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK_ACTIVE)             
        else
            ` Hot         
    		guiFastBoxText(gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW_ACTIVE)
    		guiFastBoxText(gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK_ACTIVE)    		
        endif
    else
        ` Normal
        guiFastBoxText(gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW)
    	guiFastBoxText(gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK)
    endif
    
//    if focused
//        guiDrawFocusRect(x+3, y+3, x+w-4, y+h-4, THEME_FOCUS_DARK)
//    endif
    
endfunction

+ Code Snippet

function guiTextButtonDraw(id as guiId, w, h, caption$)
    x = guiAdjustX(0)
    y = guiAdjustY(0)
    
    focused = guiGetFocus() = id
    pressed = focused and spacekey()
    
    if guiGetHot() = id or pressed
        if guiGetActive() = id or pressed
            ` Active (pressed)           
   		guiFastBoxText(gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW_ACTIVE)
    		guiFastBoxText(gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK_ACTIVE)             
        else
            ` Hot         
    		guiFastBoxText(gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW_ACTIVE)
    		guiFastBoxText(gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK_ACTIVE)    		
        endif
    else
        ` Normal
        guiFastBoxText(gui.fontId, x+4, y+4, x+w-2, y+h-2, caption$, 1, 1, 1, THEME_TEXT_SHADOW)
    	guiFastBoxText(gui.fontId, x+3, y+3, x+w-3, y+h-3, caption$, 1, 1, 1, THEME_TEXT_DARK)
    endif
    
//    if focused
//        guiDrawFocusRect(x+3, y+3, x+w-4, y+h-4, THEME_FOCUS_DARK)
//    endif
    
endfunction

(Code was just a test, maybe theres a better way.)

best regards.

edit: Gridboxes would be awesome too! Need that for my Server Browser

Back to top

Profile PM

Lost Dragon

13

Years of Service

User Offline

Joined: 22nd Aug 2010

Location:

Posted: 17th Feb 2012 05:42

Link

This is really cool.

I'm plowing through it now. Is there any help file or instructions?

I noticed that the scroll bar's "bar" (whatever that is called) will eventually get so small that it becomes really hard to grab if there are enough items in a window. It should probably have a minimum size set.

Does this have any sort of drag and drop functionality built in? Say like I wanted to drag an icon from one window and drop it in another?

It's really good work. I also use your Advanced2D functions. Thanks!

Back to top

Profile PM

Gunslinger

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 17th Feb 2012 19:26 Edited at: 17th Feb 2012 19:30

Link

How can i readout the ItemIndex or ItemText of the selected item in a combo box?

Got it, guiComboboxEnd()

Back to top

Profile PM

Diggsey

17

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 17th Feb 2012 22:58

Link

@Gunslinger
Nice idea, I'll add that for the next update. I'll see what I can do about gridboxes, but they're alot more complicated.

@Lost Dragon
Not really any help files, sorry. I'll see if I can make at least some sort of document explaining how to use it at some point.

Good point about the scrollbar, will work on fixing that.

Drag and drop is not built in. It's fairly easy to emulate, but I'll see if I can add some stuff to make it easier.

[b]

Back to top

Profile PM Email Website

Lost Dragon

13

Years of Service

User Offline

Joined: 22nd Aug 2010

Location:

Posted: 17th Feb 2012 23:17

Link

Can someone show me how to use guiTextarea properly?

I want to put some strings in a box (that can scroll) and have them word wrap when appropriate. I thought guiTextarea would be good for that but I don't understand how to use it.

I need a simple example without a parser or anything fancy.

I got buttons to work okay.

Back to top

Profile PM

Diggsey

17

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 18th Feb 2012 00:32 Edited at: 18th Feb 2012 15:23

Link

Ok, it's actually not too bad:

+ Code Snippet


` Declare a variable to hold the text document
myTextDocument as guiTextDocumentType

` Create a text document
guiCreateTextDocument()

` Put some text in it
guiSetTextDocumentFromString("<insert text here>")

` Attach the default parser (no formatting)
guiCurrentTextDocument.parser = get ptr to function("guiDefaultParser")

` Put the result into the text document variable
myTextDocument = guiCurrentTextDocument

do
    ` Activate the text document
    guiSetCurrentTextDocument(myTextDocument)
    
    ` Draw and update the textarea
    guiTextarea(GEN_ID, 50, 50, 150, 300, scrollx, scrolly, 0)
    
    ` *IMPORTANT* Save changes to text document into variable
    myTextDocument = guiCurrentTextDocument
    
    ` Update scrolling
    scrollx = guiScrollX()
    scrolly = guiScrollY()

The stuff after the "do" should go in your main loop where you actually want the text to appear.

You can't not have a parser, since it needs to know how it should display the text, but top-gui comes with a default one which just says to use the default text style for everything.

edit:
If all you want to do is display multi-line word-wrapped text with no selection or editing, you'd be better off just using a label

[b]

Back to top

Profile PM Email Website

Gunslinger

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 18th Feb 2012 01:57

Link

Found a small bug.
If you draw the windows (with a picbutton) with

guiWindowListNames(get arrayptr(windowFuncPtrs()), 1)

at a first part of the game (like the menu), and then clean the memory (deleting all images for example)

and then draw it again (ingame, after the menu) it will crash at removing the cached images (even if a new image is loaded with the same image number)

+ Code Snippet

` Clear unused text from the cache
    n = array count(guiCachedText())
    for i = 0 to n
        if guiCachedText(i).used = 0
            delete image guiCachedText(i).imageId
            array delete element guiCachedText(), i
            dec i
            dec n
        else
            guiCachedText(i).used = 0
        endif
    next i

can be fixed with

+ Code Snippet

    ` Clear unused text from the cache
    n = array count(guiCachedText())
    for i = 0 to n
        if guiCachedText(i).used = 0
            if image exist(guiCachedText(i).imageId) then delete image guiCachedText(i).imageId
            array delete element guiCachedText(), i
            dec i
            dec n
        else
            guiCachedText(i).used = 0
        endif
    next i

I think.

And, i have no clue why, if you load an image to a button, and delete it later, it cant be loaded again.

Like

load image "xxx", 2
draw a image button with image 2 at the game menu
delete all images
load image "yyy", 2

that image can't be displayed.

Back to top

Profile PM

Diggsey

17

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 18th Feb 2012 02:34 Edited at: 18th Feb 2012 02:35

Link

You shouldn't just delete all images. TopGUI has its own resource management, so you should only delete images that you have created. The simplest way of doing this is just add all image IDs you use to an array and then use that array for deleting images, but you should normally have some way of keeping track of things anyway.

[b]

Back to top

Profile PM Email Website

Gunslinger

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 18th Feb 2012 02:46

Link

Ye i put that into arrays. But i just wanted a "lazy" solution for getting from the menu into the game, and back

Back to top

Profile PM

Diggsey

17

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 18th Feb 2012 03:16

Link

Just updated the first post with a new version

- Text button is now supported
- Scrollbar thumbs won't get too small
- Drag-drop is now supported
- Altered test program to include new features

[b]

Back to top

Profile PM Email Website

Diggsey

17

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 18th Feb 2012 23:47

Link

Another update with some features I think alot of people will find useful:
- Message dialog
- Open file dialog
- Save file dialog

These are very easy to use, just call the relevent function (see TopGui_Dialog.dba) and pass in a pointer to a function to call.

When the dialog is closed the function you specified will be called and the result of the dialog passed in.

The dialogs support filters and optionally selection of multiple files at once.

[b]

Back to top

Profile PM Email Website

GlenNU

12

Years of Service

User Offline

Joined: 10th Oct 2011

Location:

Posted: 20th Feb 2012 14:17

Link

How can I make TopGUI to appear on top of sprites?

-

Back to top

Profile PM

Diggsey

17

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 20th Feb 2012 18:03

Link

The only thing that can appear on top of sprites is another sprite. The easiest thing to do would be to hide the sprite and use "paste sprite" to draw it instead. As long as the "paste sprite" command appears before that part of the GUI is drawn it will appear underneath it.

[b]

Back to top

Profile PM Email Website

Gunslinger

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 20th Feb 2012 20:19

Link

Just a question, but why do you use topgui to draw that bars?

Back to top

Profile PM

GlenNU

12

Years of Service

User Offline

Joined: 10th Oct 2011

Location:

Posted: 21st Feb 2012 14:24

Link

I'm a newbie..
I use TopGUI for HP Bars and menu buttons..

-

Back to top

Profile PM

Gunslinger

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 21st Feb 2012 16:20

Link

Nah, it's okay. Just asking

Back to top

Profile PM

Gunslinger

16

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 2nd Mar 2012 20:21 Edited at: 2nd Mar 2012 21:32

Link

Is there a way to return the selected item text of a combo box?
Did not see it in the combobox file.

e// Okay, created my own function for that.

edit again: For dialogs are no returns done too, are they? Or am i just too stupid to find that?

Back to top

Profile PM

Jimmy

20

Years of Service

User Offline

Joined: 20th Aug 2003

Location: Back in the USA

Posted: 3rd Mar 2012 00:24 Edited at: 3rd Mar 2012 00:25

Link

guiComboboxEnd() returns the index of the selected item

And it looks like, with the dialogs, you have to pass the pointer to a callback function that takes 3 parameters: param As Integer, path As String, and result As String.

Example:

+ Code Snippet

guiOpenFileDialog(RND_ID, windowId, -1, -1, -1, -1, "C:\", "Open File", "All Files|*|DBPro Files|*.dba;*.dbpro|Image Files|*.png;*.jpg;*.bmp", 1, Get Ptr To Function("openFileCallback"), 0)

Function openFileCallback(param, path$, result$)
    Open To Write 1, result$
EndFunction

Back to top

Profile PM Website

Diggsey

17

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 3rd Mar 2012 04:39

Link

Dialogs don't return a result immediately because while the user is interacting with them the program must keep running, so instead you pass in a function which will be called when the dialog is closed such as in Jimmy's example.

[b]

Back to top

Profile PM Email Website

NQC

14

Years of Service

User Offline

Joined: 14th Mar 2009

Location:

Posted: 6th May 2012 00:06

Link

What function use for remove gui?

I am a newbie. ^ ^

NQC

Back to top

Profile PM

Diggsey

17

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 6th May 2012 21:05

Link

There's no function to remove the gui, because the gui isn't a persistant thing. As soon as you stop calling the functions to draw the gui it will no longer exist.

[b]

Back to top

Profile PM Email Website

NQC

14

Years of Service

User Offline

Joined: 14th Mar 2009

Location:

Posted: 6th May 2012 21:38

Link

Thank you for answer. I'll re-coding and test again.

NQC

Back to top

Profile PM

Duffer

20

Years of Service

User Offline

Joined: 9th Feb 2003

Location: chair

Posted: 7th May 2012 13:12 Edited at: 7th May 2012 13:12

Link

@ Diggsey,

Any chance of a TopGUI design utility exporting to dba code?

[edit]

I'm being lazy - could code one myself - but wouldn't be fantastic...

a long time dabbler with DBC and DBPro with no actual talent but lots of enthusiasm...

Back to top

Profile PM Email

NQC

14

Years of Service

User Offline

Joined: 14th Mar 2009

Location:

Posted: 8th May 2012 07:52

Link

I've tested, it ok ^ ^. And i have some question. Can Topgui make item inventory gui like an online game?.

NQC

Back to top

Profile PM

basjak

13

Years of Service

User Offline

Joined: 16th Apr 2010

Location: feel like signing up for mars

Posted: 22nd May 2012 03:34

Link

@diggsey:
I already started with bbb gui by brendy boy. however, I left it for a while as i've been busy with couple of AppGameKit projects.

now I want to comeback to gui things.

which one is better bbb gui or top gui. or both are the same. however, I didn't see those coloring frames in bbb gui.

Back to top

Profile PM Email Website

Diggsey

17

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 22nd May 2012 05:48

Link

BBB gui uses the windows API to create the gui, this draws it all itself, it depends on your requirements which one you should use. If you need it to look like a standard windows application UI then use BBB gui. For something like a game, or an application where you need to do custom rendering on top of the gui I'd suggest that you use this.

[b]

Back to top

Profile PM Email Website

Sorry your browser is not supported!

Work in Progress / TopGUI - Open source immediate mode GUI