Sorry your browser is not supported!

sync on
sync rate 60
autocam off
hide mouse

_main:
   gosub _init
   position camera 500,50,100

   do
      gosub _move_target
      gosub _shoot
      sync
   loop
end


_init:
   rem make a matrix for reference
   make matrix 1,1000,1000,25,25

   rem make something to hit
   make object cube 1,50
   color object 1,0

   rem make a gun
   make object cylinder 2,6
   scale object 2,100,300,100
   xrotate object 2,90
   lock object on 2
   position object 2,0,-5,14

   rem make a projectile
   make object sphere 3,5
   set object rotation zyx 2

   rem target direction
   xdir=5
   x#=500
   z#=800
   y#=25

   rem projectyle speed
   speed#=20
return

_move_target:
   inc x#,xdir
   if x# > 900 or x# < 100 then xdir=0-xdir

   position object 1,x#,y#,z#

return

_shoot:
   rem get the slope between the proectile speed and the enemy speed
   rem this can be pre calculated but will do it here for the example
   leadang#=atanfull(xdir,speed#)

   rem find angle between camera and target
   cang#=wrapvalue(atanfull(x#-camera position x(),z#-camera position z())+leadang#)

   rem rotate camera
   yrotate camera cang#

   rem shoot
   if shot=0
      color object 1,0
      position object 3, camera position x(),camera position y(),camera position z()
      set object to camera orientation 3
      shot=1
   endif
   if shot and object position z(3) < 1000
      move object 3,speed#
      bang = object collision(3,1)
   else
      shot=0
   endif

   text 0,0,str$(cang#)
   if bang
      color object 1,rgb(255,255,0)
   endif

return


function dist(obj)
   dx#=object position x(obj)-camera position x()
   dz#=object position z(obj)-camera position z()
   dist#=sqrt((dx#*dx#)+(dz#*dz#))
endfunction dist#

`%Project Title%
`%Source File Name%
`======================
type vec2
	x as float
	y as float
endtype
type obj
	pos as vec2
	vel as vec2
endtype

global obj1 as obj //guy being shot at
global obj2 as obj //guy shooting
global bullet as obj 
global bulletvel as float
global time as integer
time=timer()
bulletvel=50

do
	cls
	moveAll()
	if spacekey()
		obj1.pos.x=rnd(screen width()/2)+screen width()/4
		obj1.pos.y=rnd(screen height()/2)+screen height()/4
		obj2.pos.x=rnd(screen width()/2)+screen width()/4
		obj2.pos.y=rnd(screen height()/2)+screen height()/4
		obj1.vel.x=rnd(50)-25
		obj1.vel.y=rnd(50)-25
		recalculateVel()
	endif
	drawAll()
	sync
loop
exit

function moveAll()
	dt as float
	dt=(timer()-time)/1000.0
	time=timer()
	
	obj1.pos.x=obj1.pos.x+obj1.vel.x*dt
	obj1.pos.y=obj1.pos.y+obj1.vel.y*dt
	
	obj2.pos.x=obj2.pos.x+obj2.vel.x*dt
	obj2.pos.y=obj2.pos.y+obj2.vel.y*dt
	
	bullet.pos.x=bullet.pos.x+bullet.vel.x*dt
	bullet.pos.y=bullet.pos.y+bullet.vel.y*dt
	
	if obj1.pos.x>screen width()
		obj1.pos.x=0
		recalculateVel()
	endif
	if obj1.pos.y>screen height()
		obj1.pos.y=0
		recalculateVel()
	endif
	if obj1.pos.x<0
		obj1.pos.x=screen width()
		recalculateVel()
	endif
	if obj1.pos.y<0
		obj1.pos.y=screen height()
		recalculateVel()
	endif
	
	
	if obj2.pos.x>screen width()
		obj2.pos.x=0
		recalculateVel()
	endif
	if obj2.pos.y>screen height()
		obj2.pos.y=0
		recalculateVel()
	endif
	if obj2.pos.x<0
		obj2.pos.x=screen width()
		recalculateVel()
	endif
	if obj2.pos.y<0
		obj2.pos.y=screen height()
		recalculateVel()
	endif
	
	if bullet.pos.x>screen width()
		bullet.pos.x=0
		recalculateVel()
	endif
	if bullet.pos.y>screen height()
		bullet.pos.y=0
		recalculateVel()
	endif
	if bullet.pos.x<0
		bullet.pos.x=screen width()
		recalculateVel()
	endif
	if bullet.pos.y<0
		bullet.pos.y=screen height()
		recalculateVel()
	endif
endfunction
function drawAll()
	ink rgb(0,255,0),0
	circle obj1.pos.x,obj1.pos.y,10
	ink rgb(255,255,0),0
	circle obj2.pos.x,obj2.pos.y,10
	ink rgb(255,255,255),0
	circle bullet.pos.x,bullet.pos.y,3
endfunction

function recalculateVel()
	t as float
	t=calculateT()
	bullet.pos.x=obj2.pos.x
	bullet.pos.y=obj2.pos.y
	dposx#=obj1.pos.x-obj2.pos.x+obj1.vel.x*t
	dposy#=obj1.pos.y-obj2.pos.y+obj1.vel.y*t
	d#=sqrt(dposx#*dposx#+dposy#*dposy#)
	bullet.vel.x=dposx#*bulletvel/d#
	bullet.vel.y=dposy#*bulletvel/d#
endfunction

function calculateT()
	a as float
	b as float
	c as float
	
	a=obj1.vel.x*obj1.vel.x+obj1.vel.y*obj1.vel.y-bulletvel*bulletvel
	b=2*obj1.vel.x*(obj1.pos.x-obj2.pos.x)+2*obj1.vel.y*(obj1.pos.y-obj2.pos.y)
	c=(obj1.pos.x-obj2.pos.x)*(obj1.pos.x-obj2.pos.x)+(obj1.pos.y-obj2.pos.y)*(obj1.pos.y-obj2.pos.y)
	disc as float
	disc=b*b-4*a*c
	if disc<0
		exitfunction -1.0
	endif
	disc=sqrt(disc)
	t1 as float
	t2 as float
	t1=.5*(-b+disc)/a
	t2=.5*(-b-disc)/a
	if t1>0 and t2>0
		if rnd(1)
			exitfunction t1
		else
			exitfunction t2
		endif
	endif
	if t1>0 then exitfunction t1
	if t2>0 then exitfunction t2
endfunction 0.0

find distance between turret and enemy
divide distance by speed of projectile = initial number of frames
how far will enemy move in that number of frames?
   move enemy espeed*frames
point turret at the new enemy position
move enemy back to start

adjusted frames = future distance of enemy to turret / projectile speed