[DBPro plugin] eXtendet Rotation

Author

Message

MadBit

VIP Member

Gold Codemaster

15

Years of Service

User Offline

Joined: 25th Jun 2009

Location: Germany

Posted: 15th Dec 2011 15:12 Edited at: 9th Jul 2012 14:15

Link

Hi, I will present you my new baby

. A rotation plugin such as EZ-Rotate. I go a lightly different way as the author of ez-rotate but it works very good for me. I think it is for almost every a useful plugin.

Here the plugin download.
File: eXtendetRotation-plugin_[en]_20111215.zip - 3.3 MB (Uploading)
Forum download

Here a demo download (Asteroidfield with an Elite like Scaner)
File: xrot-Example.7z - 6.3 MB (Uploading)
Forum download

The Source code of the demo.

`Radar
`Radar.dba
`======================

`------------------------------------------------------
`------------------------------------------------------
`Defining some constants ...
`... for Images
#CONSTANT imgID_Mfd1 = 100
#CONSTANT imgID_Mfd2 = 101
#CONSTANT imgID_Mfd3 = 102

`... for Objects
#CONSTANT objID_AstroStart = 100
#CONSTANT objID_NumAstro = 300

`... for base values.
#CONSTANT Control_Sensitivity = 2.0
#CONSTANT Roll_Factor = 30.0
#CONSTANT Pitch_Factor = 20.0
#CONSTANT Speed_Max = 1.00
#CONSTANT Speed_Min = -0.5
#CONSTANT Thrust = 0.003

`An Asteroid Type
TYPE TAsteroid
	iId AS INTEGER
	vecPos AS DWORD
	vecAxis AS DWORD
	vecDir AS DWORD
	vecRelPos AS DWORD
	fRotSpeed# AS FLOAT
	fMoveSpeed# AS FLOAT
	fDistance# AS FLOAT
	iHits AS INTEGER
ENDTYPE

`A Shot Type
TYPE TShot
	iID AS INTEGER
	fSpeed# AS FLOAT
	iLifeTime as INTEGER
ENDTYPE

`Some Global Variables we need.
GLOBAL last_timer AS INTEGER
GLOBAL frametime AS INTEGER
GLOBAL target AS INTEGER
GLOBAL press AS INTEGER
GLOBAL speed_set# AS FLOAT
GLOBAL speed_current# AS FLOAT
GLOBAL screen_width AS DWORD
GLOBAL screen_height AS DWORD
GLOBAL mfd_width AS DWORD
GLOBAL mfd_height AS DWORD
GLOBAL mfds_width AS DWORD
GLOBAL mfds_height AS DWORD
GLOBAL radar_range# AS FLOAT
radar_range# = 500.0
target = objID_AstroStart

SYNC ON
SYNC RATE 120
AUTOCAM OFF

COLOR BACKDROP 0xff202030
SET CAMERA RANGE 0.1, 50000
screen_height = SCREEN HEIGHT()
screen_width = SCREEN WIDTH()

`Make a Camera for the right MFD.
MAKE CAMERA 1
SET CAMERA TO IMAGE 1, 1, 256, 256

`Extended-Rotation must be initialized.
XROT INITIALIZE

`Load Skybox
LOAD OBJECT "../../../Media/models/skybox/skybox.x", 1
SCALE OBJECT 1, 500000, 500000, 500000
SET OBJECT LIGHT 1, 0

`Load MFD
LOAD IMAGE "../../../Media/Textures/scanner-mfd.png", 100
LOAD IMAGE "../../../Media/Textures/MFD_1_green.png", 101
mfds_height = IMAGE HEIGHT(100)
mfds_width = IMAGE WIDTH(100)
mfd_height = IMAGE HEIGHT(101)
mfd_width = IMAGE WIDTH(101)

`Make Scanner
MAKE OBJECT PLAIN 2, 1, 1, 1
LOAD IMAGE "../../../Media/Textures/scanner.png", 2
TEXTURE OBJECT 2, 2
ROTATE LIMB 2, 0, 90, 0, 0
SET OBJECT TRANSPARENCY 2, 1
SET OBJECT LIGHT 2, 0
POSITION OBJECT 2, 0, -0.9, 2.2
LOCK OBJECT ON 2
SET OBJECT MASK 2, 1

`Create vector's and matrix for calculations
GLOBAL mat1 AS DWORD
GLOBAL vec1 AS DWORD
GLOBAL vec2 AS DWORD
GLOBAL vec3 AS DWORD
GLOBAL vecScanA AS DWORD
GLOBAL vecScanR AS DWORD

mat1 = DXMAT(0)
vec1 = DXVEC3(0)
vec2 = DXVEC3(0)
vec3 = DXVEC3(0)
vecScanR  = DXVEC3(0, 0, -0.9, 2.2)
vecScanA  = DXVEC3(0)

`Create asteroid data
DIM Asteroids(objID_NumAstro) AS TAsteroid

FOR n=1 TO objID_NumAstro
	IF n=1 THEN LOAD OBJECT "../../../Media/models/Asteroids/AST_01.X", objID_AstroStart
	IF n=2 THEN LOAD OBJECT "../../../Media/models/Asteroids/AST_02.X", objID_AstroStart+1
	IF n=3 THEN LOAD OBJECT "../../../Media/models/Asteroids/AST_03.X", objID_AstroStart+2
	IF n=4 THEN LOAD OBJECT "../../../Media/models/Asteroids/AST_04.X", objID_AstroStart+3
	IF n=5 THEN LOAD OBJECT "../../../Media/models/Asteroids/AST_05.X", objID_AstroStart+4
	IF n > 5 THEN CLONE OBJECT objID_AstroStart+n-1, objID_AstroStart+RND(4)
	
	Asteroids(n).iId = objID_AstroStart+n-1
	Asteroids(n).vecPos = DXVEC3(0, RND(2000)-1000, RND(2000)-1000, RND(2000)-1000)
	Asteroids(n).vecAxis = DXVEC3(0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0)
	Asteroids(n).vecDir = DXVEC3(0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0)
	Asteroids(n).vecRelPos = DXVEC3(0)
	Asteroids(n).fRotSpeed# = RND(100)/200.0
	Asteroids(n).fMoveSpeed# = RND(100)/250.0
	
	DXVEC3 NORMALIZE Asteroids(n).vecAxis, Asteroids(n).vecAxis
	DXVEC3 NORMALIZE Asteroids(n).vecDir, Asteroids(n).vecDir

SCALE OBJECT Asteroids(n).iId, RND(30)+10, RND(30)+10, RND(30)+10
	DBOBJ SET POSITION Asteroids(n).iId, Asteroids(n).vecPos
NEXT n

DO
	time = TIMER()
	frametime = time - last_timer
	last_timer = time
	
	Control()
	
	UpdateAsteroids()
	
	DrawCockpit()
	
	`F1 - for some Info's
	IF KEYSTATE(59)
		PrintInfo()
	ELSE
		INK 0xffffffff, 0
		TEXT 0, 0, "Hold F1 for some Info!"
	ENDIF
	
	SYNC
LOOP

`I don't need this stuff and release it. Prevent for memoryleaks.
DXMAT RELEASE mat1
DXVEC3 RELEASE vec1
FOR n=1 TO objID_NumAstro
	DXVEC3 RELEASE Asteroids(n).vecAxis
	DXVEC3 RELEASE Asteroids(n).vecPos
	DXVEC3 RELEASE Asteroids(n).vecDir
	DXVEC3 RELEASE Asteroids(n).vecRelPos
NEXT n

END

FUNCTION PrintInfo()
	box 100, 100, 540, 380, 0x7f007f00, 0x7f007f00, 0x7f007f00, 0x7f007f00
	INK 0xffffff00, 0
	CENTER TEXT 320, 100, "Demonstrate Some cool Functions"
	CENTER TEXT 320, 115, "-------------------------------------------------------"
	CENTER TEXT 320, 145, "[E]-get closest asteroid."
	CENTER TEXT 320, 160, "[R]-change scaner-range."
	CENTER TEXT 320, 175, "[mouse-wheel]-set speed."
	CENTER TEXT 320, 190, "[mouse]-control the ship."
	CENTER TEXT 320, 205, "[mouse-button-middle]-set speed to zero."
	CENTER TEXT 320, 235, "I had seen the 'Example5' of EZ-Rotate. Well, this is"
	CENTER TEXT 320, 250, "my version of it."
	CENTER TEXT 320, 280, "Asteroids rotating via vector-rotation and moving with"
	CENTER TEXT 320, 295, "directional-vectors. Calculation of Scanner objects"
	CENTER TEXT 320, 310, "with CALC ABSOLUT/RELATIVE POINT."
ENDFUNCTION

FUNCTION Control()
	`Get mouse movement into variables mx#, my#, mz#
	mx# = MOUSEMOVEX() / -Control_Sensitivity
	my# = MOUSEMOVEY() / -Control_Sensitivity
	mz# = MOUSEMOVEZ() / 1000.0

`If middle mousebutten pressed the set speed to zero.
	IF MOUSECLICK() = 4 THEN speed_set# = 0.0
	
	`setup the speed
	speed_set# = speed_set# + mz#
	IF speed_set# < Speed_Min then speed_set# = Speed_Min
	IF speed_set# > Speed_Max THEN speed_set# = Speed_Max
	add# = speed_set# - speed_current#
	IF add# > Thrust THEN add# = Thrust
	IF add# < -Thrust THEN add# = -Thrust
	speed_current# = speed_current# + add#
	MOVE CAMERA speed_current#

`pitch and roll control	
	IF mx# > Roll_Factor then mx# = Roll_Factor
	IF mx# < -Roll_Factor THEN mx# = -Roll_Factor
	IF my# > Pitch_Factor THEN my# = Pitch_Factor
	IF my# < -Pitch_Factor THEN my# = -Pitch_Factor

`set radarrange	with key 'R'
	IF KEYSTATE(19) = 1 AND press = 0
		radar_range# = radar_range# / 2
		IF radar_range# < 125 THEN radar_range# = 500
		press = 19
	ELSE
		IF KEYSTATE(19) = 0 AND press = 19 THEN press = 0
	ENDIF

`Get the closest asteroid as target with key 'E'.
	IF KEYSTATE(18) = 1 AND press = 0
		dist# = 10000.0
		FOR n = 1 TO objID_NumAstro
			IF Asteroids(n).fDistance# < dist# 
				dist# = Asteroids(n).fDistance#
				target = n
			ENDIF
		NEXT n
		press = 18
	ELSE
		IF KEYSTATE(18) = 0 AND press = 18 THEN press = 0
	ENDIF
	
	`Set camera rotation and position.
	DBCAM GET MATRIX mat1, 0
	XROT LOCAL X mat1, mat1, my#
	XROT LOCAL Z mat1, mat1, mx#
	DBCAM SET MATRIX 0, mat1
	
	DBOBJ SET POSITION 1, DBCAM GET POSITION(vec1, 0)
ENDFUNCTION

FUNCTION DrawCockpit()
	`MFD - left
	`Output some usefull data.
	offY = screen_height-mfd_height
	INK 0xffa0a0a0, 0
	TEXT 35, offY+40, "S: "+str$(speed_current#, 2)+ " : "+str$(speed_set#, 2)
	DBCAM GET POSITION vec1, 0
	TEXT 35, offY+60, "P: x "+str$(DXVEC3X(vec1), 2)
	TEXT 35, offY+70, "   y "+str$(DXVEC3Y(vec1), 2)
	TEXT 35, offY+80, "   z "+str$(DXVEC3Z(vec1), 2)
	DBCAM GET EULER vec1, 0
	TEXT 35, offY+100, "R: x "+str$(DXVEC3X(vec1), 2)
	TEXT 35, offY+110, "   y "+str$(DXVEC3Y(vec1), 2)
	TEXT 35, offY+120, "   z "+str$(DXVEC3Z(vec1), 2)
	TEXT 35, offY+140, "FPS: "+str$(SCREEN FPS())
	PASTE IMAGE 101, 0, offY, 1

`MFD - mid
	`Draw an elite-like scanner
	offX = (screen_width/2)-(mfds_width/2)
	`Rotate the 'scanner-image' in same direction as the camera
	
	`For each asteroid
	FOR n=1 TO objID_NumAstro
		`If asteroid in scaner range ?
		IF Asteroids(n).fDistance# <= radar_range#
			`set color to red if the asteroid the target otherwise set grey
			IF n = target THEN INK 0xffff0000, 0 ELSE ink 0xffa0a0a0, 0

`Calculate the position of the asteroid in the scaner and draw it
			DXVEC3 DIV vec1, Asteroids(n).vecRelPos, (radar_range#*2.0)
			DXVEC3 ADD vec2, vec1, vecScanR
			XROT CALC ABSOLUT POSITION vec2, mat1, vec2
			XROT CALC SCREEN POSITION vec3, 0, vec2
			BOX DXVEC3X(vec3)-2, DXVEC3Y(vec3)-2, DXVEC3X(vec3)+2, DXVEC3Y(vec3)+2

`Draw the line from asteroid to y-axis base.
			DXVEC3 ADD vec2, vecScanR, DXVEC3(vec2, DXVEC3X(vec1), 0.0, DXVEC3Z(vec1))
			XROT CALC ABSOLUT POSITION vec2, mat1, vec2
			XROT CALC SCREEN POSITION vec2, 0, vec2
			LINE DXVEC3X(vec3), DXVEC3Y(vec3), DXVEC3X(vec2), DXVEC3Y(vec2)
		ENDIF
	NEXT n
	INK 0xffa0a0a0, 0
	TEXT offX+35, offY+40, "R: " + STR$(radar_range#, 0)+ "   " + STR$(press)
	PASTE IMAGE 100, offX, offY, 1

`MFD - right
	`draw the target camera
	offX = screen_width-mfd_width
	DXVEC3 SUB vec1, DBOBJ GET POSITION(vec2, Asteroids(target).iId), DBCAM GET POSITION(vec3, 0)
	fov# = DBCAM GET FOV(0)
	size# = OBJECT SIZE(Asteroids(target).iId, 1)
	sinfov# = SIN(fov#) * 3.0 * size#
	camdist# = SQRT((sinfov#*sinfov#)-(size# * size#))
	POSITION OBJECT Asteroids(target).iId, 0, 0, 10000
	POSITION CAMERA 1, 0, 0, 10000.0 - camdist#
	SYNC CAMERA 1
	DBOBJ SET POSITION Asteroids(target).iId, vec2
	
	PASTE IMAGE 1, offX, offY, 0
	TEXT offX+35, offY+40, "OD: "+STR$(Asteroids(target).fDistance#, 3)
	TEXT offX+35, offY+50, "OS: "+STR$(Asteroids(target).fMoveSpeed#, 3)
	TEXT offX+35, offY+60, " m: "+STR$(size#*300.0, 3)+" t"

PASTE IMAGE 101, offX, offY, 1
ENDFUNCTION

FUNCTION UpdateAsteroids()
	`Updating each Asteroid
	FOR n=1 TO objID_NumAstro
	    
		`Get asteroid matrix. 
		`rotate it via vector-rotation and 
		`apply the rotation
		DBOBJ GET MATRIX mat1, Asteroids(n).iId
		XROT VECTOR ROTATION mat1, mat1, Asteroids(n).vecAxis, Asteroids(n).fRotSpeed#
		DBOBJ SET ROTATION MATRIX objID_AstroStart+n-1, mat1
		
		`set vec1 to movingdirection and multiply by speed
		`add the result to current position of asteroid
		`apply the new position to asteroid
		DXVEC3 MUL vec1, Asteroids(n).vecDir, Asteroids(n).fMoveSpeed#
		DXVEC3 ADD Asteroids(n).vecPos, Asteroids(n).vecPos, vec1
		DBOBJ SET POSITION Asteroids(n).iId, Asteroids(n).vecPos
		
		`store the relative position of the asteroid to the main camera.
		`store the distance of the asteroid to the main camera.
		XROT CALC RELATIVE POSITION Asteroids(n).vecRelPos, DBCAM GET MATRIX(mat1, 0), Asteroids(n).vecPos
		dist# = DXVEC3 LENGTH(Asteroids(n).vecRelPos)
		Asteroids(n).fDistance# = dist#
		
		
		`let the asteroid fade out when it is to far.		
		fade# = (dist# - 1510.0)/5.0
		IF fade# < 0.0 THEN fade# = 100.0 ELSE fade# = 100.0 - fade#
		
		FADE OBJECT Asteroids(n).iId, fade#

`Make new asteroids if it go out.
		IF ABS(dist#) > 2010.0 THEN NewAsteroid(n)
	NEXT n
ENDFUNCTION

FUNCTION NewAsteroid(n AS INTEGER)
	DXVEC3 Asteroids(n).vecAxis, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0
	DXVEC3 Asteroids(n).vecDir, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0
	Asteroids(n).fRotSpeed# = RND(100)/200.0
	Asteroids(n).fMoveSpeed# = RND(100)/250.0
	
	DXVEC3 NORMALIZE Asteroids(n).vecAxis, Asteroids(n).vecAxis
	DXVEC3 NORMALIZE Asteroids(n).vecDir, Asteroids(n).vecDir
	
	DXVEC3 MUL Asteroids(n).vecPos, Asteroids(n).vecDir, -2000.0
	DXVEC3 ADD Asteroids(n).vecPos, Asteroids(n).vecPos, DBCAM GET POSITION(vec1, 0)
ENDFUNCTION

+ Code Snippet

`Radar
`Radar.dba
`======================

`------------------------------------------------------
`------------------------------------------------------
`Defining some constants ...
`... for Images
#CONSTANT imgID_Mfd1 = 100
#CONSTANT imgID_Mfd2 = 101
#CONSTANT imgID_Mfd3 = 102

`... for Objects
#CONSTANT objID_AstroStart = 100
#CONSTANT objID_NumAstro = 300

`... for base values.
#CONSTANT Control_Sensitivity = 2.0
#CONSTANT Roll_Factor = 30.0
#CONSTANT Pitch_Factor = 20.0
#CONSTANT Speed_Max = 1.00
#CONSTANT Speed_Min = -0.5
#CONSTANT Thrust = 0.003

`An Asteroid Type
TYPE TAsteroid
	iId AS INTEGER
	vecPos AS DWORD
	vecAxis AS DWORD
	vecDir AS DWORD
	vecRelPos AS DWORD
	fRotSpeed# AS FLOAT
	fMoveSpeed# AS FLOAT
	fDistance# AS FLOAT
	iHits AS INTEGER
ENDTYPE

`A Shot Type
TYPE TShot
	iID AS INTEGER
	fSpeed# AS FLOAT
	iLifeTime as INTEGER
ENDTYPE

`Some Global Variables we need.
GLOBAL last_timer AS INTEGER
GLOBAL frametime AS INTEGER
GLOBAL target AS INTEGER
GLOBAL press AS INTEGER
GLOBAL speed_set# AS FLOAT
GLOBAL speed_current# AS FLOAT
GLOBAL screen_width AS DWORD
GLOBAL screen_height AS DWORD
GLOBAL mfd_width AS DWORD
GLOBAL mfd_height AS DWORD
GLOBAL mfds_width AS DWORD
GLOBAL mfds_height AS DWORD
GLOBAL radar_range# AS FLOAT
radar_range# = 500.0
target = objID_AstroStart

SYNC ON
SYNC RATE 120
AUTOCAM OFF

COLOR BACKDROP 0xff202030
SET CAMERA RANGE 0.1, 50000
screen_height = SCREEN HEIGHT()
screen_width = SCREEN WIDTH()

`Make a Camera for the right MFD.
MAKE CAMERA 1
SET CAMERA TO IMAGE 1, 1, 256, 256

`Extended-Rotation must be initialized.
XROT INITIALIZE

`Load Skybox
LOAD OBJECT "../../../Media/models/skybox/skybox.x", 1
SCALE OBJECT 1, 500000, 500000, 500000
SET OBJECT LIGHT 1, 0

`Load MFD
LOAD IMAGE "../../../Media/Textures/scanner-mfd.png", 100
LOAD IMAGE "../../../Media/Textures/MFD_1_green.png", 101
mfds_height = IMAGE HEIGHT(100)
mfds_width = IMAGE WIDTH(100)
mfd_height = IMAGE HEIGHT(101)
mfd_width = IMAGE WIDTH(101)

`Make Scanner
MAKE OBJECT PLAIN 2, 1, 1, 1
LOAD IMAGE "../../../Media/Textures/scanner.png", 2
TEXTURE OBJECT 2, 2
ROTATE LIMB 2, 0, 90, 0, 0
SET OBJECT TRANSPARENCY 2, 1
SET OBJECT LIGHT 2, 0
POSITION OBJECT 2, 0, -0.9, 2.2
LOCK OBJECT ON 2
SET OBJECT MASK 2, 1

`Create vector's and matrix for calculations
GLOBAL mat1 AS DWORD
GLOBAL vec1 AS DWORD
GLOBAL vec2 AS DWORD
GLOBAL vec3 AS DWORD
GLOBAL vecScanA AS DWORD
GLOBAL vecScanR AS DWORD

mat1 = DXMAT(0)
vec1 = DXVEC3(0)
vec2 = DXVEC3(0)
vec3 = DXVEC3(0)
vecScanR  = DXVEC3(0, 0, -0.9, 2.2)
vecScanA  = DXVEC3(0)

`Create asteroid data
DIM Asteroids(objID_NumAstro) AS TAsteroid

FOR n=1 TO objID_NumAstro
	IF n=1 THEN LOAD OBJECT "../../../Media/models/Asteroids/AST_01.X", objID_AstroStart
	IF n=2 THEN LOAD OBJECT "../../../Media/models/Asteroids/AST_02.X", objID_AstroStart+1
	IF n=3 THEN LOAD OBJECT "../../../Media/models/Asteroids/AST_03.X", objID_AstroStart+2
	IF n=4 THEN LOAD OBJECT "../../../Media/models/Asteroids/AST_04.X", objID_AstroStart+3
	IF n=5 THEN LOAD OBJECT "../../../Media/models/Asteroids/AST_05.X", objID_AstroStart+4
	IF n > 5 THEN CLONE OBJECT objID_AstroStart+n-1, objID_AstroStart+RND(4)
	
	Asteroids(n).iId = objID_AstroStart+n-1
	Asteroids(n).vecPos = DXVEC3(0, RND(2000)-1000, RND(2000)-1000, RND(2000)-1000)
	Asteroids(n).vecAxis = DXVEC3(0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0)
	Asteroids(n).vecDir = DXVEC3(0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0)
	Asteroids(n).vecRelPos = DXVEC3(0)
	Asteroids(n).fRotSpeed# = RND(100)/200.0
	Asteroids(n).fMoveSpeed# = RND(100)/250.0
	
	DXVEC3 NORMALIZE Asteroids(n).vecAxis, Asteroids(n).vecAxis
	DXVEC3 NORMALIZE Asteroids(n).vecDir, Asteroids(n).vecDir

	SCALE OBJECT Asteroids(n).iId, RND(30)+10, RND(30)+10, RND(30)+10
	DBOBJ SET POSITION Asteroids(n).iId, Asteroids(n).vecPos
NEXT n

DO
	time = TIMER()
	frametime = time - last_timer
	last_timer = time
	
	Control()
	
	UpdateAsteroids()
	
	DrawCockpit()
	
	`F1 - for some Info's
	IF KEYSTATE(59)
		PrintInfo()
	ELSE
		INK 0xffffffff, 0
		TEXT 0, 0, "Hold F1 for some Info!"
	ENDIF
	
	SYNC
LOOP

`I don't need this stuff and release it. Prevent for memoryleaks.
DXMAT RELEASE mat1
DXVEC3 RELEASE vec1
FOR n=1 TO objID_NumAstro
	DXVEC3 RELEASE Asteroids(n).vecAxis
	DXVEC3 RELEASE Asteroids(n).vecPos
	DXVEC3 RELEASE Asteroids(n).vecDir
	DXVEC3 RELEASE Asteroids(n).vecRelPos
NEXT n

END

FUNCTION PrintInfo()
	box 100, 100, 540, 380, 0x7f007f00, 0x7f007f00, 0x7f007f00, 0x7f007f00
	INK 0xffffff00, 0
	CENTER TEXT 320, 100, "Demonstrate Some cool Functions"
	CENTER TEXT 320, 115, "-------------------------------------------------------"
	CENTER TEXT 320, 145, "[E]-get closest asteroid."
	CENTER TEXT 320, 160, "[R]-change scaner-range."
	CENTER TEXT 320, 175, "[mouse-wheel]-set speed."
	CENTER TEXT 320, 190, "[mouse]-control the ship."
	CENTER TEXT 320, 205, "[mouse-button-middle]-set speed to zero."
	CENTER TEXT 320, 235, "I had seen the 'Example5' of EZ-Rotate. Well, this is"
	CENTER TEXT 320, 250, "my version of it."
	CENTER TEXT 320, 280, "Asteroids rotating via vector-rotation and moving with"
	CENTER TEXT 320, 295, "directional-vectors. Calculation of Scanner objects"
	CENTER TEXT 320, 310, "with CALC ABSOLUT/RELATIVE POINT."
ENDFUNCTION

FUNCTION Control()
	`Get mouse movement into variables mx#, my#, mz#
	mx# = MOUSEMOVEX() / -Control_Sensitivity
	my# = MOUSEMOVEY() / -Control_Sensitivity
	mz# = MOUSEMOVEZ() / 1000.0

	`If middle mousebutten pressed the set speed to zero.
	IF MOUSECLICK() = 4 THEN speed_set# = 0.0
	
	`setup the speed
	speed_set# = speed_set# + mz#
	IF speed_set# < Speed_Min then speed_set# = Speed_Min
	IF speed_set# > Speed_Max THEN speed_set# = Speed_Max
	add# = speed_set# - speed_current#
	IF add# > Thrust THEN add# = Thrust
	IF add# < -Thrust THEN add# = -Thrust
	speed_current# = speed_current# + add#
	MOVE CAMERA speed_current#

	`pitch and roll control	
	IF mx# > Roll_Factor then mx# = Roll_Factor
	IF mx# < -Roll_Factor THEN mx# = -Roll_Factor
	IF my# > Pitch_Factor THEN my# = Pitch_Factor
	IF my# < -Pitch_Factor THEN my# = -Pitch_Factor

	`set radarrange	with key 'R'
	IF KEYSTATE(19) = 1 AND press = 0
		radar_range# = radar_range# / 2
		IF radar_range# < 125 THEN radar_range# = 500
		press = 19
	ELSE
		IF KEYSTATE(19) = 0 AND press = 19 THEN press = 0
	ENDIF

	`Get the closest asteroid as target with key 'E'.
	IF KEYSTATE(18) = 1 AND press = 0
		dist# = 10000.0
		FOR n = 1 TO objID_NumAstro
			IF Asteroids(n).fDistance# < dist# 
				dist# = Asteroids(n).fDistance#
				target = n
			ENDIF
		NEXT n
		press = 18
	ELSE
		IF KEYSTATE(18) = 0 AND press = 18 THEN press = 0
	ENDIF
	
	`Set camera rotation and position.
	DBCAM GET MATRIX mat1, 0
	XROT LOCAL X mat1, mat1, my#
	XROT LOCAL Z mat1, mat1, mx#
	DBCAM SET MATRIX 0, mat1
	
	DBOBJ SET POSITION 1, DBCAM GET POSITION(vec1, 0)
ENDFUNCTION

FUNCTION DrawCockpit()
	`MFD - left
	`Output some usefull data.
	offY = screen_height-mfd_height
	INK 0xffa0a0a0, 0
	TEXT 35, offY+40, "S: "+str$(speed_current#, 2)+ " : "+str$(speed_set#, 2)
	DBCAM GET POSITION vec1, 0
	TEXT 35, offY+60, "P: x "+str$(DXVEC3X(vec1), 2)
	TEXT 35, offY+70, "   y "+str$(DXVEC3Y(vec1), 2)
	TEXT 35, offY+80, "   z "+str$(DXVEC3Z(vec1), 2)
	DBCAM GET EULER vec1, 0
	TEXT 35, offY+100, "R: x "+str$(DXVEC3X(vec1), 2)
	TEXT 35, offY+110, "   y "+str$(DXVEC3Y(vec1), 2)
	TEXT 35, offY+120, "   z "+str$(DXVEC3Z(vec1), 2)
	TEXT 35, offY+140, "FPS: "+str$(SCREEN FPS())
	PASTE IMAGE 101, 0, offY, 1

	`MFD - mid
	`Draw an elite-like scanner
	offX = (screen_width/2)-(mfds_width/2)
	`Rotate the 'scanner-image' in same direction as the camera
	
	`For each asteroid
	FOR n=1 TO objID_NumAstro
		`If asteroid in scaner range ?
		IF Asteroids(n).fDistance# <= radar_range#
			`set color to red if the asteroid the target otherwise set grey
			IF n = target THEN INK 0xffff0000, 0 ELSE ink 0xffa0a0a0, 0

   `Calculate the position of the asteroid in the scaner and draw it
			DXVEC3 DIV vec1, Asteroids(n).vecRelPos, (radar_range#*2.0)
			DXVEC3 ADD vec2, vec1, vecScanR
			XROT CALC ABSOLUT POSITION vec2, mat1, vec2
			XROT CALC SCREEN POSITION vec3, 0, vec2
			BOX DXVEC3X(vec3)-2, DXVEC3Y(vec3)-2, DXVEC3X(vec3)+2, DXVEC3Y(vec3)+2

   `Draw the line from asteroid to y-axis base.
			DXVEC3 ADD vec2, vecScanR, DXVEC3(vec2, DXVEC3X(vec1), 0.0, DXVEC3Z(vec1))
			XROT CALC ABSOLUT POSITION vec2, mat1, vec2
			XROT CALC SCREEN POSITION vec2, 0, vec2
			LINE DXVEC3X(vec3), DXVEC3Y(vec3), DXVEC3X(vec2), DXVEC3Y(vec2)
		ENDIF
	NEXT n
	INK 0xffa0a0a0, 0
	TEXT offX+35, offY+40, "R: " + STR$(radar_range#, 0)+ "   " + STR$(press)
	PASTE IMAGE 100, offX, offY, 1

	`MFD - right
	`draw the target camera
	offX = screen_width-mfd_width
	DXVEC3 SUB vec1, DBOBJ GET POSITION(vec2, Asteroids(target).iId), DBCAM GET POSITION(vec3, 0)
	fov# = DBCAM GET FOV(0)
	size# = OBJECT SIZE(Asteroids(target).iId, 1)
	sinfov# = SIN(fov#) * 3.0 * size#
	camdist# = SQRT((sinfov#*sinfov#)-(size# * size#))
	POSITION OBJECT Asteroids(target).iId, 0, 0, 10000
	POSITION CAMERA 1, 0, 0, 10000.0 - camdist#
	SYNC CAMERA 1
	DBOBJ SET POSITION Asteroids(target).iId, vec2
	
	PASTE IMAGE 1, offX, offY, 0
	TEXT offX+35, offY+40, "OD: "+STR$(Asteroids(target).fDistance#, 3)
	TEXT offX+35, offY+50, "OS: "+STR$(Asteroids(target).fMoveSpeed#, 3)
	TEXT offX+35, offY+60, " m: "+STR$(size#*300.0, 3)+" t"

	PASTE IMAGE 101, offX, offY, 1
ENDFUNCTION

FUNCTION UpdateAsteroids()
	`Updating each Asteroid
	FOR n=1 TO objID_NumAstro
	    
		`Get asteroid matrix. 
		`rotate it via vector-rotation and 
		`apply the rotation
		DBOBJ GET MATRIX mat1, Asteroids(n).iId
		XROT VECTOR ROTATION mat1, mat1, Asteroids(n).vecAxis, Asteroids(n).fRotSpeed#
		DBOBJ SET ROTATION MATRIX objID_AstroStart+n-1, mat1
		
		`set vec1 to movingdirection and multiply by speed
		`add the result to current position of asteroid
		`apply the new position to asteroid
		DXVEC3 MUL vec1, Asteroids(n).vecDir, Asteroids(n).fMoveSpeed#
		DXVEC3 ADD Asteroids(n).vecPos, Asteroids(n).vecPos, vec1
		DBOBJ SET POSITION Asteroids(n).iId, Asteroids(n).vecPos
		
		`store the relative position of the asteroid to the main camera.
		`store the distance of the asteroid to the main camera.
		XROT CALC RELATIVE POSITION Asteroids(n).vecRelPos, DBCAM GET MATRIX(mat1, 0), Asteroids(n).vecPos
		dist# = DXVEC3 LENGTH(Asteroids(n).vecRelPos)
		Asteroids(n).fDistance# = dist#
		
		
		`let the asteroid fade out when it is to far.		
		fade# = (dist# - 1510.0)/5.0
		IF fade# < 0.0 THEN fade# = 100.0 ELSE fade# = 100.0 - fade#
		
		FADE OBJECT Asteroids(n).iId, fade#

		`Make new asteroids if it go out.
		IF ABS(dist#) > 2010.0 THEN NewAsteroid(n)
	NEXT n
ENDFUNCTION

FUNCTION NewAsteroid(n AS INTEGER)
	DXVEC3 Asteroids(n).vecAxis, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0
	DXVEC3 Asteroids(n).vecDir, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0, (RND(2000)-1000)/1000.0
	Asteroids(n).fRotSpeed# = RND(100)/200.0
	Asteroids(n).fMoveSpeed# = RND(100)/250.0
	
	DXVEC3 NORMALIZE Asteroids(n).vecAxis, Asteroids(n).vecAxis
	DXVEC3 NORMALIZE Asteroids(n).vecDir, Asteroids(n).vecDir
	
	DXVEC3 MUL Asteroids(n).vecPos, Asteroids(n).vecDir, -2000.0
	DXVEC3 ADD Asteroids(n).vecPos, Asteroids(n).vecPos, DBCAM GET POSITION(vec1, 0)
ENDFUNCTION

And the commands of the Plugin (over 160 commands). The most of them are only wrapped from the DirectX-SDK.

XROT

+ Code Snippet

XROT INITIALIZE
XROT GLOBAL X
XROT GLOBAL Y
XROT GLOBAL Z
XROT LOCAL X
XROT LOCAL Y
XROT LOCAL Z
XROT MATRIX TO EULER
XROT ORBIT ROTATION
XROT VECTOR ROTATION
XROT ROTATE TO
XROT YAW TO
XROT PITCH TO
XROT CALC NORMAL
XROT REFLECT VECTOR
XROT CALC ABSOLUT POSITION
XROT CALC RELATIVE POSITION
XROT CALC SCREEN POSITION
XROT ALIGN AXIS TO NORMAL
XROT GET AXIS ANGLE BETWEEN VECTORS

DXVEC3

+ Code Snippet

DXVEC3
DXVEC3X
DXVEC3Y
DXVEC3Z
DXVEC3$
DXVEC3 ADD
DXVEC3 MUL
DXVEC3 DIV
DXVEC3 BARY CENTRIC
DXVEC3 CATMUL ROM
DXVEC3 CROSS
DXVEC3 DOT
DXVEC3 HERMITE
DXVEC3 LENGTH
DXVEC3 LENGTH2
DXVEC3 LERP
DXVEC3 MAXIMIZE
DXVEC3 MINIMIZE
DXVEC3 NORMALIZE
DXVEC3 SCALE
DXVEC3 SUB
DXVEC3 TRANSFORM
DXVEC3 TRANSFORM NORMAL
DXVEC3 RELEASE
DXVEC3 CONVERT TO RADIANT
DXVEC3 CONVERT TO DEGREE
DXVEC3 NEGATE

DXMAT

+ Code Snippet

DXMAT
DXMAT ROWCOL
DXMAT$
DXMAT IDENTITY
DXMAT AFFINE TRANSFORMATION
DXMAT DECOMPOSE
DXMAT DETERMINANT
DXMAT INVERSE
DXMAT IS IDENTITY
DXMAT LOOK AT LH
DXMAT LOOK AT RH
DXMAT MULTIPLY
DXMAT MULTIPLY TRANSPOSE
DXMAT ORTHO LH
DXMAT ORTHO RH
DXMAT ORTHO OFF CENTER LH
DXMAT ORTHO OFF CENTER RH
DXMAT PERSPECTIVE FOV LH
DXMAT PERSPECTIVE FOV RH
DXMAT PERSPECTIVE LH
DXMAT PERSPECTIVE RH
DXMAT PERSPECTIVE OFF CENTER LH
DXMAT PERSPECTIVE OFF CENTER RH
DXMAT REFLECT
DXMAT ROTATION AXIS
DXMAT ROTATION QUATERNION
DXMAT ROTATION YPR
DXMAT ROTATION X
DXMAT ROTATION Y
DXMAT ROTATION Z
DXMAT SCALING
DXMAT TRANSFORMATION
DXMAT TRANSLATION
DXMAT TRANSPOSE
DXMAT RELEASE

DXQUAT

+ Code Snippet

DXQUAT
DXQUAT BARY CENTRIC
DXQUAT CONJUGATE
DXQUAT DOT
DXQUAT EXP
DXQUAT IDENTITY
DXQUAT INVERSE
DXQUAT IS IDENTITY
DXQUAT LENGTH
DXQUAT LENGTH2
DXQUAT LN
DXQUAT MULTIPLY
DXQUAT NORMALIZE
DXQUAT ROTATION AXIS
DXQUAT ROTATION MATRIX
DXQUAT ROTATION YPR
DXQUAT SLERP
DXQUAT SQUAD
DXQUAT SQUAD SETUP
DXQUAT TO AXIS ANGLE
DXQUAT TO EULER
DXQUAT RELEASE
DXQUATX
DXQUATY
DXQUATZ
DXQUATW
DXQUAT$

DXPLANE

+ Code Snippet

DXPLANE
DXPLANE DOT COORD
DXPLANE DOT NORMAL
DXPLANE FROM POINT NORMAL
DXPLANE FROM POINTS
DXPLANE INTERSECT LINE
DXPLANE NORMALIZE
DXPLANE SCALE
DXPLANE TRANSFORM
DXPLANEA
DXPLANEB
DXPLANEC
DXPLANED
DXPLANE$

DBOBJ

+ Code Snippet

DBOBJ GET POSITION
DBOBJ GET LOOK VECTOR
DBOBJ GET UP VECTOR
DBOBJ GET MATRIX
DBOBJ GET ROTATION MATRIX
DBOBJ GET TRANSLATION MATRIX
DBOBJ GET SCALE MATRIX
DBOBJ GET EULER
DBOBJ GET SCALE
DBOBJ SET ROTATION MATRIX
DBOBJ SET POSITION
DBOBJ SET ROTATION
DBOBJ MOVE
DBOBJ POINT TO
DBOBJ SET SCALE
DBOBJ GET SIZE
DBOBJ SET COLLISION BOX
DBOBJ INTERSECT
DBOBJ SET OFFSET LIMB
DBOBJ SET ROTATION LIMB
DBOBJ SET SCALE LIMB
DBOBJ GET OFFSET LIMB
DBOBJ GET SCALE LIMB
DBOBJ GET ANGLE LIMB
DBOBJ GET DIRECTION LIMB
DBOBJ GET POSITION LIMB
DBOBJ SET SIZE

DBCAM

+ Code Snippet

DBCAM GET MATRIX
DBCAM GET PROJECTION MATRIX
DBCAM GET VIEW MATRIX
DBCAM GET LOOK VECTOR
DBCAM GET UP VECTOR
DBCAM GET RIGHT VECTOR
DBCAM GET POSITION
DBCAM GET EULER
DBCAM GET ASPECT
DBCAM GET FOV
DBCAM SET ROTATION
DBCAM SET POSITION
DBCAM SET MATRIX
DBCAM SET PROJECTION MATRIX
DBCAM SET ORTHOGONAL MATRIX
DBCAM POINT TO
DBCAM MOVE

Questions, suggestions and comments are welcome. I hope you find not many bugs

With Computers you can solve Problems that you have never befor.
Share your knowledge. It's a way to achieve immortality. (Tenzin Gyatso)

Attachments

Login to view attachments

Back to top

Profile PM Email

MrValentine

AGK Backer

13

Years of Service

User Offline

Joined: 5th Dec 2010

Playing: FFVII

Posted: 15th Dec 2011 16:03

Link

Hmm will keep an eye on this although U do have ezrotate already...

Back to top

Profile PM

MadBit

VIP Member

Gold Codemaster

15

Years of Service

User Offline

Joined: 25th Jun 2009

Location: Germany

Posted: 15th Dec 2011 19:54

Link

Quote: "Hmm will keep an eye on this although U do have ezrotate already..."

No I have not ezrotate but a friend. So I had an overview to the demos of ezrotate.

With Computers you can solve Problems that you have never befor.
Share your knowledge. It's a way to achieve immortality. (Tenzin Gyatso)

Back to top

Profile PM Email

MrValentine

AGK Backer

13

Years of Service

User Offline

Joined: 5th Dec 2010

Playing: FFVII

Posted: 15th Dec 2011 20:14

Link

LOL sorry typo... supposed to say I do have ezrotate... wrote that last night... sorry...

Back to top

Profile PM

TheComet

17

Years of Service

User Offline

Joined: 18th Oct 2007

Location: I`m under ur bridge eating ur goatz.

Posted: 15th Dec 2011 20:20

Link

Nice work! This is a really useful piece of software you made, well done

Thanks!

TheComet

Back to top

Profile PM Email Website

gwheycs62egydws

15

Years of Service

User Offline

Joined: 17th Aug 2009

Location: The World

Posted: 5th Feb 2012 10:39

Link

@MadBit

I would like to get it but can't

umm I'm not shire if you herd Megaupload is out of services

so downloading your plugin is not an option unless you post to this forum post of yours

to move side ways - is to move forward
Since a Strait line gets thin fast

Back to top

Profile PM Email

MadBit

VIP Member

Gold Codemaster

15

Years of Service

User Offline

Joined: 25th Jun 2009

Location: Germany

Posted: 6th Feb 2012 09:08

Link

Sorry about the inconveniences.

I have now changed the Hoster see the first post.
And, thanks for the tip.

With Computers you can solve Problems that you have never befor.
Share your knowledge. It's a way to achieve immortality. (Tenzin Gyatso)

Back to top

Profile PM Email

gwheycs62egydws

15

Years of Service

User Offline

Joined: 17th Aug 2009

Location: The World

Posted: 6th Feb 2012 09:41

Link

@MadBit

thanks

stuff happens

at leas you got it posted ;o)

I was just wondering why you have not posted it in the forums ?

I own EZ-Rotate and the missle to ship example I was tweaking
I had two missles following the ship and I could control the ship speed
the next part I was working on was getting the misiles to stay a distance from each other

thanks for your work

to move side ways - is to move forward
Since a Strait line gets thin fast

Back to top

Profile PM Email

gwheycs62egydws

15

Years of Service

User Offline

Joined: 17th Aug 2009

Location: The World

Posted: 7th Feb 2012 00:44 Edited at: 7th Feb 2012 01:08

Link

@MadBit

I've been playing with Radar example

I upped the following
1. number of Meteor's to 700 - no major loss of cps
2. Radar Range - 3000

but I wanted to add was to find out which object was the farthest away

+ Code Snippet

 `Get the farthest asteroid as target with key 'F'.
 IF KEYSTATE(33) = 1 AND press = 0
  dist# = 50000.0
  FOR n = 1 TO objID_NumAstro
   IF Asteroids(n).fDistance# > dist# 
    dist# = Asteroids(n).fDistance#
    target = n
   ENDIF
  NEXT n
  press = 33
 ELSE
  IF KEYSTATE(33) = 0 AND press = 33 THEN press = 0
 ENDIF

dose not seam to work

the next part was to add to the menu and I made a function to
make it simpler to do

aaa nope that dose not work either

My math looks like it's correct

+ Code Snippet

function SpY(LoY)
SyL=15
Nip=LpL+(LoY*SyL)
center text PiA , Nip , Rd$

this is what it should do but dose not
`set cursor 320,85
`print Rd$

endfunction

remstart

FUNCTION PrintInfo()
PiA=320:LpL=85

 box 100, 100, 540, 395, 0x7f007f00, 0x7f007f00, 0x7f007f00, 0x7f007f00
 INK 0xffffff00, 0
 
 Rd$="Demonstrate Some cool Functions":SpY(1) 
 Rd$="-------------------------------------------------------":SpY(2) 
 Rd$="[E]-get closest asteroid.":SpY(3) 
 Rd$="[F]-get Farthest asteroid.":SpY(4) 
 Rd$="[R]-change scaner-range.":SpY(5) 
 Rd$="[mouse-wheel]-set speed.":SpY(6) 
 Rd$="[mouse]-control the ship.":SpY(7) 
 Rd$="[mouse-button-middle]-set speed to zero.":SpY(8) 
 Rd$="I had seen the 'Example5' of EZ-Rotate. Well, this is":SpY(9) 
 Rd$="my version of it.":SpY(10) 
 Rd$="Asteroids rotating via vector-rotation and moving with":SpY(11) 
 Rd$="directional-vectors. Calculation of Scanner objects":SpY(12) 
 Rd$="with CALC ABSOLUT/RELATIVE POINT.":SpY(13)

ENDFUNCTION

can some one tell me what I did wrong or whats missing

the original F1 pop up menu

+ Code Snippet

FUNCTION PrintInfo()
    box 100, 100, 540, 395, 0x7f007f00, 0x7f007f00, 0x7f007f00, 0x7f007f00
    INK 0xffffff00, 0
    CENTER TEXT 320, 100, "Demonstrate Some cool Functions"
    CENTER TEXT 320, 115, "-------------------------------------------------------"
    CENTER TEXT 320, 145, "[E]-get closest asteroid."
    CENTER TEXT 320, 160, "[R]-change scaner-range."
    CENTER TEXT 320, 175, "[mouse-wheel]-set speed."
    CENTER TEXT 320, 190, "[mouse]-control the ship."
    CENTER TEXT 320, 205, "[mouse-button-middle]-set speed to zero."
    CENTER TEXT 320, 235, "I had seen the 'Example5' of EZ-Rotate. Well, this is"
    CENTER TEXT 320, 250, "my version of it."
    CENTER TEXT 320, 280, "Asteroids rotating via vector-rotation and moving with"
    CENTER TEXT 320, 295, "directional-vectors. Calculation of Scanner objects"
    CENTER TEXT 320, 310, "with CALC ABSOLUT/RELATIVE POINT."
ENDFUNCTION

to move side ways - is to move forward
Since a Strait line gets thin fast

Back to top

Profile PM Email

MadBit

VIP Member

Gold Codemaster

15

Years of Service

User Offline

Joined: 25th Jun 2009

Location: Germany

Posted: 7th Feb 2012 09:08 Edited at: 7th Feb 2012 09:09

Link

@Resourceful

The asteroids are randomly set in a radius of 1000.0 units. Which provides that all asteroids are closer to 50000.0 units. So put 0.0 on initial dist# then it should work

.

the second ...
i'm not so familar with DB i programming mainly in C/C++. I don't know what your code will do. But here is my solution for this what i mean you wanted to achieve!??

first init string-table

+ Code Snippet

`Info-Text init
GLOBAL numInfoLines
READ numInfoLines
DIM infoText$(numInfoLines) AS STRING
FOR i=0 TO numInfoLines
	READ infoText$(i)
NEXT i

`Numbers of lines for output
DATA 14
`Text for output
DATA "Demonstrate Some cool Functions"
DATA "-------------------------------------------------------"
DATA ""
DATA "[E]-get closest asteroid."
DATA "[R]-change scaner-range."
DATA "[mouse-wheel]-set speed."
DATA "[mouse]-control the ship."
DATA "[mouse-button-middle]-set speed to zero."
DATA ""
DATA "I had seen the 'Example5' of EZ-Rotate. Well, this is"
DATA "my version of it."
DATA "Asteroids rotating via vector-rotation and moving with"
DATA "directional-vectors. Calculation of Scanner objects"
DATA "with CALC ABSOLUT/RELATIVE POINT."

and than output so ...

+ Code Snippet

FUNCTION PrintInfo()
	box 100, 100, 540, 380, 0x7f007f00, 0x7f007f00, 0x7f007f00, 0x7f007f00
	INK 0xffffff00, 0
	
	FOR i=0 TO numInfoLines
		CENTER TEXT 320, 100 + i*15, infoText$(i)
	NEXT i
ENDFUNCTION

With Computers you can solve Problems that you have never befor.
Share your knowledge. It's a way to achieve immortality. (Tenzin Gyatso)

Back to top

Profile PM Email

gwheycs62egydws

15

Years of Service

User Offline

Joined: 17th Aug 2009

Location: The World

Posted: 7th Feb 2012 12:51

Link

@MadBit

ok I understand

the only thing what I programed for the displaying text should work
apparently only in theory

2 more things I want to add to this example are

Show locked target on main viewer
Store target location to F4 TO F7

this should not take me long to add

the now old x-wing and tie fighter game had this
and with this example I can play around with it so to speak

Again thanks for creating the plugin and the example

to move side ways - is to move forward
Since a Strait line gets thin fast

Back to top

Profile PM Email

gwheycs62egydws

15

Years of Service

User Offline

Joined: 17th Aug 2009

Location: The World

Posted: 7th Feb 2012 13:02

Link

ummm the function I had created
was to calculate ware to place the line of text to be displayed

but for some reason it was not doing that

to move side ways - is to move forward
Since a Strait line gets thin fast

Back to top

Profile PM Email

Sergey K

20

Years of Service

User Offline

Joined: 4th Jan 2004

Location:

Posted: 7th Feb 2012 17:47

Link

for those persons who never used ez rotate and we have no idea what neither of those does, can you tell us?

more 3d models .x/.obj and more foramts here:
[href]https://www.turbosquid.com/Search/Index.cfm?keyword=gogetax1&x=0&y=0[href]

Back to top

Profile PM Website

MadBit

VIP Member

Gold Codemaster

15

Years of Service

User Offline

Joined: 25th Jun 2009

Location: Germany

Posted: 7th Feb 2012 19:54

Link

That adds many special rotation und other math's commands to DBPro.
See the first post. The commands under XROT are special rotation commands. I think the names of the commands are nearly selfexplained.

Section DXVEC3, DXMAT, DXQUAT and DXPLANE are wrapped from the DirectX-SDK. I think this can be useful for the one or other.

Section DBOBJ and DBCAM are for easy access from/to DB Object's/Camera's with DXMAT ore DXVEC3

With Computers you can solve Problems that you have never befor.
Share your knowledge. It's a way to achieve immortality. (Tenzin Gyatso)

Back to top

Profile PM Email

freight hopper

20

Years of Service

User Offline

Joined: 26th Dec 2003

Location: Just beyond the Dunsmuir yard limits

Posted: 27th Mar 2012 23:52 Edited at: 27th Mar 2012 23:54

Link

Hi Madbit. I am trying to contact you about a couple of questions I have about your XML plugin. Unfortunately, the "Yet another XML-Plugin" thread is now locked and I don't want to hi-jack this thread. Shall I post a question in the DBPro forum and you can respond there? Or if you want to post an e-mail address . . . (maybe not).

Back to top

Profile PM Email

MadBit

VIP Member

Gold Codemaster

15

Years of Service

User Offline

Joined: 25th Jun 2009

Location: Germany

Posted: 28th Mar 2012 09:47

Link

Less than 6 months without any thread activity and he's already locked? this must be a joke.

Sure you can post your question in the PBPro-Forum. i keep an eye on this forum.

With Computers you can solve Problems that you have never befor.
Share your knowledge. It's a way to achieve immortality. (Tenzin Gyatso)

Back to top

Profile PM Email

gwheycs62egydws

15

Years of Service

User Offline

Joined: 17th Aug 2009

Location: The World

Posted: 8th Jul 2012 10:00

Link

@MadBit

I need some help with anther plugin of yours
"billboard-plugin"

I get runtime error 7008 - object dose not exist at line 55: object number not found: 1

"billboard-plugin\Projects\Billboard-Examples\Example1" "Example1"

I'm using it in windows 7 but I know it worked in windows xp

to move side ways - is to move forward
Since a Strait line gets thin fast

Back to top

Profile PM Email

MadBit

VIP Member

Gold Codemaster

15

Years of Service

User Offline

Joined: 25th Jun 2009

Location: Germany

Posted: 9th Jul 2012 12:49

Link

Hmm, i can't reproduce this error. I also work with windows 7. what happens if you commenting out this line?

the source must look like this.

`Example1
`Example1.dba
`======================

animSpeed = 100
animFrame = 0

SYNC ON
SYNC RATE 60

SET WINDOW OFF

ENABLE BILLBOARDS

LOAD IMAGE "./../../../media/textures/Explo0.png", 1
CREATE ANIMATED BILLBOARD 1, 1, 8, 4
ANIMATION SPEED BILLBOARD 1, animSpeed
SET OBJECT TRANSPARENCY 1, 1
SET OBJECT LIGHT  1, 0

DO
	`Space to play animation once
	IF SPACEKEY() = 1 THEN PLAY BILLBOARD 1
	
	`F1 to lopp animation
	IF KEYSTATE(59) = 1 THEN LOOP BILLBOARD 1
	`F2 to stop animation
	IF KEYSTATE(60) = 1 THEN STOP BILLBOARD 1 : animFrame = GET BILLBOARD FRAME(1)

`[Num +] to increase the delay between two frames of animation
	IF KEYSTATE(78) = 1 THEN INC animSpeed : ANIMATION SPEED BILLBOARD 1, animSpeed
	`[Num -] to decrease the delay between two frames of animation
	IF KEYSTATE(74) = 1 THEN DEC animSpeed : ANIMATION SPEED BILLBOARD 1, animSpeed
	
	IF BILLBOARD PLAYING(1) = 0
		`[PgUp] to increase animation frame.
		IF KEYSTATE(201) = 1 THEN INC animFrame : SET BILLBOARD FRAME 1, animFrame
		`[PgDown] to decrease animation frame.
		IF KEYSTATE(209) = 1 THEN DEC animFrame : SET BILLBOARD FRAME 1, animFrame
		
		IF animFrame < 0 THEN animFrame = animFrame + (8*4)
		IF animFrame > (8*4) THEN animFrame = animFrame - (8*4)
	ENDIF
	
	move# = move# + MOUSEMOVEZ() / 10000.0
	mx# = mx# + MOUSEMOVEX() / 10.0
	my# = my# + MOUSEMOVEY() / 10.0

ROTATE CAMERA my#, mx#, 0
	MOVE CAMERA move#
	
	CENTER TEXT SCREEN WIDTH()/2, 0, "Frame :" + STR$(GET BILLBOARD FRAME(1)) + " Animation Speed :" + STR$(BILLBOARD ANIMATION SPEED(1))

UPDATE BILLBOARDS 0
    
	SYNC
LOOP

+ Code Snippet

`Example1
`Example1.dba
`======================

animSpeed = 100
animFrame = 0

SYNC ON
SYNC RATE 60

SET WINDOW OFF

ENABLE BILLBOARDS

LOAD IMAGE "./../../../media/textures/Explo0.png", 1
CREATE ANIMATED BILLBOARD 1, 1, 8, 4
ANIMATION SPEED BILLBOARD 1, animSpeed
SET OBJECT TRANSPARENCY 1, 1
SET OBJECT LIGHT  1, 0


DO
	`Space to play animation once
	IF SPACEKEY() = 1 THEN PLAY BILLBOARD 1
	
	`F1 to lopp animation
	IF KEYSTATE(59) = 1 THEN LOOP BILLBOARD 1
	`F2 to stop animation
	IF KEYSTATE(60) = 1 THEN STOP BILLBOARD 1 : animFrame = GET BILLBOARD FRAME(1)

	`[Num +] to increase the delay between two frames of animation
	IF KEYSTATE(78) = 1 THEN INC animSpeed : ANIMATION SPEED BILLBOARD 1, animSpeed
	`[Num -] to decrease the delay between two frames of animation
	IF KEYSTATE(74) = 1 THEN DEC animSpeed : ANIMATION SPEED BILLBOARD 1, animSpeed
	
	IF BILLBOARD PLAYING(1) = 0
		`[PgUp] to increase animation frame.
		IF KEYSTATE(201) = 1 THEN INC animFrame : SET BILLBOARD FRAME 1, animFrame
		`[PgDown] to decrease animation frame.
		IF KEYSTATE(209) = 1 THEN DEC animFrame : SET BILLBOARD FRAME 1, animFrame
		
		IF animFrame < 0 THEN animFrame = animFrame + (8*4)
		IF animFrame > (8*4) THEN animFrame = animFrame - (8*4)
	ENDIF
	
	move# = move# + MOUSEMOVEZ() / 10000.0
	mx# = mx# + MOUSEMOVEX() / 10.0
	my# = my# + MOUSEMOVEY() / 10.0

	ROTATE CAMERA my#, mx#, 0
	MOVE CAMERA move#
	
	CENTER TEXT SCREEN WIDTH()/2, 0, "Frame :" + STR$(GET BILLBOARD FRAME(1)) + " Animation Speed :" + STR$(BILLBOARD ANIMATION SPEED(1))

	UPDATE BILLBOARDS 0
    
	SYNC
LOOP

With Computers you can solve Problems that you have never befor.
Share your knowledge. It's a way to achieve immortality. (Tenzin Gyatso)

Back to top

Profile PM Email

Olby

21

Years of Service

User Offline

Joined: 21st Aug 2003

Location:

Posted: 9th Jul 2012 13:45

Link

Well done MadBit! Looks really good. Can you please attach it to any of your posts so it's not lost when the file sharing site goes bust (as most do recently). Thanks!

Intel Core2Duo 2.2GHZ, 2GB, GeForce 8600M GT 1280MB, Windows Vista Ultimate SP2, PureBasic 4.61 + DarkGDK 2.0

Back to top

Profile PM Website

MadBit

VIP Member

Gold Codemaster

15

Years of Service

User Offline

Joined: 25th Jun 2009

Location: Germany

Posted: 9th Jul 2012 14:10

Link

@ Olby: done!

With Computers you can solve Problems that you have never befor.
Share your knowledge. It's a way to achieve immortality. (Tenzin Gyatso)

Attachments

Login to view attachments

Back to top

Profile PM Email

gwheycs62egydws

15

Years of Service

User Offline

Joined: 17th Aug 2009

Location: The World

Posted: 10th Jul 2012 04:21

Link

@MadBit

every line is as it appears in the example

I did a copy and past of what you posted

if I turn off the loop the error dose not come up

I know this happens some time ago with 2 other plug-in's
ware it too plug-in's needed a tiny word change to work

but in this case it comes as file not found

to move side ways - is to move forward
Since a Strait line gets thin fast

Back to top

Profile PM Email

gwheycs62egydws

15

Years of Service

User Offline

Joined: 17th Aug 2009

Location: The World

Posted: 10th Jul 2012 04:37

Link

@@MadBit

the second example in the folder works
unless some thing in DBP 7.62 had changed

it seems there is a problem loading file ;o(

sorry it was not your files

to move side ways - is to move forward
Since a Strait line gets thin fast

Back to top

Profile PM Email

gwheycs62egydws

15

Years of Service

User Offline

Joined: 17th Aug 2009

Location: The World

Posted: 10th Jul 2012 04:47

Link

@MadBit

what chanced in extendetrotation-plugin_[en]_20111215.zip ?
since the other one i got worked perfectly

to move side ways - is to move forward
Since a Strait line gets thin fast

Back to top

Profile PM Email

MadBit

VIP Member

Gold Codemaster

15

Years of Service

User Offline

Joined: 25th Jun 2009

Location: Germany

Posted: 11th Jul 2012 23:21 Edited at: 11th Jul 2012 23:22

Link

Quote: "what chanced in extendetrotation-plugin_[en]_20111215.zip ?"

This is embarrassing me now. I can't remember me. That's what happens when you do not write a change log.

what a shame.
I think the changes was nothing important.

With Computers you can solve Problems that you have never befor.
Share your knowledge. It's a way to achieve immortality. (Tenzin Gyatso)

Back to top

Profile PM Email

Sorry your browser is not supported!

Program Announcements / [DBPro plugin] eXtendet Rotation

Attachments

Attachments