negative alpha blending for black smoke (source/no media)

Author

Message

Suicidal Sledder

21

Years of Service

User Offline

Joined: 17th Aug 2004

Location: Tikrit, Iraq

Posted: 16th Oct 2011 17:50 Edited at: 16th Oct 2011 17:58

Link

I am trying to use negative alpha blending to make black smoke and I am so close but yet so far. The problem is if I use ghost object on 1,1 to enable negative alpha blending I cannot fade the object out gradually to make the smoke "dissapate"(sp?). If I use positive alpha blending (using set alpha mapping on obj,perc) the smoke comes out white no matter what. I would like to be able to use set alpha mapping on in conjunction with ghost object on (flag = 1). this would be perfect but it seems the two commands are incompatible. If the object is ghosted using ghost object on then set alpha mapping on has no effect. If I use only set alpha mapping on then the alpha blending is always positive besides the fact that I cannot properly hide the "edges" around my circular smoke texture.

Here's what I got so far:

+ Code Snippet


make object cube 2,5
make object cube 1,10 : color object 1,rgb(0,0,0)
create bitmap 1,50,50
ink rgb(255,255,255),0
box 0,0,50,50
ink rgb(10,10,10),0
for x=1 to 1000
   ang=rnd(360)
   rad=rnd(20)
   dot 25-sin(ang)*rad,25-cos(ang)*rad,rgb(25,25,25)
next x
blur bitmap 1,6
img = 2
get image img,0,0,50,50,1
delete bitmap 1
sync on :sync rate 60
alpha = 50
texture object 1,0,2
ghost object on 1,1
do

yrotate object 1,wrapvalue(object angle y(1)+1)
set object transparency 1,2
if leftkey() = 1 then dec alpha,2
if rightkey() = 1 then inc alpha,2


set object light 1,0
set alpha mapping on 1,alpha
text 5,5,STR$(alpha)

sync
loop

As it stands now, altering the set alpha mapping on percentage has no effect. (Therefore impossible to fade away my smoke objects). comment out ghost object on (line 20) and you can now very smoothly fade the object in and out but obviously the edges are still there.

Anyone have any idea how to do this? If you would like my full source code for my smoke demo just ask and I'll post.

PS sorry for the sloppy code... its been edited and re-edited to death

thanks!

--STAR RUNNER-- Full game, arcade clone, nice graphics and music, small download!!

Back to top

Profile PM Email

Diggsey

20

Years of Service

User Offline

Joined: 24th Apr 2006

Location: On this web page.

Posted: 16th Oct 2011 20:37

Link

Try making the smoke white but faded to black to start with and then gradually un-fade it so that it goes back to white and transparent.

[b]

Back to top

Profile PM Email Website

Quel

17

Years of Service

User Offline

Joined: 13th Mar 2009

Location:

Posted: 16th Oct 2011 21:14

Link

I use ghosted objects the less as possible due to zdepth craziness. It just loves to pop before everything else.

By the way it is called negative ghosting...

Use black smoke texture with alpha mapping. That way you can fade out either by making frames of the smoke, or by command too.

set alpha mapping on ObjNum, Percent

-In.Dev.X: A unique heavy story based shoot'em ~35%
-CoreFleet: An underground commander unit based RTS ~15%
-TailsVSEggman: An Sonic themed RTS under development for idea presentation to Sega ~15%

Back to top

Profile PM

Suicidal Sledder

21

Years of Service

User Offline

Joined: 17th Aug 2004

Location: Tikrit, Iraq

Posted: 17th Oct 2011 21:08

Link

Hey thanks both for the responses. I tried them both but the problem is if I dont ghost the image then the background behind my texture is still visible (causing a nicely faded white plane). If I use set image colorkey to make white the transparent color then it obviously only makes pure white transparent meaning around the edges where its supposed to fade out it is very blocky and causes a sort of ring around the actual texture part. Similar to using the paint bucket tool on a jpeg due to lack of pixel perfect quality.

Thanks all

--STAR RUNNER-- Full game, arcade clone, nice graphics and music, small download!!

Back to top

Profile PM Email

Suicidal Sledder

21

Years of Service

User Offline

Joined: 17th Aug 2004

Location: Tikrit, Iraq

Posted: 17th Oct 2011 21:24

Link

i suppose the easiest way to accomplish what I am trying to do would be to fade the texture on the object. I tried using fade object object,percentage but it seems that textures are unaffected by this command.

thanks again

--STAR RUNNER-- Full game, arcade clone, nice graphics and music, small download!!

Back to top

Profile PM Email

Suicidal Sledder

21

Years of Service

User Offline

Joined: 17th Aug 2004

Location: Tikrit, Iraq

Posted: 28th Oct 2011 10:30

Link

does anyone know how to accomplish this? my project is stalled until I can resolve it.

Thanks

Sadly, programming is only a hobby for me right now. As it turns out, driving a 70 ton, 7 million dollar Abrams tank requires less qualification than pecking away at a keyboard. Who'da thunk it?

Back to top

Profile PM Email

Chris Tate

DBPro Master

17

Years of Service

User Offline

Joined: 29th Aug 2008

Location: London, England

Posted: 28th Oct 2011 13:32 Edited at: 28th Oct 2011 13:35

Link

Quote: "it seems the two commands are incompatible"

They are not, if I remember correctly, you cannot use [set object transparency] and [set alpha mapping on] at the same time either; they override each other. I think that alpha mapping is just an object based 'see-through' setting, for use with things like glass or water; object transparency is a per pixel alpha setting; you specify what is opaque and what is not using pixel alpha channels.

This doesn't mean that your goal is impossible; you just need more control over the pixel rendering. To gain the control you need, as stated earlier, you can animate the dissappearing smoke effect on a series of texture frames, and play back the animation and use [set object transparency]. In code the object will remain visible but in the view it will disappear because of what is on your textures; eventually nothing.

The other way is to use one texture in conjunction with a HLSL shader. If you know how to use shaders, you can copy a basic pixel shader and just decrease the alpha element in the ARGB [COLOR] array over time using the [TIME] variable to control how long it should take; and using a FX constant to determine when to start the effect.

What’s your best game moment?

Back to top

Profile PM Email Website

Green Gandalf

VIP Member

21

Years of Service

User Offline

Joined: 3rd Jan 2005

Playing: Malevolence:Sword of Ahkranox, Skyrim, Civ6.

Posted: 28th Oct 2011 17:48

Link

Is this what you're after? You need IanM's Matrix1 plugins to compile it.

+ Code Snippet

` this code requires IanM's Matrix1 plugin
set bitmap format 21 ` you need this so you can work with the alpha channel
make object cube 2,5
make object cube 1,10 : color object 1,rgb(0,0,0)
create bitmap 1,50,50
cls rgb(0,0,0,0) ` sets the alpha channel - needs Matrix1
ink rgb(10,10,10),0
for x=1 to 1000
   ang=rnd(360)
   rad=rnd(20)
   dot 25-sin(ang)*rad,25-cos(ang)*rad,rgb(255,25,25,25) ` sets the alpha channel - needs Matrix1
next x
blur bitmap 1,6
img = 2
get image img,0,0,50,50,1
save image "test.png", img
delete bitmap 1
sync on :sync rate 60
alpha = 50
texture object 1,0,2
do

yrotate object 1,wrapvalue(object angle y(1)+1)
if leftkey() = 1 then dec alpha,2
if rightkey() = 1 then inc alpha,2
alpha = max(0, min(100, alpha)) ` uses Matrix1 functions for simplicity

set object light 1,0
set alpha mapping on 1,alpha
text 5,5,STR$(alpha)

sync
loop

Back to top

Profile PM Email

Suicidal Sledder

21

Years of Service

User Offline

Joined: 17th Aug 2004

Location: Tikrit, Iraq

Posted: 28th Oct 2011 22:13

Link

checking it out ill get back to you. thanks

Sadly, programming is only a hobby for me right now. As it turns out, driving a 70 ton, 7 million dollar Abrams tank requires less qualification than pecking away at a keyboard. Who'da thunk it?

Back to top

Profile PM Email

Suicidal Sledder

21

Years of Service

User Offline

Joined: 17th Aug 2004

Location: Tikrit, Iraq

Posted: 28th Oct 2011 23:03

Link

Hey GG thanks a million it worked like a charm with a little tweaking. I cant wait to put this into my game, it will look awesome. Here's my full smoke demo below if you are interested in seeing my final results.

set bitmap format 21
set image colorkey 0,0,0
`Create smoke image
create bitmap 1,50,50
for x=1 to 1000
   ang=rnd(360)
   rad=rnd(20)
   dot 25-sin(ang)*rad,25-cos(ang)*rad,rgb(25,25,25)
next x
blur bitmap 1,4
img = 2
get image img,0,0,50,50,1
save image "test.png", img
delete bitmap 1

Type Vectors
   x As Float
   y As Float
   z As Float
EndType

Type Particle
   p As Vectors
   v As Vectors
   sz As Vectors
   Fade As float
   scale as integer
EndType

make matrix 1,1000,1000,20,20
position camera 0,20,-50

GOSUB makeSmoke

t = 10000
make object cube t, 10 
set object light t,0

sync on
sync rate 45
do

text 0, 0, str$(screen fps())

GOSUB loopSmoke
if leftkey() then windx# = windx# - 0.01
if rightkey() then windx# = windx# + 0.01
if upkey() then windz# = windz# + 0.01
if downkey() then windz# = windz# - 0.01

camera#=wrapvalue(camera#+0.3)
position camera -sin(camera#)*128.0,30,100+cos(camera#)*128.0
point camera 0.0,0.0,100+0.0

sync
loop

makeSmoke:
ttlPrc = 400
objPrc = free_object()
DIM Particles(ttlPrc) As Particle
`Make particles
for x=objPrc to objPrc+ttlPrc
   make object plane x,20,20
   texture object x, 0, img
   hide object x
   set object transparency x,2
   disable object zwrite x `THIS LINE NEEDS AN ALTERNATIVE
next x
RETURN

loopSmoke:
`Loop through particles
for t=1 to ttlPrc
   Particles(t).sz.x = Particles(t).sz.x + 0.5
   Particles(t).sz.y = Particles(t).sz.y + 0.5
   Particles(t).p.x = Particles(t).p.x + Particles(t).v.x + windx#
   Particles(t).p.y = Particles(t).p.y + Particles(t).v.y
   Particles(t).p.z = Particles(t).p.z + Particles(t).v.z + windz#
   particles(t).scale = particles(t).scale + 1
   `Fade particle value
   if Particles(t).Fade >0 then Particles(t).Fade = Particles(t).Fade - .2
   `Position, scale and fade particle object
   scale object t,particles(t).scale,particles(t).scale,particles(t).scale
   position object objPrc+t-1,Particles(t).p.x,Particles(t).p.y,Particles(t).p.z
   set alpha mapping on t,Particles(t).Fade

`Point at camera
   set object to camera orientation objPrc+t-1
next t

inc i
if i>ttlPrc then i=1
if Particles(i).Fade <1
   `Position
  Particles(i).p.x = 0
  Particles(i).p.y = 0
  Particles(i).p.z = 100
   `Scale
   Particles(i).sz.x = 50
   Particles(i).sz.y = 50
   `Velocity (randomize)
   Particles(i).v.x = rnd(200)/1000.0-0.1
   Particles(i).v.y = rnd(400)/1000.0+0.1
   Particles(i).v.z = rnd(200)/1000.0-0.1
   Particles(i).Fade = 50 `ttlPrc / 2.0
   particles(i).scale = 10
   `Show the particle
   show object objPrc+i-1
endif
RETURN

Function free_object()
   Repeat
      Inc i
   Until Object Exist(i) = 0
EndFunction i
Function free_image()
   Repeat
      Inc i
   Until Image Exist(i) = 0
EndFunction i

+ Code Snippet

set bitmap format 21
set image colorkey 0,0,0
`Create smoke image
create bitmap 1,50,50
for x=1 to 1000
   ang=rnd(360)
   rad=rnd(20)
   dot 25-sin(ang)*rad,25-cos(ang)*rad,rgb(25,25,25)
next x
blur bitmap 1,4
img = 2
get image img,0,0,50,50,1
save image "test.png", img
delete bitmap 1

Type Vectors
   x As Float
   y As Float
   z As Float
EndType

Type Particle
   p As Vectors
   v As Vectors
   sz As Vectors
   Fade As float
   scale as integer
EndType

make matrix 1,1000,1000,20,20
position camera 0,20,-50

GOSUB makeSmoke

t = 10000
make object cube t, 10 
set object light t,0

sync on
sync rate 45
do

text 0, 0, str$(screen fps())

GOSUB loopSmoke
if leftkey() then windx# = windx# - 0.01
if rightkey() then windx# = windx# + 0.01
if upkey() then windz# = windz# + 0.01
if downkey() then windz# = windz# - 0.01

camera#=wrapvalue(camera#+0.3)
position camera -sin(camera#)*128.0,30,100+cos(camera#)*128.0
point camera 0.0,0.0,100+0.0

sync
loop

makeSmoke:
ttlPrc = 400
objPrc = free_object()
DIM Particles(ttlPrc) As Particle
`Make particles
for x=objPrc to objPrc+ttlPrc
   make object plane x,20,20
   texture object x, 0, img
   hide object x
   set object transparency x,2
   disable object zwrite x `THIS LINE NEEDS AN ALTERNATIVE
next x
RETURN

loopSmoke:
`Loop through particles
for t=1 to ttlPrc
   Particles(t).sz.x = Particles(t).sz.x + 0.5
   Particles(t).sz.y = Particles(t).sz.y + 0.5
   Particles(t).p.x = Particles(t).p.x + Particles(t).v.x + windx#
   Particles(t).p.y = Particles(t).p.y + Particles(t).v.y
   Particles(t).p.z = Particles(t).p.z + Particles(t).v.z + windz#
   particles(t).scale = particles(t).scale + 1
   `Fade particle value
   if Particles(t).Fade >0 then Particles(t).Fade = Particles(t).Fade - .2
   `Position, scale and fade particle object
   scale object t,particles(t).scale,particles(t).scale,particles(t).scale
   position object objPrc+t-1,Particles(t).p.x,Particles(t).p.y,Particles(t).p.z
   set alpha mapping on t,Particles(t).Fade

   `Point at camera
   set object to camera orientation objPrc+t-1
next t

inc i
if i>ttlPrc then i=1
if Particles(i).Fade <1
   `Position
  Particles(i).p.x = 0
  Particles(i).p.y = 0
  Particles(i).p.z = 100
   `Scale
   Particles(i).sz.x = 50
   Particles(i).sz.y = 50
   `Velocity (randomize)
   Particles(i).v.x = rnd(200)/1000.0-0.1
   Particles(i).v.y = rnd(400)/1000.0+0.1
   Particles(i).v.z = rnd(200)/1000.0-0.1
   Particles(i).Fade = 50 `ttlPrc / 2.0
   particles(i).scale = 10
   `Show the particle
   show object objPrc+i-1
endif
RETURN

Function free_object()
   Repeat
      Inc i
   Until Object Exist(i) = 0
EndFunction i
Function free_image()
   Repeat
      Inc i
   Until Image Exist(i) = 0
EndFunction i

Thanks again!!

Sadly, programming is only a hobby for me right now. As it turns out, driving a 70 ton, 7 million dollar Abrams tank requires less qualification than pecking away at a keyboard. Who'da thunk it?

Back to top

Profile PM Email

Green Gandalf

VIP Member

21

Years of Service

User Offline

Joined: 3rd Jan 2005

Playing: Malevolence:Sword of Ahkranox, Skyrim, Civ6.

Posted: 29th Oct 2011 03:26

Link

Very nice effect. I see you simplified my code a bit too. Well done.