Dark Occlusion Problem - GameCreators Forum

Author

Message

Gunslinger

19

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 29th Mar 2012 13:15

Link

Hello,
i got a problem with Dark Occlusion. I want to setup a 99^99 object area, but it needs soooo long to setup with DC.

x as integer
		y as integer
		x = 0 : y = 0
		make object plain 1, 75,75
		make object box 2, 75,75,75
		
		// Floor
		for i = 1 to 99
			for t = 1 to 99
				cls
				print "Creating Floor: " + str$(i) + "/" + str$(t)
				ObjID = FreeObject()
				y = y + 75
				clone object ObjID, 1
				position object ObjID, x,y,0
				print "Setting up Floor: " + str$(i) + "/" + str$(t)				 
				 // Add the object to the Dark Occlusion Library
				 OC_AddObject(ObjID)
				 
				// Set the object to be dynamic
				OC_SetObjectDynamic(ObjID)

// Add bounds to the object
				OC_SetObjectBounds(ObjID, 0)	
								
				sync
			next t
			
			x = x + 75
			y = 0
		next i
		
		//No Floor
		i = 1 : t = 1
		x = 0 : y = 0

for i = 1 to 99
			for t = 1 to 99
				cls
				print "Creating Block: " + str$(i) + "/" + str$(t)
				ObjID = FreeObject()
				y = y + 75
				clone object ObjID, 2
				position object ObjID, x,y,0
				 print "Setting up Block: " + str$(i) + "/" + str$(t)
				 // Add the object to the Dark Occlusion Library
				 OC_AddObject(ObjID)
				 
				// Set the object to be dynamic
				OC_SetObjectDynamic(ObjID)

// Add bounds to the object
				OC_SetObjectBounds(ObjID, 0)				
				
				GameObject(ObjID).type# = 2 // Bla
				position object ObjID, x,y,38
				
				sync
			next t
			
			x = x + 75
			y = 0
		next i

+ Code Snippet

		x as integer
		y as integer
		x = 0 : y = 0
		make object plain 1, 75,75
		make object box 2, 75,75,75
		
		// Floor
		for i = 1 to 99
			for t = 1 to 99
				cls
				print "Creating Floor: " + str$(i) + "/" + str$(t)
				ObjID = FreeObject()
				y = y + 75
				clone object ObjID, 1
				position object ObjID, x,y,0
				print "Setting up Floor: " + str$(i) + "/" + str$(t)				 
				 // Add the object to the Dark Occlusion Library
				 OC_AddObject(ObjID)
				 
				// Set the object to be dynamic
				OC_SetObjectDynamic(ObjID)

				// Add bounds to the object
				OC_SetObjectBounds(ObjID, 0)	
								
				sync
			next t
			
			x = x + 75
			y = 0
		next i
		
		//No Floor
		i = 1 : t = 1
		x = 0 : y = 0

		for i = 1 to 99
			for t = 1 to 99
				cls
				print "Creating Block: " + str$(i) + "/" + str$(t)
				ObjID = FreeObject()
				y = y + 75
				clone object ObjID, 2
				position object ObjID, x,y,0
				 print "Setting up Block: " + str$(i) + "/" + str$(t)
				 // Add the object to the Dark Occlusion Library
				 OC_AddObject(ObjID)
				 
				// Set the object to be dynamic
				OC_SetObjectDynamic(ObjID)

				// Add bounds to the object
				OC_SetObjectBounds(ObjID, 0)				
				
				GameObject(ObjID).type# = 2 // Bla
				position object ObjID, x,y,38
				
				sync
			next t
			
			x = x + 75
			y = 0
		next i

somebody knows whats wrong?

Back to top

Profile PM

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 29th Mar 2012 13:31

Link

Are you using OC_BeginLoading() and OC_FinishLoading()?

Back to top

Profile PM

Gunslinger

19

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 29th Mar 2012 13:34 Edited at: 29th Mar 2012 13:49

Link

Tried it, still slow

edit: Okay, that code above is slow because of the sync and print.

Without Sync, Print and Dark Occlusion it loads in about 10 Seconds.

With Dark Occlusion it needs a loooong time. Try it...

Back to top

Profile PM

MrValentine

AGK Backer

15

Years of Service

User Offline

Joined: 5th Dec 2010

Playing: FFVII

Posted: 29th Mar 2012 14:58

Link

Gunslinger... what is your...

OS
CPU
MOBO
RAM
HDD

makes and part numbers... use CPU-Z to get most of this information

is your hard drive sata I or sata II?
is your RAM DDR I or DDR II or even DDR III?

Might as well throw your GPU in there too

I can not check your code right now but read Max Ps message above regarding the begin and finish commands...

Back to top

Profile PM

Gunslinger

19

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 29th Mar 2012 15:15

Link

SATA II i guess, not sure.

Back to top

Profile PM

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 29th Mar 2012 15:18 Edited at: 29th Mar 2012 15:18

Link

It loads in 1 min 50 sec here. Runs at 50-200 fps.
The loading is quite long, but Dark Occlusion wasn't really made to handle thousands of cubes, I might add an instance/clone object command in the future to speed these things up.
You can try to group the cubes together

Back to top

Profile PM

MrValentine

AGK Backer

15

Years of Service

User Offline

Joined: 5th Dec 2010

Playing: FFVII

Posted: 29th Mar 2012 15:34

Link

Gunslinger, yeah I suppose your hardware is fine, and seeing as Max ran it for over a minute too, can someone put the full code together for me to test... I will copy the OC folder into a new project folder just its been a while as I have been doing web development for a few weeks now...

Back to top

Profile PM

Max P

16

Years of Service

User Offline

Joined: 23rd Jan 2010

Location:

Posted: 29th Mar 2012 15:39

Link

@MrValentine
You might have to change the open console, print console and find free object()

#Include "Dark Occlusion/Dark_Occlusion/Dark_Occlusion.dba"
OC_Init()

sync on
sync rate 0

open console

x as integer
y as integer
x = 0 : y = 0
make object plain 1, 75,75
make object box 2, 75,75,75

objCount = 99

OC_BeginLoading()

// Floor
for i = 1 to objCount
    for t = 1 to objCount
        `cls
        `print "Creating Floor: " + str$(i) + "/" + str$(t)
        ObjID = find free object()
        y = y + 75
        clone object ObjID, 1
        position object ObjID, x,y,0
        `print "Setting up Floor: " + str$(i) + "/" + str$(t)                 
         // Add the object to the Dark Occlusion Library
         OC_AddObject(ObjID)
         
        // Set the object to be dynamic
        OC_SetObjectStatic(ObjID)

// Add bounds to the object
        OC_SetObjectBounds(ObjID, 0)    
                        
        `sync
    next t
    
    x = x + 75
    y = 0
    print console i : print console
next i

//No Floor
i = 1 : t = 1
x = 0 : y = 0

for i = 1 to objCount
    for t = 1 to objCount
        `cls
        `print "Creating Block: " + str$(i) + "/" + str$(t)
        ObjID = find free object()
        y = y + 75
        clone object ObjID, 2
        position object ObjID, x,y,0
         `print "Setting up Block: " + str$(i) + "/" + str$(t)
         // Add the object to the Dark Occlusion Library
         OC_AddObject(ObjID)
         
        // Set the object to be dynamic
        OC_SetObjectStatic(ObjID)

// Add bounds to the object
        OC_SetObjectBounds(ObjID, 0)                
        
        position object ObjID, x,y,38
        
        `sync
    next t
    
    x = x + 75
    y = 0
    print console i : print console
next i

OC_FinishLoading()

dt as float
time as float

Do
    dt = (timer() - time) * 0.001
    time = timer()
    
    set cursor 0, 0
    print "FPS: ", screen fps()
    print "Polygons: ", statistic(1)
    
    if upkey() then move camera 100*dt
    if downkey() then move camera -100*dt
    
    rotate camera camera angle x() + mousemovey() * .2, camera angle y() + mousemovex() * .2, 0
    
    OC_Update()
    Sync
Loop

+ Code Snippet

#Include "Dark Occlusion/Dark_Occlusion/Dark_Occlusion.dba"
OC_Init()

sync on
sync rate 0

open console

x as integer
y as integer
x = 0 : y = 0
make object plain 1, 75,75
make object box 2, 75,75,75

objCount = 99

OC_BeginLoading()

// Floor
for i = 1 to objCount
    for t = 1 to objCount
        `cls
        `print "Creating Floor: " + str$(i) + "/" + str$(t)
        ObjID = find free object()
        y = y + 75
        clone object ObjID, 1
        position object ObjID, x,y,0
        `print "Setting up Floor: " + str$(i) + "/" + str$(t)                 
         // Add the object to the Dark Occlusion Library
         OC_AddObject(ObjID)
         
        // Set the object to be dynamic
        OC_SetObjectStatic(ObjID)

        // Add bounds to the object
        OC_SetObjectBounds(ObjID, 0)    
                        
        `sync
    next t
    
    x = x + 75
    y = 0
    print console i : print console
next i

//No Floor
i = 1 : t = 1
x = 0 : y = 0

for i = 1 to objCount
    for t = 1 to objCount
        `cls
        `print "Creating Block: " + str$(i) + "/" + str$(t)
        ObjID = find free object()
        y = y + 75
        clone object ObjID, 2
        position object ObjID, x,y,0
         `print "Setting up Block: " + str$(i) + "/" + str$(t)
         // Add the object to the Dark Occlusion Library
         OC_AddObject(ObjID)
         
        // Set the object to be dynamic
        OC_SetObjectStatic(ObjID)

        // Add bounds to the object
        OC_SetObjectBounds(ObjID, 0)                
        
        position object ObjID, x,y,38
        
        `sync
    next t
    
    x = x + 75
    y = 0
    print console i : print console
next i

OC_FinishLoading()


dt as float
time as float

Do
    dt = (timer() - time) * 0.001
    time = timer()
    
    set cursor 0, 0
    print "FPS: ", screen fps()
    print "Polygons: ", statistic(1)
    
    if upkey() then move camera 100*dt
    if downkey() then move camera -100*dt
    
    rotate camera camera angle x() + mousemovey() * .2, camera angle y() + mousemovex() * .2, 0
    
    OC_Update()
    Sync
Loop

Back to top

Profile PM

MrValentine

AGK Backer

15

Years of Service

User Offline

Joined: 5th Dec 2010

Playing: FFVII

Posted: 29th Mar 2012 16:26

Link

I do have Matrix1Utils you know

[it is your fault that I do have it lol]

yeah this is strangely slow

took about a minute to load all objects even for me...

thanks Max

and Gunslinger, why not try creating a .dbo cube and load that 99 times instead?

Back to top

Profile PM

Gunslinger

19

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 29th Mar 2012 18:16

Link

Because the cubes are just a test.

Back to top

Profile PM

MrValentine

AGK Backer

15

Years of Service

User Offline

Joined: 5th Dec 2010

Playing: FFVII

Posted: 29th Mar 2012 20:00

Link

Still worth a go using premade objects and use instancing for benching the various methods... maybe even try memblocks...

Back to top

Profile PM

Gunslinger

19

Years of Service

User Offline

Joined: 29th May 2007

Location:

Posted: 29th Mar 2012 20:32 Edited at: 29th Mar 2012 20:34

Link

Well, the problem is, i don't even know if i'll use normal objects.
I want to create a dungeon keeper like map, and at the moment i don't know wich technic to use for creating something like that.

The blocks are changing each time you destroy (or build) a block next to it.

At least, 99^99 is not even close to the final map size. I'm targeting around 125^125 * 3 as size (3 layers).
Somebody knows Dungeon Keeper (How the blocks are changing) and got an idea how to recreate this? As a Matrix? Vertex modification? I have no clue at the moment.

With 99^99 and with normal cubes i got around 15 fps, even with occlusion culling.

Back to top

Profile PM

Seppuku Arts

Moderator

21

Years of Service

User Offline

Joined: 18th Aug 2004

Location: Cambridgeshire, England

Posted: 29th Mar 2012 22:00

Link

What you could do is use segments light Neverwinter Nights does...or FPSC for that matter. It means you can reuse parts you've already created too.

Josh Mooney actually did a segment modelling tutorial a while back (on his old account):

http://forum.thegamecreators.com/?m=forum_view&t=103187&b=3

Then as these are separate objects, Dark Occlusion ought to work (if you feel you need it).

What you could also do is code a basic placement editor that uses a grid for placing each segment piece and have it write to a file that you could code a function in your main project file to read. If you keep the size of each segment consistent and have each space in the grid equal to that set size then your segments ought to be seamless.

That's if you felt like doing it that way.

Back to top

Profile PM Website

Andrew_Neale

16

Years of Service

User Offline

Joined: 3rd Nov 2009

Location: The Normandy SR-2

Posted: 29th Mar 2012 23:03 Edited at: 29th Mar 2012 23:53

Link

Here is a quick example I just knocked together of how you could look to handle such a large grid of objects.

#constant TRUE 1
#constant FALSE 0

#constant MEDIACONTROL_MAX_OBJECT = 65535
#constant MEDIACONTROL_MAX_IMAGE = 200

disable escapeKey
autoCam off
set normalization on

set display mode 1024, 768, 32

set window on
set window title "Dungeon Keeper"

sync on
sync rate 0

sync
center text 512, 384, "LOADING..."
sync

type type_floatXYZ
    x as float
    y as float
    z as float
endType

type type_camera
    angle as type_floatXYZ
    position as type_floatXYZ
endType

type type_gridTile
    exist as boolean
    position as type_floatXYZ
    objectID as integer
    visible as boolean
endType

type type_mediaControl
    freeImageID as integer
    freeObjectID as integer
endType

global mediaControl as type_mediaControl

global camera as type_camera
camera.angle.x = 50
camera.angle.y = 0
camera.angle.z = 0
camera.position.x = 0
camera.position.y = 50
camera.position.z = 0

global firstGridObjectID as integer
global lastGridObjectID as integer
global maxRealGridObjects as integer
maxRealGridObjects = 200
isFirst = TRUE
for o = 1 to maxRealGridObjects
    tObject = mediaControl_freeObjectID()
    if (isFirst = FALSE)
        clone object tObject, 1
        lastGridObjectID = tObject
    else
        make object box tObject, 8, 8, 8
        firstGridObjectID = tObject
        isFirst = FALSE
    endIf
next o

global dim grid(100, 100) as type_gridTile
for x = 0 to 99
    for z = 0 to 99
        grid(x, z).exist = TRUE
        grid(x, z).position.x = (x * 10) + 5
        grid(x, z).position.y = 0
        grid(x, z).position.z = (z * 10) + 5        
    next z
next x

repeat

camera_update()
    grid_update()
    
    text 0, 0, str$(screen fps())

sync

until (escapeKey() = TRUE)

end

function camera_update()
    inc camera.position.x, mouseMoveX()
    dec camera.position.z, mouseMoveY()
    if (camera.position.x < -20)
        camera.position.x = -20
    endIf
    if (camera.position.x > 1020)
        camera.position.x = 1020
    endIf
    if (camera.position.z < -20)
        camera.position.z = -20
    endIf
    if (camera.position.z > 1020)
        camera.position.z = 1020
    endIf
    position camera camera.position.x, camera.position.y, camera.position.z
    rotate camera camera.angle.x, camera.angle.y, camera.angle.z
endFunction

function grid_update()
    local lowX as integer
    local lowZ as integer
    local highX as integer
    local highZ as integer
    lowX = (camera.position.x / 10) - 6
    if (lowX < 0)
        lowX = 0
    endIf
    lowZ = (camera.position.z / 10)
    if (lowZ < 0)
        lowZ = 0
    endIf
    highX = (camera.position.x / 10) + 6
    if (highX > 99)
        highX = 99
    endIf
    highZ = (camera.position.z / 10) + 13
    if (highZ > 99)
        highZ = 99
    endIf
    local currentObjectID as integer
    currentObjectID = firstGridObjectID
    for x = 0 to 99
        for z = 0 to 99
            if (grid(x, z).exist = TRUE)
                if (x >= lowX)
                    if (z >= lowZ)
                        if (x <= highX)
                            if (z <= highZ)
                                position object currentObjectID, grid(x, z).position.x, grid(x, z).position.y, grid(x, z).position.z
                                inc currentObjectID
                                if (currentObjectID > lastGridObjectID)
                                    exitFunction
                                endIf
                            endIf
                        endIf
                    endIf
                endIf
            endIf
        next z
    next x
endFunction

function mediaControl_freeImageID()
    local i as integer
    repeat
        inc mediaControl.freeImageID
		if (mediaControl.freeImageID > MEDIACONTROL_MAX_IMAGE)
			mediaControl.freeImageID = 1
		endIf
        inc i
        if (i > MEDIACONTROL_MAX_IMAGE)
            exit prompt "Media Control > Ran out of images", "Error"
            end
        endIf
    until (object exist(mediaControl.freeImageID) = FALSE)
endFunction mediaControl.freeImageID

function mediaControl_freeObjectID()
    local i as integer
    repeat
        inc mediaControl.freeObjectID
		if (mediaControl.freeObjectID > MEDIACONTROL_MAX_OBJECT)
			mediaControl.freeObjectID = 1
		endIf
        inc i
        if (i > MEDIACONTROL_MAX_OBJECT)
            exit prompt "Media Control > Ran out of objects", "Error"
            end
        endIf
    until (object exist(mediaControl.freeObjectID) = FALSE)
endFunction mediaControl.freeObjectID

+ Code Snippet

#constant TRUE 1
#constant FALSE 0

#constant MEDIACONTROL_MAX_OBJECT = 65535
#constant MEDIACONTROL_MAX_IMAGE = 200

disable escapeKey
autoCam off
set normalization on

set display mode 1024, 768, 32

set window on
set window title "Dungeon Keeper"

sync on
sync rate 0

sync
center text 512, 384, "LOADING..."
sync

type type_floatXYZ
    x as float
    y as float
    z as float
endType

type type_camera
    angle as type_floatXYZ
    position as type_floatXYZ
endType

type type_gridTile
    exist as boolean
    position as type_floatXYZ
    objectID as integer
    visible as boolean
endType

type type_mediaControl
    freeImageID as integer
    freeObjectID as integer
endType

global mediaControl as type_mediaControl

global camera as type_camera
camera.angle.x = 50
camera.angle.y = 0
camera.angle.z = 0
camera.position.x = 0
camera.position.y = 50
camera.position.z = 0

global firstGridObjectID as integer
global lastGridObjectID as integer
global maxRealGridObjects as integer
maxRealGridObjects = 200
isFirst = TRUE
for o = 1 to maxRealGridObjects
    tObject = mediaControl_freeObjectID()
    if (isFirst = FALSE)
        clone object tObject, 1
        lastGridObjectID = tObject
    else
        make object box tObject, 8, 8, 8
        firstGridObjectID = tObject
        isFirst = FALSE
    endIf
next o

global dim grid(100, 100) as type_gridTile
for x = 0 to 99
    for z = 0 to 99
        grid(x, z).exist = TRUE
        grid(x, z).position.x = (x * 10) + 5
        grid(x, z).position.y = 0
        grid(x, z).position.z = (z * 10) + 5        
    next z
next x

repeat

    camera_update()
    grid_update()
    
    text 0, 0, str$(screen fps())

    sync

until (escapeKey() = TRUE)

end

function camera_update()
    inc camera.position.x, mouseMoveX()
    dec camera.position.z, mouseMoveY()
    if (camera.position.x < -20)
        camera.position.x = -20
    endIf
    if (camera.position.x > 1020)
        camera.position.x = 1020
    endIf
    if (camera.position.z < -20)
        camera.position.z = -20
    endIf
    if (camera.position.z > 1020)
        camera.position.z = 1020
    endIf
    position camera camera.position.x, camera.position.y, camera.position.z
    rotate camera camera.angle.x, camera.angle.y, camera.angle.z
endFunction

function grid_update()
    local lowX as integer
    local lowZ as integer
    local highX as integer
    local highZ as integer
    lowX = (camera.position.x / 10) - 6
    if (lowX < 0)
        lowX = 0
    endIf
    lowZ = (camera.position.z / 10)
    if (lowZ < 0)
        lowZ = 0
    endIf
    highX = (camera.position.x / 10) + 6
    if (highX > 99)
        highX = 99
    endIf
    highZ = (camera.position.z / 10) + 13
    if (highZ > 99)
        highZ = 99
    endIf
    local currentObjectID as integer
    currentObjectID = firstGridObjectID
    for x = 0 to 99
        for z = 0 to 99
            if (grid(x, z).exist = TRUE)
                if (x >= lowX)
                    if (z >= lowZ)
                        if (x <= highX)
                            if (z <= highZ)
                                position object currentObjectID, grid(x, z).position.x, grid(x, z).position.y, grid(x, z).position.z
                                inc currentObjectID
                                if (currentObjectID > lastGridObjectID)
                                    exitFunction
                                endIf
                            endIf
                        endIf
                    endIf
                endIf
            endIf
        next z
    next x
endFunction

function mediaControl_freeImageID()
    local i as integer
    repeat
        inc mediaControl.freeImageID
		if (mediaControl.freeImageID > MEDIACONTROL_MAX_IMAGE)
			mediaControl.freeImageID = 1
		endIf
        inc i
        if (i > MEDIACONTROL_MAX_IMAGE)
            exit prompt "Media Control > Ran out of images", "Error"
            end
        endIf
    until (object exist(mediaControl.freeImageID) = FALSE)
endFunction mediaControl.freeImageID

function mediaControl_freeObjectID()
    local i as integer
    repeat
        inc mediaControl.freeObjectID
		if (mediaControl.freeObjectID > MEDIACONTROL_MAX_OBJECT)
			mediaControl.freeObjectID = 1
		endIf
        inc i
        if (i > MEDIACONTROL_MAX_OBJECT)
            exit prompt "Media Control > Ran out of objects", "Error"
            end
        endIf
    until (object exist(mediaControl.freeObjectID) = FALSE)
endFunction mediaControl.freeObjectID

It will obviously need some work. In this example you have a fixed number of real objects which are repositioned as required to look like a much larger grid. Because of how much the camera is zoomed out in this example you can see the blocks jump around but this is intentional so you can see it working.

Whilst this would need a bit of work to get it to match your needs entirely, this example runs at 1600 fps for me rather than the 15 fps you mentioned. Let me know if you need any more info.

Thanks.

[Edit]P.S. Move the mouse to move the camera about![/Edit]

Back to top

Profile PM Email Website

Sorry your browser is not supported!

DarkBASIC Professional Discussion / Dark Occlusion Problem