Sorry your browser is not supported!

rem Terrain Functionality
rem Standard Setup Code for all examples
sync on : sync rate 0 : color backdrop 0
set text font "arial" : set text size 16
set text to bold : set text transparent
autocam off
rem Make Simple Terrain
MatrixNumber=1
size# = 12800.0
ry# = 0.0
make Matrix MatrixNumber,size#,size#,64,64
rem Position The Terrain
rem base matrix position in world
maty# = 0.0
position matrix matrixNumber, 0, maty#, 0

rem **** Texture terrain ****

ImageNumber=1
texnumber = 0
rem load image "grass.bmp",ImageNumber
rem prepare matrix texture matrixnumber,imagenumber,1,1
rem fill matrix matrixnumber,0#,1
load image "losd.bmp",ImageNumber
load image "sky01.bmp",2
prepare matrix texture MatrixNumber,imageNumber,64,64
set matrix texture matrixnumber,2,0
tc=1
for nz = 0 to 63
   nx = 63
   while nx>=0
      set matrix tile MatrixNumber,nx,nz,tc
      inc tc : dec nx
   endwhile
next nz

update matrix MatrixNumber

rem Load sky object
make object sphere 1,int(size#)
scale object 1,50,10,50
rem set object cull 1,0
set object light 1,0
set object texture 1,2,1
set object cull 1,0
texture object 1,2
set object rotation xyz 1
position object 1,size#/2,10.0,size#/2
rem Position camera in center of terrain
position camera size#/2,10.0+maty#,size#/2
set camera range 0.1, 5000.0
rem Main loop
desc$="LOD Matrix"

while mouseclick()=0

rem Control camera over terrain
control camera using arrowkeys 0,2,2

rem remember that the camera works in full 3d space
rem and the matrix commands are relative to itself
rem a matrix at 0,8,0 will still return 0 for hieght if it is flat

cx#=camera position x(0)
cz#=camera position z(0)

rem limit the camera to the edges of the matrix
if cx#<0.0 then cx#=0.0
if cx#>size# then cx#=size#
if cz#<0.0 then cz#=0.0
if cz#>size# then cz#=size#
cy# = get ground height (MatrixNumber,cx#,cz#)
cy# = cy# + 10.0
position camera cx#,cy#+maty#,cz#

rem Terrain Data
set cursor 0,0
print "MATRIX DATA"
print " exist:";matrix exist(matrixNumber)
if matrix exist(matrixNumber)=1
 print " x:";matrix position x(matrixNumber)
 print " y:";matrix position y(matrixNumber)
 print " z:";matrix position z(matrixNumber)
 print " height:";get ground height(matrixnumber,cx#,cz#)
 endif
print
print "CAMERA DATA"
print " x:";camera position x(0)
print " y:";camera position y(0)
print " z:";camera position z(0)
print "Tile count: ";matrix tile count(matrixnumber)
print "Mat height at x,z: ";get ground height (matrixnumber,6400.0,6400.0)
rem Position sky at player
position object 1,camera position x(0),camera position y(0)-150,camera position z(0)
update matrix matrixnumber
rx# = rx# + .001
xrotate object 1,rx#
if rx#>=359.9 then rx# = 0

rem Raising ground height
if controlkey() = 1
   rem raise the ground under the camera
   set matrix height matrixnumber,32,32,100.0
   update matrix matrixnumber
endif
rem Show Framerate
text 20,screen height()-40,desc$
fps$="DBPro Fps: "+str$(screen fps())
text screen width()-20-text width(fps$),screen height()-40,fps$
rem Update screen
sync
rem End loop
endwhile
rem Delete matrix
delete matrix matrixNumber

ms=5000 : mt=60
sync on : sync rate 0 : autocam off : randomize timer()

w=4 : h=4 : r=64
create bitmap 1,w*r,h*r
for f=1 to h
   for g=1 to w
      b=rnd(255) : ink rgb(b,b,b),rgb(0,0,0) : box (g-1)*r,(f-1)*r,g*r,f*r
   next g
next f
for f=1 to (w*h*10)
   a1=rnd(w*r) : b1=rnd(h*r) : c1=rnd(20)+2 : d1=rnd(20)+2
   ink rgb(rnd(255),rnd(255),rnd(255)),rgb(0,0,0)
   box a1,b1,a1+c1,b1+d1
next f
get image 1,0,0,w*r,h*r,1 : delete bitmap 1

make matrix 1,ms,ms,mt,mt
prepare matrix texture 1,1,w,h
for f=0 to (mt-1)
   for g=0 to (mt-1)
      set matrix tile 1,f,g,rnd((w*h)-1)+1
   next g
next f
set matrix trim 1,0.1,0.1
for f=1 to rnd(20)
randomize matrix 1,2000
next f
smooth_matrix(1,mt,mt,6)

` set normals
for x=0 to mt
   for y=0 to mt
      a=get matrix height(1,x,y)
      if x < mt and y < mt
         b=get matrix height(1,x+1,y+1)
      endif
      dif=a-b
      x#=1-sin(dif*2) : y#=x# : z#=x#
      set matrix normal 1,x,y,x#,y#,z#
   next y
next x

update matrix 1
position camera 20,0,20

do
   control camera using arrowkeys 0,5,3
   cx#=camera position x()
   cz#=camera position z()
   h#=get ground height(1,cx#,cz#)
   position camera cx#,h#+50,cz#
   text 0,0,str$(h#)
   sync
loop

function smooth_matrix(matnum,tilex,tilez,times)
   for multiple=1 to times
      for x=1 to tilex-1
         for z=1 to tilez-1
            a=get matrix height(matnum,x-1,z+1)
            b=get matrix height(matnum,x,z+1)
            c=get matrix height(matnum,x+1,z+1)
            d=get matrix height(matnum,x+1,z)
            e=get matrix height(matnum,x+1,z-1)
            f=get matrix height(matnum,x,z-1)
            g=get matrix height(matnum,x-1,z-1)
            h=get matrix height(matnum,x-1,z)
            total=a+b+c+d+e+f+g+h
            av#=total/8
            set matrix height matnum,x,z,av#
         next z
      next x
      for x=0 to tilex
         set matrix height matnum,x,0,get matrix height(matnum,x,1)
         set matrix height matnum,x,tilez,get matrix height(matnum,x,tilez-1)
      next x
      for z=0 to tilez
         set matrix height matnum,0,z,get matrix height(matnum,1,z)
         set matrix height matnum,tilex,z,get matrix height(matnum,tilex-1,z)
      next z
   next multiple
   update matrix matnum
endfunction