To get rid of the blue screen that shows up when we use sprites we usually grab the background and use PASTE IMAGE to replace it every loop. And as Kezzla said print the text every loop.
` Set sync rate as fast as the computer can handle it
sync rate 0
` Turn on syncing
sync on
` Make the font big
set text size 100
` Create a background image
box 0,0,screen width(),screen height(),rgb(255,0,0),rgb(0,255,0),rgb(0,0,255),rgb(255,255,255)
center text screen width()/2,(screen height()-text height("B"))/2,"BACKGROUND IMAGE"
` Grab the image
get image 1,0,0,screen width(),screen height(),1
` Create a small box (for a sprite)
ink rgb(255,0,0),0
box 0,0,50,50,1
` Grab the image
get image 2,0,0,50,50,1
` Hide the mouse
hide mouse
` Reset ink color back to bright white
ink rgb(255,255,255),0
` Make the font small again
set text size 20
do
` Show the background
paste image 1,0,0,0
` Show the small box at the mouse coordinates
sprite 1,mousex(),mousey(),2
` Show some text above the sprite
center text mousex()+(sprite width(1)/2),mousey()-20,"SPRITE"
` Update the screen
sync
loop
