Hi crazy kitty
I think the problem you are having is that the line "position object 1,100,0,100" is inside the main loop so the object will always just move back to this position when the mouse is not moving.
The mousemovex() and mousemovey() can be a little flaky as well which can be confusing.
I've knocked up a little demo to give you a basic idea.
sync rate 65
sync on
hide mouse
`make a matrix to give you a reference point (not really required but I find it usefull)
make matrix 1, 1000,1000,10,10
`make a simple object to move around
make object cube 1, 50
`initial position of the object
position object 1, 500,25,500
`main loop
do
`write the mouse move values to a variable (the mousemovex() and mousemovey() are a litte flaky)
mouse_move_x = mousemovex()
mouse_move_y = mousemovey()
`if the mouse is move to the left
if mouse_move_x < 0
move object left 1, 10
endif
`if the mouse is move to the right
if mouse_move_x > 0
move object right 1, 10
endif
`if the mouse is moved forward (the cursor moves up but this is the negative direction, this confuses me but that's the way it is)
if mouse_move_y < 0
move object 1, 10
endif
`if the mouse is moved backward (the cursor moves downward but this is positive direction)
if mouse_move_y > 0
move object 1, -10
endif
`point and position the camera
position camera 500,400,-500
point camera 500,0,500
`print stuff to the screen which you might find helpful
set cursor 0,0
print "move the mouse to move the cube"
print
print "mouse_move_x : ", mouse_move_x
print "mouse_move_y : ", mouse_move_y
print "x position of the object : ", object position x(1)
print "y position of the object : ", object position y(1)
print "z position of the object : ", object position z(1)
sync
loop
If want to rotate the object the object so you can drive it around like a car have a look at the rotate, turn, pitch and roll object commands. If you want to have the camera follow the cube round, then either link the camera's position and facing to the cube or have a look at the set camera to follow command.
