vertexdata - GameCreators Forum

Author

Message

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 27th Jul 2011 21:09

Link

Hello, I'm having a really hard time getting to grips with the vertexdata commands. Basically I just want to combine lots of cubes into one object for a minecraft clone I'm making.

I've been experimenting with it, and so far I've managed this much.

+ Code Snippet

sync on: sync rate 0

make object plain 1,1.0,1.0
set object wireframe 1,1

make object cube 2,2.0
make mesh from object 2,2
delete object 2

lock vertexdata for limb 1,0

add mesh to vertexdata 2
set vertexdata position 2,6,0,0
unlock vertexdata


do

text 0,0, str$( screen fps() ) 

sync
loop

I see the cube I've added. But I expected the set vertexdata position to move one of the vertices, yet it doesn't. Have I gotten the wrong end of the stick here?

Thanks.

Back to top

Profile PM

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 27th Jul 2011 21:36

Link

Use an extra flag of 2 in your lock vertexdata command so it will update

+ Code Snippet

lock vertexdata for limb 1,0,2

But I think it would be easier to just add limbs to the object.

+ Code Snippet


sync on: sync rate 0

make object plain 1,1.0,1.0
set object wireframe 1,1

make object cube 2,2.0
make mesh from object 2,2
add limb 1, 1, 2
delete object 2


do

text 0,0, str$( screen fps() ) 

sync
loop

Back to top

Profile PM

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 27th Jul 2011 21:43 Edited at: 27th Jul 2011 21:48

Link

I've just tried that, it still doesn't have an effect. Am I using the set vertexdata position command incorrectly?
EDIT: Disregard that, I've made progress. :3

From what I've seen of the open source minecraft engine on these forums, using vertexdata instead of limbs gives a massive performance increase.

Back to top

Profile PM

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 27th Jul 2011 22:00

Link

Found the problem, you are creating a plain first as a base object and adding the cube later. But you are moving vertex #2. Vertices 0 to 6 belong to the plain, try moving vertex 10 and you will see something

Back to top

Profile PM

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 27th Jul 2011 22:08

Link

Ah, I thought at plain had 4 vertices, but now I think about it, of course it has 6. xD

Thanks. Do you know of a way I can make this work without having a plain as a base object? I don't want to use any plugins because I'm actually using GDK in my project, but dark basic for testing.

Back to top

Profile PM

chafari

Valued Member

20

Years of Service

User Offline

Joined: 2nd May 2006

Location: Canary Islands

Posted: 27th Jul 2011 22:18

Link

In the vertex data of a box, we have 24 vertex...when you add vertex data to your object plain(6 vertex), in this case 24 more vertex, you finally have 30 vertex...then if you want to separate those vertex, you will have to separate from vertex 7 to vertex 30 from the initial mesh...in this example I play with the vertex 7 of your final mesh. I hope it can help

+ Code Snippet

sync on: sync rate 0

make object plain 1,1.0,1.0
set object wireframe 1,1

make object cube 2,2.0
make mesh from object 2,2
delete object 2

lock vertexdata for limb 1,0

add mesh to vertexdata 2
set vertexdata position 7,0,0,0
unlock vertexdata

make object box 20,1,1,1
offset limb 20,0,5,0,0
position camera -10,10,-10
point camera 0,0,0

do
g#=g#+0.1
xx#=limb position x(20,0)
yy#=limb position y(20,0)
zz#=limb position z(20,0)
yrotate object 20,g#

lock vertexdata for limb 1,0
set vertexdata position 7,-xx#,yy#,-zz#
unlock vertexdata

text 0,0, str$( screen fps() )

sync
loop

I'm not a grumpy grandpa

Back to top

Profile PM Email

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 27th Jul 2011 22:26

Link

You can use DELETE MESH FROM VERTEXDATA Vertex Start, Vertex End, Index Start, Index End:

+ Code Snippet

// I guess it needs to be this
DELETE MESH FROM VERTEXDATA 0, 5, 0, 1

Back to top

Profile PM

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 27th Jul 2011 22:29 Edited at: 27th Jul 2011 22:40

Link

Ah, thanks chafari. I'm starting to understand now.

+ Code Snippet

sync on: sync rate 0

make object plain 1,1.0,1.0
set object wireframe 1,1

make object cube 2,2.0
make mesh from object 2,2
delete object 2

lock vertexdata for limb 1,0,2
index = get vertexdata vertex count()
add mesh to vertexdata 2

for i = index to index+24

	set vertexdata position i,get vertexdata position x(i)+1.0,get vertexdata position y(i),get vertexdata position z(i)
	
next i

unlock vertexdata

make object box 20,1,1,1
offset limb 20,0,5,0,0
position camera -2,2,-2
point camera 0,0,0

do

text 0,0, str$( screen fps() )

sync
loop

Is there anything here that stands out as being particularly problematic?

Edit: posted the same time as you Max. Thanks, that should work brilliantly.

Now, the only problem I've having is when I add twenty of the meshes to the object, if the first one goes out of view, they all disappear. I assume this is something to do with the culling system.

Any way around this?

Example:

+ Code Snippet

sync on: sync rate 0

make object plain 1,1.0,1.0
set object wireframe 1,1

make object cube 2,2.0
make mesh from object 2,2
delete object 2

lock vertexdata for limb 1,0,1

for x = 0 to 20
	index = get vertexdata vertex count()
	add mesh to vertexdata 2
		
	for i = index to index+24
		
		set vertexdata position i,get vertexdata position x(i)+2.0*x,get vertexdata position y(i),get vertexdata position z(i)
			
	next i
	next x

unlock vertexdata

make object box 20,1,1,1
offset limb 20,0,5,0,0
position camera -2,2,-2
point camera 0,0,0

do
xrotate camera camera angle x() + mousemovey()
yrotate camera camera angle y() + mousemovex()
text 0,0, str$( screen fps() )

sync
loop

Sorry for all the questions man, Thanks a lot for helping me out.

Indi.

Back to top

Profile PM

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 27th Jul 2011 22:44 Edited at: 27th Jul 2011 22:46

Link

looks good, maybe adding an array with the vertexdata start for every cube would be handy, so you can edit the cubes later if you want to:

sync on: sync rate 0

make object plain 1,1.0,1.0
set object wireframe 1,1

dim cubeVertexdata(-1) as integer

myCube = newCube()
moveCube(myCube, -1 , 0 , 0 )

make object box 20,1,1,1
offset limb 20,0,5,0,0
position camera -2,2,-2
point camera 0,0,0

do

text 0,0, str$( screen fps() )

sync
loop

Function newCube()
    
    make object cube 2,2.0
    make mesh from object 2,2
    delete object 2
    
    lock vertexdata for limb 1,0,2
    index = get vertexdata vertex count()
    add mesh to vertexdata 2
    
    array insert at bottom cubeVertexdata()
    arrayIndex = array count( cubeVertexdata() )
    cubeVertexdata(arrayIndex) = index
    
    unlock vertexdata
    
endFunction arrayIndex

Function moveCube(index, x as float , y as float , z as float )

lock vertexdata for limb 1, 0, 2

startIndex = cubeVertexdata(index)

for i = startIndex to startIndex+24

set vertexdata position i,get vertexdata position x(i)+x,get vertexdata position y(i)+y,get vertexdata position z(i)+z
    
    next i
    
    unlock vertexdata
    
endFunction

+ Code Snippet

sync on: sync rate 0

make object plain 1,1.0,1.0
set object wireframe 1,1

dim cubeVertexdata(-1) as integer

myCube = newCube()
moveCube(myCube, -1 , 0 , 0 )

make object box 20,1,1,1
offset limb 20,0,5,0,0
position camera -2,2,-2
point camera 0,0,0

do

text 0,0, str$( screen fps() )

sync
loop

Function newCube()
    
    make object cube 2,2.0
    make mesh from object 2,2
    delete object 2
    
    lock vertexdata for limb 1,0,2
    index = get vertexdata vertex count()
    add mesh to vertexdata 2
    
    array insert at bottom cubeVertexdata()
    arrayIndex = array count( cubeVertexdata() )
    cubeVertexdata(arrayIndex) = index
    
    unlock vertexdata
    
endFunction arrayIndex

Function moveCube(index, x as float , y as float , z as float )

    lock vertexdata for limb 1, 0, 2

    startIndex = cubeVertexdata(index)

    for i = startIndex to startIndex+24

        set vertexdata position i,get vertexdata position x(i)+x,get vertexdata position y(i)+y,get vertexdata position z(i)+z
    
    next i
    
    unlock vertexdata
    
endFunction

edit
Didn't read your edit yet when i replied

use calculate object bounds

Back to top

Profile PM

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 27th Jul 2011 22:49

Link

Sorry made a small mistake in the previous code, here is new code, including calculate object bounds

sync on: sync rate 60

make object plain 1,1.0,1.0
set object wireframe 1,1

dim cubeVertexdata(-1) as integer

make object cube 2,2.0
make mesh from object 2,2
delete object 2

for i=1 to 10
    myCube = newCube()
    moveCube(myCube, -i*2 , 0 , 0 )
next i

calculate object bounds 1

make object box 20,1,1,1
offset limb 20,0,5,0,0
position camera -2,2,-2
point camera 0,0,0

do

text 0,0, str$( screen fps() )

control camera using arrowkeys 0, 1, 2

sync
loop

Function newCube()
    
    
    lock vertexdata for limb 1,0,2
    index = get vertexdata vertex count()
    add mesh to vertexdata 2
    
    array insert at bottom cubeVertexdata()
    arrayIndex = array count( cubeVertexdata() )
    cubeVertexdata(arrayIndex) = index
    
    unlock vertexdata
    
endFunction arrayIndex

Function moveCube(index, x as float , y as float , z as float )

lock vertexdata for limb 1, 0, 2

startIndex = cubeVertexdata(index)

for i = startIndex to startIndex+24

set vertexdata position i,get vertexdata position x(i)+x,get vertexdata position y(i)+y,get vertexdata position z(i)+z
    
    next i
    
    unlock vertexdata
    
endFunction

+ Code Snippet

sync on: sync rate 60

make object plain 1,1.0,1.0
set object wireframe 1,1

dim cubeVertexdata(-1) as integer


make object cube 2,2.0
make mesh from object 2,2
delete object 2

for i=1 to 10
    myCube = newCube()
    moveCube(myCube, -i*2 , 0 , 0 )
next i

calculate object bounds 1

make object box 20,1,1,1
offset limb 20,0,5,0,0
position camera -2,2,-2
point camera 0,0,0

do

text 0,0, str$( screen fps() )

control camera using arrowkeys 0, 1, 2

sync
loop

Function newCube()
    
    
    lock vertexdata for limb 1,0,2
    index = get vertexdata vertex count()
    add mesh to vertexdata 2
    
    array insert at bottom cubeVertexdata()
    arrayIndex = array count( cubeVertexdata() )
    cubeVertexdata(arrayIndex) = index
    
    unlock vertexdata
    
endFunction arrayIndex

Function moveCube(index, x as float , y as float , z as float )

    lock vertexdata for limb 1, 0, 2

    startIndex = cubeVertexdata(index)

    for i = startIndex to startIndex+24

        set vertexdata position i,get vertexdata position x(i)+x,get vertexdata position y(i)+y,get vertexdata position z(i)+z
    
    next i
    
    unlock vertexdata
    
endFunction

Back to top

Profile PM

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 27th Jul 2011 22:50

Link

Adding an array is probably a good idea, yes.

But for now I just want to toy about with the vertexdata commands. I usually like to think I know what I'm doing, but I've never used them before.

That command worked perfectly.

There's definitely a performance increase, I get over 500fps with 2000 cubes! Compared to about 30fps using limbs. xD Now I want to experiment with making the cubes out of plains, so I can control them individually.

If you don't mind, could you explain how I would go about texturing each individual cube within the mesh?

Thanks so much man, Indi.

Back to top

Profile PM

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 27th Jul 2011 23:02

Link

That's gonna be a bit harder since it aren't sepparate limbs, but it is possible. I'll give an example in a few min

Back to top

Profile PM

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 27th Jul 2011 23:05

Link

I guessed it would be harder. ;3 Thanks man, I owe you one. If there's anything I can do for you, I usually hang around in Geek Culture haha.

Back to top

Profile PM

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 27th Jul 2011 23:40

Link

I'm sorry but I can't get it to work here (it's getting late, need some sleep

)
But I will give you the basics so you can try it

Basically you need multiple textures in one image (see attachement)

Then you need change the uv's of the cube to the right texture.
For this you need to get the amount of textures inside the image, here 3.

So for the u coordinates of the cube you need to use something like this:

+ Code Snippet

	imgSize# = 1.0/3.0 `3 textures in the image

For a plane you would do something like this:

+ Code Snippet


	texture = 1 ` we have texture 1, 2 and 3 in the image
	
	Remstart

	a----------b
	|        / |
	|      /   |
	|    /     |
	|  /       |
	|/         |
	c----------d

	For a the uv should be: (texture-1)*imgSize#, 0
	For b                 : (texture  )*imgSize#, 0
	For c                 : (texture-1)*imgSize#, 1
	For d                 : (texture  )*imgSize#, 1

	Remend

Only for a cube it is a bit harder, I'll try helping you out tomorrow

Back to top

Profile PM

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 28th Jul 2011 00:18 Edited at: 28th Jul 2011 00:41

Link

Don't worry about it man.

Thanks for trying it out. ;D I'll have a look around on the forums and see what I can find.

edit: Your explanation makes sense actually, thanks, time for me to mess abut for a few hours.

Thanks a lot for you help.

Back to top

Profile PM

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 29th Jul 2011 02:37 Edited at: 29th Jul 2011 03:48

Link

Hey again, sorry to double post but I guessed my edit wouldn't be seen.

I've tried to redo this with plains instead of cubes, I'm having a problem where my plains don't appear when adding them to the mesh.

+ Code Snippet

sync on:sync rate 0

make object plain 1,1.0,1.0

make object plain 2, 1.0,1.0
make mesh from object 1,2
delete object 2

lock vertexdata for limb 1,0,2

delete mesh from vertexdata 0,5,0,1
add mesh to vertexdata 1

unlock vertexdata

do

sync
loop

Any ideas?

Btw, I got the texturing working amazingly, thanks Max!
Thanks, Indi.

Back to top

Profile PM

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 29th Jul 2011 14:14 Edited at: 29th Jul 2011 14:18

Link

It took a while but I finally figured out a solution

sync on:sync rate 60
set camera range .01, 100000
Global worldObject as integer
Global plainMesh as integer
Global worldCubeSize as float

WorldSetCubeSize(1)
createEmptyWorld()

lockWorld()
    cube1 = addWorldCube( 0, 0, 0 )
unlockWorld()

position camera 0, -worldCubeSize*2, worldCubeSize*2, 0
point camera 0, 0, 0

NULL# = mousemovex()
NULL# = mousemovey()

do

rotate camera camera angle x() + mousemovey() , camera angle y() + mousemovex() , 0

move camera (upkey()-downkey())*0.1

set cursor 0, 0
sync
loop

Function WorldSetCubeSize( size as float )
    worldCubeSize = size
endFunction

Function createEmptyWorld()

worldObject = find free object()
    plainMesh   = find free mesh()

make object plain worldObject, 0, 0, 1, 1
    
    tmpObject = find free object()
    make object plain tmpObject, worldCubeSize, worldCubeSize, 1, 1
    make mesh from object plainMesh, tmpObject
    delete object tmpObject
    
endFunction

Function addWorldCube( x as float , y as float , z as float )
    index = 0
    for i=0 to 5
        if i=0 
            index = addWorldPlain( x, y, z, i ) 
        else
            addWorldPlain( x, y, z, i ) 
        endif
    next i
endFunction index

Function addWorldPlain( x as float , y as float , z as float , direction as integer )
    add mesh to vertexdata plainMesh
    index = get vertexdata vertex count()-4
    
    if direction=0
      set vertexdata position index,x+worldCubeSize,y,z
      set vertexdata position index+1,x,y,z
      set vertexdata position index+2,x+worldCubeSize,y,z-worldCubeSize
      set vertexdata position index+3,x,y,z-worldCubeSize
      for i=0 to 3
         set vertexdata normals index+i,0,-1.0,0
      next i
   endif
   if direction=1
      set vertexdata position index,x,y+worldCubeSize,z
      set vertexdata position index+1,x+worldCubeSize,y+worldCubeSize,z
      set vertexdata position index+2,x,y+worldCubeSize,z-worldCubeSize
      set vertexdata position index+3,x+worldCubeSize,y+worldCubeSize,z-worldCubeSize
      for i=0 to 3
         set vertexdata normals index+i,0,1.0,0
      next i
   endif
   if direction=2
      set vertexdata position index,x+worldCubeSize,y+worldCubeSize,z-worldCubeSize
      set vertexdata position index+1,x+worldCubeSize,y+worldCubeSize,z
      set vertexdata position index+2,x+worldCubeSize,y,z-worldCubeSize
      set vertexdata position index+3,x+worldCubeSize,y,z
      for i=0 to 3
         set vertexdata normals index+i,1.0,0,0
      next i
   endif
   if direction=3
      set vertexdata position index,x,y+worldCubeSize,z
      set vertexdata position index+1,x,y+worldCubeSize,z-worldCubeSize
      set vertexdata position index+2,x,y,z
      set vertexdata position index+3,x,y,z-worldCubeSize
      for i=0 to 3
         set vertexdata normals index+i,-1.0,0,0
      next i
   endif
   if direction=4
      set vertexdata position index,x,y+worldCubeSize,z-worldCubeSize
      set vertexdata position index+1,x+worldCubeSize,y+worldCubeSize,z-worldCubeSize
      set vertexdata position index+2,x,y,z-worldCubeSize
      set vertexdata position index+3,x+worldCubeSize,y,z-worldCubeSize
      for i=0 to 3
         set vertexdata normals index+i,0,0,-1.0
      next i
   endif
   if direction=5
      set vertexdata position index,x+worldCubeSize,y+worldCubeSize,z
      set vertexdata position index+1,x,y+worldCubeSize,z
      set vertexdata position index+2,x+worldCubeSize,y,z
      set vertexdata position index+3,x,y,z
      for i=0 to 3
         set vertexdata normals index+i,0,0,1.0
      next i
   endif
endFunction index

Function lockWorld()
    lock vertexdata for limb worldObject, 0, 1
endFunction

Function unlockWorld()
    unlock vertexdata
endFunction

+ Code Snippet


sync on:sync rate 60
set camera range .01, 100000
Global worldObject as integer
Global plainMesh as integer
Global worldCubeSize as float

WorldSetCubeSize(1)
createEmptyWorld()

lockWorld()
    cube1 = addWorldCube( 0, 0, 0 )
unlockWorld()

position camera 0, -worldCubeSize*2, worldCubeSize*2, 0
point camera 0, 0, 0

NULL# = mousemovex()
NULL# = mousemovey()

do

rotate camera camera angle x() + mousemovey() , camera angle y() + mousemovex() , 0

move camera (upkey()-downkey())*0.1

set cursor 0, 0
sync
loop

Function WorldSetCubeSize( size as float )
    worldCubeSize = size
endFunction

Function createEmptyWorld()

    worldObject = find free object()
    plainMesh   = find free mesh()

    make object plain worldObject, 0, 0, 1, 1
    
    tmpObject = find free object()
    make object plain tmpObject, worldCubeSize, worldCubeSize, 1, 1
    make mesh from object plainMesh, tmpObject
    delete object tmpObject
    
endFunction

Function addWorldCube( x as float , y as float , z as float )
    index = 0
    for i=0 to 5
        if i=0 
            index = addWorldPlain( x, y, z, i ) 
        else
            addWorldPlain( x, y, z, i ) 
        endif
    next i
endFunction index

Function addWorldPlain( x as float , y as float , z as float , direction as integer )
    add mesh to vertexdata plainMesh
    index = get vertexdata vertex count()-4
    
    if direction=0
      set vertexdata position index,x+worldCubeSize,y,z
      set vertexdata position index+1,x,y,z
      set vertexdata position index+2,x+worldCubeSize,y,z-worldCubeSize
      set vertexdata position index+3,x,y,z-worldCubeSize
      for i=0 to 3
         set vertexdata normals index+i,0,-1.0,0
      next i
   endif
   if direction=1
      set vertexdata position index,x,y+worldCubeSize,z
      set vertexdata position index+1,x+worldCubeSize,y+worldCubeSize,z
      set vertexdata position index+2,x,y+worldCubeSize,z-worldCubeSize
      set vertexdata position index+3,x+worldCubeSize,y+worldCubeSize,z-worldCubeSize
      for i=0 to 3
         set vertexdata normals index+i,0,1.0,0
      next i
   endif
   if direction=2
      set vertexdata position index,x+worldCubeSize,y+worldCubeSize,z-worldCubeSize
      set vertexdata position index+1,x+worldCubeSize,y+worldCubeSize,z
      set vertexdata position index+2,x+worldCubeSize,y,z-worldCubeSize
      set vertexdata position index+3,x+worldCubeSize,y,z
      for i=0 to 3
         set vertexdata normals index+i,1.0,0,0
      next i
   endif
   if direction=3
      set vertexdata position index,x,y+worldCubeSize,z
      set vertexdata position index+1,x,y+worldCubeSize,z-worldCubeSize
      set vertexdata position index+2,x,y,z
      set vertexdata position index+3,x,y,z-worldCubeSize
      for i=0 to 3
         set vertexdata normals index+i,-1.0,0,0
      next i
   endif
   if direction=4
      set vertexdata position index,x,y+worldCubeSize,z-worldCubeSize
      set vertexdata position index+1,x+worldCubeSize,y+worldCubeSize,z-worldCubeSize
      set vertexdata position index+2,x,y,z-worldCubeSize
      set vertexdata position index+3,x+worldCubeSize,y,z-worldCubeSize
      for i=0 to 3
         set vertexdata normals index+i,0,0,-1.0
      next i
   endif
   if direction=5
      set vertexdata position index,x+worldCubeSize,y+worldCubeSize,z
      set vertexdata position index+1,x,y+worldCubeSize,z
      set vertexdata position index+2,x+worldCubeSize,y,z
      set vertexdata position index+3,x,y,z
      for i=0 to 3
         set vertexdata normals index+i,0,0,1.0
      next i
   endif
endFunction index

Function lockWorld()
    lock vertexdata for limb worldObject, 0, 1
endFunction

Function unlockWorld()
    unlock vertexdata
endFunction

Still don't know what the problem was exactly, but I did figure out that it doesn't work with this command:

+ Code Snippet

make object plain id, size, size

But it does work with this one:

+ Code Snippet

make object plain id, size, size, 1, 1

From the matrixUtil plugin (Matrix1Util_18.dll), this one also creates a plain with 4 vertices instead of 6.

Quote: "I don't want to use any plugins because I'm actually using GDK in my project, but dark basic for testing"

Maybe you can find a way without a dll

edit
The code for positioning the plains in a cube was taken from the open source engine: http://forum.thegamecreators.com/?m=forum_view&t=187219&b=1

Back to top

Profile PM

IanM

Retired Moderator

23

Years of Service

User Offline

Joined: 11th Sep 2002

Location: In my moon base

Posted: 29th Jul 2011 15:23

Link

Not all objects use an index buffer - some do, some don't.
Not all objects use 3-vertices-per-poly triangle list - some use a tri-strip instead.

Basically, you have to take care as you can't just mix and match. If you add a non-indexed tri-strip to an indexed triangle list you just aren't going to get a meaningful result.

Get the latest Matrix1Utility plug-ins (20-APR-2011)

Back to top

Profile PM Email Website

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 29th Jul 2011 15:48

Link

Quote: "If you add a non-indexed tri-strip to an indexed triangle list you just aren't going to get a meaningful result"

That makes sence.. but how do you know if you have an index buffer and a 3-vertices-per-poly or a tri-srtip.

Back to top

Profile PM

IanM

Retired Moderator

23

Years of Service

User Offline

Joined: 11th Sep 2002

Location: In my moon base

Posted: 29th Jul 2011 16:01

Link

You can't get the mesh type with standard DBPro, but you can with my own GET LIMB MESH TYPE function.

You can try converting your limb to a standard tri-list using the CONVERT LIMB TO TRILIST command.

You can detect the presence of an index buffer using the standard GET VERTEXDATA INDEX COUNT() (IIRC - I don't have a copy of DBPro with me right now).

Get the latest Matrix1Utility plug-ins (20-APR-2011)

Back to top

Profile PM Email Website

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 29th Jul 2011 16:14 Edited at: 29th Jul 2011 18:30

Link

Ah thanks a lot Max, it sucks that it can (seemingly) only be done with a plugin. Ian, any chance of porting your plugins to GDK?

I kid of course.

edit I looked at the set vertexdata diffuse command in an attempt to make a sort of lighting system. I diffused every vertex to green, but there didn't seem to be a change in colour. Am I using it wrongly?

Thanks a lot guys.

Back to top

Profile PM

IanM

Retired Moderator

23

Years of Service

User Offline

Joined: 11th Sep 2002

Location: In my moon base

Posted: 29th Jul 2011 23:43

Link

Quote: "Am I using it wrongly?"

Only in that your objects are most likely in the wrong format - you need to ensure that the FVF format includes a diffuse component.

Quote: "Ian, any chance of porting your plugins to GDK?"

Not really. There's no point in this instance because most of this can be done in GDK directly.

The mesh type of an object can be accessed by getting the object pointer, using ppFrameList to access your limb (it's an array, one entry per limb), and then following the pMesh pointer to access the iPrimitiveType.

The CONVERT TO TRILIST, is a function already built into DBPro called ConvertLocalMeshToTriList - you just need to pass a pointer to an sMesh as an argument - see above for how to get this pointer for a limb.

Get the latest Matrix1Utility plug-ins (20-APR-2011)

Back to top

Profile PM Email Website

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 30th Jul 2011 01:45

Link

Quote: "you need to ensure that the FVF format includes a diffuse component."

How would I go about changing the FVF format it uses? Or have I gotten the wrong end of the stick here?

Thanks, Indi.

Back to top

Profile PM

Green Gandalf

VIP Member

21

Years of Service

User Offline

Joined: 3rd Jan 2005

Playing: Malevolence:Sword of Ahkranox, Skyrim, Civ6.

Posted: 30th Jul 2011 02:26

Link

Have a look at:

CONVERT OBJECT FVF

Back to top

Profile PM Email

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 30th Jul 2011 04:07

Link

Thanks GG, I know it seems like I'm just trying to get you guys to do all the work for me, but I honestly have no idea with this.

I've set the fvf format to this

+ Code Snippet

convert object fvf temp,0x144

but the colour of the texture doesn't show diffuse of any kind.

I don't expect you to look through it, but here's the full source if it helps you determine what's wrong, if you're up to it.

sync on: sync rate 0
set camera range 0.01, 10000
set display mode desktop width(), desktop height(), 32
set window off
make object cube 2,2.0
make mesh from object 2,2
delete object 2

load image "terrain.png",1
for chx = 1 to 1
	for chy = 1 to 1
		temp = freeobj()
		make object plain temp,1.0,1.0
		convert object fvf temp,0x144		
		set object filter temp,0
		set object temp,0,1,1
		set object wireframe temp,0

lock vertexdata for limb temp,0,1
		
		//delete mesh from vertexdata 0,5,0,1
		for x = 1 to 16
			for y=1 to 16
					
				
					index = get vertexdata vertex count()
					add mesh to vertexdata 2
				
					for i = index to index+24
						
						set vertexdata position i,get vertexdata position x(i)+2.0*16*chx + 2.0*x,get vertexdata position y(i)+2.0*z,get vertexdata position z(i)+2.0*16*chy + 2.0*y
						set vertexdata normals i,1.0,1.0,1.0
						set vertexdata diffuse i,rgb(255,255,0 ) // Here i set the vertex diffuse
					next i
					
					for index2 = index to index+24 step 4
						typeb = rnd(4)
						set vertexdata uv index2, (1.0/16)*typeb, 0.0
						set vertexdata uv index2+1,  (1.0/16)*(typeb+1), 0.0
						set vertexdata uv index2+2,  (1.0/16)*(typeb+1), (1.0/16)
						set vertexdata uv index2+3, (1.0/16)*typeb, (1.0/16)
						
						for i = 0 to 3
							
						next i
										
					next index2
					
					
			next y
		next x
		calculate object bounds temp
		texture object temp,1
	next chy
next chx

unlock vertexdata

position camera 50,3,50
do

if upkey() then move camera 0.1
xrotate camera camera angle x() + mousemovey()
yrotate camera camera angle y() + mousemovex()
text 0,0, str$( screen fps() )

sync
loop

function freeobj()
	
	for i = 1 to 100000
		if object exist( i ) = 0
			temp = i
			exit
		endif
	next i

endfunction temp

+ Code Snippet

sync on: sync rate 0
set camera range 0.01, 10000
set display mode desktop width(), desktop height(), 32
set window off
make object cube 2,2.0
make mesh from object 2,2
delete object 2

load image "terrain.png",1
for chx = 1 to 1
	for chy = 1 to 1
		temp = freeobj()
		make object plain temp,1.0,1.0
		convert object fvf temp,0x144		
		set object filter temp,0
		set object temp,0,1,1
		set object wireframe temp,0

		lock vertexdata for limb temp,0,1
		
		//delete mesh from vertexdata 0,5,0,1
		for x = 1 to 16
			for y=1 to 16
					
				
					index = get vertexdata vertex count()
					add mesh to vertexdata 2
				
					for i = index to index+24
						
						set vertexdata position i,get vertexdata position x(i)+2.0*16*chx + 2.0*x,get vertexdata position y(i)+2.0*z,get vertexdata position z(i)+2.0*16*chy + 2.0*y
						set vertexdata normals i,1.0,1.0,1.0
						set vertexdata diffuse i,rgb(255,255,0 ) // Here i set the vertex diffuse
					next i
					
					for index2 = index to index+24 step 4
						typeb = rnd(4)
						set vertexdata uv index2, (1.0/16)*typeb, 0.0
						set vertexdata uv index2+1,  (1.0/16)*(typeb+1), 0.0
						set vertexdata uv index2+2,  (1.0/16)*(typeb+1), (1.0/16)
						set vertexdata uv index2+3, (1.0/16)*typeb, (1.0/16)
						
						for i = 0 to 3
							
						next i
										
					next index2
					
					
			next y
		next x
		calculate object bounds temp
		texture object temp,1
	next chy
next chx


unlock vertexdata



position camera 50,3,50
do

if upkey() then move camera 0.1
xrotate camera camera angle x() + mousemovey()
yrotate camera camera angle y() + mousemovex()
text 0,0, str$( screen fps() )

sync
loop

function freeobj()
	
	for i = 1 to 100000
		if object exist( i ) = 0
			temp = i
			exit
		endif
	next i

endfunction temp

If you could help me out, I'd be forever in your debt.

Thanks.

Back to top

Profile PM

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 30th Jul 2011 13:08 Edited at: 30th Jul 2011 13:08

Link

When setting the fvf format you need to specify all the things you want, I use some constants to make things clearer:

+ Code Snippet

    #constant FVF_XYZ 0x002
    #constant FVF_XYZRHW 0x004
    #constant FVF_XYZB1 0x006
    #constant FVF_XYZB2 0x008
    #constant FVF_XYZB3 0x00a
    #constant FVF_XYZB4 0x00c
    #constant FVF_XYZB5 0x00e
    #constant FVF_NORMAL 0x010
    #constant FVF_PSIZE 0x020
    #constant FVF_DIFFUSE 0x040
    #constant FVF_SPECULAR 0x080
    #constant FVF_TEX0 0x000
    #constant FVF_TEX1 0x100
    #constant FVF_TEX2 0x200
    #constant FVF_TEX3 0x300
    #constant FVF_TEX4 0x400
    #constant FVF_TEX5 0x500
    #constant FVF_TEX6 0x600
    #constant FVF_TEX7 0x700
    #constant FVF_TEX8 0x800

Now when you change your objects fvf you can use something like this:

+ Code Snippet

convert object fvf object , FVF_TEX8 || FVF_DIFFUSE || FVF_NORMAL || FVF_XYZ

This will create an object with 8 texture stages, vertex diffuse data and normals. So for your objects I think you will need something like this:

+ Code Snippet

convert object fvf object , FVF_TEX0 || FVF_DIFFUSE || FVF_NORMAL || FVF_XYZ

With only the base texture, vertex diffuse and normals

Back to top

Profile PM

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 30th Jul 2011 13:47

Link

Ah brilliant! I misunderstood the command for that one, the help file needs to be a little clearer. I changed FVF_TEX0 to FVF_TEX7 and it works exactly how I want.

Everything works exactly how I want it now, I don't think I have anymore questions about vertexdata. Thanks a lot Max P, I couldn't have done any of this without you.

Thanks IanM and Chafari, I owe you guys one.

Indi.

Back to top

Profile PM

Sorry your browser is not supported!

DarkBASIC Professional Discussion / vertexdata