Timer Based Movement - Question on snippet

Author

Message

Burning Feet Man

18

Years of Service

User Offline

Joined: 4th Jan 2008

Location: Sydney, Australia

Posted: 7th Aug 2011 14:52 Edited at: 7th Aug 2011 14:53

Link

Hey all,

I've been staring at a Timer Based Movement snippet for a few minutes now. Although I've tested it months back, it works great, but rehashing over my code today, I suddenly find myself curious as to how part of it works...

From a previous thread;

http://forum.thegamecreators.com/?m=forum_view&t=171247&b=1

Quote: "The loop for smoothing basically just takes the values from the last 30 loops and averages them, so you don't end up with a sudden compensation if the framerate drops and then comes back up. It averages that over a very short amount of time, thus making the movement appear smoother."

With the code below;

+ Code Snippet

function tm_Update()
	Diff# = timer() - Flast#
	Flast# = timer()
	factor# = 0.0
	for tx = 1 to 29
		factors(tx) = factors(tx+1)
		factor# = factor# + factors(tx)
	next tx
	factors(30) = Diff# / 1000.0
	factor# = factor# + factors(30)
	factor# = factor# / 30.0
endfunction

So what I'm not understanding, is this part;

for tx = 1 to 29
factors(tx) = factors(tx+1)
factor# = factor# + factors(tx)
next tx

The OP talks about this loop "smoothing" out things and reducing jerkiness. But I thought such a loop would have to take place over 30 sync cycles, not 30 For-Next cycles?

What am I missing here...

Help build an online DarkBASIC Professional help archive.
DarkBasic Help Wikia

Back to top

Profile PM Website

Indicium

18

Years of Service

User Offline

Joined: 26th May 2008

Location:

Posted: 7th Aug 2011 15:15 Edited at: 7th Aug 2011 15:16

Link

That for loop shifts the array down one space. So factors(2) becomes factors(1), and factors(30) becomes factors(29) and factors(30) is now free for a new value.

Hope that makes sense.

Back to top

Profile PM

KISTech

18

Years of Service

User Offline

Joined: 8th Feb 2008

Location: Aloha, Oregon

Posted: 7th Aug 2011 22:12

Link

That original poster would be me.

Like Indicium said, that for next loop just shifts the values in the array to make room for the new value. There are probably faster ways to do it, but it works.

The real meat of that bit of code is that it adds all of those factors into factor#, then divides factor# by 30. Giving you the average value of the last 30 factors.

Back to top

Profile PM Email Website

Burning Feet Man

18

Years of Service

User Offline

Joined: 4th Jan 2008

Location: Sydney, Australia

Posted: 8th Aug 2011 00:10

Link

Had a slow read through your code again this morning, finally got it understood! Will see if I can improve on it tonight.

Help build an online DarkBASIC Professional help archive.
DarkBasic Help Wikia

Back to top

Profile PM Website

KISTech

18

Years of Service

User Offline

Joined: 8th Feb 2008

Location: Aloha, Oregon

Posted: 8th Aug 2011 00:15

Link

There isn't much that can be done to improve the loop, since you have to add all the elements in the array together anyway. There are likely other ways to improve smoothing, but I haven't thought of one yet.

Back to top

Profile PM Email Website

GIDustin

18

Years of Service

User Offline

Joined: 30th May 2008

Location:

Posted: 9th Aug 2011 08:12

Link

I believe this version is several nano-seconds faster. Not a whole lot of optimizing though.

+ Code Snippet

global tm_current_value,factor#
global dim factors(30)

function tm_Update()
	factors(tm_current_value) = timer()
	inc tm_current_value
	if tm_current_value = 31 then tm_current_value = 1
	factor# = ( timer() - factors(tm_current_value) ) / 30000.0
endfunction

Instead of adding up the elapsed time of the last 30 frames, why not divide the time since 30 frames ago by 30?

Of course, now we are just splitting hairs... I am sure the most anal of optimizers could even do one better! Of course, either of our methods is painfully off balance for the first 29 frames.

Back to top

Profile PM Email Website

KISTech

18

Years of Service

User Offline

Joined: 8th Feb 2008

Location: Aloha, Oregon

Posted: 9th Aug 2011 19:41

Link

Quote: "either of our methods is painfully off balance for the first 29 frames. "

Yeah, that's always been one little flaw in the system. I try and do a best guess on that and fill the array with values close to what it might be. I've been thinking of writing a test scene using a bunch of 3D shapes, but they're all black so they don't show. DBP would still think it has to render them and you could get the timing from that in about 2 seconds to fill the array with values that would be close. Then just set flast to the current timer value before heading into the main loop.

What about storing the result of the 30 values added together. Then you can subtract the oldest and add the newest each loop. That would eliminate the for next loop as well.

+ Code Snippet

global factor#
global factor_sum
global current_factor
global dim factors(30)
global flast

function tm_Update()
   t = timer()
   Diff# = t - flast
   flast = t
   inc current_factor
   if current_factor = 31 then current_factor = 1
   factor_sum = factor_sum - factors(current_factor)
   factors(current_factor) = Diff# / 1000.0
   factor_sum = factor_sum + factors(current_factor)
   factor# = factor_sum / 30.0
endfunction

Back to top

Profile PM Email Website

Burning Feet Man

18

Years of Service

User Offline

Joined: 4th Jan 2008

Location: Sydney, Australia

Posted: 10th Aug 2011 13:13 Edited at: 10th Aug 2011 14:11

Link

Haha, you guys are awesome. Myself being a DBpro novice, I was also wondering if there's a faster way to store and access the factor array, maybe memblocks? I'm not too sure through, as I've never advanced further than arrays and thus haven't practised other array techniques.

At this stage, if I can add anything to this thread, I've found that another handy TBM global variable to add is this one;

Global Factor_360 as float
Factor_360# = 360 * Factor#

Help build an online DarkBASIC Professional help archive.
DarkBasic Help Wikia

Back to top

Profile PM Website

KISTech

18

Years of Service

User Offline

Joined: 8th Feb 2008

Location: Aloha, Oregon

Posted: 10th Aug 2011 21:08

Link

Ok. What does that do?

Back to top

Profile PM Email Website

Burning Feet Man

18

Years of Service

User Offline

Joined: 4th Jan 2008

Location: Sydney, Australia

Posted: 11th Aug 2011 00:49 Edited at: 11th Aug 2011 00:50

Link

I've found it's handy for spinning objects, say I wanted to spin an object two revolutions per second;

+ Code Snippet

Rem Project: Dark Basic Pro Project
Rem Created: Thursday, August 11, 2011

Rem ***** Main Source File *****
Sync On
make object plane 1, 10, 10
position object 1, 0,0,0
GoSub Sub_Ini_TBM

Do
Set Cursor 0,0
Print screen fps()
YRotate Object 1, wrapvalue(object angle Y(1) + (2 * factor_360#))
TBM_Update()
Sync
Loop
End


Sub_Ini_TBM:
    Global Factor_Last#    as float
    Global Factor# as float
    Global Factor_360# as float
    Global Dim Factors(30) as float
Return
End

Function TBM_Update()
    Difference# = hitimer() - Factor_Last#
    Factor_Last# = hitimer()
    Factor# = 0.0
    for tx = 1 to 29
        Factors(tx) = Factors(tx+1)
        Factor# = Factor# + Factors(tx)
    next tx
    Factors(30) = Difference# / 1000
    Factor# = (Factor# + Factors(30)) / 30
    Factor_360# = 360 * Factor#
Endfunction

In saying and practising this, I'm not too sure if there's a better way, but it's working.

Help build an online DarkBASIC Professional help archive.
DarkBasic Help Wikia

Back to top

Profile PM Website

KISTech

18

Years of Service

User Offline

Joined: 8th Feb 2008

Location: Aloha, Oregon

Posted: 11th Aug 2011 00:54

Link

Ah, I see. You wouldn't necessarily need a global for that though. You would multiply factor# by your rotation speed at the line where you are rotating it. That's the purpose of making the factor# variable global.

Back to top

Profile PM Email Website

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Timer Based Movement - Question on snippet