This should be something like that using 'pick object'.
rem setup
Sync on:Sync Rate 60
Autocam Off
rem create few spheres to click on
Spheres=20
For i=1 to Spheres
Make Object Sphere i,rnd(4)+1
Position Object i,rnd(10)-5,rnd(10)-5,rnd(10)-5
Next i
rem create box to 'highlight' selected sphere
Highlight=Spheres+1
Make Object Cube Highlight,100:rem size is 100 for scaling
Set Object WireFrame Highlight,1:Color Object Highlight,rgb(255,0,0)
Hide Object Highlight
rem position camera
Position Camera 0,0,-20:Point Camera 0,0,0
rem main loop
Do
rem find object under mouse
Object=Pick Object(MouseX(),MouseY(),1,Spheres)
rem if object is clicked on
If Object<>Selected && MouseClick()=1
Selected=Object
If Object>0
rem 'highlight' it
Position Object Highlight,Object Position X(Object),Object Position Y(Object),Object Position Z(Object)
Scale Object Highlight,Object Size X(Object),Object Size Y(Object),Object Size Z(Object)
Show Object Highlight
Else
rem 'unhighlight' it
Hide Object HighLight
Endif
EndIf
rem display info
Text 0,0,"FPS: "+str$(Screen FPS())
Text 0,20,"Selected: "+str$(Selected)
Sync
Loop
