Array Pointers (Especially for the attention of IanM)

Author

Message

The Wilderbeast

20

Years of Service

User Offline

Joined: 14th Nov 2005

Location: UK

Posted: 3rd Nov 2011 22:56 Edited at: 3rd Nov 2011 22:59

Link

First of all Ian, thank you very very much for your wonderful set of plugins - I don't think I would have gotten very far with this project without them.

+ Code Snippet

type myType
    myVar as string
endtype
    
dim foo() as myType
dim bar() as myType
    
link array foo(), get arrayPtr(bar())
    
array insert at bottom foo()
array index to bottom foo()
    
foo().myVar = "Hello, world!"
    
//unlink array foo()
//undim array foo()
    
print foo(0).myVar
wait 1000
print bar(0).myVar

This code results in something along the lines of:

Quote: "Hello, world!
...
[Crash - Array subscript out of bounds]"

How closely is foo() linked with bar()? I would expect the code to insert a new row into bar(), but apparently it hasn't. Why is this, and are there any workarounds?

Cheers,
Mike

10% TGC Discount!

Back to top

Profile PM

IanM

Retired Moderator

23

Years of Service

User Offline

Joined: 11th Sep 2002

Location: In my moon base

Posted: 3rd Nov 2011 23:11

Link

Quote: "Why is this,"

There is some behaviour of arrays that I can't do too much about, and one of these is the fact that when you enlarge an array in any way it will allocate a new array, copy the old stuff over to the new, then return the old array memory to be reused at a later point.

It's also worth noting that arrays are simply glorified pointers to array-related data

With that out of the way, let's analyse what's going on.

First relevant line, which makes foo() and bar() represent the same array in memory:

+ Code Snippet

link array foo(), get arrayPtr(bar())

Next relevant line:

+ Code Snippet

array insert at bottom foo()

This allocates a new array (as explained above), and creates an entirely new array. At this point foo() represents an array, and bar() points to freed memory (ie, it's not pointing to an array any more).

BTW, when you insert into an array, the first newly inserted item becomes the current item, so using ARRAY INDEX TO BOTTOM is not needed in your code.

Next relevant line:

+ Code Snippet

print bar(0).myVar

Accessing random memory as if it were an array ... basically, you're lucky that a subscript error was what you got. The alternative would be that it works, but you overwrite some random memory which could be anything from other arrays, strings, loaded sounds/textures/objects etc and have corruption that you wouldn't be able to explain.

Quote: "and are there any workarounds?"

Let me know what you are trying to accomplish and I might be able to suggest an alternative.

Get the latest Matrix1Utility plug-ins (11-SEPT-2011)

Back to top

Profile PM Email Website

The Wilderbeast

20

Years of Service

User Offline

Joined: 14th Nov 2005

Location: UK

Posted: 3rd Nov 2011 23:28 Edited at: 3rd Nov 2011 23:32

Link

Thank you for picking up on this so quickly! I hope you didn't take it as a rant, I was just intrigued to know what was going on.

Quote: "BTW, when you insert into an array, the first newly inserted item becomes the current item, so using ARRAY INDEX TO BOTTOM is not needed in your code."

Thanks for that - you learn something new every day!

Essentially I need a way of modifying arrays without actually knowing exactly which array it is.

ie. So I have a load of arrays of myType. I have a single array which serves as a lookup table between a name and an array. Then using a set of functions I need to be able to manipulate these arrays by adding . removing data. The whole point is that the process is as abstracted as possible.

To explain more clearly, I have an assets type. I have several type of assets which I would like to keep separate and so I define them all individually. I then have an array which has the name of each asset, a unique identifier, and a pointer to the array that holds all of the assets of that type.

the aim is to be able to do pretty much anything I want to those arrays using the following commands:

+ Code Snippet

addStructureToLookup()
addAssetToStructure()
getFirstAssetInStructure()
getNextAssetInStructure()
getLastAssetInStructure()
getAssetByName()
getAssetById()
getAssetAttribute()
getAssetStructure()
removeAssetFromStructure()

Some of those are redundant for obvious reasons (it was copy+pasted from a rough prototype I made earlier).

10% TGC Discount!

Back to top

Profile PM

IanM

Retired Moderator

23

Years of Service

User Offline

Joined: 11th Sep 2002

Location: In my moon base

Posted: 4th Nov 2011 00:29

Link

I don't fully understand what you want, so I coded to my own ideas (and minimally at that).

Here's the basic example:

type MyType_t
    MyVar as string
endtype

type NamedArray_t
    Name as string
    Ptr as dword
endtype

sync sleep 1
dim NamedArray() as NamedArray_t

Found = CreateNamedArray("Ian", -1)
AppendToNamedArray("Ian", "Hello-1")
AppendToNamedArray("Ian", "Hello-2")
print "Size of array 'Ian': "; GetSizeOfNamedArray("Ian")
print

print "Content of the array:"
Top = GetSizeOfNamedArray("Ian")
for i = 0 to Top
    print i; " - "; GetFromNamedArray("Ian", i)
next

wait key
end

function GetSizeOfNamedArray(Name as string)
    local Found as integer
    local Size as integer
    
    Size = -1
    Found = FindNamedArray(Name)
    if Found <> -1
        Size = get arrayptr size( NamedArray(Found).Ptr ) - 1
        ` should be:
        ` Size = get arrayptr count( NamedArray(Found).Ptr )
        ` ...but isn't reporting correctly for some reason.
        ` I'll fix it for the next release.
    endif
endfunction Size

function GetFromNamedArray(Name as string, Index as integer)
    local Found as integer
    local dim Temp() as MyType_t
    local Result as string
    
    Result = ""
    
    ` Locate the named array
    Found = FindNamedArray(Name)
    if Found <> -1
        if Index >= 0 and Index < get arrayptr size( NamedArray(Found).Ptr )
            ` Found the named array, and the index is in range for that array.
            
            ` Link the array to the local temp array
            link array Temp(), NamedArray(Found).Ptr
            
            ` Query the array normally
            Result = Temp(Index).MyVar
        
            ` Unlink storage from the temp array so that it isn't freed
            unlink array Temp()
         endif
    endif
endfunction Result

function AppendToNamedArray(Name as string, Var as string)
    local Found as integer
    local dim Temp() as MyType_t
    
    ` Locate the named array
    Found = FindNamedArray(Name)
    
    ` Just create the array if it doesn't exist - you can create an error here instead
    if Found = -1 then Found = CreateNamedArray(Name, -1)
    
    ` Link the array to the local temp array
    link array Temp(), NamedArray(Found).Ptr
    
    ` Standard array operations...
    array insert at bottom Temp()
    Temp().MyVar = Var
    
    ` Update the pointer as the array has now grown
    NamedArray(Found).Ptr = get arrayptr( Temp() )
    
    ` Unlink storage from the temp array so that it isn't freed
    unlink array Temp()
endfunction

function CreateNamedArray(Name as string, InitialSize as integer)
    local Found as integer
    
    ` Remove the old array under this name (if it exists)
    DeleteNamedArray( Name )

` Create the new array storage
    local dim Temp(InitialSize) as MyType_t

` Record this new named array
    array insert at bottom NamedArray()
    NamedArray().Name = Name
    NamedArray().Ptr = get arrayptr( Temp() )

` Unlink storage from the temp array so that it isn't freed
    unlink array Temp()
    
    ` Return the index of this named array
    Found = get array index( NamedArray() )
endfunction Found

function DeleteNamedArray(Name as string)
    local Found as integer
    
    ` Locate the named array
    Found = FindNamedArray(Name)
    if Found > -1
        ` Free the array storage
        undim arrayptr NamedArray(Found).Ptr
        
        ` Remove the name from the list
        array delete element NamedArray(), Found
    endif
endfunction

function FindNamedArray(Name as string)
    local i as integer
    local Found as integer
    
    Found = -1
    for i = array count( NamedArray() ) to 0 step -1
        if NamedArray(i).Name = Name
            Found = i
            exit
        endif
    next
endfunction Found

+ Code Snippet

type MyType_t
    MyVar as string
endtype

type NamedArray_t
    Name as string
    Ptr as dword
endtype

sync sleep 1
dim NamedArray() as NamedArray_t

Found = CreateNamedArray("Ian", -1)
AppendToNamedArray("Ian", "Hello-1")
AppendToNamedArray("Ian", "Hello-2")
print "Size of array 'Ian': "; GetSizeOfNamedArray("Ian")
print

print "Content of the array:"
Top = GetSizeOfNamedArray("Ian")
for i = 0 to Top
    print i; " - "; GetFromNamedArray("Ian", i)
next

wait key
end



function GetSizeOfNamedArray(Name as string)
    local Found as integer
    local Size as integer
    
    Size = -1
    Found = FindNamedArray(Name)
    if Found <> -1
        Size = get arrayptr size( NamedArray(Found).Ptr ) - 1
        ` should be:
        ` Size = get arrayptr count( NamedArray(Found).Ptr )
        ` ...but isn't reporting correctly for some reason.
        ` I'll fix it for the next release.
    endif
endfunction Size


function GetFromNamedArray(Name as string, Index as integer)
    local Found as integer
    local dim Temp() as MyType_t
    local Result as string
    
    Result = ""
    
    ` Locate the named array
    Found = FindNamedArray(Name)
    if Found <> -1
        if Index >= 0 and Index < get arrayptr size( NamedArray(Found).Ptr )
            ` Found the named array, and the index is in range for that array.
            
            ` Link the array to the local temp array
            link array Temp(), NamedArray(Found).Ptr
            
            ` Query the array normally
            Result = Temp(Index).MyVar
        
            ` Unlink storage from the temp array so that it isn't freed
            unlink array Temp()
         endif
    endif
endfunction Result


function AppendToNamedArray(Name as string, Var as string)
    local Found as integer
    local dim Temp() as MyType_t
    
    ` Locate the named array
    Found = FindNamedArray(Name)
    
    ` Just create the array if it doesn't exist - you can create an error here instead
    if Found = -1 then Found = CreateNamedArray(Name, -1)
    
    ` Link the array to the local temp array
    link array Temp(), NamedArray(Found).Ptr
    
    ` Standard array operations...
    array insert at bottom Temp()
    Temp().MyVar = Var
    
    ` Update the pointer as the array has now grown
    NamedArray(Found).Ptr = get arrayptr( Temp() )
    
    ` Unlink storage from the temp array so that it isn't freed
    unlink array Temp()
endfunction



function CreateNamedArray(Name as string, InitialSize as integer)
    local Found as integer
    
    ` Remove the old array under this name (if it exists)
    DeleteNamedArray( Name )

    ` Create the new array storage
    local dim Temp(InitialSize) as MyType_t

    ` Record this new named array
    array insert at bottom NamedArray()
    NamedArray().Name = Name
    NamedArray().Ptr = get arrayptr( Temp() )

    ` Unlink storage from the temp array so that it isn't freed
    unlink array Temp()
    
    ` Return the index of this named array
    Found = get array index( NamedArray() )
endfunction Found


function DeleteNamedArray(Name as string)
    local Found as integer
    
    ` Locate the named array
    Found = FindNamedArray(Name)
    if Found > -1
        ` Free the array storage
        undim arrayptr NamedArray(Found).Ptr
        
        ` Remove the name from the list
        array delete element NamedArray(), Found
    endif
endfunction


function FindNamedArray(Name as string)
    local i as integer
    local Found as integer
    
    Found = -1
    for i = array count( NamedArray() ) to 0 step -1
        if NamedArray(i).Name = Name
            Found = i
            exit
        endif
    next
endfunction Found

There's only minimal functionality there, but it seems to hang together OK.

However, before you jump any further into this, I'll just let you know that you can get pretty much the same functionality from lookup tables, and it's probably a lot easier too.

Get the latest Matrix1Utility plug-ins (11-SEPT-2011)

Back to top

Profile PM Email Website

The Wilderbeast

20

Years of Service

User Offline

Joined: 14th Nov 2005

Location: UK

Posted: 4th Nov 2011 00:41 Edited at: 4th Nov 2011 01:22

Link

Wow thanks a lot, I'm heading off now but I'll grab a look in the morning and report back.

Many thanks,
Mike

[Edit]
Ahhhhhh, so as soon as you've linked the temp array to the one you're modifying and added the extra row, the array we wanted to modify is just pointless. But if we update the pointer in our lookup table to point to the same same thing as the temp array then we can just reference this array any time we want by linking a temporary array to the pointer in the lookup.

I take my hat off to you sir. If you leave your moon base for a visit to earth, drop by and I'll buy you a beer some time!

Cheers.

10% TGC Discount!

Back to top

Profile PM

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Array Pointers (Especially for the attention of IanM)