Oops, didn't read your original post properly.
The Comet's post had a few errors in the code:
make bitmap
should be:
create bitmap
and then you need to use a SET CURRENT BITMAP command after it otherwise everything still gets drawn to the screen.
There was quite a good post regarding memblocks, detailing the bitmap / image memblock structure:
http://forum.thegamecreators.com/?m=forum_view&t=172867&b=1
A slight modification to the code I posted creates a bitmap from the stitched together images and then turn this bitmap into a memblock but it still uses the paste image command:
set window off
hide mouse
image_size = 200
tile_size = 10
num_tiles = image_size / tile_size
`+++++++++++++++++++++++++++++++++++++++
`+++++++++++++++++++++++++++++++++++++++
`make some images (you can replace this entire block of code with loading your own images)
`three images are created: a red, green and purple square. Each square 10 x 10 pixels
`this has now been modified to create a new bitmap and do all the drawing to that bitmap so it won't get
`drawn to the screen
create bitmap 1, screen width(), screen height()
set current bitmap 1
ink rgb(255,0,0),0
box 0,0,tile_size,tile_size
get image 1,0,0,tile_size,tile_size
cls
ink rgb(0,255,0),0
box 0,0,tile_size,tile_size
get image 2,0,0,tile_size,tile_size
cls
ink rgb(0,255,255),0
box 0,0,tile_size,tile_size
get image 3,0,0,tile_size,tile_size
cls
delete bitmap 1
`+++++++++++++++++++++++++++++++++++++++
`+++++++++++++++++++++++++++++++++++++++
`past the tiles to the current bitmap
`again, another bitmap has been created so nothing is drawn to screen
create bitmap 1 , image_size , image_size
set current bitmap 1
restore _tile_placement_data
for y = 1 to num_tiles
for x = 1 to num_tiles
read tile
paste image tile, (x-1)*tile_size,(y-1)*tile_size
next x
next y
`delete the images
for i = 1 to 3
delete image i
next i
`set the current bitmap to the screen
set current bitmap 0
`make a memblock from the bitmap that was created from the stitched up images
make memblock from bitmap 1,1
`get the header data from the memblock
width = memblock dword(1,0)
height = memblock dword(1,4)
depth = memblock dword(1,8)
print "memblock data"
print
print "width : ", width
print "height : ", height
print "depth : ", depth
print
print "data for the first pixel in the image (top left)"
print "blue : ", memblock byte(1,12)
print "green : ", memblock byte(1,13)
print "red : ", memblock byte(1,14)
print "alpha : ", memblock byte(1,15)
print
print "data for the second pixel in the image"
print "blue : ", memblock byte(1,16)
print "green : ", memblock byte(1,17)
print "red : ", memblock byte(1,18)
print "alpha : ", memblock byte(1,19)
print
print "and so on..."
print
print "Press any key to continue"
wait key
cls
`make an image from the memblock
make image from memblock 1, 1
`paste the image to the screen
paste image 1, 0,0
set cursor 0,250
print "this image is created from the memblock data"
wait key
end
_tile_placement_data:
data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
data 1,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,1
data 1,2,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,1
data 1,2,3,2,2,2,2,2,2,2,2,2,2,2,2,2,2,3,2,1
data 1,2,3,2,1,1,1,1,1,1,1,1,1,1,1,1,2,3,2,1
data 1,2,3,2,1,1,1,1,1,1,1,1,1,1,1,1,2,3,2,1
data 1,2,3,2,2,2,2,2,2,2,2,2,2,2,2,2,2,3,2,1
data 1,2,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,1
data 1,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,1
data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
data 1,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,1
data 1,2,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,1
data 1,2,3,2,2,2,2,2,2,2,2,2,2,2,2,2,2,3,2,1
data 1,2,3,2,1,1,1,1,1,1,1,1,1,1,1,1,2,3,2,1
data 1,2,3,2,1,1,1,1,1,1,1,1,1,1,1,1,2,3,2,1
data 1,2,3,2,2,2,2,2,2,2,2,2,2,2,2,2,2,3,2,1
data 1,2,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,3,2,1
data 1,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,2,1
data 1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1,1
I've been looking at doing this with memblocks only but it's getting late and I really need to get some sleep. If I can figure it out I'll post. But, hopefully, TheComet will beat me to it and I can have a nice restful sunday
