It was done purely with DBPro.
I've got a cleaner version of the code here (original was a bit ugly being new to programming and all)
check it out if you want a spoiler(I think its best to code it yourself then check out how I did it
)
Rem Project: medialess island
Rem Created: Wednesday, July 27, 2011
Rem ***** Main Source File *****
autocam off
sync on:sync rate 60
randomize timer()
//set up fog
fog on
fog color RGB(80,120,80)
fog distance 5000
//make a grass texture
for x = 1 to 100
for y = 1 to 100
dot x,y,rgb(0,rnd(50)+50,0)
next y
next x
get image 1,1,1,99,99
//make a sky texture
cls rgb(255,255,255)
box 0,0,screen width(),screen height()-200,rgb(255,255,255),RGB(87,255,255),rgb(255,255,255),RGB(87,255,255)
get image 2,0,0,screen width(),screen height()
texture backdrop 2
// make a matrix for the ground
make matrix 1,5000,5000,10,10
//texture the matrix with the grass texture we made earlier
prepare matrix texture 1,1,1,1
//make some random hills
randomize matrix 1,200
//lower the edges of the matrix to make an island
for i = 0 to 10
set matrix height 1,0,i,0
set matrix height 1,10,i,0
set matrix height 1,i,0,0
set matrix height 1,i,10,0
next i
// have to update the matrix after any changes to the height of its points
update matrix 1
// make a plane for water,color it and set it in place
make object plane 1,10000,10000,1
rotate object 1,90,0,0
color object 1,rgb(0,0,200)
position object 1, 2500,0,2500
// now the water isnt affected by fog. Just because i want the water to be a strong blue
set object fog 1,0
//place the camera in the center of the matrix @ 50 units above the ground
position camera 2500,get ground height(1,2500,2500)+50,2500
//main loop
do
//move the camera round
control camera using arrowkeys 0,10,5
//keep the camera's "feet" on the ground
position camera 0, camera position x(),get ground height(1,camera position x(),camera position z())+50,camera position z()
//update
sync
loop
pick it apart and do what you will with it.
have fun
kezzla
Sometimes I like to use words out of contents
